docs/SphinxMacros.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2015,2016,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CMakeParseArguments)
  36
  37 macro(gmx_init_sphinx_setup SPHINX_INPUT_DIR)
  38     set(_SPHINX_INPUT_ROOT ${SPHINX_INPUT_DIR})
  39     set(_SPHINX_INPUT_FILES)
  40     set(_SPHINX_IMAGE_CONVERSION_FILES)
  41 endmacro()
  42
  43 macro(gmx_add_sphinx_input_file FILEPATH)
  44     list(APPEND _SPHINX_INPUT_FILES ${FILEPATH})
  45 endmacro()
  46
  47 function(gmx_add_sphinx_source_files)
  48     set(_one_value_args FROM TO PREFIX)
  49     cmake_parse_arguments(ARG "" "${_one_value_args}" "FILES" ${ARGN})
  50     if (NOT ARG_FROM)
  51         set(ARG_FROM ${CMAKE_CURRENT_SOURCE_DIR})
  52     endif()
  53     if (ARG_TO)
  54         set(ARG_TO ${ARG_TO}/)
  55     endif()
  56     foreach(_file ${ARG_FILES})
  57         set(_source ${ARG_FROM}/${_file})
  58         set(_target ${_SPHINX_INPUT_ROOT}/${ARG_TO}${_file})
  59         add_custom_command(
  60             OUTPUT  ${_target}
  61             COMMAND ${CMAKE_COMMAND} -E copy ${_source} ${_target}
  62             DEPENDS ${_source}
  63             COMMENT "Copying Sphinx input file ${ARG_PREFIX}${_file}"
  64             VERBATIM)
  65         list(APPEND _SPHINX_INPUT_FILES ${_target})
  66     endforeach()
  67     set(_SPHINX_INPUT_FILES "${_SPHINX_INPUT_FILES}" PARENT_SCOPE)
  68 endfunction()
  69
  70 macro(gmx_remove_obsolete_sphinx_input_files IGNORE_PATTERN)
  71     file(GLOB_RECURSE _obsolete_sources ${_SPHINX_INPUT_ROOT}/*.rst)
  72     list(REMOVE_ITEM _obsolete_sources ${_SPHINX_INPUT_FILES})
  73     foreach(_file ${_obsolete_sources})
  74         file(RELATIVE_PATH _rel_path ${_SPHINX_INPUT_ROOT} ${_file})
  75         if (NOT _rel_path MATCHES "${IGNORE_PATTERN}")
  76             message(STATUS "Removing obsolete Sphinx input ${_rel_path}")
  77             file(REMOVE ${_file})
  78         endif()
  79     endforeach()
  80 endmacro()
  81
  82 macro(gmx_add_sphinx_input_target TARGETNAME)
  83     gmx_add_custom_output_target(${TARGETNAME} OUTPUT STAMP
  84         DEPENDS ${_SPHINX_INPUT_FILES})
  85 endmacro()
  86
  87 function(gmx_add_sphinx_image_conversion_files)
  88     set(_one_value_args FROM TO PREFIX)
  89     cmake_parse_arguments(ARG "" "${_one_value_args}" "FILES" ${ARGN})
  90     if (NOT ARG_FROM)
  91         set(ARG_FROM ${CMAKE_CURRENT_SOURCE_DIR})
  92     endif()
  93     if (ARG_TO)
  94         set(ARG_TO ${ARG_TO}/)
  95     endif()
  96     foreach(_file ${ARG_FILES})
  97         set(_source ${ARG_FROM}/${_file})
  98         string(REGEX REPLACE "pdf" "png" _tmp ${_file})
  99         set(_target ${_SPHINX_INPUT_ROOT}/${ARG_TO}${_tmp})
 100         add_custom_command(
 101             OUTPUT  ${_target}
 102             COMMAND convert ${_source} -antialias -quality 03 -quiet -pointsize 12 -density 1200 -units PixelsPerInch  ${_target}
 103             DEPENDS ${_source}
 104             COMMENT "Converting Sphinx input graphics file ${_file} to png"
 105             VERBATIM)
 106         list(APPEND _SPHINX_IMAGE_CONVERSION_FILES ${_target})
 107     endforeach()
 108     set(_SPHINX_IMAGE_CONVERSION_FILES "${_SPHINX_IMAGE_CONVERSION_FILES}" PARENT_SCOPE)
 109 endfunction()
 110
 111 macro(gmx_add_sphinx_image_conversion_target TARGETNAME)
 112     gmx_add_custom_output_target(${TARGETNAME} OUTPUT STAMP
 113         DEPENDS ${_SPHINX_IMAGE_CONVERSION_FILES})
 114 endmacro()