CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Global non-cache variables for implementing the build system
 100 ########################################################################
 101
 102 # These variables collect libraries that GROMACS requires for
 103 # linking. They should be appended to with list(APPEND ${name}
 104 # new-library) calls. They are:
 105 #  - Libraries that are required for libgromacs (only)
 106 set(GMX_EXTRA_LIBRARIES "")
 107 #  - Libraries that are required for all code in the repository
 108 set(GMX_COMMON_LIBRARIES "")
 109 #  - Libraries that all code linked against libgromacs needs
 110 #    (i.e., something that is exposed in installed headers).
 111 set(GMX_PUBLIC_LIBRARIES "")
 112
 113 ########################################################################
 114 # Check and warn if cache generated on a different host is being reused
 115 ########################################################################
 116 if(CMAKE_HOST_UNIX)
 117     execute_process(COMMAND hostname
 118                     OUTPUT_VARIABLE TMP_HOSTNAME
 119                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 121         message(WARNING "
 122             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 123             is being reused! This could lead to inconsistencies; therefore, it is
 124             recommended to regenerate the cache!")
 125     endif()
 126     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 127             "Hostname of the machine where the cache was generated.")
 128 endif()
 129
 130 ########################################################################
 131 # Detect architecture before setting options so we can alter defaults
 132 ########################################################################
 133 # Detect the architecture the compiler is targetting, detect
 134 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 135 # to use if none is specified, and populate the cache option for CPU
 136 # SIMD.
 137 include(gmxDetectTargetArchitecture)
 138 gmx_detect_target_architecture()
 139
 140 # Permit the user to specify a particular standard library, e.g. compiling
 141 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 142 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 143 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 144 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 145 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 146
 147 ########################################################################
 148 # Detect CXX11 support and flags
 149 ########################################################################
 150 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 151 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 152 # invalid options with the Intel Compilers, and we have added a line
 153 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 154 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 155 # a semicolon. Since this is also used as a separator in lists inside CMake,
 156 # that string ends up being split into two separate patterns, and the last
 157 # part is just a single word that also matches other messages. We solved this
 158 # by replacing the semicolon with a period that matches any character.
 159 #
 160 # These files should be removed from the source tree when a CMake version that
 161 # includes the features in question becomes required for building GROMACS.
 162 include(CheckCCompilerFlag)
 163 include(CheckCXXCompilerFlag)
 164
 165 # This must come early, since some of our configuration flag tests
 166 # depend on being able to compile C++11 source files.
 167 include(gmxTestCXX11)
 168 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 169
 170 # Make sure all C++ code will be compiled in C++11 mode, with the
 171 # expected standard library.
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 173
 174 ########################################################################
 175 # User input options                                                   #
 176 ########################################################################
 177 include(gmxOptionUtilities)
 178
 179 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 180
 181 # Fujitsu only has SIMD in double precision, so this will be faster
 182 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 183 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 184 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 185 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 186
 187 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 188 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 189 gmx_dependent_option(
 190     GMX_MPI_IN_PLACE
 191     "Enable MPI_IN_PLACE for MPIs that have it defined"
 192     ON
 193     GMX_MPI)
 194 mark_as_advanced(GMX_MPI_IN_PLACE)
 195 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 196 mark_as_advanced(GMX_FAHCORE)
 197
 198 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 199 mark_as_advanced(GMX_COOL_QUOTES)
 200 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 201
 202 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 203
 204 # Decide on GPU settings based on user-settings and GPU/CUDA
 205 # detection. VS2015 requires CUDA 8.0, for the other arch/compilers
 206 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 207 if(MSVC)
 208     set(REQUIRED_CUDA_VERSION 8.0)
 209 else()
 210     set(REQUIRED_CUDA_VERSION 7.0)
 211 endif()
 212 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 213
 214 # OpenCL required version: 1.2 or newer
 215 set(REQUIRED_OPENCL_MIN_VERSION 1.2)
 216
 217 if(NOT GMX_USE_OPENCL)
 218     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 219     include(gmxManageGPU)
 220     set(GMX_USE_CUDA ${GMX_GPU})
 221     if(GMX_GPU)
 222         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 223     else()
 224         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 225     endif()
 226 else()
 227     #Now the OpenCL path (for both AMD and NVIDIA)
 228     if(GMX_GPU)
 229         include(gmxManageOpenCL)
 230         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 231     else()
 232         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 233     endif()
 234 endif()
 235
 236 gmx_option_multichoice(
 237     GMX_SIMD
 238     "SIMD instruction set for CPU kernels and compiler optimization"
 239     "AUTO"
 240     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 241
 242 if(GMX_TARGET_MIC)
 243     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 244 else()
 245     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 246 endif()
 247
 248 gmx_option_multichoice(
 249     GMX_FFT_LIBRARY
 250     "FFT library"
 251     "${GMX_FFT_LIBRARY_DEFAULT}"
 252     fftw3 mkl "fftpack[built-in]")
 253 gmx_dependent_option(
 254     GMX_BUILD_OWN_FFTW
 255     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 256     OFF
 257     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 258 gmx_dependent_option(
 259     GMX_DISABLE_FFTW_MEASURE
 260     "Do not optimize FFTW setups (not needed with SSE)"
 261     OFF
 262     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 263 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 264 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 265
 266 gmx_option_multichoice(
 267     GMX_QMMM_PROGRAM
 268     "QM package for QM/MM"
 269     None
 270     none gaussian mopac gamess orca)
 271
 272 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 273 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 274
 275 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 276
 277 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 278 mark_as_advanced(GMX_BROKEN_CALLOC)
 279
 280 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 281
 282 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 283
 284 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 285
 286 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 287 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 288
 289 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 290 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 291
 292 option(GMX_BUILD_FOR_COVERAGE
 293        "Tune build for better code coverage metrics (e.g., disable asserts)"
 294        OFF)
 295 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 296
 297 option(GMX_DEVELOPER_BUILD
 298     "Enable Developer convenience features: always build unit-tests"
 299     OFF)
 300 mark_as_advanced(GMX_DEVELOPER_BUILD)
 301
 302 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 303 option(GMX_COMPILER_WARNINGS
 304     "Enable a default set of compiler warnings"
 305     ${GMX_COMPILER_WARNINGS_DEFAULT})
 306 mark_as_advanced(GMX_COMPILER_WARNINGS)
 307 # Always turn on compiler warnings with a developer build.
 308 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 309
 310 option(GMX_BUILD_SHARED_EXE
 311     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 312     ON)
 313 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 314
 315 option(GMX_PHYSICAL_VALIDATION
 316        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 317        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 318        OFF)
 319 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 320
 321 ######################################################################
 322 # Detect OpenMP support
 323 ######################################################################
 324 # The OpenMP detection _must_ come before tests for other CFLAGS.
 325 include(gmxManageOpenMP)
 326
 327
 328
 329 ######################################################################
 330 # Compiler tests
 331 # These need to be done early (before further tests).
 332 #####################################################################
 333
 334 include(gmxCFlags)
 335 gmx_c_flags()
 336
 337 # This variable should be used for additional compiler flags which are not
 338 # generated in gmxCFlags nor are SIMD or MPI related.
 339 #
 340 # TODO These variables should be consolidated into
 341 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 342 # things that work in C compilation (e.g. merging from old branches)
 343 # also work for C++ compilation.
 344 set(EXTRA_C_FLAGS "")
 345 set(EXTRA_CXX_FLAGS "")
 346
 347 # Run through a number of tests for buggy compilers and other issues
 348 include(gmxTestCompilerProblems)
 349 gmx_test_compiler_problems()
 350
 351 # Implement double-precision option. This is complicated because we
 352 # need installed headers to use the precision mode of the build that
 353 # produced the library, but cannot use config.h in that case. We also
 354 # want such variables to always have a definition, because #if is more
 355 # robust than #ifdef. So, we put this value on the compiler command
 356 # line in all cases.
 357 #
 358 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 359 # because no installed header needs it
 360 if(GMX_DOUBLE)
 361     set(GMX_DOUBLE_VALUE 1)
 362 else()
 363     set(GMX_DOUBLE_VALUE 0)
 364 endif()
 365 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 366 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 367
 368 if(WIN32)
 369     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 370     add_definitions(-DGMX_HAVE_WINSOCK)
 371 endif()
 372
 373
 374
 375 ########################################################################
 376 # Basic system tests (standard libraries, headers, functions, types)   #
 377 ########################################################################
 378 include(CheckIncludeFiles)
 379 include(CheckIncludeFileCXX)
 380 check_include_files(unistd.h     HAVE_UNISTD_H)
 381 check_include_files(pwd.h        HAVE_PWD_H)
 382 check_include_files(dirent.h     HAVE_DIRENT_H)
 383 check_include_files(time.h       HAVE_TIME_H)
 384 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 385 check_include_files(io.h         HAVE_IO_H)
 386 check_include_files(sched.h      HAVE_SCHED_H)
 387
 388 check_include_files(regex.h      HAVE_POSIX_REGEX)
 389 # TODO: It could be nice to inform the user if no regex support is found,
 390 # as selections won't be fully functional.
 391
 392 include(CheckCXXSymbolExists)
 393 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 394 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 395 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 396 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 397 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 398 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 399 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 400 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 401
 402 # We cannot check for the __builtins as symbols, but check if code compiles
 403 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 404 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 405 if(MSVC)
 406     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 407     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 408 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 409     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 410     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 411 endif()
 412
 413 include(CheckLibraryExists)
 414 find_library(HAVE_LIBM m)
 415 mark_as_advanced(HAVE_LIBM)
 416 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 417 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 418 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 419
 420 include(TestSchedAffinity)
 421 test_sched_affinity(HAVE_SCHED_AFFINITY)
 422
 423 # Aligned memory allocation. We need to check for both mm_malloc(),
 424 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 425 include(gmxTestMMMalloc)
 426 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 427 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 428 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 429 if(MSVC)
 430     # No need to waste time on this test on platforms where it will never be true
 431     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 432 endif()
 433
 434 include(TestBigEndian)
 435 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 436
 437 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 438
 439 # Management of GROMACS options for specific toolchains should go
 440 # here. Because the initial settings for some of the main options have
 441 # already happened, but things like library detection and MPI compiler
 442 # feature detection have not, the docstrings for any over-rides of
 443 # GROMACS defaults or user settings will make sense. Also, any
 444 # toolchain-related reasons for choosing whether to detect various
 445 # things can be sorted out now, before the detection takes place.
 446 if(GMX_TARGET_FUJITSU_SPARC64)
 447     include(gmxManageFujitsuSparc64)
 448 endif()
 449
 450 ########################################################################
 451 #Process MPI settings
 452 ########################################################################
 453 include(gmxManageMPI)
 454
 455
 456 ########################################################################
 457 #Process shared/static library settings
 458 ########################################################################
 459 include(gmxManageSharedLibraries)
 460
 461
 462 ########################################################################
 463 # Find external packages                                               #
 464 ########################################################################
 465
 466 # Unconditionally find the package, as it is also required for unit
 467 # tests. This exports LIBXML2_FOUND, which we should not use because
 468 # it does not tell us that linking will succeed. Instead, we test that
 469 # next.
 470 #if(DEFINED LIBXML2_LIBRARIES)
 471 #  set(LibXml2_FIND_QUIETLY TRUE)
 472 #endif()
 473 #find_package(LibXml2)
 474 #include(gmxTestLibXml2)
 475 #gmx_test_libxml2(HAVE_LIBXML2)
 476 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 477 #set(PKG_XML "")
 478 #mark_as_advanced(GMX_XML)
 479 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 480 #if(GMX_XML AND NOT HAVE_LIBXML2)
 481 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 482 #endif()
 483 #if(GMX_XML)
 484 #    include_directories(${LIBXML2_INCLUDE_DIR})
 485 #    set(PKG_XML libxml-2.0)
 486 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 487 #endif()
 488
 489 gmx_option_trivalue(
 490     GMX_HWLOC
 491     "Use hwloc portable hardware locality library"
 492     "AUTO")
 493
 494 if (GMX_HWLOC)
 495     # Find quietly the second time.
 496     if(DEFINED HWLOC_LIBRARIES)
 497         set(Hwloc_FIND_QUIETLY TRUE)
 498     endif()
 499     find_package(Hwloc 1.5)
 500
 501     if (HWLOC_FOUND)
 502         if (HWLOC_LIBRARIES MATCHES ".a$")
 503             set(_STATIC_HWLOC TRUE)
 504         endif()
 505
 506         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 507         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 508             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 509             set(GMX_USE_HWLOC OFF)
 510         else()
 511             set(GMX_USE_HWLOC ON)
 512         endif()
 513
 514         if (GMX_USE_HWLOC)
 515             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 516             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 517         endif()
 518     elseif(GMX_HWLOC_FORCE)
 519         message(FATAL_ERROR "Hwloc package support required, but not found.")
 520     endif()
 521 endif()
 522
 523 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 524 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 525 if(GMX_EXTERNAL_TINYXML2)
 526     # Find an external TinyXML-2 library.
 527     find_package(TinyXML-2 3.0.0)
 528     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 529     if(NOT HAVE_TINYXML2)
 530         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 531     endif()
 532 endif()
 533
 534 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 535 mark_as_advanced(GMX_EXTRAE)
 536
 537 if (GMX_EXTRAE)
 538   find_package(EXTRAE)
 539   if(EXTRAE_FOUND)
 540     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 541     set(HAVE_EXTRAE 1)
 542   else()
 543     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 544   endif()
 545 endif()
 546
 547 option(GMX_X11 "Use X window system" OFF)
 548 if (GMX_X11)
 549     find_package(X11)
 550     # X11 includes/libraries are only set in the ngmx subdirectory!
 551     if(NOT X11_FOUND)
 552         message(FATAL_ERROR
 553                 "X11 include files and/or libraries were not found. "
 554                 "Set GMX_X11=OFF to compile without X11 support. "
 555                 "gmx view will not be available.")
 556     endif()
 557     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 558 endif()
 559
 560 include(ThreadMPI)
 561 # Enable core threading facilities
 562 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 563 if(GMX_THREAD_MPI)
 564     # enable MPI functions
 565     tmpi_enable()
 566     set(MPI_IN_PLACE_EXISTS 1)
 567 endif()
 568 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 569 if (TMPI_ATOMICS_DISABLED)
 570    add_definitions(-DTMPI_ATOMICS_DISABLED)
 571 endif()
 572
 573 include(gmxManageTNG)
 574
 575 include(gmxManageLmfit)
 576
 577 if(GMX_GPU)
 578     # now that we have detected the dependencies, do the second configure pass
 579     gmx_gpu_setup()
 580     if (GMX_CLANG_CUDA)
 581         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 582         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 583     endif()
 584 endif()
 585
 586 if(CYGWIN)
 587     set(GMX_CYGWIN 1)
 588 endif()
 589
 590 if(WIN32)
 591     set(GMX_NATIVE_WINDOWS 1)
 592     # This makes windows.h not declare min/max as macros that would break
 593     # C++ code using std::min/std::max.
 594     add_definitions(-DNOMINMAX)
 595 endif()
 596
 597 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 598     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 599         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 600     endif()
 601     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 602         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 603     endif()
 604 endif()
 605
 606 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 607 mark_as_advanced(GMX_BUILD_UNITTESTS)
 608 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 609
 610 ########################################################################
 611 # Our own GROMACS tests
 612 ########################################################################
 613
 614 add_definitions( -DHAVE_CONFIG_H )
 615 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 616 # TODO required at high level because both libgromacs and progs/mdrun
 617 # require it, both for thread-MPI and its atomics and mutexes.
 618 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 619 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 620 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 621
 622 include(gmxTestInlineASM)
 623 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 624
 625 include(gmxSetBuildInformation)
 626 gmx_set_build_information()
 627
 628 gmx_option_multichoice(
 629     GMX_USE_RDTSCP
 630     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 631     "AUTO"
 632     OFF ON AUTO DETECT)
 633 mark_as_advanced(GMX_USE_RDTSCP)
 634
 635 macro(gmx_check_rdtscp)
 636     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 637         set(HAVE_RDTSCP 1)
 638         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 639     else()
 640         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 641     endif()
 642 endmacro()
 643
 644 set(HAVE_RDTSCP 0)
 645 if (GMX_USE_RDTSCP STREQUAL "ON")
 646     set(HAVE_RDTSCP 1)
 647 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 648     gmx_check_rdtscp()
 649 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 650     # If the user specified automated SIMD selection, that the choice
 651     # is made based on detection on the build host. If so, then RDTSCP
 652     # should be chosen the same way.
 653     #
 654     # If the user specified an AVX SIMD level (e.g. when
 655     # cross-compiling GROMACS) then they will get our best guess, ie
 656     # that in practice AVX mostly correlates with rdtscp (and anyway
 657     # is only relevant in rather old x86 hardware).
 658     if (GMX_SIMD STREQUAL "AUTO")
 659         gmx_check_rdtscp()
 660     elseif (GMX_SIMD MATCHES "AVX")
 661         set(HAVE_RDTSCP 1)
 662     endif()
 663 endif()
 664 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 665 if (HAVE_RDTSCP_CHANGED)
 666     if (HAVE_RDTSCP)
 667         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 668     else()
 669         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 670     endif()
 671 endif()
 672
 673 include(gmxTestLargeFiles)
 674 gmx_test_large_files(GMX_LARGEFILES)
 675
 676 include(gmxTestSignal)
 677 gmx_test_sigusr1(HAVE_SIGUSR1)
 678
 679 include(gmxTestPipes)
 680 gmx_test_pipes(HAVE_PIPES)
 681
 682 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 683
 684 include(gmxTestXDR)
 685 gmx_test_xdr(GMX_SYSTEM_XDR)
 686 if(NOT GMX_SYSTEM_XDR)
 687     set(GMX_INTERNAL_XDR 1)
 688 endif()
 689
 690
 691 ##################################################
 692 # Process SIMD instruction settings
 693 ##################################################
 694 # This checks what flags to add in order to
 695 # support the SIMD instructions we need, it sets
 696 # correct defines for the SIMD instructions supported,
 697 # and adds advanced options to control accuracy
 698 # for SIMD math operations.
 699 include(gmxManageSimd)
 700 gmx_manage_simd()
 701
 702 include(gmxManageCycleCounters)
 703 gmx_manage_cycle_counters()
 704
 705 # Process QM/MM Settings
 706 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 707     set(GMX_QMMM_GAUSSIAN 1)
 708 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 709     set(GMX_QMMM_MOPAC 1)
 710 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 711     set(GMX_QMMM_GAMESS 1)
 712 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 713     set(GMX_QMMM_ORCA 1)
 714 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 715     # nothing to do
 716 else()
 717     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 718 endif()
 719
 720
 721 ##################################################
 722 # Process FFT library settings
 723 ##################################################
 724 include(gmxManageFFTLibraries)
 725
 726
 727 include(gmxManageLinearAlgebraLibraries)
 728
 729 include(gmxManagePluginSupport)
 730
 731 if (GMX_USE_PLUGINS)
 732     if(NOT GMX_VMD_PLUGIN_PATH)
 733         find_package(VMD)
 734     endif()
 735 endif()
 736
 737 # Link real-time library for POSIX timers. The check for clock_gettime
 738 # confirms the linkability of rt.
 739 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 740     list(APPEND GMX_EXTRA_LIBRARIES rt)
 741 endif()
 742
 743 # Math and thread libraries must often come after all others when linking...
 744 if (HAVE_LIBM)
 745     list(APPEND GMX_PUBLIC_LIBRARIES m)
 746 endif()
 747
 748 option(GMX_NACL "Configure for Native Client builds" OFF)
 749 if (GMX_NACL)
 750   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 751   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 752   # TODO: Is this still necessary with the check for its presence?
 753   set(GMX_USE_NICE 0)
 754   set(GMX_NO_RENAME 1)
 755 endif()
 756 mark_as_advanced(GMX_NACL)
 757
 758 if(GMX_FAHCORE)
 759   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 760       "Path to swindirect.h")
 761   include_directories(${COREWRAP_INCLUDE_DIR})
 762 endif()
 763
 764 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 765 # produce warnings if that fails.
 766 set(build_help_default AUTO)
 767 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 768     set(build_help_default OFF)
 769 endif()
 770 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 771 mark_as_advanced(GMX_BUILD_HELP)
 772 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 773     message(FATAL_ERROR
 774         "Rebuilding shell completions or man pages is not supported for "
 775         "in-source builds from a source distribution. "
 776         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 777 endif()
 778
 779 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 780 # these are set after everything else
 781 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 782     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 783     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 784     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 785     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 786 else()
 787     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 788     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 789     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 790     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 791     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 792     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 793     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 794     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 795     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 796 endif()
 797
 798 if(NOT GMX_OPENMP)
 799     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 800     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 801     unset(OpenMP_C_FLAGS CACHE)
 802     unset(OpenMP_CXX_FLAGS CACHE)
 803 else()
 804     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 805     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 806 endif()
 807
 808 ########################################################################
 809 # Specify install locations
 810 ########################################################################
 811 # Use GNUInstallDirs to set paths on multiarch systems.
 812 include(GNUInstallDirs)
 813
 814 # Customization for the installation tree paths.
 815 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 816     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 817 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 818     "Data installation directory under share/ (default: gromacs)")
 819 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 820
 821 # These variables are used internally to provide a central location for
 822 # customizing the install locations.
 823 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 824 set(BIN_INSTALL_DIR       bin)
 825 # This variable also gets written into config.h for use in finding the data
 826 # directories.
 827 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 828 set(MAN_INSTALL_DIR       share/man)
 829 # If the nesting level wrt. the installation root is changed,
 830 # gromacs-config.cmake.cmakein needs to be adapted.
 831 set(CMAKE_INSTALL_DIR     share/cmake)
 832 # TODO: Make GMXRC adapt if this is changed
 833 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 834 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 835 set(INCL_INSTALL_DIR      include)
 836
 837 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 838
 839 # Binary and library suffix options
 840 include(gmxManageSuffixes)
 841
 842 ################################################################
 843 # Shared library load path settings
 844 ################################################################
 845 if(NOT GMX_BUILD_SHARED_EXE)
 846     # No rpath
 847     set(CMAKE_SKIP_RPATH TRUE)
 848     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 849     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 850 else()
 851     # The build folder always has bin/ and lib/; if we are also going to
 852     # install to lib/, then the installation RPATH works also in the build
 853     # tree.  This makes installation slightly faster (no need to rewrite the
 854     # RPATHs), and makes the binaries in the build tree relocatable.
 855     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 856         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 857         if(POLICY CMP0068)
 858             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 859             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 860         endif()
 861     endif()
 862     # Set the RPATH as relative to the executable location to make the
 863     # binaries relocatable.
 864     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 865         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 866         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 867     else()
 868         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 869     endif()
 870     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 871     set(CMAKE_MACOSX_RPATH 1)
 872 endif()
 873
 874 #COPYING file: Only necessary for binary distributions.
 875 #Simpler to always install.
 876 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 877
 878 if (GMX_BUILD_FOR_COVERAGE)
 879     # Code heavy with asserts makes conditional coverage close to useless metric,
 880     # as by design most of the false branches are impossible to trigger in
 881     # correctly functioning code.  And the benefit of testing those that could
 882     # be triggered by using an API against its specification isn't usually
 883     # worth the effort.
 884     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 885 endif()
 886
 887 if (BUILD_TESTING)
 888     include(tests/CheckTarget.cmake)
 889 endif()
 890
 891 if (NOT GMX_BUILD_MDRUN_ONLY)
 892     add_subdirectory(docs)
 893     add_subdirectory(share)
 894     add_subdirectory(scripts)
 895 endif()
 896 add_subdirectory(src)
 897
 898 if (BUILD_TESTING)
 899     add_subdirectory(tests)
 900 endif()
 901
 902 gmx_cpack_write_config()
 903
 904 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 905 # Don't bother the user after the first configure pass.
 906 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 907     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 908 endif()
 909 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 910
 911 #######################
 912 ## uninstall target
 913 #######################
 914 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 915                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 916                   IMMEDIATE @ONLY)
 917 ###########################
 918 ADD_CUSTOM_TARGET(uninstall
 919                   "${CMAKE_COMMAND}" -P
 920                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 921 ###########################
 922 set_directory_properties(PROPERTIES
 923             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")