cmake/gmxManageLmfit.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2016,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Note that lmfit does not have a stable API, so GROMACS only supports
  36 # the same version that it bundles.
  37 set(GMX_LMFIT_REQUIRED_VERSION "7.0")
  38
  39 include(gmxOptionUtilities)
  40
  41 # Make a three-state enumeration, defaulting to
  42 gmx_option_multichoice(GMX_USE_LMFIT
  43     "How to handle the lmfit dependency of GROMACS"
  44     INTERNAL
  45     INTERNAL EXTERNAL NONE)
  46
  47 # Make a fully functional lmfit library target that libgromacs can
  48 # depend on regardless of how the user directed lmfit support and/or
  49 # linking to work.
  50 function(gmx_manage_lmfit)
  51     if(GMX_USE_LMFIT STREQUAL "INTERNAL")
  52         # Create an object library for the lmfit sources
  53         set(BUNDLED_LMFIT_DIR "${CMAKE_SOURCE_DIR}/src/external/lmfit")
  54         file(GLOB LMFIT_SOURCES ${BUNDLED_LMFIT_DIR}/*.cpp)
  55         add_library(lmfit_objlib OBJECT ${LMFIT_SOURCES})
  56         # Ensure that the objects can be used in both STATIC and SHARED
  57         # libraries.
  58         set_target_properties(lmfit_objlib PROPERTIES POSITION_INDEPENDENT_CODE ON)
  59
  60         # Create an INTERFACE (ie. fake) library for lmfit, that
  61         # libgromacs can depend on. The generator expression for the
  62         # target_sources expands to nothing when cmake builds the
  63         # export for libgromacs, so that it understands that we don't
  64         # install anything for this library - using plain source files
  65         # would not convey the right information.
  66         add_library(lmfit INTERFACE)
  67         target_sources(lmfit INTERFACE $<TARGET_OBJECTS:lmfit_objlib>)
  68         target_include_directories(lmfit INTERFACE $<BUILD_INTERFACE:${BUNDLED_LMFIT_DIR}>)
  69         # Add the lmfit interface library to the libgromacs Export name, even though
  70         # we will not be installing any content.
  71         install(TARGETS lmfit EXPORT libgromacs)
  72
  73         set(HAVE_LMFIT_VALUE TRUE)
  74     elseif(GMX_USE_LMFIT STREQUAL "EXTERNAL")
  75         # Find an external lmfit library.
  76         find_package(Lmfit ${GMX_LMFIT_MINIMUM_REQUIRED_VERSION})
  77         if(NOT LMFIT_FOUND)
  78             message(FATAL_ERROR "External lmfit could not be found, please adjust your pkg-config path to include the lmfit.pc file")
  79         endif()
  80
  81         set(HAVE_LMFIT_VALUE TRUE)
  82     else()
  83         # Create a dummy link target so the calling code doesn't need to know
  84         # whether lmfit support is being compiled.
  85         add_library(lmfit INTERFACE)
  86         # Add the lmfit interface library to the libgromacs Export name, even though
  87         # we will not be installing any content.
  88         install(TARGETS lmfit EXPORT libgromacs)
  89
  90         set(HAVE_LMFIT_VALUE FALSE)
  91     endif()
  92 endfunction()