CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # acceleration possibilities on that hardware, suggest an acceleration
 189 # to use if none is specified, and populate the cache option for CPU
 190 # accleration.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectAcceleration)
 194 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 195
 196 gmx_option_multichoice(
 197     GMX_CPU_ACCELERATION
 198     "Acceleration for CPU kernels and compiler optimization"
 199     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 200     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 201
 202 gmx_option_multichoice(
 203     GMX_FFT_LIBRARY
 204     "FFT library"
 205     "fftw3"
 206     fftw3 mkl "fftpack[built-in]")
 207 gmx_dependent_option(
 208     GMX_BUILD_OWN_FFTW
 209     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 210     OFF
 211     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 212 gmx_dependent_option(
 213     GMX_DISABLE_FFTW_MEASURE
 214     "Do not optimize FFTW setups (not needed with SSE)"
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 218 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 219
 220 gmx_option_multichoice(
 221     GMX_QMMM_PROGRAM
 222     "QM package for QM/MM"
 223     None
 224     none gaussian mopac gamess orca)
 225
 226 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 227 mark_as_advanced(GMX_BROKEN_CALLOC)
 228 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 229 mark_as_advanced(GMX_LOAD_PLUGINS)
 230
 231 option(GMX_GPU  "Enable GPU acceleration" ON)
 232 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 233
 234 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 235
 236 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 237 mark_as_advanced(GMX_GIT_VERSION_INFO)
 238
 239 if(UNIX)
 240     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 241 endif()
 242 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 243
 244 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 245 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 246
 247 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 248 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 249
 250 option(GMX_BUILD_FOR_COVERAGE
 251        "Tune build for better code coverage metrics (e.g., disable asserts)"
 252        OFF)
 253 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 254
 255
 256 ######################################################################
 257 # Detect OpenMP support
 258 ######################################################################
 259 # The OpenMP detection _must_ come before tests for other CFLAGS.
 260 include(gmxManageOpenMP)
 261
 262
 263
 264 ######################################################################
 265 # Compiler tests
 266 # These need to be done early (before further tests).
 267 #####################################################################
 268
 269 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 270 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 271 # invalid options with the Intel Compilers.
 272 # These files should be removed from the source tree when a CMake version that
 273 # includes the features in question becomes required for building GROMACS.
 274 include(CheckCCompilerFlag)
 275 include(CheckCXXCompilerFlag)
 276
 277
 278 include(gmxCFlags)
 279 gmx_c_flags()
 280
 281 # This variable should be used for additional compiler flags which are not
 282 # generated in gmxCFlags nor are acceleration or MPI related.
 283 set(EXTRA_C_FLAGS "")
 284 set(EXTRA_CXX_FLAGS "")
 285
 286 # Run through a number of tests for buggy compilers and other issues
 287 include(gmxTestCompilerProblems)
 288 gmx_test_compiler_problems()
 289
 290
 291 set(PKG_CFLAGS "")
 292 if(GMX_DOUBLE)
 293     add_definitions(-DGMX_DOUBLE)
 294     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 295 endif(GMX_DOUBLE)
 296 if(GMX_SOFTWARE_INVSQRT)
 297   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 298 endif(GMX_SOFTWARE_INVSQRT)
 299
 300
 301
 302 ########################################################################
 303 # Basic system tests (standard libraries, headers, functions, types)   #
 304 ########################################################################
 305 include(CheckIncludeFiles)
 306 include(CheckIncludeFileCXX)
 307 check_include_files(unistd.h     HAVE_UNISTD_H)
 308 check_include_files(pwd.h        HAVE_PWD_H)
 309 check_include_files(dirent.h     HAVE_DIRENT_H)
 310 check_include_files(time.h       HAVE_TIME_H)
 311 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 312 check_include_files(io.h         HAVE_IO_H)
 313 check_include_files(sched.h      HAVE_SCHED_H)
 314
 315 check_include_files(regex.h      HAVE_POSIX_REGEX)
 316 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 317 # TODO: It could be nice to inform the user if no regex support is found,
 318 # as selections won't be fully functional.
 319
 320 include(CheckFunctionExists)
 321 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 322 check_function_exists(memalign          HAVE_MEMALIGN)
 323 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 324 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 325 check_function_exists(fsync             HAVE_FSYNC)
 326 check_function_exists(_fileno           HAVE__FILENO)
 327 check_function_exists(fileno            HAVE_FILENO)
 328 check_function_exists(_commit           HAVE__COMMIT)
 329 check_function_exists(sigaction         HAVE_SIGACTION)
 330 check_function_exists(sysconf           HAVE_SYSCONF)
 331 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 332 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 333 check_function_exists(rsqrt             HAVE_RSQRT)
 334 check_function_exists(rsqrtf            HAVE_RSQRTF)
 335 check_function_exists(sqrtf             HAVE_SQRTF)
 336
 337 include(CheckLibraryExists)
 338 check_library_exists(m sqrt "" HAVE_LIBM)
 339 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 340
 341 include(TestBigEndian)
 342 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 343
 344 # Management of GROMACS options for specific toolchains should go
 345 # here. Because the initial settings for some of the main options have
 346 # already happened, but things like library detection and MPI compiler
 347 # feature detection have not, the docstrings for any over-rides of
 348 # GROMACS defaults or user settings will make sense. Also, any
 349 # toolchain-related reasons for choosing whether to detect various
 350 # things can be sorted out now, before the detection takes place.
 351 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 352     include(gmxManageBlueGene)
 353 endif()
 354
 355 ########################################################################
 356 #Process MPI settings
 357 ########################################################################
 358 include(gmxManageMPI)
 359
 360
 361 ########################################################################
 362 #Process shared/static library settings
 363 ########################################################################
 364 include(gmxManageSharedLibraries)
 365
 366
 367 ########################################################################
 368 # Find external packages                                               #
 369 ########################################################################
 370
 371 # Unconditionally find the package, as it is also required for unit tests
 372 find_package(LibXml2)
 373 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 374 set(PKG_XML "")
 375 mark_as_advanced(GMX_XML)
 376 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 377 #if(GMX_XML AND NOT LIBXML2_FOUND)
 378 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 379 #endif()
 380 #if(GMX_XML)
 381 #    include_directories(${LIBXML2_INCLUDE_DIR})
 382 #    set(PKG_XML libxml-2.0)
 383 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 384 #endif(GMX_XML)
 385
 386 option(GMX_GSL "Add support for gsl" OFF)
 387 if (GMX_GSL)
 388   find_package(GSL)
 389   set(PKG_GSL "")
 390   if(GSL_FOUND)
 391     include_directories(${GSL_INCLUDE_DIR})
 392     set(PKG_GSL gsl)
 393     set(HAVE_LIBGSL 1)
 394   endif(GSL_FOUND)
 395 endif (GMX_GSL)
 396
 397 option(GMX_X11 "Use X window system" OFF)
 398 if (GMX_X11)
 399     find_package(X11)
 400     # X11 includes/libraries are only set in the ngmx subdirectory!
 401     if(NOT X11_FOUND)
 402         message(FATAL_ERROR
 403                 "X11 include files and/or libraries were not found. "
 404                 "Set GMX_X11=OFF to compile without X11 support. "
 405                 "gmx view will not be available.")
 406     endif()
 407     include_directories(${X11_INCLUDE_DIR})
 408 endif(GMX_X11)
 409
 410 include(ThreadMPI)
 411 set(THREAD_MPI_LIB thread_mpi)
 412 # Enable core threading facilities
 413 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 414 # Enable tMPI C++ support
 415 tmpi_enable_cxx()
 416 if(GMX_THREAD_MPI)
 417     # enable MPI functions
 418     tmpi_enable()
 419     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 420     set(GMX_MPI 1)
 421     set(MPI_IN_PLACE_EXISTS 1)
 422 endif(GMX_THREAD_MPI)
 423 tmpi_get_source_list(THREAD_MPI_SRC)
 424
 425 if(GMX_GPU)
 426     # now that we have detected the dependencies, do the second configure pass
 427     gmx_gpu_setup()
 428 endif(GMX_GPU)
 429
 430 if(CYGWIN)
 431     set(GMX_CYGWIN 1)
 432 endif(CYGWIN)
 433
 434 if(WIN32 AND NOT CYGWIN)
 435     set(GMX_NATIVE_WINDOWS 1)
 436     # This makes windows.h not declare min/max as macros that would break
 437     # C++ code using std::min/std::max.
 438     add_definitions(-DNOMINMAX)
 439 endif()
 440
 441 # only bother with finding git and using version.h if the source is a git repo
 442 if(GMX_GIT_VERSION_INFO)
 443     if (NOT SOURCE_IS_GIT_REPOSITORY)
 444         message(FATAL_ERROR
 445             "Cannot generate git version information from source tree not under git. "
 446             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 447     endif ()
 448     # We need at least git v1.5.3 be able to parse git's date output. If not
 449     # found or the version is too small, we can't generate version information.
 450     find_package(Git)
 451
 452     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 453         message(FATAL_ERROR
 454             "No compatible git version found (>= 1.5.3 required). "
 455             "Won't be able to generate development version information. "
 456             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 457     endif()
 458 endif()
 459
 460 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 461 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 462 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 463     find_package(Boost 1.44.0)
 464     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 465         set(Boost_FOUND FALSE)
 466     endif()
 467     # Print the notification only on first run, when determining the default
 468     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 469         message("Boost >= 1.44 not found. Using minimal internal version. "
 470                 "This may cause trouble if you plan on compiling/linking other "
 471                 "software that uses Boost against Gromacs.")
 472     endif()
 473 endif()
 474 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 475        ${Boost_FOUND})
 476 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 477     message(FATAL_ERROR
 478         "Boost >= 1.44 not found. "
 479         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 480         "version of Boost included with Gromacs.")
 481 endif()
 482
 483 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 484 mark_as_advanced(GMX_BUILD_UNITTESTS)
 485 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 486 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 487     message(FATAL_ERROR
 488         "Cannot build unit tests without libxml2. "
 489         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 490 endif()
 491
 492 ########################################################################
 493 # Generate development version info for cache
 494 ########################################################################
 495 # set(GEN_VERSION_INFO_INTERNAL "ON")
 496 # include(gmxGenerateVersionString)
 497
 498 ########################################################################
 499 # Our own GROMACS tests
 500 ########################################################################
 501
 502 add_definitions( -DHAVE_CONFIG_H )
 503 include_directories(${CMAKE_SOURCE_DIR}/src)
 504 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 505 include_directories(${CMAKE_BINARY_DIR}/src)
 506 # Required for gmx_header_config_gen.h to be found before installation
 507 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 508 # Required for now to make old code compile
 509 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 510
 511 include(gmxTestInlineASM)
 512 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 513
 514 include(gmxSetBuildInformation)
 515 gmx_set_build_information()
 516 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 517     set(HAVE_RDTSCP 1)
 518 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 519
 520 include(gmxTestFloatFormat)
 521 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 522                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 523                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 524
 525 include(gmxTestLargeFiles)
 526 gmx_test_large_files(GMX_LARGEFILES)
 527
 528 include(gmxTestSignal)
 529 gmx_test_sigusr1(HAVE_SIGUSR1)
 530
 531 include(gmxTestInline)
 532 gmx_test_inline(INLINE_KEYWORD)
 533
 534 include(gmxTestRestrict)
 535 gmx_test_restrict(RESTRICT_KEYWORD)
 536
 537 include(gmxTestPipes)
 538 gmx_test_pipes(HAVE_PIPES)
 539
 540 include(gmxTestIsfinite)
 541 gmx_test_isfinite(HAVE_ISFINITE)
 542 gmx_test__isfinite(HAVE__ISFINITE)
 543 gmx_test__finite(HAVE__FINITE)
 544
 545 include(gmxTestCXX11)
 546 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 547 include(CMakeDependentOption)
 548 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 549 # entirely to keep the compilation environment uniform.
 550 cmake_dependent_option(GMX_CXX11
 551     "Use C++11 features"
 552     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 553 mark_as_advanced(GMX_CXX11)
 554 if(GMX_CXX11)
 555     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 556 endif()
 557
 558
 559 include(gmxTestXDR)
 560 gmx_test_xdr(GMX_SYSTEM_XDR)
 561 if(NOT GMX_SYSTEM_XDR)
 562     set(GMX_INTERNAL_XDR 1)
 563 endif(NOT GMX_SYSTEM_XDR)
 564
 565 # include avx test source, used if the AVX flags are set below
 566 include(gmxTestAVXMaskload)
 567
 568 # Process nonbonded accelerated kernels settings
 569 #
 570 # Note that for the backward-compatible x86 SIMD architectures, the
 571 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 572 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 573 # SSE2). Accordingly, there are a set of CMake variables
 574 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 575 # CPU features that should be used. This means that the logic for
 576 # requiring such backward compatibility is all located here.
 577 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 578     # nothing to do
 579     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 580
 581 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 582
 583     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 584     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 585         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 586     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 587
 588     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 589     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 590         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 591     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 592
 593     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 594
 595     # Only test the include after we have tried to add the correct flag for SSE2 support
 596     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 597
 598     if(NOT HAVE_EMMINTRIN_H)
 599         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 600     endif(NOT HAVE_EMMINTRIN_H)
 601
 602     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 603     # The user should not be able to set this orthogonally to the acceleration
 604     set(GMX_X86_SSE2 1)
 605     set(ACCELERATION_STATUS_MESSAGE
 606         "Enabling SSE2 Gromacs acceleration")
 607
 608 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 609
 610     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 611     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 612         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 613     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 614     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 615         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 616         # intrinsics when SSE2 support is enabled, so we try that instead first.
 617         if (GMX_NATIVE_WINDOWS)
 618             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 619             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 620         else()
 621             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 622         endif()
 623     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 624
 625     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 626     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 627         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 628     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 629     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 630         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 631         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 632         # intrinsics when SSE2 support is enabled, so we try that instead.
 633         if (GMX_NATIVE_WINDOWS)
 634             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 635         endif()
 636     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 637
 638     # This must come after we have added the -msse4.1 flag on some platforms.
 639     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 640
 641     if(NOT HAVE_SMMINTRIN_H)
 642         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 643     endif(NOT HAVE_SMMINTRIN_H)
 644
 645     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 646         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 647     endif()
 648
 649     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 650     # The user should not be able to set this orthogonally to the acceleration
 651     set(GMX_X86_SSE4_1 1)
 652     set(GMX_X86_SSE2   1)
 653     set(ACCELERATION_STATUS_MESSAGE
 654         "Enabling SSE4.1 Gromacs acceleration")
 655
 656 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 657
 658     # Set the AVX compiler flag for both these choices!
 659
 660     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 661     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 662         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 663     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 664     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 665         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 666     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 667
 668     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 669     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 670         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 671     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 672     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 673         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 674     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 675
 676     # Set the FMA4 flags (MSVC doesn't require any)
 677     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 678         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 679         if (NOT GNU_FMA_CFLAG)
 680             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 681         endif(NOT GNU_FMA_CFLAG)
 682         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 683         # No big deal if we do not have xop, so no point yelling warnings about it.
 684         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 685         if (NOT GNU_FMA_CXXFLAG)
 686             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 687         endif (NOT GNU_FMA_CXXFLAG)
 688         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 689         # No big deal if we do not have xop, so no point yelling warnings about it.
 690     endif()
 691
 692     # Only test the header after we have tried to add the flag for AVX support
 693     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 694
 695     if(NOT HAVE_IMMINTRIN_H)
 696         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 697     endif(NOT HAVE_IMMINTRIN_H)
 698
 699     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 700         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 701             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 702             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 703         if(NOT TEST_AVX)
 704             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 705         endif()
 706     endif()
 707
 708     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 709     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 710     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 711
 712     # The user should not be able to set this orthogonally to the acceleration
 713     set(GMX_X86_SSE4_1 1)
 714     set(GMX_X86_SSE2   1)
 715
 716     # But just enable one of the choices internally...
 717     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 718         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 719         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 720         # hackintoshes is not worth the effort.
 721         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 722                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 723             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 724         endif()
 725
 726         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 727             # we assume that we have an external assembler that supports AVX
 728             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 729             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 730         endif()
 731         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 732             # we assume that we have an external assembler that supports AVX
 733             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 734             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 735         endif()
 736
 737         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 738         set(GMX_X86_AVX_128_FMA 1)
 739         set(ACCELERATION_STATUS_MESSAGE
 740             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 741
 742     else()
 743         # If we are not doing AVX_128, it must be AVX_256...
 744         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 745         set(GMX_X86_AVX_256 1)
 746         set(ACCELERATION_STATUS_MESSAGE
 747             "Enabling 256-bit AVX Gromacs acceleration")
 748     endif()
 749
 750     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 751     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 752     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 753
 754 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 755     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 756         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 757
 758     if (TEST_QPX)
 759         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 760         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 761     else()
 762         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 763     endif()
 764 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 765     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 766 else()
 767     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 768 endif()
 769 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 770 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 771     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 772 endif()
 773
 774 # Process QM/MM Settings
 775 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 776     set(GMX_QMMM_GAUSSIAN 1)
 777 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 778     set(GMX_QMMM_MOPAC 1)
 779 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 780     set(GMX_QMMM_GAMESS 1)
 781 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 782     set(GMX_QMMM_ORCA 1)
 783 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 784     # nothing to do
 785 else()
 786     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 787 endif()
 788
 789
 790 ##################################################
 791 # Process FFT library settings
 792 ##################################################
 793 include(gmxManageFFTLibraries)
 794
 795
 796 include(gmxManageLinearAlgebraLibraries)
 797
 798 # Whether GROMACS will really try to compile support for VMD plugins
 799 set(GMX_USE_PLUGINS OFF)
 800
 801 if(GMX_LOAD_PLUGINS)
 802   if(CYGWIN OR NOT WIN32)
 803     # Native Windows does not have, nor need dlopen
 804     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 805     include(gmxTestdlopen)
 806     gmx_test_dlopen(HAVE_DLOPEN)
 807   endif()
 808
 809   # so, should we use plug-ins?
 810   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 811     if(NOT VMD_QUIETLY)
 812       MESSAGE(STATUS
 813           "Found the ability to use plug-ins when building shared libaries, "
 814           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 815           "formats).")
 816     endif()
 817     if(NOT GMX_VMD_PLUGIN_PATH)
 818       find_package(VMD)
 819     endif()
 820     set(GMX_USE_PLUGINS ON)
 821     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 822     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 823   else()
 824     set(PKG_DL_LIBS)
 825   endif()
 826 endif(GMX_LOAD_PLUGINS)
 827 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 828
 829 # Link real-time library for POSIX timers. The check for clock_gettime
 830 # confirms the linkability of rt.
 831 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 832     list(APPEND GMX_EXTRA_LIBRARIES rt)
 833 endif()
 834
 835 # Math and thread libraries must often come after all others when linking...
 836 if(HAVE_LIBM)
 837     list(APPEND GMX_EXTRA_LIBRARIES m)
 838 endif(HAVE_LIBM)
 839 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 840     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 841     if(HAVE_MASS_SIMD)
 842         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 843     else()
 844         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 845     endif()
 846 endif()
 847
 848
 849 option(GMX_NACL "Configure for Native Client builds" OFF)
 850 if (GMX_NACL)
 851   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 852   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 853   set(GMX_NO_NICE 1)
 854   set(GMX_NO_RENAME 1)
 855 endif()
 856 mark_as_advanced(GMX_NACL)
 857
 858 if(GMX_FAHCORE)
 859   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 860       "Path to swindirect.h")
 861   include_directories(${COREWRAP_INCLUDE_DIR})
 862 endif(GMX_FAHCORE)
 863
 864 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 865 # these are set after everything else
 866 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 867     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 868     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 869     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 870     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 871 else()
 872     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 873     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 874     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 875     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 876     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 877     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 878     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 879     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 880     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 881 endif()
 882
 883 if(NOT GMX_OPENMP)
 884     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 885     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 886     unset(OpenMP_C_FLAGS CACHE)
 887     unset(OpenMP_CXX_FLAGS CACHE)
 888 else()
 889     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 890     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 891 endif()
 892 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 893
 894 ########################################################################
 895 # Specify install locations
 896 ########################################################################
 897 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 898     "Library installation directory (default: lib)")
 899 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 900     "Data installation directory under share/ (default: gromacs)")
 901 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 902
 903 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 904 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 905 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 906 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 907 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 908
 909 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 910 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 911
 912 # Binary and library suffix options
 913 include(gmxManageSuffixes)
 914
 915 ##################################################################
 916 # Shared library settings
 917 ##################################################################
 918 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 919     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 920     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 921     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 922     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 923 else()
 924     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 925         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 926         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 927     else()
 928         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 929     endif()
 930 endif()
 931
 932 #COPYING file: Only necessary for binary distributions.
 933 #Simpler to always install.
 934 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 935
 936 if(GMX_EXTERNAL_BOOST)
 937     include_directories(${Boost_INCLUDE_DIRS})
 938 else()
 939     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 940     # typeid not supported for minimal internal version
 941     # (would add significant amount of code)
 942     add_definitions(-DBOOST_NO_TYPEID)
 943     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 944     # (from share/template/)
 945     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 946     if (NOT GMX_BUILD_MDRUN_ONLY)
 947         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 948                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 949                 COMPONENT development)
 950     endif ()
 951 endif()
 952
 953 # TODO The Windows builds are still broken (we are avoiding some
 954 # unknown bug, perhaps with checkpointing?), because defaulting to
 955 # .tng output leads to calling null-op implementation functions, so
 956 # regressiontests will fail on Windows at the post-mdrun stages. We
 957 # can fix this during the 5.0 beta phase.
 958 gmx_add_cache_dependency(GMX_USE_TNG BOOL "NOT GMX_NATIVE_WINDOWS" OFF)
 959
 960 if(GMX_USE_TNG)
 961     find_package(ZLIB)
 962     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 963     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 964     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 965     # TODO reconsider use of OpenMP in TNG if/when trajectory writing is not serial in mdrun
 966     set(TNG_USE_OPENMP ${GMX_OPENMP} CACHE BOOL "Try to use the OpenMP library (if available) with TNG")
 967     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 968     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 969     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 970     set(GMX_TNG_LIBRARIES tng_io)
 971 endif()
 972 mark_as_advanced(TNG_BUILD_FORTRAN)
 973 mark_as_advanced(TNG_BUILD_EXAMPLES)
 974 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 975 mark_as_advanced(TNG_USE_OPENMP)
 976 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 977 mark_as_advanced(TNG_BUILD_TEST)
 978 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 979
 980 if (GMX_BUILD_FOR_COVERAGE)
 981     # Code heavy with asserts makes conditional coverage close to useless metric,
 982     # as by design most of the false branches are impossible to trigger in
 983     # correctly functioning code.  And the benefit of testing those that could
 984     # be triggered by using an API against its specification isn't usually
 985     # worth the effort.
 986     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 987 endif ()
 988
 989 if (BUILD_TESTING)
 990     # "tests" target builds all the separate test binaries.
 991     add_custom_target(tests)
 992     # "run-ctest" is an internal target that actually runs the tests.
 993     # This is necessary to be able to add separate targets that execute as part
 994     # of 'make check', but are ensured to be executed after the actual tests.
 995     add_custom_target(run-ctest
 996                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 997                       COMMENT "Running all tests"
 998                       VERBATIM)
 999     add_dependencies(run-ctest tests)
1000     # "check" target builds and runs all tests.
1001     add_custom_target(check DEPENDS run-ctest)
1002 endif()
1003
1004 if (NOT GMX_BUILD_MDRUN_ONLY)
1005     add_subdirectory(doxygen)
1006     add_subdirectory(share)
1007     add_subdirectory(scripts)
1008 endif ()
1009 add_subdirectory(src)
1010
1011 if (BUILD_TESTING)
1012     add_subdirectory(tests)
1013 endif()
1014
1015 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
1016 # Don't bother the user after the first configure pass.
1017 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
1018     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
1019 endif()
1020 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
1021
1022 #######################
1023 ## uninstall target
1024 #######################
1025     CONFIGURE_FILE(
1026                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
1027                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
1028                    IMMEDIATE @ONLY)
1029 ###########################
1030 ADD_CUSTOM_TARGET(uninstall
1031                   "${CMAKE_COMMAND}" -P
1032                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1033 ###########################
1034
1035 ########################################################################
1036 # Manual                                                               #
1037 ########################################################################
1038
1039 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1040 mark_as_advanced(GMX_BUILD_MANUAL)
1041 if(GMX_BUILD_MANUAL)
1042     # Make sure we only do detection of manual-building dependencies
1043     # when the user opted in for that.
1044     add_subdirectory(manual)
1045 endif()