cmake/FindEXTRAE.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Try to find EXTRAE
  36 # Once done this will define
  37 #  EXTRAE_FOUND - System has EXTRAE
  38 #  EXTRAE_INCLUDE_DIRS - The EXTRAE include directories
  39 #  EXTRAE_LIBRARIES - The libraries needed to use EXTRAE
  40
  41 find_path(EXTRAE_INCLUDE_DIR extrae_user_events.h)
  42
  43 # EXTRAE libraries have different names depending on the supported features,
  44 # and in extrae-2.5.0 the following combinations are supported:
  45
  46 # seqtrace:        seq code
  47 # mpitrace:        MPI
  48 # omptrace:        OpenMP
  49 # ompitrace:       MPI + OpenMP
  50 # pttrace:         pthreads
  51 # ptmpitrace       pthreads + MPI (unsupported combination in Gromacs)
  52 # cudatrace:       CUDA
  53 # cudampitrace:    CUDA + MPI
  54 # cudaompitrace:   CUDA+OPENMP+MPI (in the dev version)
  55
  56 # TODO: Add support for the following combinations when available in a future release:
  57
  58 # cudaomptrace:    CUDA + OPENMP
  59 # cudapttrace:        CUDA + pthreads
  60 # cudaptmpitrace:    CUDA + pthreads + MPI (unsupported combination in Gromacs)
  61
  62 set (extraelib "trace")
  63
  64 # libs with MPI support
  65 if (GMX_MPI)
  66   if (GMX_OPENMP)
  67     set (extraelib "ompi${extraelib}")
  68   else()
  69     set (extraelib "mpi${extraelib}")
  70   endif()
  71   if (GMX_GPU)
  72     set (extraelib "cuda${extraelib}")
  73   endif()
  74
  75 # other libs with OpenMP support
  76 elseif (GMX_OPENMP)
  77   set (extraelib "omp${extraelib}")
  78     if (GMX_GPU)
  79       set (extraelib "cuda${extraelib}")
  80     endif()
  81
  82 # library with CUDA only support
  83 elseif (GMX_GPU)
  84     set (extraelib "cuda${extraelib}")
  85
  86 # library with PThreads support
  87 elseif (GMX_THREAD_MPI)
  88     set (extraelib "pt${extraelib}")
  89
  90 else()
  91   set (extraelib "seq${extraelib}")
  92 endif()
  93
  94 find_library(EXTRAE_LIBRARY NAMES  ${extraelib})
  95
  96 set(EXTRAE_LIBRARIES ${EXTRAE_LIBRARY} )
  97 set(EXTRAE_INCLUDE_DIRS ${EXTRAE_INCLUDE_DIR} )
  98
  99 # handle the QUIETLY and REQUIRED arguments and set EXTRAE_FOUND to TRUE
 100 # if all listed variables are TRUE
 101 include(FindPackageHandleStandardArgs)
 102 find_package_handle_standard_args(EXTRAE  DEFAULT_MSG
 103                                   EXTRAE_LIBRARY EXTRAE_INCLUDE_DIR)
 104
 105 mark_as_advanced(EXTRAE_INCLUDE_DIR EXTRAE_LIBRARY )
 106