src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 ######################################
  36 # Output compiler and CFLAGS used
  37 ######################################
  38 include(GetCompilerInfo.cmake)
  39 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
  40 get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
  41 if(GMX_USE_CUDA)
  42     if(NOT GMX_CLANG_CUDA)
  43         GMX_SET_CUDA_NVCC_FLAGS()
  44     endif()
  45
  46     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_COMPILER_FLAGS)
  47 endif()
  48
  49 configure_file(config.h.cmakein config.h)
  50 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
  51 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)
  52
  53 ####
  54 set(IGNORED_CLANG_ALL_WARNINGS
  55     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  56     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  57     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  58     "-Wno-documentation-unknown-command" #Custom commands are used
  59     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  60     "-Wno-switch-enum" # default statement for enum is OK
  61
  62     #Following ones are undecided/TODO
  63     "-Wno-disabled-macro-expansion"
  64     "-Wno-cast-align"
  65     "-Wno-reserved-id-macro"
  66     "-Wno-global-constructors"
  67     "-Wno-exit-time-destructors"
  68     "-Wno-unused-macros"
  69     "-Wno-weak-vtables"
  70     "-Wno-conditional-uninitialized"
  71     "-Wno-format-nonliteral"
  72     "-Wno-shadow"
  73     "-Wno-cast-qual"
  74     "-Wno-documentation"
  75     "-Wno-used-but-marked-unused"
  76     "-Wno-padded"
  77     "-Wno-float-equal"
  78     "-Wno-old-style-cast"
  79     "-Wno-conversion"
  80     "-Wno-double-promotion")
  81 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  82
  83 if (GMX_CLANG_TIDY)
  84    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
  85    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
  86        DOC "Path to clang-tidy executable")
  87    if(NOT CLANG_TIDY_EXE)
  88        message(FATAL_ERROR "clang-tidy not found.")
  89    endif()
  90    if(CMAKE_VERSION VERSION_LESS "3.6")
  91        message(FATAL_ERROR "clang-tidy support requires cmake 3.6.")
  92    endif()
  93 endif()
  94 #####
  95
  96 if (BUILD_TESTING)
  97     if(NOT GMX_DEVELOPER_BUILD)
  98         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
  99     endif()
 100     if (GMX_BUILD_UNITTESTS)
 101         add_subdirectory(external/googletest)
 102     endif()
 103     include(testutils/TestMacros.cmake)
 104     add_subdirectory(testutils)
 105 endif()
 106
 107 add_subdirectory(gromacs)
 108 add_subdirectory(programs)
 109
 110 # Activate targets for new C++ API components and docs.
 111 if(GMX_NATIVE_WINDOWS)
 112     # GMXAPI has not been tested in Microsoft environments.
 113     set(_GMXAPI_DEFAULT OFF)
 114 else()
 115     set(_GMXAPI_DEFAULT ON)
 116 endif()
 117 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 118 if (GMXAPI)
 119    add_subdirectory(api)
 120 endif()