cmake/gmxTestCXX11.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CheckCXXSourceCompiles)
  36
  37 # Check whether both a suitable C++11-compatible compiler and standard
  38 # library is available, and give a fatal error if not.
  39 #
  40 # Any required compiler flag for C++11 support is returned in
  41 # ${FLAG}. The other parameters are only inputs, naming variables that
  42 # contain flags that may have been detected, or set by the user.
  43 function(GMX_TEST_CXX11 CXX11_CXX_FLAG_NAME STDLIB_CXX_FLAG_NAME STDLIB_LIBRARIES_NAME)
  44
  45     # First check that the compiler is OK, and find the appropriate flag.
  46
  47     if(WIN32 AND NOT MINGW)
  48         set(CXX11_CXX_FLAG "/Qstd=c++0x")
  49     elseif(CYGWIN)
  50         set(CXX11_CXX_FLAG "-std=gnu++0x") #required for strdup
  51     else()
  52         set(CXX11_CXX_FLAG "-std=c++0x")
  53     endif()
  54     CHECK_CXX_COMPILER_FLAG("${CXX11_CXX_FLAG}" CXXFLAG_STD_CXX0X)
  55     if(NOT CXXFLAG_STD_CXX0X)
  56         set(CXX11_CXX_FLAG "")
  57     endif()
  58     set(CMAKE_REQUIRED_FLAGS "${CXX11_CXX_FLAG}")
  59     check_cxx_source_compiles(
  60 "struct a {
  61   explicit operator bool() {return true;}
  62   a() {};
  63   a(a&&) = default;
  64   a(const a&) = delete;
  65 };
  66 class b: public a {};
  67 b f() {
  68   return b();
  69 }
  70 constexpr int factorial(int n)
  71 {
  72     return n <= 1? 1 : (n * factorial(n - 1));
  73 }
  74 void checkRvalueReference(int &&);
  75 template <typename T> void someFunction();
  76 extern template void someFunction<int>();
  77 int main() {
  78   double *x = nullptr;
  79   int array[5] = { 1, 2, 3, 4, 5 };
  80   for (int& x : array)
  81     x *= 2;
  82 }" CXX11_SUPPORTED)
  83     if(CXX11_SUPPORTED)
  84         set(${CXX11_CXX_FLAG_NAME} ${CXX11_CXX_FLAG} PARENT_SCOPE)
  85     else()
  86         message(FATAL_ERROR "This version of GROMACS requires a C++11 compiler. Please use a newer compiler or use the GROMACS 5.1.x release. See the installation guide for details.")
  87     endif()
  88
  89     # Now check the standard library is OK
  90
  91     set(CMAKE_REQUIRED_FLAGS "${CXX11_CXX_FLAG} ${${STDLIB_CXX_FLAG_NAME}}")
  92     set(CMAKE_REQUIRED_LIBRARIES "${${STDLIB_LIBRARIES_NAME}}")
  93     check_cxx_source_compiles(
  94 "#include <map>
  95 #include <memory>
  96 #include <utility>
  97 int main() {
  98   typedef std::unique_ptr<int> intPointer;
  99   intPointer p(new int(10));
 100   std::map<int, std::unique_ptr<int>> m;
 101   m.insert(std::make_pair(5, std::move(p)));
 102 }" CXX11_STDLIB_PRESENT)
 103     if(NOT CXX11_STDLIB_PRESENT)
 104         message(FATAL_ERROR "This version of GROMACS requires C++11-compatible standard library. Please use a newer compiler, or a newer standard library, or use the GROMACS 5.1.x release. See the installation guide for details.")
 105     endif()
 106 endfunction()