docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/commitstyle.rst
 108         dev-manual/documentation-generation.rst
 109         dev-manual/contribute.rst
 110         dev-manual/doxygen.rst
 111         dev-manual/error-handling.rst
 112         dev-manual/formatting.rst
 113         dev-manual/gmxtree.rst
 114         dev-manual/includestyle.rst
 115         dev-manual/jenkins.rst
 116         dev-manual/language-features.rst
 117         dev-manual/naming.rst
 118         dev-manual/overview.rst
 119         dev-manual/redmine-states.png
 120         dev-manual/relocatable-binaries.rst
 121         dev-manual/reportstyle.rst
 122         dev-manual/style.rst
 123         dev-manual/testutils.rst
 124         dev-manual/tools.rst
 125         dev-manual/uncrustify.rst
 126         fragments/doxygen-links.rst
 127         install-guide/index.rst
 128         release-notes/index.rst
 129         release-notes/features.rst
 130         release-notes/performance.rst
 131         release-notes/tools.rst
 132         release-notes/bugs-fixed.rst
 133         release-notes/removed-features.rst
 134         release-notes/portability.rst
 135         release-notes/miscellaneous.rst
 136         user-guide/index.rst
 137         user-guide/cutoff-schemes.rst
 138         user-guide/getting-started.rst
 139         user-guide/force-fields.rst
 140         user-guide/faq.rst
 141         user-guide/flow.rst
 142         user-guide/floating-point.rst
 143         user-guide/system-preparation.rst
 144         user-guide/managing-simulations.rst
 145         user-guide/mdrun-features.rst
 146         user-guide/mdrun-performance.rst
 147         user-guide/mdp-options.rst
 148         user-guide/run-time-errors.rst
 149         user-guide/file-formats.rst
 150         user-guide/cmdline.rst
 151         user-guide/environment-variables.rst
 152         user-guide/terminology.rst
 153         user-guide/plotje.gif
 154         user-guide/xvgr.gif
 155         conf.py
 156         links.dat
 157         )
 158
 159     include(SphinxMacros.cmake)
 160     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 161
 162     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 163     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 164         EXTRA_VARS
 165             SPHINX_EXTENSION_PATH RELENG_PATH
 166             EXPECTED_DOXYGEN_VERSION
 167             EXPECTED_SPHINX_VERSION
 168             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 169             REQUIRED_OPENCL_MIN_VERSION
 170             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 171             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 172             GMX_TNG_MINIMUM_REQUIRED_VERSION
 173             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 174         COMMENT "Configuring Sphinx configuration file")
 175     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 176     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 177     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 178         include(${RELENG_PATH}/docs/FileList.cmake)
 179         gmx_add_sphinx_source_files(
 180             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 181             FILES ${RELENG_SPHINX_FILES})
 182     else()
 183         gmx_add_sphinx_source_files(FILES
 184             dev-manual/releng/index.rst
 185             dev-manual/releng/jenkins-howto.rst
 186             dev-manual/releng/jenkins-ui.rst
 187             )
 188     endif()
 189     gmx_add_sphinx_input_target(sphinx-input)
 190     # Remove other rst files from the build tree, since they confuse Sphinx.
 191     # Skip generated files in onlinehelp/, and fragments.
 192     # The latter do not cause issues with obsolete files, as they
 193     # are not considered as Sphinx input files, but will only be
 194     # included using an explicit .. include::.
 195     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 196
 197     # TODO: Make this remove obsolete .rst files.
 198     # TODO: This does not work in cross-compilation scenarios; disable up to
 199     # the necessary level.
 200     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 201         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 202         COMMAND gmx -quiet help -export rst
 203         DEPENDS gmx
 204         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 205         COMMENT "Generating reStructuredText help")
 206     # This dependency ensures that the directories exist before the
 207     # executable tries to write things there.
 208     add_dependencies(sphinx-programs sphinx-input)
 209
 210     # Make the INSTALL file for CPack for the tarball. This gets put
 211     # into the tarball via the CPack rules below, which requires that
 212     # the INSTALL file is in a separate directory by itself.
 213     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 214     add_custom_target(install-guide
 215         COMMAND
 216             ${SPHINX_EXECUTABLE}
 217             -q -b text
 218             -w sphinx-install.log
 219             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 220             -c ${SPHINX_INPUT_DIR}
 221             "${SPHINX_INPUT_DIR}/install-guide"
 222             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 223         COMMAND
 224             ${CMAKE_COMMAND} -E rename
 225             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 226             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 227         WORKING_DIRECTORY
 228             ${CMAKE_CURRENT_BINARY_DIR}
 229         COMMENT "Building INSTALL with Sphinx"
 230         VERBATIM
 231         )
 232     add_dependencies(install-guide sphinx-input)
 233     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 234
 235     # Sphinx cache with pickled ReST documents
 236     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 237
 238     add_custom_target(webpage-sphinx
 239         COMMAND
 240             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 241         COMMAND
 242             ${SPHINX_EXECUTABLE}
 243             -q -b html
 244             -w sphinx-html.log
 245             -d "${SPHINX_CACHE_DIR}"
 246             "${SPHINX_INPUT_DIR}"
 247             "${HTML_OUTPUT_DIR}"
 248         WORKING_DIRECTORY
 249             ${CMAKE_CURRENT_BINARY_DIR}
 250         COMMENT "Building HTML documentation with Sphinx"
 251         VERBATIM
 252         )
 253     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 254
 255     add_custom_target(man
 256         COMMAND
 257             ${SPHINX_EXECUTABLE}
 258             -q -b man
 259             -w sphinx-man.log
 260             -d ${SPHINX_CACHE_DIR}
 261             -t do_man
 262             ${SPHINX_INPUT_DIR}
 263             ${CMAKE_CURRENT_BINARY_DIR}/man
 264         COMMENT "Building man pages with Sphinx"
 265         VERBATIM)
 266     add_dependencies(man sphinx-input sphinx-programs)
 267     if (GMX_BUILD_HELP)
 268         # If requested, install the man pages built by the 'man' target
 269         # created above.  Nothing will be installed if the user did not
 270         # manually build the target.
 271         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 272     endif()
 273 else()
 274     add_custom_target(webpage-sphinx
 275         COMMAND ${CMAKE_COMMAND} -E echo
 276             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 277         VERBATIM)
 278     add_custom_target(install-guide
 279         COMMAND ${CMAKE_COMMAND} -E echo
 280             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 281         VERBATIM)
 282     add_custom_target(man
 283         COMMAND ${CMAKE_COMMAND} -E echo
 284             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 285         VERBATIM)
 286 endif()
 287
 288 if (MAN_PAGE_DIR)
 289     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 290     # Trailing slash on directory is significant for
 291     # install(DIRECTORY). See CMake docs.
 292     install(DIRECTORY ${MAN_PAGE_DIR}/
 293         DESTINATION ${MAN_INSTALL_DIR}/man1
 294         COMPONENT man OPTIONAL
 295         FILES_MATCHING PATTERN "*.1")
 296 endif()
 297 gmx_cpack_add_generated_source_directory(man)
 298
 299 # Determine whether we can build all the HTML pages and content linked from
 300 # there.  If not, construct an informative message if the user tries to
 301 # build the target; most people never need to know, unless they've asked for
 302 # the webpage build.
 303 set(HTML_BUILD_IS_POSSIBLE ON)
 304 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 305 set(HTML_BUILD_WARNINGS)
 306
 307 # Next, turn it off if any of the preconditions are unsatisified
 308 if (NOT PYTHON_EXECUTABLE)
 309     set(HTML_BUILD_IS_POSSIBLE OFF)
 310     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 311 elseif (NOT SPHINX_FOUND)
 312     # Hardly anything gets built if Sphinx is not available, so don't bother.
 313     set(HTML_BUILD_IS_POSSIBLE OFF)
 314     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 315 endif()
 316 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 317     list(APPEND HTML_BUILD_WARNINGS
 318          "Reference PDF manual was not built, so links to it do not work")
 319 endif()
 320 if (NOT DOXYGEN_EXECUTABLE)
 321     list(APPEND HTML_BUILD_WARNINGS
 322         "Doxygen was not available, so links to Doxygen do not work")
 323 endif()
 324 if (NOT DOXYGEN_DOT_EXECUTABLE)
 325     list(APPEND HTML_BUILD_WARNINGS
 326         "dot/graphviz was not found, so some graphs are missing")
 327 endif()
 328
 329 if (HTML_BUILD_IS_POSSIBLE)
 330     set(_webpage_target_properties)
 331     if (HTML_BUILD_WARNINGS)
 332         list(APPEND _webpage_target_properties
 333              COMMAND ${CMAKE_COMMAND} -E echo
 334                  "webpage was built, but with the following limitations:")
 335         foreach(_warning ${HTML_BUILD_WARNINGS})
 336         list(APPEND _webpage_target_properties
 337              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 338         endforeach()
 339     endif()
 340
 341     if (MANUAL_BUILD_IS_POSSIBLE)
 342         # Make the PDF reference guide
 343         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 344         # TODO Make this depend on the output of the manual build, so that the
 345         # file actually gets copied multiple times.
 346         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 347         add_custom_command(
 348             OUTPUT ${_manual_target_location}
 349             COMMAND ${CMAKE_COMMAND}
 350                 -E remove -f ${_manual_target_location}
 351             COMMAND ${CMAKE_COMMAND}
 352                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 353             DEPENDS manual
 354             VERBATIM)
 355         list(APPEND _webpage_target_properties
 356              DEPENDS ${_manual_target_location})
 357     endif()
 358
 359     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 360     # makes all the Doxygen output directly in
 361     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 362     # to).
 363
 364     # Add a top-level target that builds everything related to the webpage,
 365     # for Jenkins (and possibly others) to use
 366     add_custom_target(webpage ${_webpage_target_properties}
 367         COMMENT "Building webpage"
 368         VERBATIM)
 369     add_dependencies(webpage webpage-sphinx doxygen-all)
 370 else()
 371     add_custom_target(webpage
 372         COMMAND ${CMAKE_COMMAND} -E echo
 373             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 374         COMMENT "Webpage build not possible"
 375         VERBATIM)
 376 endif()