CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 # PROJECT_VERSION should have the following structure:
   6 # VERSION[-dev-SUFFIX] where the VERSION can have any form and the suffix
   7 set(PROJECT_VERSION "4.5-beta3"
   8     CACHE STRING "Gromacs version string")
   9
  10 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  11 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  12
  13 if(NOT CMAKE_BUILD_TYPE)
  14     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  15 endif(NOT CMAKE_BUILD_TYPE)
  16
  17 enable_language(C)
  18
  19 ########################################################################
  20 # Fix stupid flags on MSVC
  21 ########################################################################
  22 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  23     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  24     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  25     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  26     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  27 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  28
  29 set(GMX_EXTRA_LIBRARIES)
  30
  31 ######################################################################
  32 # compiler tests
  33 # these need ot be done early (before further tests).
  34 #####################################################################
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckCXXCompilerFlag)
  38
  39 include(gmxCFlags)
  40 gmx_c_flags()
  41
  42 ########################################################################
  43 # User input options                                                   #
  44 ########################################################################
  45 option(GMX_DOUBLE "Use double precision" OFF)
  46 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
  47 option(GMX_THREADS    "Build a parallel (threaded-based) version of GROMACS)" ON)
  48 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
  49 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
  50 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library" OFF)
  51 set(GMX_ACCELERATION "auto"
  52     CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec")
  53
  54 set(GMX_FFT_LIBRARY "fftw3"
  55     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
  56 option(GMX_DISABLE_FFTW_MEASURE
  57        "Do not optimize FFTW setups (not needed with SSE)" OFF)
  58 set(GMX_QMMM_PROGRAM "none"
  59     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
  60 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
  61 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI)" OFF)
  62 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
  63 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
  64 mark_as_advanced(GMX_MPI_IN_PLACE)
  65
  66
  67 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
  68 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
  69
  70 option(USE_VERSION_H "Generate development version string/information" ON)
  71
  72 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries.")
  73
  74 set(PKG_CFLAGS "")
  75 if(GMX_DOUBLE)
  76   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
  77 endif(GMX_DOUBLE)
  78 if(GMX_SOFTWARE_INVSQRT)
  79   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
  80 endif(GMX_SOFTWARE_INVSQRT)
  81
  82 ########################################################################
  83 #Process MPI settings
  84 ########################################################################
  85 if(GMX_MPI)
  86         MESSAGE(WARNING "
  87             There are known problems with some MPI implementations:
  88                      OpenMPI version < 1.4.1
  89                      MVAPICH2 version <= 1.4.1                               *")
  90     if(GMX_THREADS)
  91         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
  92         set(GMX_THREADS OFF CACHE BOOL
  93             "Thread-based parallelization conflicts with MPI." FORCE)
  94     endif(GMX_THREADS)
  95     find_package(MPI)
  96     if(MPI_FOUND)
  97         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
  98         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
  99
 100         include_directories(${MPI_INCLUDE_PATH})
 101         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 102         add_definitions( -DMPI ) #for FAHCORE
 103         include(gmxTestMPI_IN_PLACE)
 104         if (GMX_MPI_IN_PLACE)
 105             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 106         endif (GMX_MPI_IN_PLACE)
 107     else(MPI_FOUND)
 108         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 109     endif(MPI_FOUND)
 110     include(gmxTestCatamount)
 111     gmx_test_catamount(GMX_CRAY_XT3)
 112     if(GMX_CRAY_XT3)
 113         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 114         set(GMX_NO_SYSTEM 1)
 115         set(GMX_NO_NICE 1)
 116     endif(GMX_CRAY_XT3)
 117     set(GMX_LIB_MPI 1)
 118     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 119 endif(GMX_MPI)
 120
 121
 122 #######################################################################
 123 # Check for options incompatible with OpenMM build                    #
 124 #######################################################################
 125 if(GMX_OPENMM)
 126     cmake_minimum_required(VERSION 2.6.4)
 127     # we'll use the built-in fft to avoid unnecessary dependencies
 128     set (GMX_FFT_LIBRARY "fftpack")
 129     if(GMX_MPI)
 130         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 131     endif(GMX_MPI)
 132     if(GMX_THREADS)
 133         message(STATUS "Threads not compatible with OpenMM build, disabled")
 134         set(GMX_THREADS OFF)
 135     endif(GMX_THREADS)
 136     if(GMX_SOFTWARE_INVSQRT)
 137         set(GMX_SOFTWARE_INVSQRT OFF)
 138     endif(GMX_SOFTWARE_INVSQRT)
 139     if(NOT GMX_ACCELERATION MATCHES "auto|none|None|NONE" OR NOT ${GMX_ACCELERATION} STREQUAL "")
 140         message(WARNING "The OpenMM build does not support other acceleration modes!")
 141         set(GMX_ACCELERATION "none")
 142     endif()
 143     if(GMX_FAHCORE)
 144         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 145     endif(GMX_FAHCORE)
 146 endif(GMX_OPENMM)
 147
 148
 149 ########################################################################
 150 # Basic system tests (standard libraries, headers, functions, types)   #
 151 ########################################################################
 152 include(CheckIncludeFiles)
 153 check_include_files(string.h     HAVE_STRING_H)
 154 check_include_files(math.h       HAVE_MATH_H)
 155 check_include_files(limits.h     HAVE_LIMITS_H)
 156 check_include_files(memory.h     HAVE_MEMORY_H)
 157 check_include_files(unistd.h     HAVE_UNISTD_H)
 158 check_include_files(pwd.h        HAVE_PWD_H)
 159 check_include_files(stdint.h     HAVE_STDINT_H)
 160 check_include_files(stdlib.h     HAVE_STDLIB_H)
 161 check_include_files(pthread.h    HAVE_PTHREAD_H)
 162 check_include_files(dirent.h     HAVE_DIRENT_H)
 163 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 164 check_include_files(regex.h      HAVE_REGEX_H)
 165 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 166 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 167 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 168 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 169 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 170 # SSE support
 171 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 172 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 173 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 174 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 175 check_include_files(io.h                 HAVE_IO_H)
 176
 177
 178 include(CheckFunctionExists)
 179 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 180 check_function_exists(strdup            HAVE_STRDUP)
 181 check_function_exists(vprintf           HAVE_VPRINTF)
 182 check_function_exists(memcmp            HAVE_MEMCMP)
 183 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 184 check_function_exists(memalign          HAVE_MEMALIGN)
 185 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 186 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 187 check_function_exists(isnan             HAVE_ISNAN)
 188 check_function_exists(_isnan            HAVE__ISNAN)
 189 check_function_exists(isfinite          HAVE_ISFINITE)
 190 check_function_exists(_isfinite         HAVE__ISFINITE)
 191 check_function_exists(fsync             HAVE_FSYNC)
 192 check_function_exists(_fileno           HAVE__FILENO)
 193 check_function_exists(fileno            HAVE_FILENO)
 194 check_function_exists(_commit           HAVE__COMMIT)
 195
 196 include(CheckLibraryExists)
 197 check_library_exists(m sqrt "" HAVE_LIBM)
 198 check_library_exists(m cbrt "" HAVE_CBRT)
 199
 200
 201 include(CheckTypeSize)
 202
 203 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 204 check_type_size("int"           SIZEOF_INT)
 205 check_type_size("long int"      SIZEOF_LONG_INT)
 206 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 207 check_type_size("off_t"         SIZEOF_OFF_T)
 208 check_type_size("void *"        SIZEOF_VOIDP)
 209
 210 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 211     set(GMX_64_BIT TRUE)
 212 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 213     set(GMX_64_BIT FALSE)
 214 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 215
 216 # Check for some basic types that we *need*, so set these to int if they are not present
 217 check_type_size(uid_t uid_t)
 218 if(NOT uid_t)
 219   set(uid_t int)
 220 else(NOT uid_t)
 221   set(uid_t 0)
 222 endif(NOT uid_t)
 223
 224 check_type_size(gid_t gid_t)
 225 if(NOT gid_t)
 226   set(gid_t 1)
 227 else(NOT gid_t)
 228   set(gid_t 0)
 229 endif(NOT gid_t)
 230
 231 check_type_size(size_t size_t)
 232 if(NOT size_t)
 233   set(size_t int)
 234 else(NOT size_t)
 235   set(size_t 0)
 236 endif(NOT size_t)
 237
 238 check_type_size(off_t off_t)
 239 if(NOT off_t)
 240   set(off_t int)
 241 else(NOT off_t)
 242   set(off_t 0)
 243 endif(NOT off_t)
 244
 245 include(TestBigEndian)
 246 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 247
 248
 249
 250
 251 ########################################################################
 252 # Find external packages                                               #
 253 ########################################################################
 254
 255 find_package(LibXml2)
 256 set(PKG_XML "")
 257 if(LIBXML2_FOUND)
 258     include_directories(${LIBXML2_INCLUDE_DIR})
 259     set(PKG_XML libxml-2.0)
 260     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 261     set(HAVE_LIBXML2 1)
 262 endif(LIBXML2_FOUND)
 263
 264 find_package(X11)
 265 # X11 includes/libraries are only set in the ngmx subdirectory!
 266 if(X11_FOUND)
 267     set(HAVE_X11 1)
 268 endif(X11_FOUND)
 269
 270 if(GMX_THREADS)
 271     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 272     include(ThreadMPI)
 273     set(THREAD_MPI_LIB thread_mpi)
 274     set(GMX_MPI 1)
 275     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 276     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 277         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 278     endif()
 279 endif(GMX_THREADS)
 280
 281 if(GMX_OPENMM)
 282     set(CUDA_BUILD_EMULATION OFF)
 283     find_package(CUDA 3.1 REQUIRED)
 284     add_definitions(-DGMX_OPENMM)
 285     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 286         set(CUDA_VERBOSE_BUILD ON)
 287     endif()
 288     find_package(OpenMM)
 289 endif(GMX_OPENMM)
 290
 291 if(APPLE)
 292    find_library(ACCELERATE_FRAMEWORK Accelerate)
 293    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 294 endif(APPLE)
 295
 296 # only bother with finding git and using version.h if the source is a git repo
 297 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 298     if(USE_VERSION_H)
 299         # We need at least git v1.5.1 be able to parse git's date output. If not
 300         # fund or the version is too small, we can't generate version information.
 301         find_package(Git 1.5.1)
 302         # this should at some point become VERSION_LESS
 303         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 304             message("No compatible git version found, won't be able to generate proper development version information.")
 305         endif()
 306     endif()
 307 else()
 308     set(USE_VERSION_H OFF)
 309 endif()
 310
 311 if (GMX_DLOPEN)
 312     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 313 endif (GMX_DLOPEN)
 314
 315 ########################################################################
 316 # Generate development version info for cache
 317 ########################################################################
 318 # set(GEN_VERSION_INFO_INTERNAL "ON")
 319 # include(gmxGenerateVersionString)
 320
 321 ########################################################################
 322 # Our own GROMACS tests
 323 ########################################################################
 324
 325 add_definitions( -DHAVE_CONFIG_H )
 326 include_directories(${CMAKE_BINARY_DIR}/src)
 327 include_directories(${CMAKE_SOURCE_DIR}/include)
 328
 329 include(gmxCheckBuildUserTime)
 330 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 331
 332 include(gmxTestFloatFormat)
 333 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 334                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 335                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 336
 337 include(gmxTestLargeFiles)
 338 gmx_test_large_files(GMX_LARGEFILES)
 339 check_function_exists(fseeko     HAVE_FSEEKO)
 340
 341 include(gmxTestSignal)
 342 gmx_test_retsigtype(RETSIGTYPE)
 343
 344 include(gmxTestInline)
 345 gmx_test_inline(INLINE_KEYWORD)
 346
 347 include(gmxTestRestrict)
 348 gmx_test_inline(RESTRICT_KEYWORD)
 349
 350 include(gmxTestPipes)
 351 gmx_test_pipes(HAVE_PIPES)
 352
 353 include(gmxTestInlineASM)
 354 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 355 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 356
 357 # turn on SSE if supported with reasonable defaults.
 358 if (${GMX_ACCELERATION} STREQUAL "auto")
 359   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 360
 361     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 362
 363     if (GMX_64_BIT)
 364       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 365     else (GMX_64_BIT)
 366       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 367     endif (GMX_64_BIT)
 368
 369     # Determine the assembler/compiler to use
 370   else()
 371     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: none, SSE, BlueGene, Power6, ia64, altivec" FORCE)
 372   endif()
 373 endif (${GMX_ACCELERATION} STREQUAL "auto")
 374
 375
 376 include(gmxTestXDR)
 377 gmx_test_xdr(GMX_SYSTEM_XDR)
 378 if(NOT GMX_SYSTEM_XDR)
 379     set(GMX_INTERNAL_XDR 1)
 380     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 381 endif(NOT GMX_SYSTEM_XDR)
 382
 383 if(GMX_FORTRAN OR GMX_POWER6)
 384     enable_language(Fortran)
 385     include(FortranCInterface)
 386     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 387     if(extra_under_score)
 388         set(extrasuffix "_")
 389     endif(extra_under_score)
 390
 391     if(isupper)
 392         set(F77_FUNCDEF   "${prefix} ## NAME ## ${suffix}")
 393         set(F77_FUNCDEF_  "${prefix} ## NAME ## ${suffix}${extrasuffix}")
 394     else(isupper)
 395         set(F77_FUNCDEF   "${prefix} ## name ## ${suffix}")
 396         set(F77_FUNCDEF_  "${prefix} ## name ## ${suffix}${extrasuffix}")
 397     endif(isupper)
 398 else(GMX_FORTRAN OR GMX_POWER6)
 399         set(F77_FUNCDEF   "name ## _")
 400         set(F77_FUNCDEF_  "name ## _")
 401 endif(GMX_FORTRAN OR GMX_POWER6)
 402
 403
 404 # Process nonbonded accelerated kernels settings
 405 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 406 if(${GMX_ACCELERATION} STREQUAL "NONE")
 407   # nothing to do
 408 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 409
 410     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 411       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 412     else(CMAKE_GENERATOR MATCHES "Visual Studio")
 413       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 414     endif(CMAKE_GENERATOR MATCHES "Visual Studio")
 415     if (NOT GMX_64_BIT)
 416         # for 32-bit compiles, we might need to turn on sse
 417         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 418         if (XFLAGS_SSE)
 419             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 420         endif (XFLAGS_SSE)
 421         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 422         if (XXFLAGS_SSE)
 423             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 424         endif (XXFLAGS_SSE)
 425     endif (NOT GMX_64_BIT)
 426
 427     if(GMX_IA32_ASM)
 428       if(GMX_DOUBLE)
 429         set(GMX_IA32_SSE2 1)
 430       else()
 431         set(GMX_IA32_SSE 1)
 432       endif()
 433     elseif(GMX_X86_64_ASM)
 434       if(GMX_DOUBLE)
 435         set(GMX_X86_64_SSE2 1)
 436       else()
 437         set(GMX_X86_64_SSE 1)
 438       endif()
 439     endif()
 440
 441 #    if(HAVE_PMMINTRIN_H)
 442 #        set(GMX_SSE3 1)
 443 #    endif(HAVE_PMMINTRIN_H)
 444 #    if(HAVE_SMMINTRIN_H)
 445 #        set(GMX_SSE4_1 1)
 446 #    endif(HAVE_SMMINTRIN_H)
 447
 448 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 449     set(GMX_FORTRAN 1)
 450 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 451     set(GMX_BLUEGENE 1)
 452 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 453     set(GMX_POWER6 1)
 454 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 455     set(GMX_IA64_ASM 1)
 456     set(DISABLE_WATERWATER_NLIST 1)
 457     set(DISABLE_WATER_NLIST 1)
 458 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 459     check_include_files(altivec.h HAVE_ALTIVEC_H)
 460     if(HAVE_ALTIVEC_H)
 461         set(GMX_PPC_ALTIVEC 1)
 462     endif(HAVE_ALTIVEC_H)
 463 else(${GMX_ACCELERATION} STREQUAL "NONE")
 464     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 465 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 466
 467
 468
 469
 470
 471
 472
 473 # Process QM/MM Settings
 474 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 475 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 476     set(GMX_QMMM_GAUSSIAN 1)
 477 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 478     set(GMX_QMMM_MOPAC 1)
 479 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 480     set(GMX_QMMM_GAMESS 1)
 481 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 482     set(GMX_QMMM_ORCA 1)
 483 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 484     # nothing to do
 485 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 486     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 487 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 488
 489 # Process FFT library settings - if not OpenMM build
 490 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 491 set(PKG_FFT "")
 492 set(PKG_FFT_LIBS "")
 493 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 494 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 495     if(GMX_DOUBLE)
 496         find_package(FFTW3 REQUIRED)
 497                 include_directories(${FFTW3_INCLUDE_DIR})
 498         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 499         set(PKG_FFT "fftw3")
 500     else(GMX_DOUBLE)
 501         find_package(FFTW3F REQUIRED)
 502         include_directories(${FFTW3F_INCLUDE_DIR})
 503         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 504         set(PKG_FFT "fftw3f")
 505     endif(GMX_DOUBLE)
 506
 507     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 508         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 509     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 510
 511     set(GMX_FFT_FFTW3 1)
 512
 513 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 514 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 515     if(GMX_DOUBLE)
 516         find_package(FFTW2 REQUIRED)
 517     else(GMX_DOUBLE)
 518         find_package(FFTW2F REQUIRED)
 519     endif(GMX_DOUBLE)
 520
 521     if(NOT FFTW2_FOUND)
 522            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 523     endif(NOT FFTW2_FOUND)
 524     include_directories(${FFTW2_INCLUDE_DIR})
 525     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 526     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 527
 528     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 529         set(FFTW2_NAME_DFFTW 1)
 530     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 531         set(FFTW2_NAME_SFFTW 1)
 532     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 533         set(FFTW2_NAME_FFTW 1)
 534     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 535
 536     set(GMX_FFT_FFTW2 1)
 537 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 538 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 539     find_package(MKL REQUIRED)
 540     include_directories(${MKL_INCLUDE_DIR})
 541     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 542     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 543
 544     set(GMX_FFT_MKL 1)
 545     set(HAVE_MKL 1)
 546
 547 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 548 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 549 #    set(GMX_FFT_ACML 1)
 550 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 551     MESSAGE(STATUS "Using internal FFT library - fftpack")
 552     set(GMX_FFT_FFTPACK 1)
 553 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 554     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 555 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 556
 557 # MKL has BLAS/LAPACK routines
 558 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 559   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 560   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 561 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 562   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 563   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 564 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 565
 566 # Math and thread libraries must often come after all others when linking...
 567 if(HAVE_LIBM)
 568     list(APPEND GMX_EXTRA_LIBRARIES m)
 569 endif(HAVE_LIBM)
 570
 571
 572
 573 if(GMX_FAHCORE)
 574   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 575       "Path to swindirect.h")
 576   include_directories(${COREWRAP_INCLUDE_DIR})
 577 endif(GMX_FAHCORE)
 578
 579 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 580 # these are set after everything else
 581 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 582     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 583         FORCE)
 584     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 585         "Flags used by the compiler during all build types" FORCE)
 586     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 587         "Flags used by the compiler during all build types" FORCE)
 588     set(CMAKE_EXE_LINKER_FLAGS
 589         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 590         CACHE STRING "Linker flags" FORCE)
 591 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 592
 593 ########################################################################
 594 # Specify install locations and which subdirectories to process        #
 595 ########################################################################
 596 set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 597 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 598 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 599 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 600 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 601
 602 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 603
 604
 605 add_subdirectory(share)
 606 add_subdirectory(include)
 607 add_subdirectory(man)
 608 add_subdirectory(src)
 609 add_subdirectory(scripts)
 610
 611 #######################
 612 ## uninstall target
 613 #######################
 614     CONFIGURE_FILE(
 615                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 616                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 617                    IMMEDIATE @ONLY)
 618 ###########################
 619 ADD_CUSTOM_TARGET(uninstall
 620                   "${CMAKE_COMMAND}" -P
 621                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 622 ###########################
 623
 624
 625 ########################################################################
 626 # Tests                                                                #
 627 ########################################################################
 628
 629 enable_testing()
 630 add_test(TestBuildAll make)
 631
 632 add_subdirectory(tests)