cmake/FindFFTW.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Find FFTW 3
  36 # Find the native FFTW headers and libraries.
  37 #
  38 #  ${FFTW}_INCLUDE_DIRS - where to find FFTW headers
  39 #  ${FFTW}_LIBRARIES    - List of libraries when using FFTW.
  40 #  ${FFTW}_PKG          - The name of the pkg-config package needed
  41 #  ${FFTW}_HAVE_SIMD    - True if FFTW was built with SIMD support
  42 #  ${FFTW}_HAVE_SSE     - True if FFTW was built with SSE support
  43 #  ${FFTW}_HAVE_SSE2    - True if FFTW was built with SSE2 support
  44 #  ${FFTW}_FOUND        - True if FFTW was found
  45 #  where ${FFTW} is FFTW or FFTWF
  46
  47 list(LENGTH FFTW_FIND_COMPONENTS FFTW_NUM_COMPONENTS_WANTED)
  48 if(${FFTW_NUM_COMPONENTS_WANTED} LESS 1)
  49   message(FATAL_ERROR "No FFTW component to search given")
  50 elseif(${FFTW_NUM_COMPONENTS_WANTED} GREATER 1)
  51   message(FATAL_ERROR "We only support finding one FFTW component at the time, go and implement it ;-)")
  52 elseif(${FFTW_FIND_COMPONENTS} MATCHES "^fftw(f)?$")
  53   if (NOT FFTW_FIND_VERSION OR FFTW_FIND_VERSION EQUAL 3) #find FFTW3 by default
  54     string(TOUPPER "${FFTW_FIND_COMPONENTS}" FFTW)
  55     string(REGEX REPLACE "fftw" "fftw3" ${FFTW}_PKG "${FFTW_FIND_COMPONENTS}")
  56     set(${FFTW}_FUNCTION_PREFIX "${FFTW_FIND_COMPONENTS}")
  57   else()
  58     message(FATAL_ERROR "We only support finding FFTW version 3, go and implement it ;-)")
  59   endif()
  60 else()
  61   message(FATAL_ERROR "We do not support finding ${FFTW_FIND_COMPONENTS}, go and implement it ;-)")
  62 endif()
  63
  64 find_package(PkgConfig QUIET)
  65 if(NOT __pkg_config_checked_PC_${FFTW} OR NOT ${FFTW}_LIBRARY)
  66   pkg_check_modules(PC_${FFTW} "${${FFTW}_PKG}")
  67   if(NOT PC_${FFTW}_FOUND)
  68     message(STATUS "pkg-config could not detect ${${FFTW}_PKG}, trying generic detection")
  69   endif()
  70 endif()
  71
  72 find_path(${FFTW}_INCLUDE_DIR "fftw3.h" HINTS ${PC_${FFTW}_INCLUDE_DIRS})
  73 find_library(${FFTW}_LIBRARY NAMES "${${FFTW}_PKG}" HINTS ${PC_${FFTW}_LIBRARY_DIRS})
  74
  75 set(${FFTW}_LIBRARIES "${${FFTW}_LIBRARY}")
  76 set(${FFTW}_INCLUDE_DIRS "${${FFTW}_INCLUDE_DIR}")
  77
  78 #better error message than find_package_handle_standard_args
  79 if (${FFTW}_LIBRARY AND ${FFTW}_INCLUDE_DIR)
  80   set(${FFTW}_FOUND TRUE)
  81 elseif (NOT ${FFTW}_LIBRARY)
  82   message("Could not find ${${FFTW}_PKG} library named lib${${FFTW}_PKG}, please specify its location in CMAKE_PREFIX_PATH or ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so')")
  83 elseif (NOT ${FFTW}_INCLUDE_DIR)
  84   message("Could not the ${${FFTW}_PKG} header fftw3.h, please specify its path in ${FFTW}_INCLUDE_DIR by hand (e.g. -D${FFTW}_INCLUDE_DIR='/path/to/include')")
  85 endif()
  86
  87 if (${FFTW}_FOUND)
  88   #The user could specify trash in ${FFTW}_LIBRARY, so test if we can link it
  89   include(CheckLibraryExists)
  90   include(gmxOptionUtilities)
  91   if (HAVE_LIBM)
  92     #adding MATH_LIBRARIES here to allow static libs, this does not harm us as we are anyway using it
  93     set(CMAKE_REQUIRED_LIBRARIES m)
  94   endif ()
  95   gmx_check_if_changed(FFTW_LIBRARY_CHANGED ${FFTW}_LIBRARIES)
  96   if (FFTW_LIBRARY_CHANGED)
  97     unset(FOUND_${FFTW}_PLAN CACHE)
  98   endif()
  99   check_library_exists("${${FFTW}_LIBRARIES}" "${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d" "" FOUND_${FFTW}_PLAN)
 100   if(NOT FOUND_${FFTW}_PLAN)
 101     message(FATAL_ERROR "Could not find ${${FFTW}_FUNCTION_PREFIX}_plan_r2r_1d in ${${FFTW}_LIBRARY}, take a look at the error message in ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log to find out what went wrong. If you are using a static lib (.a) make sure you have specified all dependencies of ${${FFTW}_PKG} in ${FFTW}_LIBRARY by hand (e.g. -D${FFTW}_LIBRARY='/path/to/lib${${FFTW}_PKG}.so;/path/to/libm.so') !")
 102   endif()
 103
 104   # Check for FFTW3 compiled with --enable-sse
 105   foreach(SSE_FUNCTION ${${FFTW}_FUNCTION_PREFIX}_have_simd_sse ${${FFTW}_FUNCTION_PREFIX}_have_sse)
 106     if (FFTW_LIBRARY_CHANGED)
 107       unset(${FFTW}_HAVE_${SSE_FUNCTION} CACHE)
 108     endif()
 109     check_library_exists("${${FFTW}_LIBRARIES}" "${SSE_FUNCTION}" "" ${FFTW}_HAVE_${SSE_FUNCTION})
 110     if(${FFTW}_HAVE_${SSE_FUNCTION})
 111       set(${FFTW}_HAVE_SSE TRUE)
 112       set(${FFTW}_HAVE_SIMD TRUE)
 113       break()
 114     endif()
 115   endforeach()
 116
 117   # Check for FFTW3 compiled with --enable-sse2
 118   foreach(SSE2_FUNCTION ${${FFTW}_FUNCTION_PREFIX}_have_simd_sse2 ${${FFTW}_FUNCTION_PREFIX}_have_sse2)
 119     if (FFTW_LIBRARY_CHANGED)
 120       unset(${FFTW}_HAVE_${SSE2_FUNCTION} CACHE)
 121     endif()
 122     check_library_exists("${${FFTW}_LIBRARIES}" "${SSE2_FUNCTION}" "" ${FFTW}_HAVE_${SSE2_FUNCTION})
 123     if(${FFTW}_HAVE_${SSE2_FUNCTION})
 124       set(${FFTW}_HAVE_SSE2 TRUE)
 125       set(${FFTW}_HAVE_SIMD TRUE)
 126       break()
 127     endif()
 128   endforeach()
 129
 130   # Check for any other SIMD support in FFTW
 131   if (NOT ${FFTW}_HAVE_SIMD)
 132       foreach(SIMD_FCT
 133               ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx
 134               ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx2
 135               ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx2_128
 136               ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx512
 137               ${${FFTW}_FUNCTION_PREFIX}_have_simd_avx_128_fma
 138               ${${FFTW}_FUNCTION_PREFIX}_have_simd_altivec
 139               ${${FFTW}_FUNCTION_PREFIX}_have_simd_neon
 140               ${${FFTW}_FUNCTION_PREFIX}_have_simd_vsx
 141               ${${FFTW}_FUNCTION_PREFIX}_have_simd_altivec
 142               ${${FFTW}_FUNCTION_PREFIX}_have_altivec) # Name used before FFTW 3.3
 143           if (FFTW_LIBRARY_CHANGED)
 144               unset(${FFTW}_HAVE_${SIMD_FCT} CACHE)
 145           endif()
 146           check_library_exists("${${FFTW}_LIBRARIES}" "${SIMD_FCT}" "" ${FFTW}_HAVE_${SIMD_FCT})
 147           if(${FFTW}_HAVE_${SIMD_FCT})
 148               set(${FFTW}_HAVE_SIMD TRUE)
 149               break()
 150           endif()
 151       endforeach()
 152   endif()
 153
 154   #Verify FFTW is compiled with fPIC (necessary for shared libraries)
 155   if (CMAKE_OBJDUMP AND CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64" AND BUILD_SHARED_LIBS AND NOT CYGWIN AND NOT APPLE)
 156       execute_process(COMMAND ${CMAKE_OBJDUMP} --reloc ${${FFTW}_LIBRARY} OUTPUT_VARIABLE ${FFTW}_OBJDUMP)
 157       if (${${FFTW}_OBJDUMP} MATCHES "R_X86_64" #Should always be true for static libraries. Checks that objdump works properly and that the library isn't dynamic
 158               AND NOT ${${FFTW}_OBJDUMP} MATCHES "R_X86_64_PLT32")
 159           message(FATAL_ERROR "The FFTW library ${${FFTW}_LIBRARY} cannot be used with shared libraries. Provide a different FFTW library by setting ${FFTW}_LIBRARY. If you don't have a different one, recompile FFTW with \"--enable-shared\" or \"--with-pic\". Or disable shared libraries for GROMACS by setting BUILD_SHARED_LIBS to \"no\". Note: Disabling shared libraries requires up to 10x as much disk space.")
 160       endif()
 161   endif()
 162   set(CMAKE_REQUIRED_LIBRARIES)
 163 endif ()
 164
 165 mark_as_advanced(${FFTW}_INCLUDE_DIR ${FFTW}_LIBRARY)