CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135
 136 ########################################################################
 137 # Detect CXX11 support and flags
 138 ########################################################################
 139 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 140 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 141 # invalid options with the Intel Compilers, and we have added a line
 142 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 143 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 144 # a semicolon. Since this is also used as a separator in lists inside CMake,
 145 # that string ends up being split into two separate patterns, and the last
 146 # part is just a single word that also matches other messages. We solved this
 147 # by replacing the semicolon with a period that matches any character.
 148 #
 149 # These files should be removed from the source tree when a CMake version that
 150 # includes the features in question becomes required for building GROMACS.
 151 include(CheckCCompilerFlag)
 152 include(CheckCXXCompilerFlag)
 153
 154 # This must come early, since some of our configuration flag tests
 155 # depend on being able to compile C++11 source files
 156 include(gmxTestCXX11)
 157 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 158 if(NOT GMX_CXX11_SUPPORTED)
 159 message(FATAL_ERROR "This version of GROMACS requires C++11. Please use a newer compiler or use the GROMACS 5.1.x release. Note it might be sufficient to instruct the compiler to use a newer STL version. See the installation guide for details.")
 160 endif()
 161
 162 # Make sure all tests are run in C++11 mode
 163 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 164
 165 ########################################################################
 166 # User input options                                                   #
 167 ########################################################################
 168 include(gmxOptionUtilities)
 169
 170 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 171
 172 # Fujitsu only has SIMD in double precision, so this will be faster
 173 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 174 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 175 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 176 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 177
 178 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 179 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 180 gmx_dependent_option(
 181     GMX_MPI_IN_PLACE
 182     "Enable MPI_IN_PLACE for MPIs that have it defined"
 183     ON
 184     GMX_MPI)
 185 mark_as_advanced(GMX_MPI_IN_PLACE)
 186 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 187 mark_as_advanced(GMX_FAHCORE)
 188
 189 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 190 mark_as_advanced(GMX_COOL_QUOTES)
 191 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 192
 193 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 194
 195 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 196 # GCC 4.6 requires CUDA 5.0 and VS2015 requires CUDA 8.0
 197 if(MSVC)
 198     set(REQUIRED_CUDA_VERSION 8.0)
 199 else()
 200     set(REQUIRED_CUDA_VERSION 5.0)
 201 endif()
 202 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 203
 204 # OpenCL required version: 1.1 or newer
 205 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 206
 207 if(NOT GMX_USE_OPENCL)
 208     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 209     include(gmxManageGPU)
 210     set(GMX_USE_CUDA ${GMX_GPU})
 211     if(GMX_GPU)
 212         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 213     else()
 214         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 215     endif()
 216 else()
 217     #Now the OpenCL path (for both AMD and NVIDIA)
 218     if(GMX_GPU)
 219         include(gmxManageOpenCL)
 220         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 221     else()
 222         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 223     endif()
 224 endif()
 225
 226 include(gmxDetectSimd)
 227 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 228
 229 gmx_option_multichoice(
 230     GMX_SIMD
 231     "SIMD instruction set for CPU kernels and compiler optimization"
 232     "${GMX_SUGGESTED_SIMD}"
 233     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 234
 235 if(GMX_TARGET_MIC)
 236     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 237 else()
 238     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 239 endif()
 240
 241 gmx_option_multichoice(
 242     GMX_FFT_LIBRARY
 243     "FFT library"
 244     "${GMX_FFT_LIBRARY_DEFAULT}"
 245     fftw3 mkl "fftpack[built-in]")
 246 gmx_dependent_option(
 247     GMX_BUILD_OWN_FFTW
 248     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 249     OFF
 250     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 251 gmx_dependent_option(
 252     GMX_DISABLE_FFTW_MEASURE
 253     "Do not optimize FFTW setups (not needed with SSE)"
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 257 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 258
 259 gmx_option_multichoice(
 260     GMX_QMMM_PROGRAM
 261     "QM package for QM/MM"
 262     None
 263     none gaussian mopac gamess orca)
 264
 265 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 266 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 267
 268 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 269
 270 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 271 mark_as_advanced(GMX_BROKEN_CALLOC)
 272 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 273 mark_as_advanced(GMX_LOAD_PLUGINS)
 274
 275 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 276
 277 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 278
 279 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 280
 281 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 282 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 283
 284 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 285 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 286
 287 option(GMX_BUILD_FOR_COVERAGE
 288        "Tune build for better code coverage metrics (e.g., disable asserts)"
 289        OFF)
 290 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 291
 292 option(GMX_DEVELOPER_BUILD
 293     "Enable Developer convenience features: always build unit-tests"
 294     OFF)
 295 mark_as_advanced(GMX_DEVELOPER_BUILD)
 296
 297 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 298 option(GMX_COMPILER_WARNINGS
 299     "Enable a default set of compiler warnings"
 300     ${GMX_COMPILER_WARNINGS_DEFAULT})
 301 mark_as_advanced(GMX_COMPILER_WARNINGS)
 302 # Always turn on compiler warnings with a developer build.
 303 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 304
 305 option(GMX_BUILD_SHARED_EXE
 306     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 307     ON)
 308 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 309
 310 ######################################################################
 311 # Detect OpenMP support
 312 ######################################################################
 313 # The OpenMP detection _must_ come before tests for other CFLAGS.
 314 include(gmxManageOpenMP)
 315
 316
 317
 318 ######################################################################
 319 # Compiler tests
 320 # These need to be done early (before further tests).
 321 #####################################################################
 322
 323 include(gmxCFlags)
 324 gmx_c_flags()
 325
 326 # This variable should be used for additional compiler flags which are not
 327 # generated in gmxCFlags nor are SIMD or MPI related.
 328 set(EXTRA_C_FLAGS "")
 329 set(EXTRA_CXX_FLAGS "")
 330
 331 # Run through a number of tests for buggy compilers and other issues
 332 include(gmxTestCompilerProblems)
 333 gmx_test_compiler_problems()
 334 # GMX_SIMD will not be set automatically until the second
 335 # pass (which is not strictly guaranteed to occur), so putting this
 336 # check here among logically-related tests is inefficient, but the
 337 # potential loss is likely zero.
 338 if(GMX_SIMD STREQUAL "AVX_256"
 339         AND CMAKE_COMPILER_IS_GNUCC
 340         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 341             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 342     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 343     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 344 endif()
 345
 346 # Implement double-precision option. This is complicated because we
 347 # need installed headers to use the precision mode of the build that
 348 # produced the library, but cannot use config.h in that case. We also
 349 # want such variables to always have a definition, because #if is more
 350 # robust than #ifdef. So, we put this value on the compiler command
 351 # line in all cases.
 352 #
 353 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 354 # because no installed header needs it
 355 if(GMX_DOUBLE)
 356     set(GMX_DOUBLE_VALUE 1)
 357 else()
 358     set(GMX_DOUBLE_VALUE 0)
 359 endif()
 360 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 361 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 362
 363 if(WIN32)
 364     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 365     add_definitions(-DGMX_HAVE_WINSOCK)
 366 endif()
 367
 368
 369
 370 ########################################################################
 371 # Basic system tests (standard libraries, headers, functions, types)   #
 372 ########################################################################
 373 include(CheckIncludeFiles)
 374 include(CheckIncludeFileCXX)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(dirent.h     HAVE_DIRENT_H)
 378 check_include_files(time.h       HAVE_TIME_H)
 379 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 380 check_include_files(io.h         HAVE_IO_H)
 381 check_include_files(sched.h      HAVE_SCHED_H)
 382
 383 check_include_files(regex.h      HAVE_POSIX_REGEX)
 384 # TODO: It could be nice to inform the user if no regex support is found,
 385 # as selections won't be fully functional.
 386
 387 include(CheckCXXSymbolExists)
 388 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 389 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 390 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 391 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 392 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 393 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 394 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 395 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 396
 397 # We cannot check for the __builtins as symbols, but check if code compiles
 398 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 399 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 400 if(MSVC)
 401     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 402     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 403 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 404     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 405     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 406 endif()
 407
 408 include(CheckLibraryExists)
 409 find_library(HAVE_LIBM m)
 410 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 411 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 412
 413 include(TestSchedAffinity)
 414 test_sched_affinity(HAVE_SCHED_AFFINITY)
 415
 416 # Aligned memory allocation. We need to check for both mm_malloc(),
 417 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 418 include(gmxTestMMMalloc)
 419 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 420 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 421 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 422 if(MSVC)
 423     # No need to waste time on this test on platforms where it will never be true
 424     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 425 endif()
 426
 427 include(TestBigEndian)
 428 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 429
 430 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 431
 432 # Management of GROMACS options for specific toolchains should go
 433 # here. Because the initial settings for some of the main options have
 434 # already happened, but things like library detection and MPI compiler
 435 # feature detection have not, the docstrings for any over-rides of
 436 # GROMACS defaults or user settings will make sense. Also, any
 437 # toolchain-related reasons for choosing whether to detect various
 438 # things can be sorted out now, before the detection takes place.
 439 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 440     include(gmxManageBlueGene)
 441 endif()
 442
 443 if(GMX_TARGET_FUJITSU_SPARC64)
 444     include(gmxManageFujitsuSparc64)
 445 endif()
 446
 447 ########################################################################
 448 #Process MPI settings
 449 ########################################################################
 450 include(gmxManageMPI)
 451
 452
 453 ########################################################################
 454 #Process shared/static library settings
 455 ########################################################################
 456 include(gmxManageSharedLibraries)
 457
 458
 459 ########################################################################
 460 # Find external packages                                               #
 461 ########################################################################
 462
 463 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 464 find_package(ZLIB QUIET)
 465 include(gmxTestZLib)
 466 gmx_test_zlib(HAVE_ZLIB)
 467
 468 # Unconditionally find the package, as it is also required for unit
 469 # tests. This exports LIBXML2_FOUND, which we should not use because
 470 # it does not tell us that linking will succeed. Instead, we test that
 471 # next.
 472 if(DEFINED LIBXML2_LIBRARIES)
 473   set(LibXml2_FIND_QUIETLY TRUE)
 474 endif()
 475 find_package(LibXml2)
 476 include(gmxTestLibXml2)
 477 gmx_test_libxml2(HAVE_LIBXML2)
 478 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 479 set(PKG_XML "")
 480 mark_as_advanced(GMX_XML)
 481 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 482 #if(GMX_XML AND NOT HAVE_LIBXML2)
 483 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 484 #endif()
 485 #if(GMX_XML)
 486 #    include_directories(${LIBXML2_INCLUDE_DIR})
 487 #    set(PKG_XML libxml-2.0)
 488 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 489 #endif()
 490
 491 if(DEFINED HWLOC_LIBRARIES)
 492   set(Hwloc_FIND_QUIETLY TRUE)
 493 endif()
 494 find_package(Hwloc 1.5)
 495 if(HWLOC_FOUND)
 496     set(GMX_HWLOC_DEFAULT ON)
 497 else()
 498     set(GMX_HWLOC_DEFAULT OFF)
 499 endif()
 500 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 501 if(GMX_HWLOC)
 502     if(HWLOC_FOUND)
 503         include_directories(${HWLOC_INCLUDE_DIRS})
 504         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 505     else()
 506         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 507     endif()
 508 endif()
 509
 510 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 511 mark_as_advanced(GMX_EXTRAE)
 512
 513 if (GMX_EXTRAE)
 514   find_package(EXTRAE)
 515   if(EXTRAE_FOUND)
 516     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 517     set(HAVE_EXTRAE 1)
 518   else()
 519     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 520   endif()
 521 endif()
 522
 523 option(GMX_X11 "Use X window system" OFF)
 524 if (GMX_X11)
 525     find_package(X11)
 526     # X11 includes/libraries are only set in the ngmx subdirectory!
 527     if(NOT X11_FOUND)
 528         message(FATAL_ERROR
 529                 "X11 include files and/or libraries were not found. "
 530                 "Set GMX_X11=OFF to compile without X11 support. "
 531                 "gmx view will not be available.")
 532     endif()
 533     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 534 endif()
 535
 536 include(ThreadMPI)
 537 # Enable core threading facilities
 538 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 539 # Enable tMPI C++ support
 540 tmpi_enable_cxx()
 541 if(GMX_THREAD_MPI)
 542     # enable MPI functions
 543     tmpi_enable()
 544     set(MPI_IN_PLACE_EXISTS 1)
 545 endif()
 546 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 547 if (TMPI_ATOMICS_DISABLED)
 548    add_definitions(-DTMPI_ATOMICS_DISABLED)
 549 endif()
 550
 551 # now that we have detected the dependencies, do the second GPU configure pass
 552 gmx_gpu_setup()
 553
 554 if(CYGWIN)
 555     set(GMX_CYGWIN 1)
 556 endif()
 557
 558 if(WIN32)
 559     set(GMX_NATIVE_WINDOWS 1)
 560     # This makes windows.h not declare min/max as macros that would break
 561     # C++ code using std::min/std::max.
 562     add_definitions(-DNOMINMAX)
 563 endif()
 564
 565 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 566     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 567         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 568     endif()
 569     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 570         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 571     endif()
 572 endif()
 573
 574 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 575     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 576 endif()
 577 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 578 mark_as_advanced(GMX_BUILD_UNITTESTS)
 579 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 580 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 581     message(FATAL_ERROR
 582         "Cannot build unit tests without libxml2. "
 583         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 584 endif()
 585
 586 ########################################################################
 587 # Our own GROMACS tests
 588 ########################################################################
 589
 590 add_definitions( -DHAVE_CONFIG_H )
 591 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 592 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 593 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 594 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 595
 596 include(gmxTestInlineASM)
 597 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 598
 599 include(gmxSetBuildInformation)
 600 gmx_set_build_information()
 601 # Turn on RDTSCP if:
 602 # - the build system's CPU supports it
 603 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 604 #   at this point means that the user set it).
 605 # Note: it's better to not use the later set value of GMX_SIMD because
 606 # it reflects the system's capability of both compiling and running AVX code.
 607 # TODO: After merge with 5.0 one could implement a cache variable dependency
 608 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 609 # after the first cmake pass.
 610 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 611     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 612 else()
 613     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 614 endif()
 615 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 616 mark_as_advanced(GMX_USE_RDTSCP)
 617 if(GMX_USE_RDTSCP)
 618     set(HAVE_RDTSCP 1)
 619 endif()
 620
 621 include(gmxTestLargeFiles)
 622 gmx_test_large_files(GMX_LARGEFILES)
 623
 624 include(gmxTestSignal)
 625 gmx_test_sigusr1(HAVE_SIGUSR1)
 626
 627 include(gmxTestPipes)
 628 gmx_test_pipes(HAVE_PIPES)
 629
 630 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 631
 632 include(gmxTestXDR)
 633 gmx_test_xdr(GMX_SYSTEM_XDR)
 634 if(NOT GMX_SYSTEM_XDR)
 635     set(GMX_INTERNAL_XDR 1)
 636 endif()
 637
 638
 639 ##################################################
 640 # Process SIMD instruction settings
 641 ##################################################
 642 # This checks what flags to add in order to
 643 # support the SIMD instructions we need, it sets
 644 # correct defines for the SIMD instructions supported,
 645 # and adds advanced options to control accuracy
 646 # for SIMD math operations.
 647 include(gmxManageSimd)
 648 gmx_manage_simd()
 649
 650 # Process QM/MM Settings
 651 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 652     set(GMX_QMMM_GAUSSIAN 1)
 653 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 654     set(GMX_QMMM_MOPAC 1)
 655 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 656     set(GMX_QMMM_GAMESS 1)
 657 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 658     set(GMX_QMMM_ORCA 1)
 659 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 660     # nothing to do
 661 else()
 662     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 663 endif()
 664
 665
 666 ##################################################
 667 # Process FFT library settings
 668 ##################################################
 669 include(gmxManageFFTLibraries)
 670
 671
 672 include(gmxManageLinearAlgebraLibraries)
 673
 674 # Whether GROMACS will really try to compile support for VMD plugins
 675 set(GMX_USE_PLUGINS OFF)
 676
 677 if(GMX_LOAD_PLUGINS)
 678   if(NOT WIN32)
 679     # Native Windows does not have, nor need dlopen
 680     include(gmxTestdlopen)
 681     gmx_test_dlopen(HAVE_DLOPEN)
 682   endif()
 683
 684   # so, should we use plug-ins?
 685   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 686     if(NOT VMD_QUIETLY)
 687       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 688     endif()
 689     if(NOT GMX_VMD_PLUGIN_PATH)
 690       find_package(VMD)
 691     endif()
 692     set(GMX_USE_PLUGINS ON)
 693     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 694     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 695   else()
 696     set(PKG_DL_LIBS)
 697   endif()
 698 endif()
 699 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 700
 701 # Link real-time library for POSIX timers. The check for clock_gettime
 702 # confirms the linkability of rt.
 703 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 704     list(APPEND GMX_EXTRA_LIBRARIES rt)
 705 endif()
 706
 707 # Math and thread libraries must often come after all others when linking...
 708 if(HAVE_LIBM)
 709     list(APPEND GMX_EXTRA_LIBRARIES m)
 710 endif()
 711
 712 option(GMX_NACL "Configure for Native Client builds" OFF)
 713 if (GMX_NACL)
 714   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 715   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 716   # TODO: Is this still necessary with the check for its presence?
 717   set(GMX_USE_NICE 0)
 718   set(GMX_NO_RENAME 1)
 719 endif()
 720 mark_as_advanced(GMX_NACL)
 721
 722 if(GMX_FAHCORE)
 723   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 724       "Path to swindirect.h")
 725   include_directories(${COREWRAP_INCLUDE_DIR})
 726 endif()
 727
 728 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 729 # produce warnings if that fails.
 730 set(build_help_default AUTO)
 731 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 732     set(build_help_default OFF)
 733 endif()
 734 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 735 mark_as_advanced(GMX_BUILD_HELP)
 736 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 737     message(FATAL_ERROR
 738         "Rebuilding shell completions or man pages is not supported for "
 739         "in-source builds from a source distribution. "
 740         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 741 endif()
 742
 743 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 744 # these are set after everything else
 745 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 746     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 747     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 748     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 749     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 750 else()
 751     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 752     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 753     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 754     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 755     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 756     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 757     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 758     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 759     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 760 endif()
 761
 762 if(NOT GMX_OPENMP)
 763     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 764     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 765     unset(OpenMP_C_FLAGS CACHE)
 766     unset(OpenMP_CXX_FLAGS CACHE)
 767 else()
 768     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 769     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 770 endif()
 771
 772 ########################################################################
 773 # Specify install locations
 774 ########################################################################
 775 # Use GNUInstallDirs to set paths on multiarch systems.
 776 include(GNUInstallDirs)
 777
 778 # Customization for the installation tree paths.
 779 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 780     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 781 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 782     "Data installation directory under share/ (default: gromacs)")
 783 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 784
 785 # These variables are used internally to provide a central location for
 786 # customizing the install locations.
 787 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 788 set(BIN_INSTALL_DIR       bin)
 789 # This variable also gets written into config.h for use in finding the data
 790 # directories.
 791 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 792 set(MAN_INSTALL_DIR       share/man)
 793 # If the nesting level wrt. the installation root is changed,
 794 # gromacs-config.cmake.cmakein needs to be adapted.
 795 set(CMAKE_INSTALL_DIR     share/cmake)
 796 # TODO: Make GMXRC adapt if this is changed
 797 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 798 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 799 set(INCL_INSTALL_DIR      include)
 800
 801 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 802
 803 # Binary and library suffix options
 804 include(gmxManageSuffixes)
 805
 806 ################################################################
 807 # Shared library load path settings
 808 ################################################################
 809 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 810 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 811 # was added.
 812
 813 if(NOT GMX_BUILD_SHARED_EXE)
 814     # No rpath
 815     set(CMAKE_SKIP_RPATH TRUE)
 816     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 817     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 818 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 819    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 820     # The build folder always has bin/ and lib/; if we are also going to
 821     # install to lib/, then the installation RPATH works also in the build
 822     # tree.  This makes installation slightly faster (no need to rewrite the
 823     # RPATHs), and makes the binaries in the build tree relocatable.
 824     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 825         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 826     endif()
 827     # Set the RPATH as relative to the executable location to make the
 828     # binaries relocatable.
 829     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 830         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 831     else()
 832         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 833     endif()
 834     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 835     set(CMAKE_MACOSX_RPATH 1)
 836 else()
 837     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 838     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 839         # Set the RPATH options manually.
 840         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 841         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 842     else()
 843         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 844         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 845     endif()
 846 endif()
 847
 848 #COPYING file: Only necessary for binary distributions.
 849 #Simpler to always install.
 850 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 851
 852 if (GMX_BUILD_FOR_COVERAGE)
 853     # Code heavy with asserts makes conditional coverage close to useless metric,
 854     # as by design most of the false branches are impossible to trigger in
 855     # correctly functioning code.  And the benefit of testing those that could
 856     # be triggered by using an API against its specification isn't usually
 857     # worth the effort.
 858     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 859 endif()
 860
 861 if (BUILD_TESTING)
 862     # "tests" target builds all the separate test binaries.
 863     add_custom_target(tests)
 864     # "run-ctest" is an internal target that actually runs the tests.
 865     # This is necessary to be able to add separate targets that execute as part
 866     # of 'make check', but are ensured to be executed after the actual tests.
 867     add_custom_target(run-ctest
 868                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 869                       COMMENT "Running all tests"
 870                       VERBATIM)
 871     add_dependencies(run-ctest tests)
 872     # "check" target builds and runs all tests.
 873     add_custom_target(check DEPENDS run-ctest)
 874 endif()
 875
 876 if (NOT GMX_BUILD_MDRUN_ONLY)
 877     add_subdirectory(docs)
 878     add_subdirectory(share)
 879     add_subdirectory(scripts)
 880 endif()
 881 add_subdirectory(src)
 882
 883 if (BUILD_TESTING)
 884     add_subdirectory(tests)
 885 endif()
 886
 887 gmx_cpack_write_config()
 888
 889 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 890 # Don't bother the user after the first configure pass.
 891 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 892     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 893 endif()
 894 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 895
 896 #######################
 897 ## uninstall target
 898 #######################
 899 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 900                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 901                   IMMEDIATE @ONLY)
 902 ###########################
 903 ADD_CUSTOM_TARGET(uninstall
 904                   "${CMAKE_COMMAND}" -P
 905                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 906 ###########################
 907 set_directory_properties(PROPERTIES
 908             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")