src/gromacs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(LIBGROMACS_SOURCES)
  36
  37 if (GMX_CLANG_CUDA)
  38     include(gmxClangCudaUtils)
  39 endif()
  40
  41 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
  42 set_property(GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
  43 set_property(GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  44 set_property(GLOBAL PROPERTY GMX_AVX_512_SOURCE)
  45
  46 function (_gmx_add_files_to_property PROPERTY)
  47     foreach (_file ${ARGN})
  48         if (IS_ABSOLUTE "${_file}")
  49             set_property(GLOBAL APPEND PROPERTY ${PROPERTY} ${_file})
  50         else()
  51             set_property(GLOBAL APPEND PROPERTY ${PROPERTY}
  52                          ${CMAKE_CURRENT_LIST_DIR}/${_file})
  53         endif()
  54     endforeach()
  55 endfunction ()
  56
  57 function (gmx_add_libgromacs_sources)
  58     _gmx_add_files_to_property(GMX_LIBGROMACS_SOURCES ${ARGN})
  59 endfunction ()
  60
  61 # TODO Reconsider this, as the CUDA driver API is probably a simpler
  62 # approach, at least for the build system. See Redmine #2530
  63 function (gmx_compile_cpp_as_cuda)
  64     _gmx_add_files_to_property(GMX_LIBGROMACS_GPU_IMPL_SOURCES ${ARGN})
  65 endfunction ()
  66
  67 function (gmx_install_headers)
  68     if (NOT GMX_BUILD_MDRUN_ONLY)
  69         file(RELATIVE_PATH _dest ${PROJECT_SOURCE_DIR}/src ${CMAKE_CURRENT_LIST_DIR})
  70         install(FILES       ${ARGN}
  71                 DESTINATION "${INCL_INSTALL_DIR}/${_dest}"
  72                 COMPONENT   development)
  73     endif()
  74     _gmx_add_files_to_property(GMX_INSTALLED_HEADERS ${ARGN})
  75 endfunction ()
  76
  77 function (gmx_write_installed_header_list)
  78     get_property(_list GLOBAL PROPERTY GMX_INSTALLED_HEADERS)
  79     string(REPLACE ";" "\n" _list "${_list}")
  80     # TODO: Make this only update the file timestamp if the contents actually change.
  81     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/installed-headers.txt "${_list}")
  82 endfunction()
  83
  84 add_subdirectory(gmxlib)
  85 add_subdirectory(mdlib)
  86 add_subdirectory(applied-forces)
  87 add_subdirectory(listed-forces)
  88 add_subdirectory(commandline)
  89 add_subdirectory(domdec)
  90 add_subdirectory(ewald)
  91 add_subdirectory(fft)
  92 add_subdirectory(gpu_utils)
  93 add_subdirectory(hardware)
  94 add_subdirectory(linearalgebra)
  95 add_subdirectory(math)
  96 add_subdirectory(mdrun)
  97 add_subdirectory(mdrunutility)
  98 add_subdirectory(mdtypes)
  99 add_subdirectory(onlinehelp)
 100 add_subdirectory(options)
 101 add_subdirectory(pbcutil)
 102 add_subdirectory(random)
 103 add_subdirectory(tables)
 104 add_subdirectory(taskassignment)
 105 add_subdirectory(timing)
 106 add_subdirectory(topology)
 107 add_subdirectory(trajectory)
 108 add_subdirectory(utility)
 109 add_subdirectory(fileio)
 110 add_subdirectory(swap)
 111 add_subdirectory(essentialdynamics)
 112 add_subdirectory(pulling)
 113 add_subdirectory(awh)
 114 add_subdirectory(simd)
 115 add_subdirectory(imd)
 116 if (NOT GMX_BUILD_MDRUN_ONLY)
 117     add_subdirectory(gmxana)
 118     add_subdirectory(gmxpreprocess)
 119     add_subdirectory(correlationfunctions)
 120     add_subdirectory(statistics)
 121     add_subdirectory(analysisdata)
 122     add_subdirectory(selection)
 123     add_subdirectory(trajectoryanalysis)
 124     add_subdirectory(energyanalysis)
 125     add_subdirectory(tools)
 126 endif()
 127
 128 get_property(PROPERTY_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_SOURCES)
 129 list(APPEND LIBGROMACS_SOURCES ${GMXLIB_SOURCES} ${MDLIB_SOURCES} ${PROPERTY_SOURCES})
 130
 131 # This would be the standard way to include thread_mpi, but
 132 # we want libgromacs to link the functions directly
 133 #if(GMX_THREAD_MPI)
 134 #    add_subdirectory(thread_mpi)
 135 #endif()
 136 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 137
 138 tmpi_get_source_list(THREAD_MPI_SOURCES ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/src)
 139 list(APPEND LIBGROMACS_SOURCES ${THREAD_MPI_SOURCES})
 140
 141 get_lmfit_properties(LMFIT_SOURCES LMFIT_LIBRARIES_TO_LINK LMFIT_INCLUDE_DIRECTORY LMFIT_INCLUDE_DIR_ORDER)
 142 include_directories(${LMFIT_INCLUDE_DIR_ORDER} SYSTEM "${LMFIT_INCLUDE_DIRECTORY}")
 143 list(APPEND LIBGROMACS_SOURCES ${LMFIT_SOURCES})
 144
 145 configure_file(version.h.cmakein version.h)
 146 gmx_install_headers(
 147     analysisdata.h
 148     commandline.h
 149     options.h
 150     random.h
 151     selection.h
 152     trajectoryanalysis.h
 153     utility.h
 154     ${CMAKE_CURRENT_BINARY_DIR}/version.h
 155     )
 156
 157 # This code is here instead of utility/CMakeLists.txt, because CMake
 158 # custom commands and source file properties can only be set in the directory
 159 # that contains the target that uses them.
 160 # TODO: Generate a header instead that can be included from baseversion.c.
 161 # That probably simplifies things somewhat.
 162 set(GENERATED_VERSION_FILE utility/baseversion-gen.c)
 163 gmx_configure_version_file(
 164     utility/baseversion-gen.c.cmakein ${GENERATED_VERSION_FILE}
 165     REMOTE_HASH)
 166 list(APPEND LIBGROMACS_SOURCES ${GENERATED_VERSION_FILE})
 167
 168 # Mark some shared GPU implementation files to compile with CUDA if needed
 169 if (GMX_USE_CUDA)
 170     get_property(LIBGROMACS_GPU_IMPL_SOURCES GLOBAL PROPERTY GMX_LIBGROMACS_GPU_IMPL_SOURCES)
 171     set_source_files_properties(${LIBGROMACS_GPU_IMPL_SOURCES} PROPERTIES CUDA_SOURCE_PROPERTY_FORMAT OBJ)
 172 endif()
 173
 174 # set up CUDA compilation with clang
 175 if (GMX_CLANG_CUDA)
 176     foreach (_file ${LIBGROMACS_SOURCES})
 177         get_filename_component(_ext ${_file} EXT)
 178         get_source_file_property(_cuda_source_format ${_file} CUDA_SOURCE_PROPERTY_FORMAT)
 179         if (${_ext} STREQUAL ".cu" OR _cuda_source_format)
 180             gmx_compile_cuda_file_with_clang(${_file})
 181         endif()
 182     endforeach()
 183 endif()
 184
 185 if (GMX_USE_CUDA)
 186     # Work around FindCUDA that prevents using target_link_libraries()
 187     # with keywords otherwise...
 188     set(CUDA_LIBRARIES PRIVATE ${CUDA_LIBRARIES})
 189     if (NOT GMX_CLANG_CUDA)
 190         cuda_add_library(libgromacs ${LIBGROMACS_SOURCES})
 191     else()
 192         add_library(libgromacs ${LIBGROMACS_SOURCES})
 193     endif()
 194     target_link_libraries(libgromacs PRIVATE ${CUDA_CUFFT_LIBRARIES})
 195 else()
 196     add_library(libgromacs ${LIBGROMACS_SOURCES})
 197 endif()
 198
 199 # Recent versions of gcc and clang give warnings on scanner.cpp, which
 200 # is a generated source file. These are awkward to suppress inline, so
 201 # we do it in the compilation command (after testing that the compiler
 202 # supports the suppressions).
 203 include(CheckCXXCompilerFlag)
 204 check_cxx_compiler_flag(-Wno-unused HAS_NO_UNUSED)
 205 if (HAS_NO_UNUSED)
 206     set(_scanner_cpp_compiler_flags "${_scanner_cpp_compiler_flags} -Wno-unused-parameter -Wno-unused-function")
 207 endif()
 208 set_source_files_properties(selection/scanner.cpp PROPERTIES COMPILE_FLAGS "${_scanner_cpp_compiler_flags}")
 209
 210 if(SIMD_AVX_512_CXX_SUPPORTED)
 211     # Since we might be overriding -march=core-avx2, add a flag so we don't warn for this specific file
 212     set_source_files_properties(hardware/identifyavx512fmaunits.cpp PROPERTIES COMPILE_FLAGS "${SIMD_AVX_512_CXX_FLAGS} ${CXX_NO_UNUSED_OPTION_WARNING_FLAGS}")
 213 endif()
 214
 215 gmx_setup_tng_for_libgromacs()
 216
 217 target_link_libraries(libgromacs
 218                       PRIVATE
 219                       ${EXTRAE_LIBRARIES}
 220                       ${GMX_EXTRA_LIBRARIES}
 221                       ${GMX_COMMON_LIBRARIES}
 222                       ${FFT_LIBRARIES} ${LINEAR_ALGEBRA_LIBRARIES}
 223                       ${LMFIT_LIBRARIES_TO_LINK}
 224                       ${THREAD_LIB} ${GMX_SHARED_LINKER_FLAGS} ${OpenCL_LIBRARIES}
 225                       ${GMX_STDLIB_LIBRARIES}
 226                       PUBLIC
 227                       ${GMX_PUBLIC_LIBRARIES}
 228                       )
 229 set_target_properties(libgromacs PROPERTIES
 230                       OUTPUT_NAME "gromacs${GMX_LIBS_SUFFIX}"
 231                       SOVERSION ${LIBRARY_SOVERSION_MAJOR}
 232                       VERSION ${LIBRARY_VERSION}
 233                       COMPILE_FLAGS "${OpenMP_C_FLAGS}")
 234
 235 gmx_write_installed_header_list()
 236
 237 # Only install the library in mdrun-only mode if it is actually necessary
 238 # for the binary
 239 if (NOT GMX_BUILD_MDRUN_ONLY OR BUILD_SHARED_LIBS)
 240     install(TARGETS libgromacs
 241             EXPORT libgromacs
 242             LIBRARY DESTINATION ${LIB_INSTALL_DIR}
 243             RUNTIME DESTINATION ${BIN_INSTALL_DIR}
 244             ARCHIVE DESTINATION ${LIB_INSTALL_DIR}
 245             COMPONENT libraries)
 246 endif()
 247
 248 if (NOT GMX_BUILD_MDRUN_ONLY)
 249     include(InstallLibInfo.cmake)
 250 endif()
 251
 252 # Technically, the user could want to do this for an OpenCL build
 253 # using the CUDA runtime, but currently there's no reason to want to
 254 # do that.
 255 if (INSTALL_CUDART_LIB) #can be set manual by user
 256     if (GMX_USE_CUDA)
 257         foreach(CUDA_LIB ${CUDA_LIBRARIES})
 258             string(REGEX MATCH "cudart" IS_CUDART ${CUDA_LIB})
 259             if(IS_CUDART) #libcuda should not be installed
 260                 #install also name-links (linker uses those)
 261                 file(GLOB CUDA_LIBS ${CUDA_LIB}*)
 262                 install(FILES ${CUDA_LIBS} DESTINATION
 263                     ${LIB_INSTALL_DIR} COMPONENT libraries)
 264             endif()
 265         endforeach()
 266     else()
 267         message(WARNING "INSTALL_CUDART_LIB only makes sense when configuring for CUDA support")
 268     endif()
 269 endif()
 270
 271 if(GMX_USE_OPENCL)
 272     set(OPENCL_KERNELS ${MDLIB_OPENCL_KERNELS})
 273
 274     install(FILES ${OPENCL_KERNELS} DESTINATION
 275         ${OCL_INSTALL_DIR} COMPONENT libraries)
 276 endif()
 277
 278 if (BUILD_TESTING)
 279     add_subdirectory(compat/tests)
 280 endif()