CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012, by the GROMACS development team, led by
   5 # David van der Spoel, Berk Hess, Erik Lindahl, and including many
   6 # others, as listed in the AUTHORS file in the top-level source
   7 # directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34 #
  35 cmake_minimum_required(VERSION 2.8)
  36 # Keep CMake suitably quiet on Cygwin
  37 set(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  38
  39 # Allows CPack to act differently for normal tools and mdrun (e.g. because of MPI)
  40 set(CPACK_COMPONENT_GROUP_TOOLS_DESCRIPTION "All GROMACS executable tools")
  41 set(CPACK_COMPONENT_GROUP_MDRUN_DESCRIPTION "GROMACS executable for running simulations")
  42
  43 # CMake modules/macros are in a subdirectory to keep this file cleaner
  44 # This needs to be set before project() in order to pick up toolchain files
  45 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  46
  47 project(Gromacs C)
  48 include(Dart)
  49 mark_as_advanced(DART_ROOT)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 set(PROJECT_VERSION "4.6-beta3-dev")
  60 set(CUSTOM_VERSION_STRING ""
  61     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  62 mark_as_advanced(CUSTOM_VERSION_STRING)
  63 if (CUSTOM_VERSION_STRING)
  64     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  65 endif (CUSTOM_VERSION_STRING)
  66 set(SOVERSION 6)
  67 # It is a bit irritating, but this has to be set separately for now!
  68 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  69 SET(CPACK_PACKAGE_VERSION_MINOR "6")
  70 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  71
  72 # The numerical gromacs version. It is 40600 for 4.6.0.
  73 # The #define GMX_VERSION in gmx_header_config_h is set to this value.
  74 math(EXPR NUM_VERSION
  75     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  76 if(CPACK_PACKAGE_VERSION_PATCH)
  77     math(EXPR NUM_VERSION
  78          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  79 endif()
  80
  81 # The API version tracks the numerical Gromacs version (for now).
  82 # It is potentially different from the Gromacs version in the future, if
  83 # the programs/libraries diverge from the presumably more stable API.
  84 # The #define GMX_API_VERSION in version.h is set to this value to
  85 # provide backward compatibility of software written against the Gromacs API.
  86 set(API_VERSION ${NUM_VERSION})
  87
  88 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  89 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  90 endif()
  91
  92 include(gmxBuildTypeReference)
  93
  94 if(NOT CMAKE_BUILD_TYPE)
  95     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
  96 endif(NOT CMAKE_BUILD_TYPE)
  97
  98 enable_language(C)
  99
 100 set(GMX_USE_RELATIVE_INSTALL_PATH OFF CACHE STRING "Use relative paths not absolute paths for cmake install. Has only an effect on cpack.")
 101 mark_as_advanced(GMX_USE_RELATIVE_INSTALL_PATH)
 102
 103 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 104 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 105 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 106 if (NOT GMX_USE_RELATIVE_INSTALL_PATH)
 107     set(CPACK_SET_DESTDIR "ON")
 108 endif()
 109 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 110 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 111 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 112 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 113 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 114 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 115 SET(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/man;man")
 116 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 117
 118 #must come after all cpack settings!
 119 include(CPack)
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsitencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # User input options - enable C++ - before any CXX flags are changed   #
 140 ########################################################################
 141
 142 # decide on GPU settings based on user-settings and GPU/CUDA detection
 143 include(gmxManageGPU)
 144
 145 # TODO: move OpenMM to contrib
 146 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (not fully supported)" OFF)
 147 mark_as_advanced(GMX_OPENMM)
 148
 149 option(GMX_FORCE_CXX "Enable C++ compilation even if not necessary" OFF)
 150 mark_as_advanced(GMX_FORCE_CXX)
 151
 152 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 153 mark_as_advanced(GMX_COOL_QUOTES)
 154
 155 if(GMX_GPU OR GMX_OPENMM OR GMX_FORCE_CXX)
 156     enable_language(CXX)
 157 endif()
 158 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 159
 160 ########################################################################
 161 # User input options                                                   #
 162 ########################################################################
 163 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 164 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 165 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 166 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 167 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 168 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 169 mark_as_advanced(GMX_FAHCORE)
 170
 171 include(gmxDetectAcceleration)
 172 if(NOT DEFINED GMX_CPU_ACCELERATION)
 173     if(CMAKE_CROSSCOMPILING)
 174         set(GMX_SUGGESTED_CPU_ACCELERATION "None")
 175     else(CMAKE_CROSSCOMPILING)
 176         gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 177     endif(CMAKE_CROSSCOMPILING)
 178 endif(NOT DEFINED GMX_CPU_ACCELERATION)
 179
 180 set(GMX_CPU_ACCELERATION "@GMX_SUGGESTED_CPU_ACCELERATION@"
 181     CACHE STRING "Accelerated CPU kernels. Pick one of: None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 182
 183 set(GMX_FFT_LIBRARY "fftw3"
 184     CACHE STRING "FFT library choices: fftw3,mkl,fftpack[built-in]")
 185 option(GMX_BUILD_OWN_FFTW "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack." OFF)
 186 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 187 option(GMX_DISABLE_FFTW_MEASURE
 188        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 189 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 190 set(GMX_QMMM_PROGRAM "none"
 191     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 192 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 193 mark_as_advanced(GMX_BROKEN_CALLOC)
 194 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 195 mark_as_advanced(GMX_MPI_IN_PLACE)
 196 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 197 mark_as_advanced(GMX_LOAD_PLUGINS)
 198
 199 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 200
 201 option(USE_VERSION_H "Generate development version string/information" ON)
 202 mark_as_advanced(USE_VERSION_H)
 203
 204 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 205
 206 if(UNIX)
 207     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static archives (not available on non-*nix platforms and it will only work if static versions of external dependencies are available and found)!" OFF)
 208     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 209 endif()
 210
 211 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 212 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 213
 214 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 215 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 216
 217 ######################################################################
 218 # Compiler tests
 219 # These need to be done early (before further tests).
 220 #####################################################################
 221
 222 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 223 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 224 # invalid options with the Intel Compilers.
 225 # These files should be removed from the source tree when a CMake version that
 226 # includes the features in question becomes required for building GROMACS.
 227 include(CheckCCompilerFlag)
 228 if(CMAKE_CXX_COMPILER_LOADED)
 229     include(CheckCXXCompilerFlag)
 230 endif()
 231
 232 # OpenMP check must come before other CFLAGS!
 233 if(GMX_OPENMP)
 234     find_package(OpenMP)
 235     if(OPENMP_FOUND)
 236         # CMake on Windows doesn't support linker flags passed to target_link_libraries
 237         # (i.e. it treats /openmp as \openmp library file). Also, no OpenMP linker flags are needed.
 238         if(NOT (WIN32 AND NOT CYGWIN))
 239             if(CMAKE_COMPILER_IS_GNUCC AND GMX_PREFER_STATIC_OPENMP)
 240                 set(OpenMP_LINKER_FLAGS "-Wl,-static -lgomp -lrt -Wl,-Bdynamic -lpthread")
 241                 set(OpenMP_SHARED_LINKER_FLAGS "")
 242             else()
 243                 # Only set a linker flag if the user didn't set them manually
 244                 if(NOT DEFINED OpenMP_LINKER_FLAGS)
 245                     set(OpenMP_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 246                 endif()
 247                 if(NOT DEFINED OpenMP_SHARED_LINKER_FLAGS)
 248                     set(OpenMP_SHARED_LINKER_FLAGS "${OpenMP_C_FLAGS}")
 249                 endif()
 250             endif()
 251         endif()
 252     else(OPENMP_FOUND)
 253         message(WARNING
 254                 "The compiler you are using does not support OpenMP parallelism. This might hurt your performance a lot, in particular with GPUs. Try using a more recent version, or a different compiler. For now, we are proceeding by turning off OpenMP.")
 255         set(GMX_OPENMP OFF CACHE STRING "Whether GROMACS will use OpenMP parallelism." FORCE)
 256     endif(OPENMP_FOUND)
 257 endif()
 258
 259
 260 include(gmxCFlags)
 261 gmx_c_flags()
 262
 263 include(gmxGetCompilerInfo)
 264 get_compiler_version()
 265
 266 # gcc 4.4.x is buggy and crashes when compiling some files with O3 and OpenMP on.
 267 # Detect here whether applying a workaround is needed and will apply it later
 268 # on the affected files.
 269 include(gmxGCC44O3BugWorkaround)
 270 gmx_check_gcc44_bug_workaround_needed(GMX_USE_GCC44_BUG_WORKAROUND)
 271
 272 # clang 3.0 is buggy for some unknown reason detected during adding
 273 # the SSE2 group kernels for GROMACS 4.6. If we ever work out what
 274 # that is, we should replace these tests with a compiler feature test,
 275 # update GROMACS Redmine task #1039 and perhaps report a clang bug.
 276 #
 277 # In the meantime, until we require CMake 2.8.10 we cannot rely on it to detect
 278 # the compiler version for us. So we need a manual check for clang 3.0.
 279 include(gmxDetectClang30)
 280 gmx_detect_clang_3_0(COMPILER_IS_CLANG_3_0)
 281 if(COMPILER_IS_CLANG_3_0)
 282     message(FATAL_ERROR "Your compiler is clang version 3.0, which is known to be buggy for GROMACS. Use a different compiler.")
 283 endif()
 284
 285 if (CMAKE_C_COMPILER_ID STREQUAL "PGI")
 286     message(WARNING "All tested PGI compiler versions (up to 12.9.0) generate binaries which produce incorrect results, or even fail to compile Gromacs. Highly recommended to use a different compiler. If you choose to use PGI, make sure to run the regressiontests.")
 287 endif()
 288
 289 ########################################################################
 290 # Set up binary and library suffixing
 291 ########################################################################
 292 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 293 set(GMX_LIBS_SUFFIX ""
 294   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 295 if (GMX_DEFAULT_SUFFIX)
 296   set(GMX_BINARY_SUFFIX "")
 297   set(GMX_LIBS_SUFFIX "")
 298   if (GMX_MPI)
 299     set(GMX_BINARY_SUFFIX "_mpi")
 300     set(GMX_LIBS_SUFFIX "_mpi")
 301   endif(GMX_MPI)
 302   if (GMX_DOUBLE)
 303     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 304     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 305   endif(GMX_DOUBLE)
 306   if (GMX_OPENMM)
 307     set (GMX_BINARY_SUFFIX "-openmm")
 308     set (GMX_LIBS_SUFFIX "_openmm")
 309   endif(GMX_OPENMM)
 310   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 311   if (NOT SUFFIX_QUIETLY)
 312     message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 313     message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 314   endif (NOT SUFFIX_QUIETLY)
 315 else(GMX_DEFAULT_SUFFIX)
 316   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 317   if (NOT SUFFIX_QUIETLY)
 318     message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 319     message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 320   endif (NOT SUFFIX_QUIETLY)
 321 endif(GMX_DEFAULT_SUFFIX)
 322 set(SUFFIX_QUIETLY TRUE CACHE INTERNAL "")
 323
 324 set(PKG_CFLAGS "")
 325 if(GMX_DOUBLE)
 326     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 327 endif(GMX_DOUBLE)
 328 if(GMX_SOFTWARE_INVSQRT)
 329   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 330 endif(GMX_SOFTWARE_INVSQRT)
 331
 332 #######################################################################
 333 # Check for options incompatible with OpenMM build                    #
 334 #######################################################################
 335 if(GMX_OPENMM)
 336     # we'll use the built-in fft to avoid unnecessary dependencies
 337     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 338     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 339         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 340         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 341                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 342     endif()
 343     if(GMX_MPI)
 344         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 345     endif(GMX_MPI)
 346     if(GMX_THREAD_MPI)
 347         message(STATUS "Thread-MPI not compatible with OpenMM, disabled!")
 348         set(GMX_THREAD_MPI OFF CACHE BOOL
 349                 "Thread-MPI not compatible with OpenMM build, disabled!" FORCE)
 350     endif(GMX_THREAD_MPI)
 351     if(GMX_OPENMP)
 352         message(STATUS "OpenMP multithreading not compatible with OpenMM, disabled")
 353         set(GMX_OPENMP OFF CACHE BOOL
 354             "OpenMP multithreading not compatible with OpenMM, disabled!" FORCE)
 355     endif()
 356     if(GMX_SOFTWARE_INVSQRT)
 357         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 358                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 359     endif(GMX_SOFTWARE_INVSQRT)
 360     string(TOUPPER ${GMX_CPU_ACCELERATION} GMX_CPU_ACCELERATION)
 361     if(NOT GMX_CPU_ACCELERATION STREQUAL "NONE")
 362         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 363         set(GMX_CPU_ACCELERATION "None" CACHE STRING
 364             "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 365     endif()
 366     if(GMX_FAHCORE)
 367         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 368     endif(GMX_FAHCORE)
 369     if(GMX_DOUBLE)
 370         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 371     endif()
 372     # mark as advanced the unused variables
 373     mark_as_advanced(FORCE GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 374         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 375 else(GMX_OPENMM)
 376      mark_as_advanced(CLEAR GMX_CPU_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 377         GMX_QMMM_PROGRAM GMX_THREAD_MPI GMX_DOUBLE)
 378 endif(GMX_OPENMM)
 379
 380
 381 ########################################################################
 382 # Basic system tests (standard libraries, headers, functions, types)   #
 383 ########################################################################
 384 include(CheckIncludeFiles)
 385 check_include_files(string.h     HAVE_STRING_H)
 386 check_include_files(math.h       HAVE_MATH_H)
 387 check_include_files(limits.h     HAVE_LIMITS_H)
 388 check_include_files(memory.h     HAVE_MEMORY_H)
 389 check_include_files(unistd.h     HAVE_UNISTD_H)
 390 check_include_files(direct.h     HAVE_DIRECT_H)
 391 check_include_files(pwd.h        HAVE_PWD_H)
 392 check_include_files(stdint.h     HAVE_STDINT_H)
 393 check_include_files(stdlib.h     HAVE_STDLIB_H)
 394 check_include_files(pthread.h    HAVE_PTHREAD_H)
 395 check_include_files(dirent.h     HAVE_DIRENT_H)
 396 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 397 check_include_files(regex.h      HAVE_REGEX_H)
 398 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 399 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 400 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 401 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 402 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 403 check_include_files(io.h                 HAVE_IO_H)
 404 check_include_files(sched.h      HAVE_SCHED_H)
 405
 406 include(CheckFunctionExists)
 407 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 408 check_function_exists(strdup            HAVE_STRDUP)
 409 check_function_exists(vprintf           HAVE_VPRINTF)
 410 check_function_exists(memcmp            HAVE_MEMCMP)
 411 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 412 check_function_exists(memalign          HAVE_MEMALIGN)
 413 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 414 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 415 check_function_exists(isnan             HAVE_ISNAN)
 416 check_function_exists(_isnan            HAVE__ISNAN)
 417 check_function_exists(fsync             HAVE_FSYNC)
 418 check_function_exists(_fileno           HAVE__FILENO)
 419 check_function_exists(fileno            HAVE_FILENO)
 420 check_function_exists(_commit           HAVE__COMMIT)
 421 check_function_exists(sigaction         HAVE_SIGACTION)
 422 check_function_exists(sysconf           HAVE_SYSCONF)
 423 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 424 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 425 check_function_exists(rsqrt             HAVE_RSQRT)
 426 check_function_exists(rsqrtf            HAVE_RSQRTF)
 427 check_function_exists(sqrtf             HAVE_SQRTF)
 428
 429 include(CheckLibraryExists)
 430 check_library_exists(m sqrt "" HAVE_LIBM)
 431 check_library_exists(m cbrt "" HAVE_CBRT)
 432
 433
 434 include(CheckTypeSize)
 435
 436 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 437 check_type_size("int"           SIZEOF_INT)
 438 check_type_size("long int"      SIZEOF_LONG_INT)
 439 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 440 check_type_size("off_t"         SIZEOF_OFF_T)
 441 check_type_size("void *"        SIZEOF_VOIDP)
 442
 443 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 444     set(GMX_64_BIT TRUE)
 445 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 446     set(GMX_64_BIT FALSE)
 447 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 448
 449 # Check for some basic types that we *need*, so set these to int if they are not present
 450 check_type_size(uid_t uid_t)
 451 if(NOT uid_t)
 452   set(uid_t int)
 453 else(NOT uid_t)
 454   set(uid_t 0)
 455 endif(NOT uid_t)
 456
 457 check_type_size(gid_t gid_t)
 458 if(NOT gid_t)
 459   set(gid_t 1)
 460 else(NOT gid_t)
 461   set(gid_t 0)
 462 endif(NOT gid_t)
 463
 464 check_type_size(size_t size_t)
 465 if(NOT size_t)
 466   set(size_t int)
 467 else(NOT size_t)
 468   set(size_t 0)
 469 endif(NOT size_t)
 470
 471 check_type_size(off_t off_t)
 472 if(NOT off_t)
 473   set(off_t int)
 474 else(NOT off_t)
 475   set(off_t 0)
 476 endif(NOT off_t)
 477
 478 include(TestBigEndian)
 479 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 480
 481
 482 if(APPLE OR CYGWIN OR ${CMAKE_SYSTEM_NAME} MATCHES "Linux|.*BSD")
 483     # Maybe Solaris should be here? Patch this if you know!
 484     SET(SHARED_LIBS_DEFAULT ON)
 485 elseif(WIN32 OR ${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 486     # Support for shared libs on native Windows is a bit new. Its
 487     # default might change later if/when we sort things out. Also,
 488     # Cray should go here. What variable value can detect it?
 489     SET(SHARED_LIBS_DEFAULT OFF)
 490 else()
 491     message(STATUS "Defaulting to building static libraries")
 492     SET(SHARED_LIBS_DEFAULT OFF)
 493 endif()
 494
 495 # Management of GROMACS options for specific toolchains should go
 496 # here. Because the initial settings for some of the main options have
 497 # already happened, but things like library detection and MPI compiler
 498 # feature detection have not, the docstrings for any over-rides of
 499 # GROMACS defaults or user settings will make sense. Also, any
 500 # toolchain-related reasons for choosing whether to detect various
 501 # things can be sorted out now, before the detection takes place.
 502
 503 if(UNIX AND GMX_PREFER_STATIC_LIBS AND SHARED_LIBS_DEFAULT)
 504     if(BUILD_SHARED_LIBS)
 505         # Warn the user about the combination. But don't overwrite the request.
 506         message(WARNING "Searching for static libraries requested, and building shared Gromacs libraries requested. This might cause problems linking later.")
 507     elseif(NOT DEFINED BUILD_SHARED_LIBS)
 508         # Change default to OFF. Don't warn if it's already off.
 509         message(WARNING "Searching for static libraries requested, so the GROMACS libraries will also be built statically (BUILD_SHARED_LIBS=OFF)")
 510         set(SHARED_LIBS_DEFAULT OFF)
 511     endif()
 512 endif()
 513
 514 # By now, all tool chains should have spoken up if they care about
 515 # the setting of SHARED_LIBS_DEFAULT.
 516 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic e.g. with MPI, or on some HPC systems)" ${SHARED_LIBS_DEFAULT})
 517
 518 ########################################################################
 519 #Process MPI settings
 520 ########################################################################
 521 include(gmxManageMPI)
 522
 523 ########################################################################
 524 # Find external packages                                               #
 525 ########################################################################
 526 if(UNIX AND GMX_PREFER_STATIC_LIBS)
 527     # On Linux .a is the static library suffix, on Mac OS X .lib can also
 528     # be used, so we'll add both to the preference list.
 529     SET(CMAKE_FIND_LIBRARY_SUFFIXES ".lib;.a" ${CMAKE_FIND_LIBRARY_SUFFIXES})
 530 endif()
 531
 532 IF( WIN32 AND NOT CYGWIN)
 533   if (NOT BUILD_SHARED_LIBS)
 534       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" ON)
 535       if(NOT GMX_PREFER_STATIC_LIBS)
 536           message(WARNING "Shared system libraries requested, and static Gromacs libraries requested.")
 537       endif()
 538   else()
 539       option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer static system libraries (MT instead of MD)!" OFF)
 540       if(GMX_PREFER_STATIC_LIBS)
 541           #this combination segfaults (illigal passing of file handles)
 542           message(FATAL_ERROR "Static system libraries requested, and shared Gromacs libraries requested.")
 543       endif()
 544       add_definitions(-DUSE_VISIBILITY -DTMPI_USE_VISIBILITY)
 545       set(PKG_CFLAGS "$PKG_CFLAGS -DUSE_VISIBILITY -DTMPI_USE_VISIBILITY")
 546   endif()
 547   mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 548
 549   IF (GMX_PREFER_STATIC_LIBS)
 550       #Only setting Debug and Release flags. Others configurations are current not used.
 551       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
 552       STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
 553       if(CMAKE_CXX_COMPILER_LOADED)
 554           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_RELEASE ${CMAKE_CXX_FLAGS_RELEASE})
 555           STRING(REPLACE /MD /MT CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_DEBUG})
 556       endif()
 557   ENDIF()
 558   IF( CMAKE_C_COMPILER_ID MATCHES "Intel" )
 559     if(BUILD_SHARED_LIBS) #not sure why incremental building with shared libs doesn't work
 560         STRING(REPLACE "/INCREMENTAL:YES" "" CMAKE_SHARED_LINKER_FLAGS ${CMAKE_SHARED_LINKER_FLAGS})
 561     endif()
 562   ENDIF()
 563 ENDIF()
 564
 565 option(GMX_GSL "Add support for gsl" OFF)
 566 if (GMX_GSL)
 567   find_package(gsl)
 568   set(PKG_GSL "")
 569   if(GSL_FOUND)
 570     include_directories(${GSL_INCLUDE_DIR})
 571     set(PKG_GSL gsl)
 572     set(HAVE_LIBGSL 1)
 573   endif(GSL_FOUND)
 574 endif (GMX_GSL)
 575
 576 option(GMX_X11 "Use X window system" OFF)
 577 if (GMX_X11)
 578         find_package(X11)
 579         # X11 includes/libraries are only set in the ngmx subdirectory!
 580         if(X11_FOUND)
 581         set(HAVE_X11 1)
 582         endif(X11_FOUND)
 583 endif(GMX_X11)
 584
 585 include(ThreadMPI)
 586 set(THREAD_MPI_LIB thread_mpi)
 587 if(GMX_THREAD_MPI)
 588     tmpi_get_source_list(THREAD_MPI_SRC)
 589     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 590     set(GMX_MPI 1)
 591 else(GMX_THREAD_MPI)
 592     tmpi_get_source_list(THREAD_MPI_SRC NOMPI)
 593 endif(GMX_THREAD_MPI)
 594
 595 if(GMX_OPENMM)
 596     set(CUDA_BUILD_EMULATION OFF)
 597     find_package(CUDA 3.1 REQUIRED)
 598     add_definitions(-DGMX_OPENMM)
 599     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 600         set(CUDA_VERBOSE_BUILD ON)
 601     endif()
 602     find_package(OpenMM)
 603 endif(GMX_OPENMM)
 604
 605 if(GMX_GPU)
 606     # now that we have detected the dependencies, do the second configure pass
 607     gmx_gpu_setup()
 608 endif(GMX_GPU)
 609
 610 if(APPLE)
 611    find_library(ACCELERATE_FRAMEWORK Accelerate)
 612    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 613 endif(APPLE)
 614
 615 if(CYGWIN)
 616     set(GMX_CYGWIN 1)
 617 endif(CYGWIN)
 618
 619 if(WIN32 AND NOT CYGWIN)
 620     set(GMX_NATIVE_WINDOWS 1)
 621 endif()
 622
 623 # only bother with finding git and using version.h if the source is a git repo
 624 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 625     if(USE_VERSION_H)
 626         # We need at least git v1.5.3 be able to parse git's date output. If not
 627         # found or the version is too small, we can't generate version information.
 628         find_package(Git)
 629
 630         # Find out the git version
 631         if(GIT_FOUND AND NOT GIT_VERSION)
 632           execute_process(COMMAND ${GIT_EXECUTABLE} "--version"
 633             OUTPUT_VARIABLE _exec_out
 634             OUTPUT_STRIP_TRAILING_WHITESPACE)
 635           string(REGEX REPLACE "git version (.*)" "\\1" GIT_VERSION ${_exec_out})
 636           set(GIT_VERSION ${GIT_VERSION} CACHE STRING "Git version")
 637           mark_as_advanced(GIT_VERSION)
 638         endif()
 639
 640         if(NOT GIT_FOUND OR GIT_VERSION VERSION_LESS "1.5.3")
 641           message("No compatible git version found, won't be able to generate proper development version information.")
 642           set(USE_VERSION_H OFF)
 643         endif()
 644     endif()
 645 else()
 646     set(USE_VERSION_H OFF)
 647 endif()
 648
 649 ########################################################################
 650 # Generate development version info for cache
 651 ########################################################################
 652 # set(GEN_VERSION_INFO_INTERNAL "ON")
 653 # include(gmxGenerateVersionString)
 654
 655 ########################################################################
 656 # Our own GROMACS tests
 657 ########################################################################
 658
 659 add_definitions( -DHAVE_CONFIG_H )
 660 include_directories(${CMAKE_BINARY_DIR}/src)
 661 include_directories(${CMAKE_BINARY_DIR}/include)
 662 include_directories(${CMAKE_SOURCE_DIR}/include)
 663
 664 include(gmxTestInlineASM)
 665 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 666
 667 include(gmxSetBuildInformation)
 668 gmx_set_build_information()
 669 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 670     # The timestep counter headers do not include config.h
 671     add_definitions(-DHAVE_RDTSCP)
 672 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 673
 674 include(gmxTestFloatFormat)
 675 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 676                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 677                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 678
 679 include(gmxTestLargeFiles)
 680 gmx_test_large_files(GMX_LARGEFILES)
 681
 682 include(gmxTestSignal)
 683 gmx_test_sigusr1(HAVE_SIGUSR1)
 684
 685 include(gmxTestInline)
 686 gmx_test_inline(INLINE_KEYWORD)
 687
 688 include(gmxTestRestrict)
 689 gmx_test_restrict(RESTRICT_KEYWORD)
 690
 691 include(gmxTestPipes)
 692 gmx_test_pipes(HAVE_PIPES)
 693
 694 include(gmxTestIsfinite)
 695 gmx_test_isfinite(HAVE_ISFINITE)
 696 gmx_test__isfinite(HAVE__ISFINITE)
 697 gmx_test__finite(HAVE__FINITE)
 698
 699 include(gmxTestXDR)
 700 gmx_test_xdr(GMX_SYSTEM_XDR)
 701 if(NOT GMX_SYSTEM_XDR)
 702     set(GMX_INTERNAL_XDR 1)
 703     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 704 endif(NOT GMX_SYSTEM_XDR)
 705
 706 # include avx test source, used if the AVX flags are set below
 707 include(gmxTestAVXMaskload)
 708
 709 # Process nonbonded accelerated kernels settings
 710 string(TOUPPER ${GMX_CPU_ACCELERATION} ${GMX_CPU_ACCELERATION})
 711 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 712     # nothing to do
 713 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 714
 715     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 716     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 717         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 718     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 719
 720     if (CMAKE_CXX_COMPILER_LOADED)
 721         GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 722         if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 723             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 724         endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 725     endif()
 726
 727     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 728
 729     # Only test the include after we have tried to add the correct flag for SSE2 support
 730     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 731
 732     if(NOT HAVE_EMMINTRIN_H)
 733         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 734     endif(NOT HAVE_EMMINTRIN_H)
 735
 736     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 737     # The user should not be able to set this orthogonally to the acceleration
 738     set(GMX_X86_SSE2 1)
 739     if (NOT ACCELERATION_QUIETLY)
 740       message(STATUS "Enabling SSE2 Gromacs acceleration, and it will help compiler optimization.")
 741     endif()
 742
 743 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 744
 745     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 746     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 747         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 748     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 749     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 750         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 751         # intrinsics when SSE2 support is enabled, so we try that instead first.
 752         if (GMX_NATIVE_WINDOWS)
 753             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 754             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 755         else()
 756             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 757         endif()
 758     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 759
 760     if (CMAKE_CXX_COMPILER_LOADED)
 761         GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" GROMACS_CXX_FLAG)
 762         if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 763             GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 764         endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 765         if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 766             message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 767             # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 768             # intrinsics when SSE2 support is enabled, so we try that instead.
 769             if (GMX_NATIVE_WINDOWS)
 770                 GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 771             endif()
 772         endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 773     endif()
 774
 775     # This must come after we have added the -msse4.1 flag on some platforms.
 776     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 777
 778     if(NOT HAVE_SMMINTRIN_H)
 779         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 780     endif(NOT HAVE_SMMINTRIN_H)
 781
 782     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 783     # The user should not be able to set this orthogonally to the acceleration
 784     set(GMX_X86_SSE4_1 1)
 785     set(GMX_X86_SSE2   1)
 786     if (NOT ACCELERATION_QUIETLY)
 787       message(STATUS "Enabling SSE4.1 Gromacs acceleration, and it will help compiler optimization.")
 788     endif()
 789
 790 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 791
 792     # Set the AVX compiler flag for both these choices!
 793
 794     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 795     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 796         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 797     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 798     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 799         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 800     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 801
 802     if (CMAKE_CXX_COMPILER_LOADED)
 803         GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 804         if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 805             GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 806         endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 807         if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 808             message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 809         endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 810     endif()
 811
 812     # Set the FMA4 flags (MSVC doesn't require any)
 813     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 814         if (${CMAKE_COMPILER_ID} MATCHES "Clang")
 815             message(FATAL_ERROR "Clang up to at least version 3.2 produces incorrect code for AVX_128_FMA. Sorry, but you will have to select a different compiler or acceleration.")
 816         endif()
 817         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 818         if (NOT GNU_FMA_CFLAG)
 819             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 820         endif(NOT GNU_FMA_CFLAG)
 821         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 822         # No big deal if we do not have xop, so no point yelling warnings about it.
 823         if (CMAKE_CXX_COMPILER_LOADED)
 824             GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 825             if (NOT GNU_FMA_CXXFLAG)
 826                 message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 827             endif (NOT GNU_FMA_CXXFLAG)
 828             GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 829             # No big deal if we do not have xop, so no point yelling warnings about it.
 830         endif()
 831     endif()
 832
 833     # Only test the header after we have tried to add the flag for AVX support
 834     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 835
 836     if(NOT HAVE_IMMINTRIN_H)
 837         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 838     endif(NOT HAVE_IMMINTRIN_H)
 839
 840     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 841         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 842             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 843             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 844         if(NOT TEST_AVX)
 845             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 846         endif()
 847     endif()
 848
 849     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 850     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 851     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 852
 853     # The user should not be able to set this orthogonally to the acceleration
 854     set(GMX_X86_SSE4_1 1)
 855     set(GMX_X86_SSE2   1)
 856
 857     # But just enable one of the choices internally...
 858     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 859         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 860         set(GMX_X86_AVX_128_FMA 1)
 861         if (NOT ACCELERATION_QUIETLY)
 862           message(STATUS "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add), and it will help compiler optimization.")
 863         endif()
 864     else()
 865         # If we are not doing AVX_128, it must be AVX_256...
 866         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 867         set(GMX_X86_AVX_256 1)
 868         if (NOT ACCELERATION_QUIETLY)
 869           message(STATUS "Enabling 256-bit AVX Gromacs acceleration, and it will help compiler optimization.")
 870         endif()
 871     endif()
 872
 873     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 874     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 875     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 876
 877 elseif(${GMX_CPU_ACCELERATION} STREQUAL "BLUEGENE")
 878 # GMX_CPU_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 879     if (NOT ACCELERATION_QUIETLY)
 880       message(STATUS "Configuring for BlueGene")
 881     endif()
 882     set(GMX_BLUEGENE 1)
 883     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 884         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 885         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 886     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 887     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 888     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 889     set(GMX_THREAD_MPI OFF CACHE BOOL "Thread-MPI not compatible with BlueGene, disabled!" FORCE)
 890     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 891 # Access to /etc/passwd is not available on the back end of BlueGene,
 892 # despite being detected by CMake. This can cause linker warnings
 893 # about harmless things in src/gmxlib/string2.h.
 894     set(HAVE_PWD_H OFF)
 895 # The automatic testing for endianness does not work for the BlueGene cross-compiler
 896     set(GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP byte order (by default)" FORCE)
 897     set(GMX_IEEE754_BIG_ENDIAN_WORD_ORDER 1 CACHE INTERNAL "BlueGene has big endian FP word order (by default)" FORCE)
 898 else(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 899     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_CPU_ACCELERATION}. Pick one of None, SSE2, SSE4.1, AVX_128_FMA, AVX_256, BlueGene")
 900 endif(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 901 set(ACCELERATION_QUIETLY TRUE CACHE INTERNAL "")
 902
 903 # Process QM/MM Settings
 904 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 905 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 906     set(GMX_QMMM_GAUSSIAN 1)
 907 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 908     set(GMX_QMMM_MOPAC 1)
 909 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 910     set(GMX_QMMM_GAMESS 1)
 911 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 912     set(GMX_QMMM_ORCA 1)
 913 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 914     # nothing to do
 915 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 916     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 917 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 918
 919 # Process FFT library settings - if not OpenMM build
 920 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 921 set(PKG_FFT "")
 922 set(PKG_FFT_LIBS "")
 923 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 924     if(GMX_DOUBLE)
 925         set(FFTW fftw)
 926     else()
 927         set(FFTW fftwf)
 928     endif()
 929
 930     if(GMX_BUILD_OWN_FFTW)
 931       add_subdirectory(src/contrib/fftw)
 932     else()
 933       find_package(FFTW COMPONENTS ${FFTW})
 934     endif()
 935
 936     string(TOUPPER "${FFTW}" FFTW)
 937     set(PKG_FFT "${${FFTW}_PKG}")
 938     include_directories(${${FFTW}_INCLUDE_DIRS})
 939     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 940     if(NOT ${FFTW}_FOUND)
 941       MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for single-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library, enable the advanced option to let GROMACS build FFTW 3 for you, or use the really slow GROMACS built-in fftpack library.")
 942     endif()
 943
 944     set(GMX_FFT_FFTW3 1)
 945
 946     if (NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND NOT ${FFTW}_HAVE_SIMD)
 947       message(WARNING "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
 948     endif()
 949
 950     if(NOT ${GMX_CPU_ACCELERATION} STREQUAL "NONE" AND ${FFTW}_HAVE_AVX)
 951         # If we're not doing CPU acceleration, we don't care about FFTW performance on x86 either
 952         message(WARNING "The FFTW library was compiled with --enable-avx to enable AVX SIMD instructions. That might sound like a good idea for your processor, but for FFTW versions up to 3.3.3, these are slower than the SSE/SSE2 SIMD instructions for the way GROMACS uses FFTs. Limitations in the way FFTW allows GROMACS to measure performance make it awkward for either GROMACS or FFTW to make the decision for you based on runtime performance. You should compile a different FFTW library with --enable-sse or --enable-sse2. If you have a more recent FFTW, you may like to compare the performance of GROMACS with FFTW libraries compiled with and without --enable-avx. However, the GROMACS developers do not really expect the FFTW AVX optimization to help, because the performance is limited by memory access, not computation.")
 953     endif()
 954
 955 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 956 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 957     find_package(MKL REQUIRED)
 958     include_directories(${MKL_INCLUDE_DIR})
 959     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 960     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 961
 962     set(GMX_FFT_MKL 1)
 963     set(HAVE_MKL 1)
 964
 965 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 966 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 967 #    set(GMX_FFT_ACML 1)
 968 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 969     MESSAGE(STATUS "Using internal FFT library - fftpack")
 970     set(GMX_FFT_FFTPACK 1)
 971 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 972     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, mkl, fftpack")
 973 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 974
 975 # enable threaded fftw3 if we've found it
 976 if(FFTW3_THREADS OR FFTW3F_THREADS)
 977     add_definitions(-DFFT5D_FFTW_THREADS)
 978 endif()
 979
 980 set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 981 set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 982 # MKL has BLAS/LAPACK routines
 983 if(NOT HAVE_MKL AND NOT ACCELERATE_FRAMEWORK)
 984   if(GMX_EXTERNAL_BLAS)
 985     if (GMX_BLAS_USER)
 986         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_BLAS_USER})
 987     else(GMX_BLAS_USER)
 988         set(BLAS_FIND_QUIETLY ON)
 989         find_package(BLAS)
 990         if (BLAS_FOUND)
 991           list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 992         else()
 993           MESSAGE(STATUS "Using internal BLAS library")
 994           set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external BLAS instead of built-in" FORCE)
 995         endif()
 996     endif(GMX_BLAS_USER)
 997   endif(GMX_EXTERNAL_BLAS)
 998   if(GMX_EXTERNAL_LAPACK)
 999     if (GMX_LAPACK_USER)
1000         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_LAPACK_USER})
1001     else(GMX_LAPACK_USER)
1002         set(LAPACK_FIND_QUIETLY ON)
1003         find_package(LAPACK)
1004         if (LAPACK_FOUND)
1005           list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
1006         else()
1007           MESSAGE(STATUS "Using internal LAPACK library")
1008           set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in" FORCE)
1009         endif()
1010     endif(GMX_LAPACK_USER)
1011   endif(GMX_EXTERNAL_LAPACK)
1012 endif()
1013 mark_as_advanced(GMX_EXTERNAL_LAPACK)
1014 mark_as_advanced(GMX_EXTERNAL_BLAS)
1015
1016 set(GMX_USE_PLUGINS OFF CACHE INTERNAL "Whether GROMACS will really try to compile support for VMD plugins")
1017
1018 if(GMX_LOAD_PLUGINS)
1019   if(CYGWIN OR NOT WIN32)
1020     # Native Windows does not have, nor need dlopen
1021     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
1022     include(gmxTestdlopen)
1023     gmx_test_dlopen(HAVE_DLOPEN)
1024   endif()
1025
1026   # so, should we use plug-ins?
1027   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
1028     if(NOT VMD_QUIETLY)
1029       MESSAGE(STATUS
1030           "Found the ability to use plug-ins when building shared libaries, "
1031           "so will compile to use plug-ins (e.g. to read VMD-supported file "
1032           "formats).")
1033     endif()
1034     if(NOT GMX_VMD_PLUGIN_PATH)
1035       find_package(VMD)
1036     endif()
1037     set(GMX_USE_PLUGINS ON)
1038     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
1039     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
1040   else()
1041     set(PKG_DL_LIBS)
1042   endif()
1043 endif(GMX_LOAD_PLUGINS)
1044 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
1045
1046 if(EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
1047     if(NOT CMAKE_CROSSCOMPILING)
1048         option(GMX_BUILD_MANPAGES "Build man pages" ON)
1049     else()
1050         message(STATUS "Building the man pages is not available when "
1051             "cross-compiling the developer version from git")
1052     endif()
1053 else()
1054     #make sure source package contains all man pages
1055     if(NOT EXISTS "${CMAKE_SOURCE_DIR}/man/man1/ngmx.1")
1056         message(FATAL_ERROR "Man pages are missing from source package.")
1057     endif()
1058 endif()
1059 mark_as_advanced(GMX_BUILD_MANPAGES)
1060
1061 # Math and thread libraries must often come after all others when linking...
1062 if(HAVE_LIBM)
1063     list(APPEND GMX_EXTRA_LIBRARIES m)
1064 endif(HAVE_LIBM)
1065
1066 if(GMX_FAHCORE)
1067   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
1068       "Path to swindirect.h")
1069   include_directories(${COREWRAP_INCLUDE_DIR})
1070   set_property(CACHE GMX_COOL_QUOTES VALUE OFF)
1071 endif(GMX_FAHCORE)
1072
1073 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
1074 # these are set after everything else
1075 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
1076     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_C_FLAGS}")
1077     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${CMAKE_CXX_FLAGS}")
1078     set(CMAKE_EXE_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
1079     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
1080 else()
1081     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
1082     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CFLAGS}")
1083     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
1084     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
1085     if(CMAKE_CXX_COMPILER_LOADED)
1086         message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${GMXC_CXXFLAGS}")
1087         message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
1088         message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
1089     endif()
1090     message("CMAKE_EXE_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1091     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
1092 endif()
1093
1094 if(NOT GMX_OPENMP)
1095     #Unset all OpenMP flags in case OpenMP was disabled either by the user
1096     #or because it was only partially detected (e.g. only for C but not C++ compiler)
1097     unset(OpenMP_C_FLAGS CACHE)
1098     unset(OpenMP_CXX_FLAGS CACHE)
1099     unset(OpenMP_LINKER_FLAGS CACHE)
1100     unset(OpenMP_SHARED_LINKER_FLAGS)
1101 endif()
1102 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
1103
1104 ######################################
1105 # Output compiler and CFLAGS used
1106 ######################################
1107 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
1108 if (CMAKE_CXX_COMPILER_LOADED)
1109     get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
1110 endif ()
1111
1112 ########################################################################
1113 # Specify install locations and which subdirectories to process        #
1114 ########################################################################
1115 if (GMX_USE_RELATIVE_INSTALL_PATH)
1116     set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
1117     mark_as_advanced(GMX_INSTALL_PREFIX)
1118 else()
1119     set(GMX_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
1120 endif()
1121
1122 if ( NOT DEFINED GMXLIB )
1123     set(GMXLIB lib)
1124 endif()
1125 set(LIB_INSTALL_DIR "${GMX_INSTALL_PREFIX}${GMXLIB}")
1126 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
1127 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/gromacs)
1128 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
1129 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
1130
1131 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
1132
1133 ##################################################################
1134 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
1135 ##################################################################
1136 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
1137     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
1138     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
1139     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
1140     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
1141 endif()
1142
1143 #COPYING file: Only necessary for binary distributions.
1144 #Simpler to always install.
1145 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
1146
1147 add_subdirectory(share)
1148 add_subdirectory(include)
1149 add_subdirectory(src)
1150 add_subdirectory(scripts)
1151
1152 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1153 # Don't bother the user after the first configure pass.
1154 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1155     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1156     unset(CUDA_NOTFOUND_AUTO)
1157     unset(CUDA_NOTFOUND_MESSAGE)
1158 endif()
1159 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1160
1161 #######################
1162 ## uninstall target
1163 #######################
1164     CONFIGURE_FILE(
1165                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1166                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1167                    IMMEDIATE @ONLY)
1168 ###########################
1169 ADD_CUSTOM_TARGET(uninstall
1170                   "${CMAKE_COMMAND}" -P
1171                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1172 ###########################
1173
1174 ########################################################################
1175 # Tests                                                                #
1176 ########################################################################
1177
1178 include(CTest)
1179 mark_as_advanced(BUILD_TESTING)
1180 IF(BUILD_TESTING)
1181         enable_testing()
1182         add_subdirectory(tests)
1183 ENDIF()
1184