configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.69])
   4 AC_INIT([got-portable], [0.67], [thomas@xteddy.org])
   5 AC_CONFIG_AUX_DIR(etc)
   6 AC_CONFIG_SRCDIR([lib/rcsutil.h])
   7 AM_INIT_AUTOMAKE([foreign subdir-objects])
   8
   9 GOT_RELEASE=No
  10
  11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  12 AC_SUBST(VERSION)
  13 AC_SUBST(GOT_RELEASE)
  14
  15 AC_CANONICAL_HOST
  16
  17 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
  18 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
  19 # empty default.
  20 : ${CFLAGS=""}
  21
  22 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
  23 # AC_CHECK_HEADER doesn't give us any other way to update the include
  24 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
  25 SAVED_CFLAGS="$CFLAGS"
  26 SAVED_CPPFLAGS="$CPPFLAGS"
  27 SAVED_LDFLAGS="$LDFLAGS"
  28
  29 # Checks for programs.
  30 AC_PROG_CC
  31 AC_PROG_CPP
  32 AC_PROG_INSTALL
  33 AC_PROG_LN_S
  34 AC_PROG_MAKE_SET
  35 AC_PROG_YACC
  36 AC_PROG_RANLIB
  37 PKG_PROG_PKG_CONFIG
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Checks for header files.
  41 AC_CHECK_HEADERS([ \
  42         fcntl.h \
  43         langinfo.h \
  44         limits.h \
  45         linux/landlock.h \
  46         locale.h \
  47         netdb.h \
  48         netinet/in.h \
  49         paths.h \
  50         poll.h \
  51         stddef.h \
  52         stdint.h \
  53         stdlib.h \
  54         string.h \
  55         sys/ioctl.h \
  56         sys/param.h \
  57         sys/poll.h \
  58         sys/socket.h \
  59         sys/time.h \
  60         sys/tree.h \
  61         util.h \
  62         unistd.h \
  63         wchar.h \
  64 ])
  65
  66 # Checks for typ edefs, structures, and compiler characteristics.
  67 AC_CHECK_HEADER_STDBOOL
  68 AC_C_INLINE
  69 AC_TYPE_INT64_T
  70 AC_TYPE_MODE_T
  71 AC_TYPE_OFF_T
  72 AC_TYPE_PID_T
  73 AC_TYPE_SIZE_T
  74 AC_TYPE_SSIZE_T
  75 AC_TYPE_UINT16_T
  76 AC_TYPE_UINT32_T
  77 AC_TYPE_UINT64_T
  78 AC_TYPE_UINT8_T
  79
  80 # Look for library needed for flock.
  81 AC_SEARCH_LIBS(flock, bsd)
  82
  83 # Checks for library functions.
  84 AC_FUNC_FORK
  85 AC_FUNC_FSEEKO
  86 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  87 AC_FUNC_MALLOC
  88 AC_FUNC_MMAP
  89 AC_FUNC_REALLOC
  90 AC_FUNC_STRERROR_R
  91 AC_FUNC_STRNLEN
  92 AC_CHECK_FUNCS([ \
  93         dup2 \
  94         flock \
  95         getcwd \
  96         localtime_r \
  97         memchr \
  98         memmove \
  99         memset \
 100         mkdir \
 101         munmap \
 102         nl_langinfo \
 103         realpath \
 104         regcomp \
 105         rmdir \
 106         setlocale \
 107         socket \
 108         strcasecmp \
 109         strchr \
 110         strcspn \
 111         strdup \
 112         strerror \
 113         strlcpy \
 114         strncasecmp \
 115         strndup \
 116         strrchr \
 117         strspn \
 118         strstr \
 119         strtol \
 120         strtoul \
 121         wcwidth \
 122 ])
 123
 124 # Check for functions with a compatibility implementation.
 125 AC_REPLACE_FUNCS([ \
 126         asprintf \
 127         closefrom \
 128         explicit_bzero \
 129         fmt_scaled \
 130         freezero \
 131         getdtablecount \
 132         getline \
 133         getprogname \
 134         recallocarray \
 135         reallocarray \
 136         strlcat \
 137         strlcpy \
 138         strndup \
 139         strsep \
 140         strtonum \
 141 ])
 142
 143 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
 144 # musl does not set optarg to NULL for flags without arguments (although it is
 145 # not required to, but it is helpful) 3) there are probably other weird
 146 # implementations.
 147 AC_LIBOBJ(getopt)
 148
 149 # Check the platform we're compiling on.
 150 AC_MSG_CHECKING(platform)
 151 case "$host_os" in
 152         *linux*)
 153                 AC_MSG_RESULT(linux)
 154                 PLATFORM=linux
 155                 ;;
 156         *freebsd*)
 157                 AC_MSG_RESULT(freebsd)
 158                 PLATFORM=freebsd
 159                 ;;
 160         *darwin*)
 161                 AC_MSG_RESULT(darwin)
 162                 PLATFORM=darwin
 163                 ;;
 164         *netbsd*)
 165                 AC_MSG_RESULT(netbsd)
 166                 PLATFORM=netbsd
 167                 ;;
 168         *)
 169                 AC_MSG_RESULT(unknown)
 170                 PLATFORM=unknown
 171                 ;;
 172 esac
 173 AC_SUBST(PLATFORM)
 174 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
 175 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
 176 AM_CONDITIONAL([HOST_DARWIN], [test "$PLATFORM" = "darwin"])
 177 AM_CONDITIONAL([HOST_NETBSD], [test "$PLATFORM" = "netbsd"])
 178
 179 # Landlock detection.
 180 AC_MSG_CHECKING([for landlock])
 181 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
 182     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
 183 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
 184         AC_MSG_RESULT(yes)
 185 else
 186         AC_MSG_RESULT(no)
 187 fi
 188
 189 # Clang sanitizers wrap reallocarray even if it isn't available on the target
 190 # system. When compiled it always returns NULL and crashes the program. To
 191 # detect this we need a more complicated test.
 192 AC_MSG_CHECKING([for working reallocarray])
 193 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 194                 [#include <stdlib.h>],
 195                 [return (reallocarray(NULL, 1, 1) == NULL);]
 196         )],
 197         AC_MSG_RESULT(yes),
 198         [AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
 199 )
 200 AC_MSG_CHECKING([for working recallocarray])
 201 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 202                 [#include <stdlib.h>],
 203                 [return (recallocarray(NULL, 1, 1, 1) == NULL);]
 204         )],
 205         AC_MSG_RESULT(yes),
 206         [AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
 207 )
 208
 209 # Look for imsg_init in libutil.
 210 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
 211 if test "x$found_imsg_init" = xyes; then
 212         AC_DEFINE(HAVE_IMSG)
 213 else
 214         AC_LIBOBJ(imsg)
 215         AC_LIBOBJ(imsg-buffer)
 216 fi
 217
 218 # libcrypto (via libssl for SHA information)
 219 PKG_CHECK_MODULES(
 220         LIBCRYPTO,
 221         libcrypto,
 222         [
 223                 AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
 224                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 225                 LIBS="$LIBCRYPTO_LIBS $LIBS"
 226                 found_libcrypto=yes
 227         ],
 228         [
 229                 found_libcrypto=no
 230         ]
 231 )
 232
 233 if test "x$found_libcrypto" = "xyes"; then
 234         AC_DEFINE(HAVE_LIBCRYPTO)
 235 fi
 236
 237 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
 238 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
 239 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
 240
 241 # Don't define HAVE_BSD_UUID on darwin (Apple) as this breaks the BSD API.
 242 # Instead, use the UUID implementation wrapper that's in compat/ plus uuid
 243 # ossp
 244 if test "x$found_uuid" = "xyes" -a "x$PLATFORM" != "darwin"; then
 245         AC_DEFINE(HAVE_BSD_UUID)
 246 else
 247         PKG_CHECK_MODULES(
 248                 LIBUUID,
 249                 uuid,
 250                 [
 251                         AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
 252                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 253                         LIBS="$LIBUUID_LIBS $LIBS"
 254                         found_libuuid=yes
 255                 ],
 256                 [
 257                         found_libuuid=no
 258                 ]
 259         )
 260
 261         if test "x$found_libuuid" = "xno"; then
 262                 AC_CHECK_HEADER(
 263                         uuid.h,
 264                         found_libuuid=yes,
 265                         found_libuuid=no)
 266         fi
 267 fi
 268
 269 if test "x$found_libuuid" = "xno"; then
 270         AC_MSG_ERROR("*** couldn't find uuid ***")
 271 fi
 272
 273 PKG_CHECK_MODULES(
 274         ZLIB,
 275         zlib,
 276         [
 277                 AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
 278                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 279                 LIBS="$ZLIB_LIBS $LIBS"
 280                 found_zlib=yes
 281         ],
 282         [
 283                 found_zlib=no
 284         ]
 285 )
 286
 287 if test "x$found_zlib" = "xno"; then
 288         AC_CHECK_HEADER(
 289                 zlib.h,
 290                 ,
 291                 found_zlib=no)
 292 fi
 293
 294 if test "x$found_zlib" = "xno"; then
 295         AC_MSG_ERROR("*** couldn't find zlib ***")
 296 fi
 297
 298 if test "$PLATFORM" = "linux"; then
 299         PKG_CHECK_MODULES(
 300                 LIBMD,
 301                 libmd,
 302                 [
 303                         AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
 304                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 305                         LIBS="$LIBMD_LIBS $LIBS"
 306                 ],
 307                 [
 308                         AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
 309                 ]
 310         )
 311         PKG_CHECK_MODULES(
 312                 LIBBSD,
 313                 libbsd-overlay,
 314                 [
 315                         AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
 316                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 317                         LIBS="$LIBBSD_LIBS $LIBS"
 318                         found_libbsd=yes
 319                         AC_DEFINE(HAVE_LIBBSD)
 320                 ],
 321                 []
 322         )
 323 fi
 324
 325 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
 326 # SIMPLEQ.
 327 AC_CHECK_DECL(
 328         SIMPLEQ_INIT,
 329         found_queue_h=yes,
 330         found_queue_h=no,
 331         [#include <sys/queue.h>]
 332 )
 333 AC_CHECK_DECL(
 334         TAILQ_CONCAT,
 335         found_queue_h=yes,
 336         found_queue_h=no,
 337         [#include <sys/queue.h>]
 338 )
 339 AC_CHECK_DECL(
 340         TAILQ_PREV,
 341         found_queue_h=yes,
 342         found_queue_h=no,
 343         [#include <sys/queue.h>]
 344 )
 345 AC_CHECK_DECL(
 346         TAILQ_REPLACE,
 347         found_queue_h=yes,
 348         found_queue_h=no,
 349         [#include <sys/queue.h>]
 350 )
 351 AC_CHECK_DECL(
 352         SIMPLEQ_ENTRY,
 353         ,
 354         found_queue_h=no,
 355         [#include <sys/queue.h>]
 356 )
 357 AC_CHECK_DECL(
 358         TAILQ_FOREACH_SAFE,
 359         ,
 360         found_queue_h=no,
 361         [#include <sys/queue.h>]
 362 )
 363 if test "x$found_queue_h" = xyes; then
 364         AC_DEFINE(HAVE_QUEUE_H)
 365 fi
 366
 367 # Look for __progname.
 368 AC_MSG_CHECKING(for __progname)
 369 AC_LINK_IFELSE([AC_LANG_SOURCE(
 370         [
 371                 #include <stdio.h>
 372                 #include <stdlib.h>
 373                 extern char *__progname;
 374                 int main(void) {
 375                         const char *cp = __progname;
 376                         printf("%s\n", cp);
 377                         exit(0);
 378                 }
 379         ])],
 380         [AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
 381         AC_MSG_RESULT(no)
 382 )
 383
 384 if test "$PLATFORM" = "linux"; then
 385         PKG_CHECK_MODULES(
 386                 LIBPANELW,
 387                 panelw,
 388                 found_panel=yes,
 389                 AC_MSG_ERROR("*** couldn't find -lpanel from ncurses")
 390         )
 391 elif test "$PLATFORM" = "netbsd"; then
 392         PKG_CHECK_MODULES(
 393                 LIBPANELW,
 394                 gnupanelw,
 395                 found_panel=yes,
 396                 AC_MSG_ERROR("*** couldn't find -lgnupanelw from ncurses")
 397         )
 398 else
 399         AC_CHECK_LIB(panelw, update_panels,,
 400                 AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"])
 401         )
 402
 403         LIBPANELW_LIBS="-lpanelw"
 404 fi
 405
 406 PKG_CHECK_MODULES(
 407         LIBNCURSES,
 408         ncursesw,
 409         found_ncurses=yes,
 410         found_ncurses=no
 411 )
 412 if test "x$found_ncurses" = xyes; then
 413         AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
 414         CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
 415         LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
 416 else
 417         AC_CHECK_LIB(
 418                 ncursesw,
 419                 setupterm,
 420                 found_ncurses=yes,
 421                 found_ncurses=no
 422         )
 423         if test "x$found_ncurses" = xyes; then
 424                 AC_CHECK_HEADER(
 425                         ncurses.h,
 426                         AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 427                         CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 428                         LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
 429                         found_ncurses=no
 430                 )
 431         fi
 432 fi
 433 if test "x$found_ncurses" = xyes; then
 434         AC_DEFINE(HAVE_NCURSES_H)
 435 else
 436         # No ncurses, try curses.
 437         AC_CHECK_LIB(
 438                 cursesw,
 439                 setupterm,
 440                 found_curses=yes,
 441                 found_curses=no
 442         )
 443         AC_CHECK_HEADER(
 444                 curses.h,
 445                 ,
 446                 found_curses=no)
 447         if test "x$found_curses" = xyes; then
 448                 AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 449                 CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 450                 LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
 451                 AC_DEFINE(HAVE_CURSES_H)
 452         else
 453                 AC_MSG_ERROR("curses not found")
 454         fi
 455 fi
 456
 457 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
 458 # variables.
 459 AC_SUBST(AM_CPPFLAGS)
 460 CPPFLAGS="$SAVED_CPPFLAGS"
 461 AC_SUBST(AM_CFLAGS)
 462 CFLAGS="$SAVED_CFLAGS"
 463 AC_SUBST(AM_LDFLAGS)
 464 LDFLAGS="$SAVED_LDFLAGS"
 465
 466 AC_CONFIG_FILES([Makefile
 467                  compat/Makefile
 468                  libexec/Makefile
 469                  libexec/got-read-tree/Makefile
 470                  libexec/got-fetch-pack/Makefile
 471                  libexec/got-index-pack/Makefile
 472                  libexec/got-read-blob/Makefile
 473                  libexec/got-read-commit/Makefile
 474                  libexec/got-read-gitconfig/Makefile
 475                  libexec/got-read-gotconfig/Makefile
 476                  libexec/got-read-object/Makefile
 477                  libexec/got-read-pack/Makefile
 478                  libexec/got-read-tag/Makefile
 479                  libexec/got-send-pack/Makefile
 480                  got/Makefile
 481                  gotadmin/Makefile
 482                  tog/Makefile
 483                  Makefile.common:Makefile.common.in])
 484 AC_OUTPUT
 485
 486 #                tog/GNUMakefile])
 487 #                regress/GNUMakefile
 488 #                regress/cmdline/GNUMakefile
 489 #                regress/delta/GNUMakefile
 490 #                regress/fetch/GNUMakefile
 491 #                regress/idset/GNUMakefile
 492 #                regress/path/GNUMakefile
 493 #                 gotweb/GNUMakefile
 494 #                 gotweb/libexec/GNUMakefile
 495 #                 gotweb/libexec/got-read-blob/GNUMakefile
 496 #                 gotweb/libexec/got-read-commit/GNUMakefile
 497 #                 gotweb/libexec/got-read-gitconfig/GNUMakefile
 498 #                 gotweb/libexec/got-read-gotconfig/GNUMakefile
 499 #                 gotweb/libexec/got-read-object/GNUMakefile
 500 #                 gotweb/libexec/got-read-pack/GNUMakefile
 501 #                 gotweb/libexec/got-read-tag/GNUMakefile
 502 #                 gotweb/libexec/got-read-tree/GNUMakefile