docs/manual/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # TODO: Consider whether this could just be replaced by using
  36 # GMX_DEVELOPER_BUILD to control this as well.
  37 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  38 mark_as_advanced(GMX_BUILD_MANUAL)
  39
  40 set(MANUAL_BUILD_IS_POSSIBLE ON)
  41 set(IMAGE_CONVERT_POSSIBLE ON)
  42 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
  43 set(NO_IMAGE_CONVERT_REASON)
  44 if (NOT GMX_BUILD_MANUAL)
  45     # Make sure we only do detection of manual-building dependencies
  46     # when the user opted in for that.
  47     set(MANUAL_BUILD_IS_POSSIBLE OFF)
  48     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
  49 elseif (BUILD_IS_INSOURCE)
  50     # UseLATEX.cmake does not work with an in-source build
  51     set(MANUAL_BUILD_IS_POSSIBLE OFF)
  52     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
  53 else()
  54     include(UseLATEX.cmake)
  55
  56     if(NOT SPHINX_FOUND)
  57         set(MANUAL_BUILD_IS_POSSIBLE OFF)
  58         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "Sphinx has not been found and is needed to create the LaTex input files")
  59     endif()
  60
  61     if(NOT PDFLATEX_COMPILER OR NOT IMAGEMAGICK_CONVERT)
  62         set(MANUAL_BUILD_IS_POSSIBLE OFF)
  63         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex or some other dependency (ImageMagick convert) is not available")
  64         if (NOT IMAGEMAGICK_CONVERT)
  65             set(IMAGE_CONVERT_POSSIBLE OFF)
  66             set(NO_IMAGE_CONVERT_REASON "Can not convert files for online or pdf manual")
  67         endif()
  68         # TODO Later, identify other dependencies like bibtex,
  69         # make_index, date, some graphics conversion program,
  70         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
  71     endif()
  72
  73 endif()
  74
  75 if(MANUAL_BUILD_IS_POSSIBLE)
  76     add_custom_command(
  77         OUTPUT ${SPHINX_LATEX_FILE}
  78         DEPENDS sphinx-programs sphinx-input
  79         COMMAND
  80             ${SPHINX_EXECUTABLE}
  81             -q -E -b latex
  82             -w sphinx-latex.log
  83             -d "${SPHINX_CACHE_DIR}"
  84             "${SPHINX_INPUT_DIR}"
  85             "${TEX_OUTPUT_DIR}"
  86         WORKING_DIRECTORY
  87             ${CMAKE_CURRENT_BINARY_DIR}
  88         COMMENT "Preparing PDF manual LaTeX input files"
  89         VERBATIM
  90         )
  91
  92
  93     LATEX_GET_OUTPUT_PATH(output_dir)
  94
  95     # Avoid generating a global "html" target that clashes with the
  96     # html target from program generation of help text in share/html.
  97     set(LATEX2HTML_CONVERTER off)
  98
  99     # This helps make the index look decent.
 100     set(MAKEINDEX_COMPILER_FLAGS -s ${CMAKE_CURRENT_SOURCE_DIR}/hfill.ist)
 101     # UseLATEX.cmake is hacked to call Anton Feenstra's subindex script
 102     # to improve the index generation and to use the Sphinx generated
 103     # gromacs.tex file. Don't replace UseLATEX.cmake
 104     # blindly from upstream!
 105
 106     # An explicit "make manual" will still be required for the manual
 107     # to be built.
 108
 109     # TODO The whole script needs to be part of a subprocess called at make
 110     # time so that the generated gromacs.tex file is available for ADD_LATEX_DOCUMENT
 111     # when it searches for it.
 112     # Note: The gromacs.tex file is not actually copied by the UseLatex.cmake script,
 113     # but generated by Sphinx during the make step.
 114     ADD_LATEX_DOCUMENT(gromacs.tex
 115         DEPENDS ${SPHINX_LATEX_FILE}
 116         DEFAULT_PDF
 117         )
 118
 119     # Finally, the command to build the manual.
 120
 121     add_custom_target(manual
 122         DEPENDS pdf
 123         )
 124 else()
 125         add_custom_target(manual
 126         COMMAND ${CMAKE_COMMAND} -E echo
 127         "Cannot build PDF manual, because ${MANUAL_BUILD_NOT_POSSIBLE_REASON}"
 128         VERBATIM)
 129 endif()
 130
 131 set(MANUAL_BUILD_IS_POSSIBLE ${MANUAL_BUILD_IS_POSSIBLE} PARENT_SCOPE)
 132 set(IMAGE_CONVERT_POSSIBLE ${IMAGE_CONVERT_POSSIBLE} PARENT_SCOPE)