CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeReleaseWithAssert)
  69
  70 if(NOT CMAKE_BUILD_TYPE)
  71     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  72     # There's no need to offer a user the choice of ThreadSanitizer
  73     # Set the possible values of build type for cmake-gui
  74     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  75         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  76 endif()
  77 if(CMAKE_CONFIGURATION_TYPES)
  78     # Add appropriate GROMACS-specific build types for the Visual
  79     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  80     # are already present by default).
  81     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  82     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  83     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  84         "List of configuration types"
  85         FORCE)
  86 endif()
  87 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  88
  89 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  90
  91 # Set a default valgrind suppression file.
  92 # This unfortunately needs to duplicate information from CTest to work as
  93 # expected...
  94 set(MEMORYCHECK_SUPPRESSIONS_FILE
  95     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  96     CACHE FILEPATH
  97     "File that contains suppressions for the memory checker")
  98 include(CTest)
  99
 100 include(gmxCPackUtilities)
 101 gmx_cpack_init()
 102
 103 # Variables that accumulate stuff influencing the installed headers
 104 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 105 set(INSTALLED_HEADER_DEFINITIONS "")
 106
 107 ########################################################################
 108 # Check and warn if cache generated on a different host is being reused
 109 ########################################################################
 110 if(CMAKE_HOST_UNIX)
 111     execute_process(COMMAND hostname
 112                     OUTPUT_VARIABLE TMP_HOSTNAME
 113                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 114     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 115         message(WARNING "
 116             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 117             is being reused! This could lead to inconsistencies; therefore, it is
 118             recommended to regenerate the cache!")
 119     endif()
 120     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 121             "Hostname of the machine where the cache was generated.")
 122 endif()
 123
 124 ########################################################################
 125 # Detect architecture before setting options so we can alter defaults
 126 ########################################################################
 127 # Detect the architecture the compiler is targetting, detect
 128 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 129 # to use if none is specified, and populate the cache option for CPU
 130 # SIMD.
 131 include(gmxDetectTargetArchitecture)
 132 gmx_detect_target_architecture()
 133
 134 ########################################################################
 135 # User input options                                                   #
 136 ########################################################################
 137 include(gmxOptionUtilities)
 138
 139 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 140
 141 if(GMX_TARGET_FUJITSU_SPARC64)
 142     # Fujitsu only has SIMD in double precision, so this will be faster
 143     set(GMX_DOUBLE_DEFAULT ON)
 144 else()
 145     set(GMX_DOUBLE_DEFAULT OFF)
 146 endif()
 147 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 148 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 149 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 150
 151 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 152 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 153 gmx_dependent_option(
 154     GMX_MPI_IN_PLACE
 155     "Enable MPI_IN_PLACE for MPIs that have it defined"
 156     ON
 157     GMX_MPI)
 158 mark_as_advanced(GMX_MPI_IN_PLACE)
 159 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 160 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 161 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 162 mark_as_advanced(GMX_FAHCORE)
 163
 164 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 165 mark_as_advanced(GMX_COOL_QUOTES)
 166 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 167
 168 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 169 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 170 if(MSVC)
 171     set(REQUIRED_CUDA_VERSION 4.1)
 172 else()
 173     set(REQUIRED_CUDA_VERSION 4.0)
 174 endif()
 175 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 176 include(gmxManageGPU)
 177
 178 include(gmxDetectSimd)
 179 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 180
 181 gmx_option_multichoice(
 182     GMX_SIMD
 183     "SIMD instruction set for CPU kernels and compiler optimization"
 184     "${GMX_SUGGESTED_SIMD}"
 185     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 186
 187 if(GMX_TARGET_MIC)
 188     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 189 else()
 190     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 191 endif()
 192
 193 gmx_option_multichoice(
 194     GMX_FFT_LIBRARY
 195     "FFT library"
 196     "${GMX_FFT_LIBRARY_DEFAULT}"
 197     fftw3 mkl "fftpack[built-in]")
 198 gmx_dependent_option(
 199     GMX_BUILD_OWN_FFTW
 200     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 201     OFF
 202     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 203 gmx_dependent_option(
 204     GMX_DISABLE_FFTW_MEASURE
 205     "Do not optimize FFTW setups (not needed with SSE)"
 206     OFF
 207     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 208 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 209 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 210
 211 gmx_option_multichoice(
 212     GMX_QMMM_PROGRAM
 213     "QM package for QM/MM"
 214     None
 215     none gaussian mopac gamess orca)
 216
 217 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 218 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 219
 220 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 221
 222 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 223 mark_as_advanced(GMX_BROKEN_CALLOC)
 224 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 225 mark_as_advanced(GMX_LOAD_PLUGINS)
 226
 227 option(GMX_GPU  "Enable GPU acceleration" ON)
 228 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 229
 230 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 231
 232 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 233
 234 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 235 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 236
 237 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 238 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 239
 240 option(GMX_BUILD_FOR_COVERAGE
 241        "Tune build for better code coverage metrics (e.g., disable asserts)"
 242        OFF)
 243 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 244
 245 option(GMX_DEVELOPER_BUILD
 246     "Enable Developer convenience features: always build unit-tests"
 247     OFF)
 248 mark_as_advanced(GMX_DEVELOPER_BUILD)
 249
 250 option(GMX_BUILD_SHARED_EXE
 251     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 252     ON)
 253 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 254
 255 ######################################################################
 256 # Detect OpenMP support
 257 ######################################################################
 258 # The OpenMP detection _must_ come before tests for other CFLAGS.
 259 include(gmxManageOpenMP)
 260
 261
 262
 263 ######################################################################
 264 # Compiler tests
 265 # These need to be done early (before further tests).
 266 #####################################################################
 267
 268 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 269 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 270 # invalid options with the Intel Compilers, and we have added a line
 271 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 272 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 273 # a semicolon. Since this is also used as a separator in lists inside CMake,
 274 # that string ends up being split into two separate patterns, and the last
 275 # part is just a single word that also matches other messages. We solved this
 276 # by replacing the semicolon with a period that matches any character.
 277 #
 278 # These files should be removed from the source tree when a CMake version that
 279 # includes the features in question becomes required for building GROMACS.
 280 include(CheckCCompilerFlag)
 281 include(CheckCXXCompilerFlag)
 282
 283 include(gmxCFlags)
 284 gmx_c_flags()
 285
 286 # This variable should be used for additional compiler flags which are not
 287 # generated in gmxCFlags nor are SIMD or MPI related.
 288 set(EXTRA_C_FLAGS "")
 289 set(EXTRA_CXX_FLAGS "")
 290
 291 # Run through a number of tests for buggy compilers and other issues
 292 include(gmxTestCompilerProblems)
 293 gmx_test_compiler_problems()
 294 # GMX_SIMD will not be set automatically until the second
 295 # pass (which is not strictly guaranteed to occur), so putting this
 296 # check here among logically-related tests is inefficient, but the
 297 # potential loss is likely zero.
 298 if(GMX_SIMD STREQUAL "AVX_256"
 299         AND CMAKE_COMPILER_IS_GNUCC
 300         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 301             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 302     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 303     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 304 endif()
 305
 306
 307 if(GMX_DOUBLE)
 308     add_definitions(-DGMX_DOUBLE)
 309     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 310     if(GMX_RELAXED_DOUBLE_PRECISION)
 311         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 312     endif()
 313 endif()
 314 if(GMX_SOFTWARE_INVSQRT)
 315     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 316 endif()
 317
 318 if(WIN32)
 319     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 320     add_definitions(-DGMX_HAVE_WINSOCK)
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337
 338 check_include_files(regex.h      HAVE_POSIX_REGEX)
 339 # TODO: It could be nice to inform the user if no regex support is found,
 340 # as selections won't be fully functional.
 341
 342 include(CheckCXXSymbolExists)
 343 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 344 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 345 check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 346 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 347 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 348 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 349 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 350 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 351 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 352 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 353 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 354 check_cxx_symbol_exists(rsqrt             math.h       HAVE_RSQRT)
 355 check_cxx_symbol_exists(rsqrtf            math.h       HAVE_RSQRTF)
 356 check_cxx_symbol_exists(sqrtf             math.h       HAVE_SQRTF)
 357
 358 include(CheckLibraryExists)
 359 check_library_exists(m sqrt "" HAVE_LIBM)
 360 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 361 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 362
 363 include(TestSchedAffinity)
 364 test_sched_affinity(HAVE_SCHED_AFFINITY)
 365
 366 include(TestBigEndian)
 367 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 368
 369 set(GMX_USE_NICE 0)
 370 if (HAVE_UNISTD_H AND HAVE_NICE)
 371     set(GMX_USE_NICE 1)
 372 endif()
 373
 374 # Management of GROMACS options for specific toolchains should go
 375 # here. Because the initial settings for some of the main options have
 376 # already happened, but things like library detection and MPI compiler
 377 # feature detection have not, the docstrings for any over-rides of
 378 # GROMACS defaults or user settings will make sense. Also, any
 379 # toolchain-related reasons for choosing whether to detect various
 380 # things can be sorted out now, before the detection takes place.
 381 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 382     include(gmxManageBlueGene)
 383 endif()
 384
 385 if(GMX_TARGET_FUJITSU_SPARC64)
 386     include(gmxManageFujitsuSparc64)
 387 endif()
 388
 389 ########################################################################
 390 #Process MPI settings
 391 ########################################################################
 392 include(gmxManageMPI)
 393
 394
 395 ########################################################################
 396 #Process shared/static library settings
 397 ########################################################################
 398 include(gmxManageSharedLibraries)
 399
 400
 401 ########################################################################
 402 # Find external packages                                               #
 403 ########################################################################
 404
 405 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 406 find_package(ZLIB QUIET)
 407 include(gmxTestZLib)
 408 gmx_test_zlib(HAVE_ZLIB)
 409
 410 # Unconditionally find the package, as it is also required for unit
 411 # tests. This exports LIBXML2_FOUND, which we should not use because
 412 # it does not tell us that linking will succeed. Instead, we test that
 413 # next.
 414 if(DEFINED LIBXML2_LIBRARIES)
 415   set(LibXml2_FIND_QUIETLY TRUE)
 416 endif()
 417 find_package(LibXml2)
 418 include(gmxTestLibXml2)
 419 gmx_test_libxml2(HAVE_LIBXML2)
 420 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 421 set(PKG_XML "")
 422 mark_as_advanced(GMX_XML)
 423 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 424 #if(GMX_XML AND NOT HAVE_LIBXML2)
 425 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 426 #endif()
 427 #if(GMX_XML)
 428 #    include_directories(${LIBXML2_INCLUDE_DIR})
 429 #    set(PKG_XML libxml-2.0)
 430 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 431 #endif()
 432
 433 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 434 mark_as_advanced(GMX_EXTRAE)
 435
 436 if (GMX_EXTRAE)
 437   find_package(EXTRAE)
 438   if(EXTRAE_FOUND)
 439     include_directories(${EXTRAE_INCLUDE_DIR})
 440     set(HAVE_EXTRAE 1)
 441   else()
 442     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 443   endif()
 444 endif()
 445
 446 option(GMX_X11 "Use X window system" OFF)
 447 if (GMX_X11)
 448     find_package(X11)
 449     # X11 includes/libraries are only set in the ngmx subdirectory!
 450     if(NOT X11_FOUND)
 451         message(FATAL_ERROR
 452                 "X11 include files and/or libraries were not found. "
 453                 "Set GMX_X11=OFF to compile without X11 support. "
 454                 "gmx view will not be available.")
 455     endif()
 456     include_directories(${X11_INCLUDE_DIR})
 457 endif()
 458
 459 include(ThreadMPI)
 460 # Enable core threading facilities
 461 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 462 # Enable tMPI C++ support
 463 tmpi_enable_cxx()
 464 if(GMX_THREAD_MPI)
 465     # enable MPI functions
 466     tmpi_enable()
 467     set(MPI_IN_PLACE_EXISTS 1)
 468 endif()
 469 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 470 if (TMPI_ATOMICS_DISABLED)
 471    add_definitions(-DTMPI_ATOMICS_DISABLED)
 472 endif()
 473
 474 if(GMX_GPU)
 475     # now that we have detected the dependencies, do the second configure pass
 476     gmx_gpu_setup()
 477 endif()
 478
 479 if(CYGWIN)
 480     set(GMX_CYGWIN 1)
 481 endif()
 482
 483 if(WIN32)
 484     set(GMX_NATIVE_WINDOWS 1)
 485     # This makes windows.h not declare min/max as macros that would break
 486     # C++ code using std::min/std::max.
 487     add_definitions(-DNOMINMAX)
 488 endif()
 489
 490 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 491     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 492         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 493     endif()
 494     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 495         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 496     endif()
 497 endif()
 498
 499 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 500 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 501 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 502     if(DEFINED Boost_INCLUDE_DIR)
 503         set(Boost_FIND_QUIETLY TRUE)
 504     endif()
 505     find_package(Boost 1.44.0)
 506     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 507         set(Boost_FOUND FALSE)
 508     endif()
 509     # Print the notification only on first run, when determining the default
 510     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 511         message("Boost >= 1.44 not found. Using minimal internal version. "
 512                 "This may cause trouble if you plan on compiling/linking other "
 513                 "software that uses Boost against GROMACS.")
 514     endif()
 515 endif()
 516 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 517        ${Boost_FOUND})
 518 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 519     message(FATAL_ERROR
 520         "Boost >= 1.44 not found. "
 521         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 522         "version of Boost included with GROMACS.")
 523 endif()
 524
 525 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 526     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 527 endif()
 528 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 529 mark_as_advanced(GMX_BUILD_UNITTESTS)
 530 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 531 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 532     message(FATAL_ERROR
 533         "Cannot build unit tests without libxml2. "
 534         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 535 endif()
 536
 537 ########################################################################
 538 # Our own GROMACS tests
 539 ########################################################################
 540
 541 add_definitions( -DHAVE_CONFIG_H )
 542 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 543 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 544 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 545 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 546
 547 include(gmxTestInlineASM)
 548 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 549
 550 include(gmxSetBuildInformation)
 551 gmx_set_build_information()
 552 # Turn on RDTSCP if:
 553 # - the build system's CPU supports it
 554 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 555 #   at this point means that the user set it).
 556 # Note: it's better to not use the later set value of GMX_SIMD because
 557 # it reflects the system's capability of both compiling and running AVX code.
 558 # TODO: After merge with 5.0 one could implement a cache variable dependency
 559 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 560 # after the first cmake pass.
 561 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 562     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 563 else()
 564     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 565 endif()
 566 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 567 mark_as_advanced(GMX_USE_RDTSCP)
 568 if(GMX_USE_RDTSCP)
 569     set(HAVE_RDTSCP 1)
 570 endif()
 571
 572 include(gmxTestFloatFormat)
 573 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 574                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 575                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 576
 577 include(gmxTestLargeFiles)
 578 gmx_test_large_files(GMX_LARGEFILES)
 579
 580 include(gmxTestSignal)
 581 gmx_test_sigusr1(HAVE_SIGUSR1)
 582
 583 include(gmxTestPipes)
 584 gmx_test_pipes(HAVE_PIPES)
 585
 586 include(gmxTestIsfinite)
 587 gmx_test_isfinite(HAVE_ISFINITE)
 588 gmx_test__isfinite(HAVE__ISFINITE)
 589 gmx_test__finite(HAVE__FINITE)
 590
 591 include(gmxTestCXX11)
 592 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 593 include(CMakeDependentOption)
 594 # clang with some older versions of boost fail to work with C++11
 595 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 596     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 597     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 598 endif()
 599 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 600 # entirely to keep the compilation environment uniform.
 601 cmake_dependent_option(GMX_CXX11
 602     "Use C++11 features"
 603     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 604 mark_as_advanced(GMX_CXX11)
 605 if(GMX_CXX11)
 606     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 607 endif()
 608
 609 # Now we can test for CXX11_REGEX include file
 610 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 611
 612 include(gmxTestXDR)
 613 gmx_test_xdr(GMX_SYSTEM_XDR)
 614 if(NOT GMX_SYSTEM_XDR)
 615     set(GMX_INTERNAL_XDR 1)
 616 endif()
 617
 618
 619 ##################################################
 620 # Process SIMD instruction settings
 621 ##################################################
 622 # This checks what flags to add in order to
 623 # support the SIMD instructions we need, it sets
 624 # correct defines for the SIMD instructions supported,
 625 # and adds advanced options to control accuracy
 626 # for SIMD math operations.
 627 include(gmxManageSimd)
 628 gmx_manage_simd()
 629
 630 # Process QM/MM Settings
 631 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 632     set(GMX_QMMM_GAUSSIAN 1)
 633 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 634     set(GMX_QMMM_MOPAC 1)
 635 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 636     set(GMX_QMMM_GAMESS 1)
 637 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 638     set(GMX_QMMM_ORCA 1)
 639 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 640     # nothing to do
 641 else()
 642     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 643 endif()
 644
 645
 646 ##################################################
 647 # Process FFT library settings
 648 ##################################################
 649 include(gmxManageFFTLibraries)
 650
 651
 652 include(gmxManageLinearAlgebraLibraries)
 653
 654 # Whether GROMACS will really try to compile support for VMD plugins
 655 set(GMX_USE_PLUGINS OFF)
 656
 657 if(GMX_LOAD_PLUGINS)
 658   if(NOT WIN32)
 659     # Native Windows does not have, nor need dlopen
 660     include(gmxTestdlopen)
 661     gmx_test_dlopen(HAVE_DLOPEN)
 662   endif()
 663
 664   # so, should we use plug-ins?
 665   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 666     if(NOT VMD_QUIETLY)
 667       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 668     endif()
 669     if(NOT GMX_VMD_PLUGIN_PATH)
 670       find_package(VMD)
 671     endif()
 672     set(GMX_USE_PLUGINS ON)
 673     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 674     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 675   else()
 676     set(PKG_DL_LIBS)
 677   endif()
 678 endif()
 679 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 680
 681 # Link real-time library for POSIX timers. The check for clock_gettime
 682 # confirms the linkability of rt.
 683 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 684     list(APPEND GMX_EXTRA_LIBRARIES rt)
 685 endif()
 686
 687 # Math and thread libraries must often come after all others when linking...
 688 if(HAVE_LIBM)
 689     list(APPEND GMX_EXTRA_LIBRARIES m)
 690 endif()
 691
 692 option(GMX_NACL "Configure for Native Client builds" OFF)
 693 if (GMX_NACL)
 694   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 695   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 696   # TODO: Is this still necessary with the check for its presence?
 697   set(GMX_USE_NICE 0)
 698   set(GMX_NO_RENAME 1)
 699 endif()
 700 mark_as_advanced(GMX_NACL)
 701
 702 if(GMX_FAHCORE)
 703   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 704       "Path to swindirect.h")
 705   include_directories(${COREWRAP_INCLUDE_DIR})
 706 endif()
 707
 708 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 709 # produce warnings if that fails.
 710 set(build_help_default AUTO)
 711 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 712     set(build_help_default OFF)
 713 endif()
 714 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 715 mark_as_advanced(GMX_BUILD_HELP)
 716 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 717     message(FATAL_ERROR
 718         "Rebuilding shell completions or man pages is not supported for "
 719         "in-source builds from a source distribution. "
 720         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 721 endif()
 722
 723 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 724 # these are set after everything else
 725 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 726     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 727     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 728     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 729     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 730 else()
 731     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 732     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 733     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 734     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 735     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 736     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 737     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 738     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 739     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 740 endif()
 741
 742 if(NOT GMX_OPENMP)
 743     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 744     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 745     unset(OpenMP_C_FLAGS CACHE)
 746     unset(OpenMP_CXX_FLAGS CACHE)
 747 else()
 748     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 749     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 750 endif()
 751
 752 ########################################################################
 753 # Specify install locations
 754 ########################################################################
 755 # Use GNUInstallDirs to set paths on multiarch systems.
 756 include(GNUInstallDirs)
 757
 758 # Customization for the installation tree paths.
 759 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 760     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 761 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 762     "Data installation directory under share/ (default: gromacs)")
 763 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 764
 765 # These variables are used internally to provide a central location for
 766 # customizing the install locations.
 767 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 768 set(BIN_INSTALL_DIR       bin)
 769 # This variable also gets written into config.h for use in finding the data
 770 # directories.
 771 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 772 set(MAN_INSTALL_DIR       share/man)
 773 # If the nesting level wrt. the installation root is changed,
 774 # gromacs-config.cmake.cmakein needs to be adapted.
 775 set(CMAKE_INSTALL_DIR     share/cmake)
 776 # TODO: Make GMXRC adapt if this is changed
 777 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 778 set(INCL_INSTALL_DIR      include)
 779
 780 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 781
 782 # Binary and library suffix options
 783 include(gmxManageSuffixes)
 784
 785 ################################################################
 786 # Shared library load path settings
 787 ################################################################
 788 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 789 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 790 # was added.
 791
 792 if(NOT GMX_BUILD_SHARED_EXE)
 793     # No rpath
 794     set(CMAKE_SKIP_RPATH TRUE)
 795     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 796     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 797 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 798    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 799     # The build folder always has bin/ and lib/; if we are also going to
 800     # install to lib/, then the installation RPATH works also in the build
 801     # tree.  This makes installation slightly faster (no need to rewrite the
 802     # RPATHs), and makes the binaries in the build tree relocatable.
 803     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 804         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 805     endif()
 806     # Set the RPATH as relative to the executable location to make the
 807     # binaries relocatable.
 808     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 809         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 810     else()
 811         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 812     endif()
 813     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 814     set(CMAKE_MACOSX_RPATH 1)
 815 else()
 816     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 817     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 818         # Set the RPATH options manually.
 819         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 820         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 821     else()
 822         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 823         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 824     endif()
 825 endif()
 826
 827 #COPYING file: Only necessary for binary distributions.
 828 #Simpler to always install.
 829 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 830
 831 if(GMX_EXTERNAL_BOOST)
 832     include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
 833     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 834 else()
 835     include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/boost)
 836     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 837     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 838     # typeid not supported for minimal internal version
 839     # (would add significant amount of code)
 840     add_definitions(-DBOOST_NO_TYPEID)
 841     if (NOT GMX_BUILD_MDRUN_ONLY)
 842         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 843                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 844                 COMPONENT development)
 845     endif()
 846 endif()
 847
 848 if (GMX_BUILD_FOR_COVERAGE)
 849     # Code heavy with asserts makes conditional coverage close to useless metric,
 850     # as by design most of the false branches are impossible to trigger in
 851     # correctly functioning code.  And the benefit of testing those that could
 852     # be triggered by using an API against its specification isn't usually
 853     # worth the effort.
 854     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 855 endif()
 856
 857 if (BUILD_TESTING)
 858     # "tests" target builds all the separate test binaries.
 859     add_custom_target(tests)
 860     # "run-ctest" is an internal target that actually runs the tests.
 861     # This is necessary to be able to add separate targets that execute as part
 862     # of 'make check', but are ensured to be executed after the actual tests.
 863     add_custom_target(run-ctest
 864                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 865                       COMMENT "Running all tests"
 866                       VERBATIM)
 867     add_dependencies(run-ctest tests)
 868     # "check" target builds and runs all tests.
 869     add_custom_target(check DEPENDS run-ctest)
 870 endif()
 871
 872 if (NOT GMX_BUILD_MDRUN_ONLY)
 873     add_subdirectory(docs)
 874     add_subdirectory(share)
 875     add_subdirectory(scripts)
 876 endif()
 877 add_subdirectory(src)
 878
 879 if (BUILD_TESTING)
 880     add_subdirectory(tests)
 881 endif()
 882
 883 gmx_cpack_write_config()
 884
 885 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 886 # Don't bother the user after the first configure pass.
 887 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 888     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 889 endif()
 890 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 891
 892 #######################
 893 ## uninstall target
 894 #######################
 895 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 896                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 897                   IMMEDIATE @ONLY)
 898 ###########################
 899 ADD_CUSTOM_TARGET(uninstall
 900                   "${CMAKE_COMMAND}" -P
 901                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 902 ###########################
 903 set_directory_properties(PROPERTIES
 904             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")