src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 set(libgromacs_object_library_dependencies "")
  47 function (_gmx_add_files_to_property PROPERTY)
  48     foreach (_file ${ARGN})
  49         if (IS_ABSOLUTE "${_file}")
  50             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  51         else()
  52             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  53                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  54         endif()
  55     endforeach()
  56 endfunction ()
  57
  58 function (gmx_add_libgromacs_sources)
  59     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  60 endfunction ()
  61
  62 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  63 # approach, at least for the build system. See Redmine #2530
  64 function (gmx_compile_cpp_as_cuda)
  65     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  66 endfunction ()
  67
  68 # Add these contents first because linking their tests can take a lot
  69 # of time, so we want lots of parallel work still available after
  70 # linking starts.
  71 add_subdirectory(utility)
  72 # Add normal contents
  73 add_subdirectory(gmxlib)
  74 add_subdirectory(mdlib)
  75 add_subdirectory(applied_forces)
  76 add_subdirectory(listed_forces)
  77 add_subdirectory(nbnxm)
  78 add_subdirectory(commandline)
  79 add_subdirectory(domdec)
  80 add_subdirectory(ewald)
  81 add_subdirectory(fft)
  82 add_subdirectory(gpu_utils)
  83 add_subdirectory(hardware)
  84 add_subdirectory(linearalgebra)
  85 add_subdirectory(math)
  86 add_subdirectory(mdrun)
  87 add_subdirectory(mdrunutility)
  88 add_subdirectory(mdspan)
  89 add_subdirectory(mdtypes)
  90 add_subdirectory(onlinehelp)
  91 add_subdirectory(options)
  92 add_subdirectory(pbcutil)
  93 add_subdirectory(random)
  94 add_subdirectory(restraint)
  95 add_subdirectory(tables)
  96 add_subdirectory(taskassignment)
  97 add_subdirectory(timing)
  98 add_subdirectory(topology)
  99 add_subdirectory(trajectory)
 100 add_subdirectory(swap)
 101 add_subdirectory(essentialdynamics)
 102 add_subdirectory(pulling)
 103 add_subdirectory(awh)
 104 add_subdirectory(simd)
 105 add_subdirectory(imd)
 106 add_subdirectory(compat)
 107 add_subdirectory(mimic)
 108 add_subdirectory(modularsimulator)
 109 if (NOT GMX_BUILD_MDRUN_ONLY)
 110     add_subdirectory(gmxana)
 111     add_subdirectory(gmxpreprocess)
 112     add_subdirectory(correlationfunctions)
 113     add_subdirectory(statistics)
 114     add_subdirectory(analysisdata)
 115     add_subdirectory(coordinateio)
 116     add_subdirectory(trajectoryanalysis)
 117     add_subdirectory(energyanalysis)
 118     add_subdirectory(tools)
 119 endif()
 120
 121 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 122 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 123
 124 # This would be the standard way to include thread_mpi, but
 125 # we want libgromacs to link the functions directly
 126 #if(GMX_THREAD_MPI)
 127 #    add_subdirectory(thread_mpi)
 128 #endif()
 129 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 130 tmpi_get_source_list(THREAD_MPI_SOURCES ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/src)
 131 add_library(thread_mpi OBJECT ${THREAD_MPI_SOURCES})
 132 target_compile_definitions(thread_mpi PRIVATE HAVE_CONFIG_H)
 133 gmx_target_compile_options(thread_mpi)
 134 if (WIN32)
 135     gmx_target_warning_suppression(thread_mpi /wd4996 HAS_NO_MSVC_UNSAFE_FUNCTION)
 136 endif()
 137 list(APPEND libgromacs_object_library_dependencies thread_mpi)
 138
 139 configure_file(version.h.cmakein version.h)
 140 if(GMX_INSTALL_LEGACY_API)
 141   install(FILES
 142           ${CMAKE_CURRENT_BINARY_DIR}/version.h
 143           DESTINATION include/gromacs)
 144 endif()
 145
 146 # This code is here instead of utility/CMakeLists.txt, because CMake
 147 # custom commands and source file properties can only be set in the directory
 148 # that contains the target that uses them.
 149 # TODO: Generate a header instead that can be included from baseversion.cpp.
 150 # That probably simplifies things somewhat.
 151 set(GENERATED_VERSION_FILE utility/baseversion-gen.cpp)
 152 gmx_configure_version_file(
 153     utility/baseversion-gen.cpp.cmakein ${GENERATED_VERSION_FILE}
 154     REMOTE_HASH
 155     EXTRA_VARS
 156         GMX_SOURCE_DOI
 157         GMX_RELEASE_HASH
 158         GMX_SOURCE_HASH
 159         )
 160 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 161
 162 # Mark some shared GPU implementation files to compile with CUDA if needed
 163 if (GMX_USE_CUDA)
 164     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 165     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 166 endif()
 167
 168 # set up CUDA compilation with clang
 169 if (GMX_CLANG_CUDA)
 170     foreach (_file ${LIBGROMACS_SOURCES})
 171         get_filename_component(_ext ${_file} EXT)
 172         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 173         if ("${_ext}" STREQUAL ".cu" OR _cuda_source_format)
 174             gmx_compile_cuda_file_with_clang(${_file})
 175         endif()
 176     endforeach()
 177 endif()
 178
 179 if (GMX_USE_CUDA)
 180     # Work around FindCUDA that prevents using target_link_libraries()
 181     # with keywords otherwise...
 182     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 183     if (NOT GMX_CLANG_CUDA)
 184         gmx_cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 185     else()
 186         add_library(libgromacs ${LIBGROMACS_SOURCES})
 187     endif()
 188     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 189 else()
 190     add_library(libgromacs ${LIBGROMACS_SOURCES})
 191 endif()
 192
 193 # Add these contents first because linking their tests can take a lot
 194 # of time, so we want lots of parallel work still available after
 195 # linking starts.
 196 add_subdirectory(fileio)
 197 add_subdirectory(selection)
 198
 199 # Suppress a warning about our abuse of t_inputrec
 200 gmx_source_file_warning_suppression(mdtypes/inputrec.cpp -Wno-class-memaccess HAS_NO_CLASS_MEMACCESS)
 201
 202 # Handle the object libraries that contain the source file
 203 # dependencies that need special handling because they are generated
 204 # or external code.
 205 foreach(object_library ${libgromacs_object_library_dependencies})
 206     if (BUILD_SHARED_LIBS)
 207         set_target_properties(${object_library} PROPERTIES POSITION_INDEPENDENT_CODE true)
 208     endif()
 209     target_include_directories(${object_library} SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 210
 211     # Add the sources from the object libraries to the main library.
 212     target_sources(libgromacs PRIVATE $<TARGET_OBJECTS:${object_library}>)
 213 endforeach()
 214 gmx_target_compile_options(libgromacs)
 215 target_compile_definitions(libgromacs PRIVATE HAVE_CONFIG_H)
 216 target_include_directories(libgromacs SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
 217
 218 if (GMX_USE_OPENCL)
 219     option(GMX_EXTERNAL_CLFFT "True if an external clFFT is required to be used" FALSE)
 220     mark_as_advanced(GMX_EXTERNAL_CLFFT)
 221
 222     # Default to using clFFT found on the system
 223     # switch to quiet at the second run.
 224     if (DEFINED clFFT_LIBRARY)
 225         set (clFFT_FIND_QUIETLY TRUE)
 226     endif()
 227     find_package(clFFT)
 228     if (NOT clFFT_FOUND)
 229         if (GMX_EXTERNAL_CLFFT)
 230             message(FATAL_ERROR "Did not find required external clFFT library, consider setting clFFT_ROOT_DIR")
 231         endif()
 232
 233         if(MSVC)
 234             message(FATAL_ERROR
 235 "An OpenCL build was requested with Visual Studio compiler, but GROMACS
 236 requires clFFT, which was not found on your system. GROMACS does bundle
 237 clFFT to help with building for OpenCL, but that clFFT has not yet been
 238 ported to the more recent versions of that compiler that GROMACS itself
 239 requires. Thus for now, OpenCL is not available with MSVC and the internal
 240 build of clFFT in GROMACS 2019. Either change compiler, try installing
 241 a clFFT package, or use the latest GROMACS 2018 point release.")
 242         endif()
 243
 244         # Fall back on the internal version
 245         set (_clFFT_dir ../external/clFFT/src)
 246         add_subdirectory(${_clFFT_dir} clFFT-build)
 247         target_sources(libgromacs PRIVATE
 248             $<TARGET_OBJECTS:clFFT>
 249         )
 250         target_include_directories(libgromacs SYSTEM PRIVATE ${_clFFT_dir}/include)
 251         # Use the magic variable for how to link any library needed for
 252         # dlopen, etc.  which is -ldl where needed, and empty otherwise
 253         # (e.g. Windows, BSD, Mac).
 254         target_link_libraries(libgromacs PRIVATE "${CMAKE_DL_LIBS}")
 255     else()
 256         target_link_libraries(libgromacs PRIVATE clFFT)
 257     endif()
 258 endif()
 259
 260 # Permit GROMACS code to include externally developed headers, such as
 261 # the functionality from the nonstd project that we use for
 262 # gmx::compat::optional. These are included as system headers so that
 263 # no warnings are issued from them.
 264 #
 265 # TODO Perhaps generalize this for all headers from src/external
 266 target_include_directories(libgromacs SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
 267
 268 # Temporary fix to allow external access to restraintpotentail
 269 target_include_directories(libgromacs PUBLIC
 270                            $<INSTALL_INTERFACE:include>
 271                            )
 272
 273 if(SIMD_AVX_512_CXX_SUPPORTED AND NOT ("${GMX_SIMD_ACTIVE}" STREQUAL "AVX_512_KNL"))
 274     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file.
 275     # On KNL this can cause illegal instruction because the compiler might use non KNL AVX instructions
 276     # with the SIMD_AVX_512_CXX_FLAGS flags.
 277     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 278 endif()
 279
 280 gmx_setup_tng_for_libgromacs()
 281
 282 target_link_libraries(libgromacs
 283                       PRIVATE
 284                       ${EXTRAE_LIBRARIES}
 285                       ${GMX_EXTRA_LIBRARIES}
 286                       ${GMX_COMMON_LIBRARIES}
 287                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 288                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS}
 289                       ${OpenCL_LIBRARIES}
 290                       $<$<PLATFORM_ID:SunOS>:socket>
 291                       PUBLIC
 292                       ${GMX_PUBLIC_LIBRARIES}
 293                       )
 294 if (GMX_OPENMP)
 295     target_link_libraries(libgromacs PUBLIC OpenMP::OpenMP_CXX)
 296 endif()
 297 set_target_properties(libgromacs PROPERTIES
 298                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 299                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 300                       VERSION ${LIBRARY_VERSION}
 301                       )
 302
 303 gmx_manage_lmfit()
 304 target_link_libraries(libgromacs PRIVATE lmfit)
 305
 306 # Fix everything found by the latest version of clang that we use in
 307 # Jenkins testing. This should be updated when we update the latest
 308 # tested version of clang.
 309 if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION MATCHES "^7\.0")
 310    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-Weverything ${IGNORED_CLANG_ALL_WARNINGS}>)
 311 endif()
 312 if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
 313    target_compile_options(libgromacs PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/analyze /analyze:stacksize 70000
 314      #Control flow warnings are disabled because the commond line output is insufficient. There is no tool
 315      #to convert the xml report to e.g. HTML and even in Visual Studio the viewer doesn't work with cmake support.
 316      /wd6001  #unitialized memory
 317      /wd6011  #derefencing NULL
 318      /wd6053  #prior call not zero-terminate
 319      /wd6054  #might not be zero-terminated
 320      /wd6385  #reading invalid data
 321      /wd6386  #buffer overrun
 322      /wd6387  #could be '0'
 323      /wd28199 #uninitialized memory
 324      # For compile time constant (e.g. templates) the following warnings have flase postives
 325      /wd6239  #(<non-zero> && <expr>)
 326      /wd6240  #(<expr> && <non-zero>)
 327      /wd6294  #Ill-defined for-loop
 328      /wd6326  #comparison of constant with other constant
 329      /wd28020 #expression involving paramter is not true
 330      # Misc
 331      /wd6330  #incorrect type to function (warns for char (instead of unsigned) for isspace/isalpha/isdigit/..))
 332      /wd6993  #OpenMP ignored
 333      #TODO
 334      /wd6031  #return value ignored (important - mostly warnigns about sscanf)
 335      /wd6244  #hides declaration (known issue - we ingore similar warnings for other compilers)
 336      /wd6246  #hides declaration
 337      >
 338    )
 339 endif()
 340
 341 if (GMX_CLANG_TIDY)
 342    set_target_properties(libgromacs PROPERTIES CXX_CLANG_TIDY
 343        "${CLANG_TIDY_EXE};-warnings-as-errors=*")
 344 endif()
 345
 346 # Only install the library in mdrun-only mode if it is actually necessary
 347 # for the binary
 348 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 349     install(TARGETS libgromacs
 350             EXPORT libgromacs
 351             LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 352             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 353             ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 354             INCLUDES DESTINATION include
 355             COMPONENT libraries)
 356 endif()
 357
 358 if (NOT GMX_BUILD_MDRUN_ONLY)
 359     include(InstallLibInfo.cmake)
 360 endif()
 361
 362 # Technically, the user could want to do this for an OpenCL build
 363 # using the CUDA runtime, but currently there's no reason to want to
 364 # do that.
 365 if (INSTALL_CUDART_LIB) #can be set manual by user
 366     if (GMX_USE_CUDA)
 367         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 368             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 369             if(IS_CUDART) #libcuda should not be installed
 370                 #install also name-links (linker uses those)
 371                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 372                 install(FILES ${CUDA_LIBS} DESTINATION
 373                     ${CMAKE_INSTALL_LIBDIR} COMPONENT libraries)
 374             endif()
 375         endforeach()
 376     else()
 377         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 378     endif()
 379 endif()
 380
 381 if(GMX_USE_OPENCL)
 382     # Install the utility headers
 383     file(GLOB OPENCL_INSTALLED_FILES
 384         gpu_utils/vectype_ops.clh
 385         gpu_utils/device_utils.clh
 386         )
 387     install(FILES ${OPENCL_INSTALLED_FILES}
 388         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/gpu_utils
 389         COMPONENT libraries)
 390     file(GLOB OPENCL_INSTALLED_FILES
 391         pbcutil/ishift.h
 392         )
 393     install(FILES ${OPENCL_INSTALLED_FILES}
 394         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/pbcutil
 395         COMPONENT libraries)
 396
 397     # Install the NBNXM source and headers
 398     file(GLOB OPENCL_INSTALLED_FILES
 399         nbnxm/constants.h
 400         )
 401     install(FILES ${OPENCL_INSTALLED_FILES}
 402         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm
 403         COMPONENT libraries)
 404     file(GLOB OPENCL_INSTALLED_FILES
 405         nbnxm/opencl/nbnxm_ocl_kernels.cl
 406         nbnxm/opencl/nbnxm_ocl_kernel.clh
 407         nbnxm/opencl/nbnxm_ocl_kernel_pruneonly.clh
 408         nbnxm/opencl/nbnxm_ocl_kernels.clh
 409         nbnxm/opencl/nbnxm_ocl_kernels_fastgen.clh
 410         nbnxm/opencl/nbnxm_ocl_kernels_fastgen_add_twincut.clh
 411         nbnxm/opencl/nbnxm_ocl_kernel_utils.clh
 412         nbnxm/opencl/nbnxm_ocl_consts.h
 413         )
 414     install(FILES ${OPENCL_INSTALLED_FILES}
 415         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/nbnxm/opencl
 416         COMPONENT libraries)
 417
 418     # Install the PME source and headers
 419     file(GLOB OPENCL_INSTALLED_FILES
 420         ewald/pme_spread.clh
 421         ewald/pme_solve.clh
 422         ewald/pme_gather.clh
 423         ewald/pme_gpu_utils.clh
 424         ewald/pme_program.cl
 425         ewald/pme_gpu_types.h
 426         )
 427     install(FILES ${OPENCL_INSTALLED_FILES}
 428         DESTINATION ${GMX_INSTALL_OCLDIR}/gromacs/ewald
 429         COMPONENT libraries)
 430 endif()