cmake/gmxManageFFTLibraries.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Manage setup of the different FFT libraries we can use in Gromacs.
  36 set(PKG_FFT "")
  37 set(PKG_FFT_LIBS "")
  38 # Intel 11 and up makes life somewhat easy if you just want to use
  39 # all their stuff. It's not easy if you only want some of their
  40 # stuff...
  41 set(MKL_MANUALLY FALSE)
  42 if (GMX_FFT_LIBRARY STREQUAL "MKL" AND
  43     NOT (CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_GREATER "11"))
  44     # The user will have to provide the set of magic libraries in
  45     # MKL_LIBRARIES (see below), which we cache (non-advanced), so that they
  46     # don't have to keep specifying it, and can easily see that
  47     # CMake is still using that information.
  48     set(MKL_MANUALLY TRUE)
  49 endif()
  50 set(MKL_LIBRARIES_FORMAT_DESCRIPTION "Use full paths to library files, in the right order, and separated by semicolons.")
  51 gmx_dependent_cache_variable(
  52     MKL_LIBRARIES
  53     "List of libraries for linking to MKL. ${MKL_LIBRARIES_FORMAT_DESCRIPTION}"
  54     STRING ""
  55     MKL_MANUALLY)
  56 gmx_dependent_cache_variable(
  57     MKL_INCLUDE_DIR
  58     "Path to mkl.h (non-inclusive)."
  59     PATH ""
  60     MKL_MANUALLY)
  61 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
  62     # ${FFTW} must be in upper case
  63     if(GMX_DOUBLE)
  64         set(FFTW "FFTW")
  65     else()
  66         set(FFTW "FFTWF")
  67     endif()
  68
  69     if(GMX_BUILD_OWN_FFTW)
  70
  71         if(MSVC)
  72             message(FATAL_ERROR "Cannot build FFTW3 automatically (GMX_BUILD_OWN_FFTW=ON) in Visual Studio")
  73         endif()
  74         if(CMAKE_GENERATOR STREQUAL "Ninja")
  75             message(FATAL_ERROR "Cannot build FFTW3 automatically (GMX_BUILD_OWN_FFTW=ON) with ninja")
  76         endif()
  77
  78         add_subdirectory(src/contrib/fftw)
  79         include_directories(BEFORE ${${FFTW}_INCLUDE_DIRS})
  80         # libgmxfftw is always built static, so libgromacs does not
  81         # have a dependency on anything, so PKG_FFT should be empty
  82         set(PKG_FFT "")
  83         set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3 build managed by GROMACS")
  84     else()
  85         string(TOLOWER "${FFTW}" LOWERFFTW)
  86         find_package(FFTW COMPONENTS ${LOWERFFTW})
  87
  88         if(NOT ${FFTW}_FOUND)
  89             MESSAGE(FATAL_ERROR "Cannot find FFTW 3 (with correct precision - libfftw3f for mixed-precision GROMACS or libfftw3 for double-precision GROMACS). Either choose the right precision, choose another FFT(W) library (-DGMX_FFT_LIBRARY), enable the advanced option to let GROMACS build FFTW 3 for you (-DGMX_BUILD_OWN_FFTW=ON), or use the really slow GROMACS built-in fftpack library (-DGMX_FFT_LIBRARY=fftpack).")
  90         endif()
  91
  92         set(PKG_FFT "${${FFTW}_PKG}")
  93         include_directories(SYSTEM ${${FFTW}_INCLUDE_DIRS})
  94
  95         if ((${GMX_SIMD_ACTIVE} MATCHES "SSE" OR ${GMX_SIMD_ACTIVE} MATCHES "AVX") AND NOT ${FFTW}_HAVE_SIMD)
  96             set(FFT_WARNING_MESSAGE "The fftw library found is compiled without SIMD support, which makes it slow. Consider recompiling it or contact your admin")
  97         else()
  98             if(${GMX_SIMD_ACTIVE} MATCHES "AVX" AND NOT (${FFTW}_HAVE_SSE OR ${FFTW}_HAVE_SSE2))
  99                 # If we end up here we have an AVX Gromacs build, and
 100                 # FFTW with SIMD.
 101                 set(FFT_WARNING_MESSAGE "The FFTW library was compiled with neither --enable-sse nor --enable-sse2; those would have enabled SSE(2) SIMD instructions. This will give suboptimal performance. You should (re)compile the FFTW library with --enable-sse2 and --enable-avx (and --enable-avx2 or --enable-avx512 if supported).")
 102             endif()
 103         endif()
 104         set(FFT_STATUS_MESSAGE "Using external FFT library - FFTW3")
 105     endif()
 106
 107     set(FFT_LIBRARIES ${${FFTW}_LIBRARIES})
 108     set(GMX_FFT_FFTW3 1)
 109 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 110     # Intel 11 and up makes life somewhat easy if you just want to use
 111     # all their stuff. It's not easy if you only want some of their
 112     # stuff...
 113     if (NOT MKL_MANUALLY)
 114         # The next line takes care of everything for MKL
 115         if (WIN32)
 116             # This works according to the Intel MKL 10.3 for Windows
 117             # docs, but on Jenkins Win2k8, icl tries to interpret it
 118             # as a file. Shrug.
 119             set(FFT_LINKER_FLAGS "/Qmkl:sequential")
 120         else()
 121             set(FFT_LINKER_FLAGS "-mkl=sequential")
 122         endif()
 123         # Some versions of icc require this in order that mkl.h can be
 124         # found at compile time.
 125         set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} ${FFT_LINKER_FLAGS}")
 126         set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${FFT_LINKER_FLAGS}")
 127
 128         set(MKL_ERROR_MESSAGE "Make sure you have configured your compiler so that ${FFT_LINKER_FLAGS} will work.")
 129     else()
 130         include_directories(SYSTEM ${MKL_INCLUDE_DIR})
 131         set(FFT_LIBRARIES "${MKL_LIBRARIES}")
 132         set(MKL_ERROR_MESSAGE "The include path to mkl.h in MKL_INCLUDE_DIR, and the link libraries in MKL_LIBRARIES=${MKL_LIBRARIES} need to match what the MKL documentation says you need for your system: ${MKL_LIBRARIES_FORMAT_DESCRIPTION}")
 133         # Convert the semi-colon separated list to a list of
 134         # command-line linker arguments so that code using our
 135         # pkgconfig setup can use it.
 136         string(REGEX REPLACE ";" " " PKG_FFT_LIBS "${MKL_LIBRARIES}")
 137     endif()
 138
 139     # Check MKL works. If we were in a non-global scope, we wouldn't
 140     # have to play nicely.
 141     set(old_CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 142     set(CMAKE_REQUIRED_FLAGS "${FFT_LINKER_FLAGS}")
 143     set(old_CMAKE_REQUIRED_LIBRARIES "${CMAKE_REQUIRED_LIBRARIES}")
 144     set(CMAKE_REQUIRED_LIBRARIES "${FFT_LIBRARIES}")
 145
 146     check_function_exists(DftiCreateDescriptor TEST_MKL)
 147
 148     set(CMAKE_REQUIRED_FLAGS "${old_CMAKE_REQUIRED_FLAGS}")
 149     set(CMAKE_REQUIRED_LIBRARIES "${old_CMAKE_REQUIRED_LIBRARIES}")
 150
 151     if(NOT TEST_MKL)
 152         # Hack to help the user vary MKL settings until they work.
 153         # TODO Make this logic more useful.
 154         unset(TEST_MKL CACHE)
 155         message(FATAL_ERROR "Linking with MKL was requested, but was not successful: ${MKL_ERROR_MESSAGE}")
 156     endif()
 157
 158     # Set variables to signal that we have MKL available and should use it for FFTs.
 159     set(GMX_FFT_MKL 1)
 160     set(HAVE_LIBMKL 1)
 161
 162     set(FFT_STATUS_MESSAGE "Using external FFT library - Intel MKL")
 163 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 164     set(GMX_FFT_FFTPACK 1)
 165     set(FFT_STATUS_MESSAGE "Using internal FFT library - fftpack")
 166 else()
 167     gmx_invalid_option_value(GMX_FFT_LIBRARY)
 168 endif()
 169 gmx_check_if_changed(FFT_CHANGED GMX_FFT_LIBRARY)
 170 if (FFT_CHANGED)
 171     if(FFT_WARNING_MESSAGE)
 172         message(WARNING "${FFT_WARNING_MESSAGE}")
 173     endif()
 174     message(STATUS "${FFT_STATUS_MESSAGE}")
 175 endif()
 176
 177 # enable threaded fftw3 if we've found it
 178 if(FFTW3_THREADS OR FFTW3F_THREADS)
 179     add_definitions(-DFFT5D_FFTW_THREADS)
 180 endif()
 181