CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxBuildTreeInfo)
  56 include(gmxVersionInfo)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  62     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  63 endif()
  64
  65 include(gmxBuildTypeReference)
  66 include(gmxBuildTypeProfile)
  67 include(gmxBuildTypeTSAN)
  68 include(gmxBuildTypeASAN)
  69 include(gmxBuildTypeMSAN)
  70 include(gmxBuildTypeReleaseWithAssert)
  71
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  74     # There's no need to offer a user the choice of ThreadSanitizer
  75     # Set the possible values of build type for cmake-gui
  76     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  77         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  78 endif()
  79 if(CMAKE_CONFIGURATION_TYPES)
  80     # Add appropriate GROMACS-specific build types for the Visual
  81     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  82     # are already present by default).
  83     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  84     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  85     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  86         "List of configuration types"
  87         FORCE)
  88 endif()
  89 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  90
  91 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  92
  93 # Set a default valgrind suppression file.
  94 # This unfortunately needs to duplicate information from CTest to work as
  95 # expected...
  96 set(MEMORYCHECK_SUPPRESSIONS_FILE
  97     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  98     CACHE FILEPATH
  99     "File that contains suppressions for the memory checker")
 100 include(CTest)
 101
 102 include(gmxCPackUtilities)
 103 gmx_cpack_init()
 104
 105 # Variables that accumulate stuff influencing the installed headers
 106 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 107 set(INSTALLED_HEADER_DEFINITIONS "")
 108
 109 ########################################################################
 110 # Check and warn if cache generated on a different host is being reused
 111 ########################################################################
 112 if(CMAKE_HOST_UNIX)
 113     execute_process(COMMAND hostname
 114                     OUTPUT_VARIABLE TMP_HOSTNAME
 115                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 116     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 117         message(WARNING "
 118             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 119             is being reused! This could lead to inconsistencies; therefore, it is
 120             recommended to regenerate the cache!")
 121     endif()
 122     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 123             "Hostname of the machine where the cache was generated.")
 124 endif()
 125
 126 ########################################################################
 127 # Detect architecture before setting options so we can alter defaults
 128 ########################################################################
 129 # Detect the architecture the compiler is targetting, detect
 130 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 131 # to use if none is specified, and populate the cache option for CPU
 132 # SIMD.
 133 include(gmxDetectTargetArchitecture)
 134 gmx_detect_target_architecture()
 135
 136 # Permit the user to specify a particular standard library, e.g. compiling
 137 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 138 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 139 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 140 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 141 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 142
 143 ########################################################################
 144 # Detect CXX11 support and flags
 145 ########################################################################
 146 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 147 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 148 # invalid options with the Intel Compilers, and we have added a line
 149 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 150 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 151 # a semicolon. Since this is also used as a separator in lists inside CMake,
 152 # that string ends up being split into two separate patterns, and the last
 153 # part is just a single word that also matches other messages. We solved this
 154 # by replacing the semicolon with a period that matches any character.
 155 #
 156 # These files should be removed from the source tree when a CMake version that
 157 # includes the features in question becomes required for building GROMACS.
 158 include(CheckCCompilerFlag)
 159 include(CheckCXXCompilerFlag)
 160
 161 # This must come early, since some of our configuration flag tests
 162 # depend on being able to compile C++11 source files.
 163 include(gmxTestCXX11)
 164 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 165
 166 # Make sure all C++ code will be compiled in C++11 mode, with the
 167 # expected standard library.
 168 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 199
 200 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 201 # GCC 4.6 requires CUDA 5.0 and VS2015 requires CUDA 8.0
 202 if(MSVC)
 203     set(REQUIRED_CUDA_VERSION 8.0)
 204 else()
 205     set(REQUIRED_CUDA_VERSION 5.0)
 206 endif()
 207 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 208
 209 # OpenCL required version: 1.1 or newer
 210 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 211
 212 if(NOT GMX_USE_OPENCL)
 213     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 214     include(gmxManageGPU)
 215     set(GMX_USE_CUDA ${GMX_GPU})
 216     if(GMX_GPU)
 217         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 218     else()
 219         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 220     endif()
 221 else()
 222     #Now the OpenCL path (for both AMD and NVIDIA)
 223     if(GMX_GPU)
 224         include(gmxManageOpenCL)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 226     else()
 227         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 228     endif()
 229 endif()
 230
 231 include(gmxDetectSimd)
 232 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 233
 234 gmx_option_multichoice(
 235     GMX_SIMD
 236     "SIMD instruction set for CPU kernels and compiler optimization"
 237     "${GMX_SUGGESTED_SIMD}"
 238     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 239
 240 if(GMX_TARGET_MIC)
 241     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 242 else()
 243     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 244 endif()
 245
 246 gmx_option_multichoice(
 247     GMX_FFT_LIBRARY
 248     "FFT library"
 249     "${GMX_FFT_LIBRARY_DEFAULT}"
 250     fftw3 mkl "fftpack[built-in]")
 251 gmx_dependent_option(
 252     GMX_BUILD_OWN_FFTW
 253     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 gmx_dependent_option(
 257     GMX_DISABLE_FFTW_MEASURE
 258     "Do not optimize FFTW setups (not needed with SSE)"
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 262 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 263
 264 gmx_option_multichoice(
 265     GMX_QMMM_PROGRAM
 266     "QM package for QM/MM"
 267     None
 268     none gaussian mopac gamess orca)
 269
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 271 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 272
 273 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 274
 275 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 276 mark_as_advanced(GMX_BROKEN_CALLOC)
 277 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 278 mark_as_advanced(GMX_LOAD_PLUGINS)
 279
 280 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 281
 282 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 283
 284 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 285
 286 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 287 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 288
 289 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 290 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 291
 292 option(GMX_BUILD_FOR_COVERAGE
 293        "Tune build for better code coverage metrics (e.g., disable asserts)"
 294        OFF)
 295 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 296
 297 option(GMX_DEVELOPER_BUILD
 298     "Enable Developer convenience features: always build unit-tests"
 299     OFF)
 300 mark_as_advanced(GMX_DEVELOPER_BUILD)
 301
 302 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 303 option(GMX_COMPILER_WARNINGS
 304     "Enable a default set of compiler warnings"
 305     ${GMX_COMPILER_WARNINGS_DEFAULT})
 306 mark_as_advanced(GMX_COMPILER_WARNINGS)
 307 # Always turn on compiler warnings with a developer build.
 308 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 309
 310 option(GMX_BUILD_SHARED_EXE
 311     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 312     ON)
 313 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 314
 315 ######################################################################
 316 # Detect OpenMP support
 317 ######################################################################
 318 # The OpenMP detection _must_ come before tests for other CFLAGS.
 319 include(gmxManageOpenMP)
 320
 321
 322
 323 ######################################################################
 324 # Compiler tests
 325 # These need to be done early (before further tests).
 326 #####################################################################
 327
 328 include(gmxCFlags)
 329 gmx_c_flags()
 330
 331 # This variable should be used for additional compiler flags which are not
 332 # generated in gmxCFlags nor are SIMD or MPI related.
 333 set(EXTRA_C_FLAGS "")
 334 set(EXTRA_CXX_FLAGS "")
 335
 336 # Run through a number of tests for buggy compilers and other issues
 337 include(gmxTestCompilerProblems)
 338 gmx_test_compiler_problems()
 339 # GMX_SIMD will not be set automatically until the second
 340 # pass (which is not strictly guaranteed to occur), so putting this
 341 # check here among logically-related tests is inefficient, but the
 342 # potential loss is likely zero.
 343 if(GMX_SIMD STREQUAL "AVX_256"
 344         AND CMAKE_COMPILER_IS_GNUCC
 345         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 346             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 347     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 348     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 349 endif()
 350
 351 # Implement double-precision option. This is complicated because we
 352 # need installed headers to use the precision mode of the build that
 353 # produced the library, but cannot use config.h in that case. We also
 354 # want such variables to always have a definition, because #if is more
 355 # robust than #ifdef. So, we put this value on the compiler command
 356 # line in all cases.
 357 #
 358 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 359 # because no installed header needs it
 360 if(GMX_DOUBLE)
 361     set(GMX_DOUBLE_VALUE 1)
 362 else()
 363     set(GMX_DOUBLE_VALUE 0)
 364 endif()
 365 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 366 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 367
 368 if(WIN32)
 369     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 370     add_definitions(-DGMX_HAVE_WINSOCK)
 371 endif()
 372
 373
 374
 375 ########################################################################
 376 # Basic system tests (standard libraries, headers, functions, types)   #
 377 ########################################################################
 378 include(CheckIncludeFiles)
 379 include(CheckIncludeFileCXX)
 380 check_include_files(unistd.h     HAVE_UNISTD_H)
 381 check_include_files(pwd.h        HAVE_PWD_H)
 382 check_include_files(dirent.h     HAVE_DIRENT_H)
 383 check_include_files(time.h       HAVE_TIME_H)
 384 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 385 check_include_files(io.h         HAVE_IO_H)
 386 check_include_files(sched.h      HAVE_SCHED_H)
 387
 388 check_include_files(regex.h      HAVE_POSIX_REGEX)
 389 # TODO: It could be nice to inform the user if no regex support is found,
 390 # as selections won't be fully functional.
 391
 392 include(CheckCXXSymbolExists)
 393 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 394 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 395 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 396 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 397 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 398 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 399 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 400 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 401
 402 # We cannot check for the __builtins as symbols, but check if code compiles
 403 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 404 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 405 if(MSVC)
 406     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 407     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 408 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 409     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 410     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 411 endif()
 412
 413 include(CheckLibraryExists)
 414 find_library(HAVE_LIBM m)
 415 mark_as_advanced(HAVE_LIBM)
 416 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 417 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 418
 419 include(TestSchedAffinity)
 420 test_sched_affinity(HAVE_SCHED_AFFINITY)
 421
 422 # Aligned memory allocation. We need to check for both mm_malloc(),
 423 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 424 include(gmxTestMMMalloc)
 425 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 426 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 427 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 428 if(MSVC)
 429     # No need to waste time on this test on platforms where it will never be true
 430     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 431 endif()
 432
 433 include(TestBigEndian)
 434 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 435
 436 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 437
 438 # Management of GROMACS options for specific toolchains should go
 439 # here. Because the initial settings for some of the main options have
 440 # already happened, but things like library detection and MPI compiler
 441 # feature detection have not, the docstrings for any over-rides of
 442 # GROMACS defaults or user settings will make sense. Also, any
 443 # toolchain-related reasons for choosing whether to detect various
 444 # things can be sorted out now, before the detection takes place.
 445 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 446     include(gmxManageBlueGene)
 447 endif()
 448
 449 if(GMX_TARGET_FUJITSU_SPARC64)
 450     include(gmxManageFujitsuSparc64)
 451 endif()
 452
 453 ########################################################################
 454 #Process MPI settings
 455 ########################################################################
 456 include(gmxManageMPI)
 457
 458
 459 ########################################################################
 460 #Process shared/static library settings
 461 ########################################################################
 462 include(gmxManageSharedLibraries)
 463
 464
 465 ########################################################################
 466 # Find external packages                                               #
 467 ########################################################################
 468
 469 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 470 find_package(ZLIB QUIET)
 471 include(gmxTestZLib)
 472 gmx_test_zlib(HAVE_ZLIB)
 473
 474 # Unconditionally find the package, as it is also required for unit
 475 # tests. This exports LIBXML2_FOUND, which we should not use because
 476 # it does not tell us that linking will succeed. Instead, we test that
 477 # next.
 478 #if(DEFINED LIBXML2_LIBRARIES)
 479 #  set(LibXml2_FIND_QUIETLY TRUE)
 480 #endif()
 481 #find_package(LibXml2)
 482 #include(gmxTestLibXml2)
 483 #gmx_test_libxml2(HAVE_LIBXML2)
 484 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 485 #set(PKG_XML "")
 486 #mark_as_advanced(GMX_XML)
 487 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 488 #if(GMX_XML AND NOT HAVE_LIBXML2)
 489 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 490 #endif()
 491 #if(GMX_XML)
 492 #    include_directories(${LIBXML2_INCLUDE_DIR})
 493 #    set(PKG_XML libxml-2.0)
 494 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 495 #endif()
 496
 497 if(DEFINED HWLOC_LIBRARIES)
 498   set(Hwloc_FIND_QUIETLY TRUE)
 499 endif()
 500 find_package(Hwloc 1.5)
 501 if(HWLOC_FOUND)
 502     set(GMX_HWLOC_DEFAULT ON)
 503 else()
 504     set(GMX_HWLOC_DEFAULT OFF)
 505 endif()
 506 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 507 if(GMX_HWLOC)
 508     if(HWLOC_FOUND)
 509         include_directories(${HWLOC_INCLUDE_DIRS})
 510         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 511     else()
 512         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 513     endif()
 514 endif()
 515
 516 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 517 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 518 if(GMX_EXTERNAL_TINYXML2)
 519     # Find an external TinyXML-2 library.
 520     find_package(TinyXML-2 3.0.0)
 521     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 522     if(NOT HAVE_TINYXML2)
 523         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 524     endif()
 525 endif()
 526
 527 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 528 mark_as_advanced(GMX_EXTRAE)
 529
 530 if (GMX_EXTRAE)
 531   find_package(EXTRAE)
 532   if(EXTRAE_FOUND)
 533     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 534     set(HAVE_EXTRAE 1)
 535   else()
 536     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 537   endif()
 538 endif()
 539
 540 option(GMX_X11 "Use X window system" OFF)
 541 if (GMX_X11)
 542     find_package(X11)
 543     # X11 includes/libraries are only set in the ngmx subdirectory!
 544     if(NOT X11_FOUND)
 545         message(FATAL_ERROR
 546                 "X11 include files and/or libraries were not found. "
 547                 "Set GMX_X11=OFF to compile without X11 support. "
 548                 "gmx view will not be available.")
 549     endif()
 550     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 551 endif()
 552
 553 include(ThreadMPI)
 554 # Enable core threading facilities
 555 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 556 # Enable tMPI C++ support
 557 tmpi_enable_cxx()
 558 if(GMX_THREAD_MPI)
 559     # enable MPI functions
 560     tmpi_enable()
 561     set(MPI_IN_PLACE_EXISTS 1)
 562 endif()
 563 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 564 if (TMPI_ATOMICS_DISABLED)
 565    add_definitions(-DTMPI_ATOMICS_DISABLED)
 566 endif()
 567
 568 # Note this relies on zlib detection having already run
 569 include(gmxManageTNG)
 570
 571 include(gmxManageLmfit)
 572
 573 if(GMX_GPU)
 574     # now that we have detected the dependencies, do the second configure pass
 575     gmx_gpu_setup()
 576 else()
 577     mark_as_advanced(CUDA_HOST_COMPILER)
 578 endif()
 579
 580 if(CYGWIN)
 581     set(GMX_CYGWIN 1)
 582 endif()
 583
 584 if(WIN32)
 585     set(GMX_NATIVE_WINDOWS 1)
 586     # This makes windows.h not declare min/max as macros that would break
 587     # C++ code using std::min/std::max.
 588     add_definitions(-DNOMINMAX)
 589 endif()
 590
 591 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 592     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 593         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 594     endif()
 595     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 596         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 597     endif()
 598 endif()
 599
 600 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 601 mark_as_advanced(GMX_BUILD_UNITTESTS)
 602 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 603
 604 ########################################################################
 605 # Our own GROMACS tests
 606 ########################################################################
 607
 608 add_definitions( -DHAVE_CONFIG_H )
 609 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 610 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 611 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 612 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 613
 614 include(gmxTestInlineASM)
 615 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 616
 617 include(gmxSetBuildInformation)
 618 gmx_set_build_information()
 619 # Turn on RDTSCP if:
 620 # - the build system's CPU supports it
 621 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 622 #   at this point means that the user set it).
 623 # Note: it's better to not use the later set value of GMX_SIMD because
 624 # it reflects the system's capability of both compiling and running AVX code.
 625 # TODO: After merge with 5.0 one could implement a cache variable dependency
 626 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 627 # after the first cmake pass.
 628 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 629     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 630 else()
 631     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 632 endif()
 633 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 634 mark_as_advanced(GMX_USE_RDTSCP)
 635 if(GMX_USE_RDTSCP)
 636     set(HAVE_RDTSCP 1)
 637 endif()
 638
 639 include(gmxTestLargeFiles)
 640 gmx_test_large_files(GMX_LARGEFILES)
 641
 642 include(gmxTestSignal)
 643 gmx_test_sigusr1(HAVE_SIGUSR1)
 644
 645 include(gmxTestPipes)
 646 gmx_test_pipes(HAVE_PIPES)
 647
 648 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 649
 650 include(gmxTestXDR)
 651 gmx_test_xdr(GMX_SYSTEM_XDR)
 652 if(NOT GMX_SYSTEM_XDR)
 653     set(GMX_INTERNAL_XDR 1)
 654 endif()
 655
 656
 657 ##################################################
 658 # Process SIMD instruction settings
 659 ##################################################
 660 # This checks what flags to add in order to
 661 # support the SIMD instructions we need, it sets
 662 # correct defines for the SIMD instructions supported,
 663 # and adds advanced options to control accuracy
 664 # for SIMD math operations.
 665 include(gmxManageSimd)
 666 gmx_manage_simd()
 667
 668 include(gmxManageCycleCounters)
 669 gmx_manage_cycle_counters()
 670
 671 # Process QM/MM Settings
 672 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 673     set(GMX_QMMM_GAUSSIAN 1)
 674 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 675     set(GMX_QMMM_MOPAC 1)
 676 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 677     set(GMX_QMMM_GAMESS 1)
 678 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 679     set(GMX_QMMM_ORCA 1)
 680 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 681     # nothing to do
 682 else()
 683     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 684 endif()
 685
 686
 687 ##################################################
 688 # Process FFT library settings
 689 ##################################################
 690 include(gmxManageFFTLibraries)
 691
 692
 693 include(gmxManageLinearAlgebraLibraries)
 694
 695 # Whether GROMACS will really try to compile support for VMD plugins
 696 set(GMX_USE_PLUGINS OFF)
 697
 698 if(GMX_LOAD_PLUGINS)
 699   if(NOT WIN32)
 700     # Native Windows does not have, nor need dlopen
 701     include(gmxTestdlopen)
 702     gmx_test_dlopen(HAVE_DLOPEN)
 703   endif()
 704
 705   # so, should we use plug-ins?
 706   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 707     if(NOT VMD_QUIETLY)
 708       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 709     endif()
 710     if(NOT GMX_VMD_PLUGIN_PATH)
 711       find_package(VMD)
 712     endif()
 713     set(GMX_USE_PLUGINS ON)
 714     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 715     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 716   else()
 717     set(PKG_DL_LIBS)
 718   endif()
 719 endif()
 720 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 721
 722 # Link real-time library for POSIX timers. The check for clock_gettime
 723 # confirms the linkability of rt.
 724 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 725     list(APPEND GMX_EXTRA_LIBRARIES rt)
 726 endif()
 727
 728 # Math and thread libraries must often come after all others when linking...
 729 if(HAVE_LIBM)
 730     list(APPEND GMX_EXTRA_LIBRARIES m)
 731 endif()
 732
 733 option(GMX_NACL "Configure for Native Client builds" OFF)
 734 if (GMX_NACL)
 735   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 736   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 737   # TODO: Is this still necessary with the check for its presence?
 738   set(GMX_USE_NICE 0)
 739   set(GMX_NO_RENAME 1)
 740 endif()
 741 mark_as_advanced(GMX_NACL)
 742
 743 if(GMX_FAHCORE)
 744   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 745       "Path to swindirect.h")
 746   include_directories(${COREWRAP_INCLUDE_DIR})
 747 endif()
 748
 749 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 750 # produce warnings if that fails.
 751 set(build_help_default AUTO)
 752 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 753     set(build_help_default OFF)
 754 endif()
 755 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 756 mark_as_advanced(GMX_BUILD_HELP)
 757 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 758     message(FATAL_ERROR
 759         "Rebuilding shell completions or man pages is not supported for "
 760         "in-source builds from a source distribution. "
 761         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 762 endif()
 763
 764 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 765 # these are set after everything else
 766 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 767     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 768     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 769     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 770     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 771 else()
 772     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 773     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 774     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 775     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 776     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 777     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 778     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 779     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 780     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 781 endif()
 782
 783 if(NOT GMX_OPENMP)
 784     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 785     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 786     unset(OpenMP_C_FLAGS CACHE)
 787     unset(OpenMP_CXX_FLAGS CACHE)
 788 else()
 789     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 790     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 791 endif()
 792
 793 ########################################################################
 794 # Specify install locations
 795 ########################################################################
 796 # Use GNUInstallDirs to set paths on multiarch systems.
 797 include(GNUInstallDirs)
 798
 799 # Customization for the installation tree paths.
 800 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 801     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 802 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 803     "Data installation directory under share/ (default: gromacs)")
 804 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 805
 806 # These variables are used internally to provide a central location for
 807 # customizing the install locations.
 808 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 809 set(BIN_INSTALL_DIR       bin)
 810 # This variable also gets written into config.h for use in finding the data
 811 # directories.
 812 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 813 set(MAN_INSTALL_DIR       share/man)
 814 # If the nesting level wrt. the installation root is changed,
 815 # gromacs-config.cmake.cmakein needs to be adapted.
 816 set(CMAKE_INSTALL_DIR     share/cmake)
 817 # TODO: Make GMXRC adapt if this is changed
 818 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 819 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 820 set(INCL_INSTALL_DIR      include)
 821
 822 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 823
 824 # Binary and library suffix options
 825 include(gmxManageSuffixes)
 826
 827 ################################################################
 828 # Shared library load path settings
 829 ################################################################
 830 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 831 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 832 # was added.
 833
 834 if(NOT GMX_BUILD_SHARED_EXE)
 835     # No rpath
 836     set(CMAKE_SKIP_RPATH TRUE)
 837     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 838     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 839 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 840    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 841     # The build folder always has bin/ and lib/; if we are also going to
 842     # install to lib/, then the installation RPATH works also in the build
 843     # tree.  This makes installation slightly faster (no need to rewrite the
 844     # RPATHs), and makes the binaries in the build tree relocatable.
 845     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 846         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 847     endif()
 848     # Set the RPATH as relative to the executable location to make the
 849     # binaries relocatable.
 850     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 851         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 852     else()
 853         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 854     endif()
 855     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 856     set(CMAKE_MACOSX_RPATH 1)
 857 else()
 858     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 859     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 860         # Set the RPATH options manually.
 861         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 862         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 863     else()
 864         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 865         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 866     endif()
 867 endif()
 868
 869 #COPYING file: Only necessary for binary distributions.
 870 #Simpler to always install.
 871 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 872
 873 if (GMX_BUILD_FOR_COVERAGE)
 874     # Code heavy with asserts makes conditional coverage close to useless metric,
 875     # as by design most of the false branches are impossible to trigger in
 876     # correctly functioning code.  And the benefit of testing those that could
 877     # be triggered by using an API against its specification isn't usually
 878     # worth the effort.
 879     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 880 endif()
 881
 882 if (BUILD_TESTING)
 883     # "tests" target builds all the separate test binaries.
 884     add_custom_target(tests)
 885     # "run-ctest" is an internal target that actually runs the tests.
 886     # This is necessary to be able to add separate targets that execute as part
 887     # of 'make check', but are ensured to be executed after the actual tests.
 888     add_custom_target(run-ctest
 889                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 890                       COMMENT "Running all tests"
 891                       VERBATIM)
 892     add_dependencies(run-ctest tests)
 893     # "check" target builds and runs all tests.
 894     add_custom_target(check DEPENDS run-ctest)
 895 endif()
 896
 897 if (NOT GMX_BUILD_MDRUN_ONLY)
 898     add_subdirectory(docs)
 899     add_subdirectory(share)
 900     add_subdirectory(scripts)
 901 endif()
 902 add_subdirectory(src)
 903
 904 if (BUILD_TESTING)
 905     add_subdirectory(tests)
 906 endif()
 907
 908 gmx_cpack_write_config()
 909
 910 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 911 # Don't bother the user after the first configure pass.
 912 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 913     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 914 endif()
 915 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 916
 917 #######################
 918 ## uninstall target
 919 #######################
 920 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 921                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 922                   IMMEDIATE @ONLY)
 923 ###########################
 924 ADD_CUSTOM_TARGET(uninstall
 925                   "${CMAKE_COMMAND}" -P
 926                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 927 ###########################
 928 set_directory_properties(PROPERTIES
 929             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")