rombios32start.S

   1 /////////////////////////////////////////////////////////////////////////
   2 // $Id$
   3 /////////////////////////////////////////////////////////////////////////
   4 //
   5 //  32 bit Bochs BIOS init code
   6 //  Copyright (C) 2006 Fabrice Bellard
   7 //
   8 //  This library is free software; you can redistribute it and/or
   9 //  modify it under the terms of the GNU Lesser General Public
  10 //  License as published by the Free Software Foundation; either
  11 //  version 2 of the License, or (at your option) any later version.
  12 //
  13 //  This library is distributed in the hope that it will be useful,
  14 //  but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 //  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 //  Lesser General Public License for more details.
  17 //
  18 //  You should have received a copy of the GNU Lesser General Public
  19 //  License along with this library; if not, write to the Free Software
  20 //  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301 USA
  21 #include "rombios.h"
  22
  23 .globl _start
  24 .globl smp_ap_boot_code_start
  25 .globl smp_ap_boot_code_end
  26 .global smm_relocation_start
  27 .global smm_relocation_end
  28 .global smm_code_start
  29 .global smm_code_end
  30
  31 _start:
  32   /* clear bss section */
  33   xor %eax, %eax
  34   mov $__bss_start, %edi
  35   mov $__bss_end, %ecx
  36   sub %edi, %ecx
  37   rep stosb
  38
  39   /* copy data section */
  40   mov $_end, %esi
  41   mov $__data_start, %edi
  42   mov $__data_end, %ecx
  43   sub %edi, %ecx
  44   rep movsb
  45
  46   jmp rombios32_init
  47
  48   .code16
  49 smp_ap_boot_code_start:
  50   xor %ax, %ax
  51   mov %ax, %ds
  52   lock incw smp_cpus
  53 1:
  54   hlt
  55   jmp 1b
  56 smp_ap_boot_code_end:
  57
  58 /* code to relocate SMBASE to 0xa0000 */
  59 smm_relocation_start:
  60   mov $0x38000 + 0x7efc, %ebx
  61   addr32 mov (%ebx), %al  /* revision ID to see if x86_64 or x86 */
  62   cmp $0x64, %al
  63   je 1f
  64   mov $0x38000 + 0x7ef8, %ebx
  65   jmp 2f
  66 1:
  67   mov $0x38000 + 0x7f00, %ebx
  68 2:
  69   movl $0xa0000, %eax
  70   addr32 movl %eax, (%ebx)
  71   /* indicate to the BIOS that the SMM code was executed */
  72   mov $0x00, %al
  73   movw $0xb3, %dx
  74   outb %al, %dx
  75   rsm
  76 smm_relocation_end:
  77
  78 /* minimal SMM code to enable or disable ACPI */
  79 smm_code_start:
  80   movw $0xb2, %dx
  81   inb %dx, %al
  82   cmp $0xf0, %al
  83   jne 1f
  84
  85   /* ACPI disable */
  86   mov $PM_IO_BASE + 0x04, %dx /* PMCNTRL */
  87   inw %dx, %ax
  88   andw $~1, %ax
  89   outw %ax, %dx
  90
  91   jmp 2f
  92
  93 1:
  94   cmp $0xf1, %al
  95   jne 2f
  96
  97   /* ACPI enable */
  98   mov $PM_IO_BASE + 0x04, %dx /* PMCNTRL */
  99   inw %dx, %ax
 100   orw $1, %ax
 101   outw %ax, %dx
 102
 103 2:
 104   rsm
 105 smm_code_end: