src/testutils/TestMacros.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CMakeParseArguments)
  36
  37 function (gmx_add_unit_test_library NAME)
  38     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  39         add_library(${NAME} STATIC ${UNITTEST_TARGET_OPTIONS} ${ARGN})
  40         gmx_target_compile_options(${NAME})
  41         target_compile_definitions(${NAME} PRIVATE HAVE_CONFIG_H)
  42         target_include_directories(${NAME} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  43         target_link_libraries(${NAME} PRIVATE testutils gmock)
  44     endif()
  45 endfunction ()
  46
  47 function (gmx_add_gtest_executable EXENAME)
  48     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  49         set(_options MPI HARDWARE_DETECTION)
  50         cmake_parse_arguments(ARG "${_options}" "" "" ${ARGN})
  51         set(_source_files ${ARG_UNPARSED_ARGUMENTS})
  52
  53         file(RELATIVE_PATH _input_files_path ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  54         set(_temporary_files_path "${CMAKE_CURRENT_BINARY_DIR}/Testing/Temporary")
  55         file(MAKE_DIRECTORY ${_temporary_files_path})
  56         # Note that the quotation marks in the next line form part of
  57         # the defined symbol, so that the macro replacement in the
  58         # source file is as a string.
  59         # These are only needed for unittest_main.cpp, but for simplicity used
  60         # for the whole target (since there may be multiple executables in the
  61         # same directory, it is not straightforward to use a source file
  62         # property).
  63         set(EXTRA_COMPILE_DEFINITIONS
  64             TEST_DATA_PATH="${_input_files_path}"
  65             TEST_TEMP_PATH="${_temporary_files_path}")
  66         if (ARG_MPI)
  67             list(APPEND EXTRA_COMPILE_DEFINITIONS
  68                  TEST_USES_MPI=true)
  69         endif()
  70         if (ARG_HARDWARE_DETECTION)
  71             list(APPEND EXTRA_COMPILE_DEFINITIONS
  72                  TEST_USES_HARDWARE_DETECTION=true)
  73         endif()
  74
  75         add_executable(${EXENAME} ${UNITTEST_TARGET_OPTIONS}
  76             ${_source_files} ${TESTUTILS_DIR}/unittest_main.cpp)
  77         gmx_target_compile_options(${EXENAME})
  78         target_compile_definitions(${EXENAME} PRIVATE HAVE_CONFIG_H ${EXTRA_COMPILE_DEFINITIONS})
  79         target_include_directories(${EXENAME} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  80         # Permit GROMACS code to include externally developed headers,
  81         # such as the functionality from the nonstd project that we
  82         # use for gmx::compat::optional. These are included as system
  83         # headers so that no warnings are issued from them.
  84         target_include_directories(${EXENAME} SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  85
  86         target_link_libraries(${EXENAME} PRIVATE
  87             testutils libgromacs gmock
  88             ${GMX_COMMON_LIBRARIES} ${GMX_EXE_LINKER_FLAGS})
  89
  90         if(GMX_CLANG_TIDY)
  91             set_target_properties(${EXENAME} PROPERTIES CXX_CLANG_TIDY
  92                 "${CLANG_TIDY_EXE};-warnings-as-errors=*;-header-filter=.*")
  93         endif()
  94         if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^6\.0")
  95             target_compile_options(${EXENAME} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS} -Wno-gnu-zero-variadic-macro-arguments -Wno-zero-as-null-pointer-constant -Wno-missing-variable-declarations>)
  96         endif()
  97     endif()
  98 endfunction()
  99
 100 # This function can be called with extra options and arguments:
 101 #   OPENMP_THREADS <N>    declares the requirement to run the test binary with N OpenMP
 102 #                           threads (when supported by the build configuration)
 103 #   MPI_RANKS <N>         declares the requirement to run the test binary with N ranks
 104 #   INTEGRATION_TEST      requires the use of the IntegrationTest label in CTest
 105 #   SLOW_TEST             requires the use of the SlowTest label in CTest, and
 106 #                         increase the length of the ctest timeout.
 107 #
 108 # TODO When a test case needs it, generalize the MPI_RANKS mechanism so
 109 # that ctest can run the test binary over a range of numbers of MPI
 110 # ranks.
 111 function (gmx_register_gtest_test NAME EXENAME)
 112     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
 113         set(_options INTEGRATION_TEST SLOW_TEST)
 114         set(_one_value_args MPI_RANKS OPENMP_THREADS)
 115         cmake_parse_arguments(ARG "${_options}" "${_one_value_args}" "" ${ARGN})
 116         set(_xml_path ${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml)
 117         set(_labels GTest)
 118         set(_timeout 30)
 119         if (ARG_INTEGRATION_TEST)
 120             list(APPEND _labels IntegrationTest)
 121             # Slow build configurations should have longer timeouts.
 122             # Both OpenCL (from JIT) and ThreadSanitizer (from how it
 123             # checks) can take signficantly more time than other
 124             # configurations.
 125             if (GMX_USE_OPENCL)
 126                 set(_timeout 240)
 127             elseif (${CMAKE_BUILD_TYPE} STREQUAL TSAN)
 128                 set(_timeout 300)
 129             else()
 130                 set(_timeout 120)
 131             endif()
 132             gmx_get_test_prefix_cmd(_prefix_cmd IGNORE_LEAKS)
 133         elseif (ARG_SLOW_TEST)
 134             list(APPEND _labels SlowTest)
 135             set(_timeout 480)
 136             gmx_get_test_prefix_cmd(_prefix_cmd IGNORE_LEAKS)
 137         else()
 138             list(APPEND _labels UnitTest)
 139             gmx_get_test_prefix_cmd(_prefix_cmd)
 140         endif()
 141         set(_cmd ${_prefix_cmd} $<TARGET_FILE:${EXENAME}>)
 142         if (ARG_OPENMP_THREADS)
 143             if (GMX_OPENMP)
 144                 list(APPEND _cmd -ntomp ${ARG_OPENMP_THREADS})
 145             endif()
 146         endif()
 147         if (ARG_MPI_RANKS)
 148             if (NOT GMX_CAN_RUN_MPI_TESTS)
 149                 return()
 150             endif()
 151             list(APPEND _labels MpiTest)
 152             if (GMX_MPI)
 153                 set(_cmd
 154                     ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} ${ARG_MPI_RANKS}
 155                     ${MPIEXEC_PREFLAGS} ${_cmd} ${MPIEXEC_POSTFLAGS})
 156             elseif (GMX_THREAD_MPI)
 157                 list(APPEND _cmd -ntmpi ${ARG_MPI_RANKS})
 158             endif()
 159         endif()
 160         add_test(NAME ${NAME}
 161                  COMMAND ${_cmd} --gtest_output=xml:${_xml_path})
 162         set_tests_properties(${NAME} PROPERTIES LABELS "${_labels}")
 163         set_tests_properties(${NAME} PROPERTIES TIMEOUT ${_timeout})
 164         add_dependencies(tests ${EXENAME})
 165     endif()
 166 endfunction ()
 167
 168 function (gmx_add_unit_test NAME EXENAME)
 169     gmx_add_gtest_executable(${EXENAME} ${ARGN})
 170     gmx_register_gtest_test(${NAME} ${EXENAME})
 171 endfunction()
 172
 173 function (gmx_add_mpi_unit_test NAME EXENAME RANKS)
 174     if (GMX_MPI OR (GMX_THREAD_MPI AND GTEST_IS_THREADSAFE))
 175         gmx_add_gtest_executable(${EXENAME} MPI ${ARGN})
 176         gmx_register_gtest_test(${NAME} ${EXENAME} MPI_RANKS ${RANKS})
 177     endif()
 178 endfunction()