configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.69])
   4 AC_INIT([got-portable], [0.67], [thomas@xteddy.org])
   5 AC_CONFIG_AUX_DIR(etc)
   6 AC_CONFIG_SRCDIR([lib/rcsutil.h])
   7 AM_INIT_AUTOMAKE([foreign subdir-objects])
   8
   9 GOT_RELEASE=No
  10
  11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  12 AC_SUBST(VERSION)
  13 AC_SUBST(GOT_RELEASE)
  14
  15 AC_CANONICAL_HOST
  16
  17 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
  18 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
  19 # empty default.
  20 : ${CFLAGS=""}
  21
  22 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
  23 # AC_CHECK_HEADER doesn't give us any other way to update the include
  24 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
  25 SAVED_CFLAGS="$CFLAGS"
  26 SAVED_CPPFLAGS="$CPPFLAGS"
  27 SAVED_LDFLAGS="$LDFLAGS"
  28
  29 # Checks for programs.
  30 AC_PROG_CC
  31 AC_PROG_CPP
  32 AC_PROG_INSTALL
  33 AC_PROG_LN_S
  34 AC_PROG_MAKE_SET
  35 AC_PROG_YACC
  36 AC_PROG_RANLIB
  37 PKG_PROG_PKG_CONFIG
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 # Checks for header files.
  41 AC_CHECK_HEADERS([ \
  42         fcntl.h \
  43         langinfo.h \
  44         limits.h \
  45         linux/landlock.h \
  46         locale.h \
  47         netdb.h \
  48         netinet/in.h \
  49         paths.h \
  50         stddef.h \
  51         stdint.h \
  52         stdlib.h \
  53         string.h \
  54         sys/ioctl.h \
  55         sys/param.h \
  56         sys/socket.h \
  57         sys/time.h \
  58         sys/tree.h \
  59         util.h \
  60         unistd.h \
  61         wchar.h \
  62 ])
  63
  64 # Checks for typ edefs, structures, and compiler characteristics.
  65 AC_CHECK_HEADER_STDBOOL
  66 AC_C_INLINE
  67 AC_TYPE_INT64_T
  68 AC_TYPE_MODE_T
  69 AC_TYPE_OFF_T
  70 AC_TYPE_PID_T
  71 AC_TYPE_SIZE_T
  72 AC_TYPE_SSIZE_T
  73 AC_TYPE_UINT16_T
  74 AC_TYPE_UINT32_T
  75 AC_TYPE_UINT64_T
  76 AC_TYPE_UINT8_T
  77
  78 # Look for library needed for flock.
  79 AC_SEARCH_LIBS(flock, bsd)
  80
  81 # Checks for library functions.
  82 AC_FUNC_FORK
  83 AC_FUNC_FSEEKO
  84 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
  85 AC_FUNC_MALLOC
  86 AC_FUNC_MMAP
  87 AC_FUNC_REALLOC
  88 AC_FUNC_STRERROR_R
  89 AC_FUNC_STRNLEN
  90 AC_CHECK_FUNCS([ \
  91         dup2 \
  92         flock \
  93         getcwd \
  94         localtime_r \
  95         memchr \
  96         memmove \
  97         memset \
  98         mkdir \
  99         munmap \
 100         nl_langinfo \
 101         realpath \
 102         regcomp \
 103         rmdir \
 104         setlocale \
 105         socket \
 106         strcasecmp \
 107         strchr \
 108         strcspn \
 109         strdup \
 110         strerror \
 111         strlcpy \
 112         strncasecmp \
 113         strndup \
 114         strrchr \
 115         strspn \
 116         strstr \
 117         strtol \
 118         strtoul \
 119         wcwidth \
 120 ])
 121
 122 # Check for functions with a compatibility implementation.
 123 AC_REPLACE_FUNCS([ \
 124         asprintf \
 125         closefrom \
 126         explicit_bzero \
 127         fmt_scaled \
 128         freezero \
 129         getdtablecount \
 130         getline \
 131         getprogname \
 132         recallocarray \
 133         reallocarray \
 134         strlcat \
 135         strlcpy \
 136         strndup \
 137         strsep \
 138         strtonum \
 139 ])
 140
 141 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
 142 # musl does not set optarg to NULL for flags without arguments (although it is
 143 # not required to, but it is helpful) 3) there are probably other weird
 144 # implementations.
 145 AC_LIBOBJ(getopt)
 146
 147 # Check the platform we're compiling on.
 148 AC_MSG_CHECKING(platform)
 149 case "$host_os" in
 150         *linux*)
 151                 AC_MSG_RESULT(linux)
 152                 PLATFORM=linux
 153                 ;;
 154         *freebsd*)
 155                 AC_MSG_RESULT(freebsd)
 156                 PLATFORM=freebsd
 157                 ;;
 158         *)
 159                 AC_MSG_RESULT(unknown)
 160                 PLATFORM=unknown
 161                 ;;
 162 esac
 163 AC_SUBST(PLATFORM)
 164 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
 165 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
 166
 167 # Landlock detection.
 168 AC_MSG_CHECKING([for landlock])
 169 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
 170     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
 171 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
 172         AC_MSG_RESULT(yes)
 173 else
 174         AC_MSG_RESULT(no)
 175 fi
 176
 177 # Clang sanitizers wrap reallocarray even if it isn't available on the target
 178 # system. When compiled it always returns NULL and crashes the program. To
 179 # detect this we need a more complicated test.
 180 AC_MSG_CHECKING([for working reallocarray])
 181 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 182                 [#include <stdlib.h>],
 183                 [return (reallocarray(NULL, 1, 1) == NULL);]
 184         )],
 185         AC_MSG_RESULT(yes),
 186         [AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
 187 )
 188 AC_MSG_CHECKING([for working recallocarray])
 189 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 190                 [#include <stdlib.h>],
 191                 [return (recallocarray(NULL, 1, 1, 1) == NULL);]
 192         )],
 193         AC_MSG_RESULT(yes),
 194         [AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
 195 )
 196
 197 # Look for imsg_init in libutil.
 198 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
 199 if test "x$found_imsg_init" = xyes; then
 200         AC_DEFINE(HAVE_IMSG)
 201 else
 202         AC_LIBOBJ(imsg)
 203         AC_LIBOBJ(imsg-buffer)
 204 fi
 205
 206 # libcrypto (via libssl for SHA information)
 207 PKG_CHECK_MODULES(
 208         LIBCRYPTO,
 209         libcrypto,
 210         [
 211                 AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
 212                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 213                 LIBS="$LIBCRYPTO_LIBS $LIBS"
 214                 found_libcrypto=yes
 215         ],
 216         [
 217                 found_libcrypto=no
 218         ]
 219 )
 220
 221 if test "x$found_libcrypto" = "xyes"; then
 222         AC_DEFINE(HAVE_LIBCRYPTO)
 223 fi
 224
 225 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
 226 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
 227 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
 228
 229 if test "x$found_uuid" = "xyes"; then
 230         AC_DEFINE(HAVE_BSD_UUID)
 231 else
 232         PKG_CHECK_MODULES(
 233                 LIBUUID,
 234                 uuid,
 235                 [
 236                         AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
 237                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 238                         LIBS="$LIBUUID_LIBS $LIBS"
 239                         found_libuuid=yes
 240                 ],
 241                 [
 242                         found_libuuid=no
 243                 ]
 244         )
 245
 246         if test "x$found_libuuid" = "xno"; then
 247                 AC_CHECK_HEADER(
 248                         uuid.h,
 249                         found_libuuid=yes,
 250                         found_libuuid=no)
 251         fi
 252 fi
 253
 254 if test "x$found_libuuid" = "xno"; then
 255         AC_MSG_ERROR("*** couldn't find uuid ***")
 256 fi
 257
 258 PKG_CHECK_MODULES(
 259         ZLIB,
 260         zlib,
 261         [
 262                 AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
 263                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 264                 LIBS="$ZLIB_LIBS $LIBS"
 265                 found_zlib=yes
 266         ],
 267         [
 268                 found_zlib=no
 269         ]
 270 )
 271
 272 if test "x$found_zlib" = "xno"; then
 273         AC_CHECK_HEADER(
 274                 zlib.h,
 275                 ,
 276                 found_zlib=no)
 277 fi
 278
 279 if test "x$found_zlib" = "xno"; then
 280         AC_MSG_ERROR("*** couldn't find zlib ***")
 281 fi
 282
 283 if test "$PLATFORM" = "linux"; then
 284         PKG_CHECK_MODULES(
 285                 LIBMD,
 286                 libmd,
 287                 [
 288                         AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
 289                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 290                         LIBS="$LIBMD_LIBS $LIBS"
 291                 ],
 292                 [
 293                         AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
 294                 ]
 295         )
 296         PKG_CHECK_MODULES(
 297                 LIBBSD,
 298                 libbsd-overlay,
 299                 [
 300                         AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
 301                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 302                         LIBS="$LIBBSD_LIBS $LIBS"
 303                         found_libbsd=yes
 304                         AC_DEFINE(HAVE_LIBBSD)
 305                 ],
 306                 []
 307         )
 308 fi
 309
 310 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
 311 # SIMPLEQ.
 312 AC_CHECK_DECL(
 313         SIMPLEQ_INIT,
 314         found_queue_h=yes,
 315         found_queue_h=no,
 316         [#include <sys/queue.h>]
 317 )
 318 AC_CHECK_DECL(
 319         TAILQ_CONCAT,
 320         found_queue_h=yes,
 321         found_queue_h=no,
 322         [#include <sys/queue.h>]
 323 )
 324 AC_CHECK_DECL(
 325         TAILQ_PREV,
 326         found_queue_h=yes,
 327         found_queue_h=no,
 328         [#include <sys/queue.h>]
 329 )
 330 AC_CHECK_DECL(
 331         TAILQ_REPLACE,
 332         found_queue_h=yes,
 333         found_queue_h=no,
 334         [#include <sys/queue.h>]
 335 )
 336 AC_CHECK_DECL(
 337         SIMPLEQ_ENTRY,
 338         ,
 339         found_queue_h=no,
 340         [#include <sys/queue.h>]
 341 )
 342 AC_CHECK_DECL(
 343         TAILQ_FOREACH_SAFE,
 344         ,
 345         found_queue_h=no,
 346         [#include <sys/queue.h>]
 347 )
 348 if test "x$found_queue_h" = xyes; then
 349         AC_DEFINE(HAVE_QUEUE_H)
 350 fi
 351
 352 # Look for __progname.
 353 AC_MSG_CHECKING(for __progname)
 354 AC_LINK_IFELSE([AC_LANG_SOURCE(
 355         [
 356                 #include <stdio.h>
 357                 #include <stdlib.h>
 358                 extern char *__progname;
 359                 int main(void) {
 360                         const char *cp = __progname;
 361                         printf("%s\n", cp);
 362                         exit(0);
 363                 }
 364         ])],
 365         [AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
 366         AC_MSG_RESULT(no)
 367 )
 368
 369 if test "$PLATFORM" = "linux"; then
 370         PKG_CHECK_MODULES(
 371                 LIBPANELW,
 372                 panelw,
 373                 found_panel=yes,
 374                 AC_MSG_ERROR("*** couldn't find -lpanel from ncurses")
 375         )
 376 else
 377         AC_CHECK_LIB(panelw, update_panels,,
 378                 AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"])
 379         )
 380
 381         LIBPANELW_LIBS="-lpanelw"
 382 fi
 383
 384 PKG_CHECK_MODULES(
 385         LIBNCURSES,
 386         ncursesw,
 387         found_ncurses=yes,
 388         found_ncurses=no
 389 )
 390 if test "x$found_ncurses" = xyes; then
 391         AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
 392         CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
 393         LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
 394 else
 395         AC_CHECK_LIB(
 396                 ncursesw,
 397                 setupterm,
 398                 found_ncurses=yes,
 399                 found_ncurses=no
 400         )
 401         if test "x$found_ncurses" = xyes; then
 402                 AC_CHECK_HEADER(
 403                         ncurses.h,
 404                         AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 405                         CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 406                         LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
 407                         found_ncurses=no
 408                 )
 409         fi
 410 fi
 411 if test "x$found_ncurses" = xyes; then
 412         AC_DEFINE(HAVE_NCURSES_H)
 413 else
 414         # No ncurses, try curses.
 415         AC_CHECK_LIB(
 416                 cursesw,
 417                 setupterm,
 418                 found_curses=yes,
 419                 found_curses=no
 420         )
 421         AC_CHECK_HEADER(
 422                 curses.h,
 423                 ,
 424                 found_curses=no)
 425         if test "x$found_curses" = xyes; then
 426                 AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 427                 CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 428                 LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
 429                 AC_DEFINE(HAVE_CURSES_H)
 430         else
 431                 AC_MSG_ERROR("curses not found")
 432         fi
 433 fi
 434
 435 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
 436 # variables.
 437 AC_SUBST(AM_CPPFLAGS)
 438 CPPFLAGS="$SAVED_CPPFLAGS"
 439 AC_SUBST(AM_CFLAGS)
 440 CFLAGS="$SAVED_CFLAGS"
 441 AC_SUBST(AM_LDFLAGS)
 442 LDFLAGS="$SAVED_LDFLAGS"
 443
 444 AC_CONFIG_FILES([Makefile
 445                  compat/Makefile
 446                  libexec/Makefile
 447                  libexec/got-read-tree/Makefile
 448                  libexec/got-fetch-pack/Makefile
 449                  libexec/got-index-pack/Makefile
 450                  libexec/got-read-blob/Makefile
 451                  libexec/got-read-commit/Makefile
 452                  libexec/got-read-gitconfig/Makefile
 453                  libexec/got-read-gotconfig/Makefile
 454                  libexec/got-read-object/Makefile
 455                  libexec/got-read-pack/Makefile
 456                  libexec/got-read-tag/Makefile
 457                  libexec/got-send-pack/Makefile
 458                  got/Makefile
 459                  gotadmin/Makefile
 460                  tog/Makefile
 461                  Makefile.common:Makefile.common.in])
 462 AC_OUTPUT
 463
 464 #                tog/GNUMakefile])
 465 #                regress/GNUMakefile
 466 #                regress/cmdline/GNUMakefile
 467 #                regress/delta/GNUMakefile
 468 #                regress/fetch/GNUMakefile
 469 #                regress/idset/GNUMakefile
 470 #                regress/path/GNUMakefile
 471 #                 gotweb/GNUMakefile
 472 #                 gotweb/libexec/GNUMakefile
 473 #                 gotweb/libexec/got-read-blob/GNUMakefile
 474 #                 gotweb/libexec/got-read-commit/GNUMakefile
 475 #                 gotweb/libexec/got-read-gitconfig/GNUMakefile
 476 #                 gotweb/libexec/got-read-gotconfig/GNUMakefile
 477 #                 gotweb/libexec/got-read-object/GNUMakefile
 478 #                 gotweb/libexec/got-read-pack/GNUMakefile
 479 #                 gotweb/libexec/got-read-tag/GNUMakefile
 480 #                 gotweb/libexec/got-read-tree/GNUMakefile