configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.0.13], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *)
  71   ;;
  72 esac
  73
  74 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  75
  76 dnl Hardware Acceleration
  77 AC_ARG_ENABLE(hardware-acceleration,
  78   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  79     use_accel=$enableval, use_accel=yes)
  80 hw_accel=none
  81
  82
  83 if test "$use_accel" != "no"; then
  84 case $host_cpu in
  85   i?86 | x86_64 | amd64)
  86 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  87 dnl    if test "x$X86" = "xyes";then
  88       AC_CHECK_HEADERS(cpuid.h)
  89       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  90         hw_accel="x86-64"
  91       else
  92         hw_accel="x86"
  93       fi
  94 dnl    fi
  95   ;;
  96   *)
  97   ;;
  98 esac
  99
 100 fi
 101
 102 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 103 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 104 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 105 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 106 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 107
 108 dnl Try the hooks.m4
 109 LIBGNUTLS_HOOKS
 110 LIBGNUTLS_EXTRA_HOOKS
 111
 112 GTK_DOC_CHECK(1.1)
 113 AM_GNU_GETTEXT([external])
 114 AM_GNU_GETTEXT_VERSION([0.18])
 115
 116 AC_C_BIGENDIAN
 117
 118
 119
 120 dnl No fork on MinGW, disable some self-tests until we fix them.
 121 AC_CHECK_FUNCS([fork getrusage getpwuid_r daemon fchmod],,)
 122 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 123 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 124
 125 dnl Check for p11-kit
 126 AC_ARG_WITH(p11-kit,
 127         AS_HELP_STRING([--without-p11-kit],
 128                 [Build without p11-kit and PKCS#11 support]))
 129 if test "$with_p11_kit" != "no"; then
 130         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
 131         if test "$with_p11_kit" != "no";then
 132                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 133                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 134                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 135                 else
 136                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 137                 fi
 138         else
 139                 with_p11_kit=no
 140                 AC_MSG_WARN([[
 141 ***
 142 *** p11-kit was not found. PKCS #11 support will be disabled.
 143 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 144 *** ]])
 145         fi
 146 fi
 147
 148 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 149
 150 dnl Checks for programs in src/
 151 NEED_LIBOPTS_DIR=true
 152 LIBOPTS_CHECK([src/libopts])
 153
 154 AC_CHECK_TYPE(ssize_t,
 155   [
 156     DEFINE_SSIZE_T="#include <sys/types.h>"
 157     AC_SUBST(DEFINE_SSIZE_T)
 158   ], [
 159     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 160     DEFINE_SSIZE_T="typedef int ssize_t;"
 161     AC_SUBST(DEFINE_SSIZE_T)
 162   ], [
 163     #include <sys/types.h>
 164   ])
 165
 166 # For minitasn1.
 167 AC_CHECK_SIZEOF(unsigned long int, 4)
 168 AC_CHECK_SIZEOF(unsigned int, 4)
 169
 170 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 171                                  [disable zlib compression support]),
 172             ac_zlib=$withval, ac_zlib=yes)
 173 AC_MSG_CHECKING([whether to include zlib compression support])
 174 if test x$ac_zlib != xno; then
 175  AC_MSG_RESULT(yes)
 176  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 177  if test x$ac_cv_libz != xyes; then
 178    AC_MSG_WARN(
 179 ***
 180 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 181  fi
 182 else
 183  AC_MSG_RESULT(no)
 184 fi
 185
 186 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 187
 188 if test x$ac_zlib != xno; then
 189   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 190     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 191       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 192     else
 193       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 194     fi
 195   else
 196     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 197   fi
 198 fi
 199 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 200 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 201
 202
 203 gl_INIT
 204
 205 dnl GCC warnings to enable
 206
 207 AC_ARG_ENABLE([gcc-warnings],
 208   [AS_HELP_STRING([--enable-gcc-warnings],
 209                   [turn on lots of GCC warnings (for developers)])],
 210   [case $enableval in
 211      yes|no) ;;
 212      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 213    esac
 214    gl_gcc_warnings=$enableval],
 215   [gl_gcc_warnings=no]
 216 )
 217
 218 if test "$gl_gcc_warnings" = yes; then
 219   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 220   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 221
 222   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 223   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 224   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 225   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 226   nw="$nw -Wlogical-op"             # Too many false positives
 227   nw="$nw -Wold-style-definition"   #
 228   nw="$nw -Wpadded"                 # Our structs are not padded
 229   nw="$nw -Wunreachable-code"       # Too many false positives
 230   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 231   nw="$nw -Wcast-qual"              # Too many warnings for now
 232   nw="$nw -Waggregate-return"       # Too many warnings for now
 233   nw="$nw -Wshadow"                 # Too many warnings for now
 234   nw="$nw -Wswitch-default"         # Too many warnings for now
 235   nw="$nw -Wswitch-enum"            # Too many warnings for now
 236   nw="$nw -Wconversion"             # Too many warnings for now
 237   nw="$nw -Wsign-conversion"        # Too many warnings for now
 238   nw="$nw -Wformat-y2k"             # Too many warnings for now
 239   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 240   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 241   nw="$nw -Wunsafe-loop-optimizations"
 242   nw="$nw -Wstrict-overflow"
 243   nw="$nw -Wmissing-noreturn"
 244
 245   gl_MANYWARN_ALL_GCC([ws])
 246   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 247   for w in $ws; do
 248     gl_WARN_ADD([$w])
 249   done
 250
 251   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 252   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 253   gl_WARN_ADD([-Wno-suggest-attribute=pure])     # Too many warnings for now
 254   gl_WARN_ADD([-Wno-suggest-attribute=const])     # Too many warnings for now
 255   gl_WARN_ADD([-Wno-suggest-attribute=noreturn])     # Too many warnings for now
 256   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 257   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 258   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 259   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 260   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 261   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 262   gl_WARN_ADD([-Wno-redundant-decls])  # Some files cannot be compiled with that (gl_fd_to_handle)
 263   gl_WARN_ADD([-fdiagnostics-show-option])
 264 fi
 265
 266 AC_SUBST([WERROR_CFLAGS])
 267 AC_SUBST([WSTACK_CFLAGS])
 268 AC_SUBST([WARN_CFLAGS])
 269
 270 dnl Programs for compilation or development
 271 AC_PROG_LN_S
 272 AC_LIBTOOL_WIN32_DLL
 273 AC_PROG_LIBTOOL
 274
 275 dnl Guile bindings.
 276 opt_guile_bindings=yes
 277 AC_MSG_CHECKING([whether building Guile bindings])
 278 AC_ARG_ENABLE(guile,
 279         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 280 opt_guile_bindings=$enableval)
 281 AC_MSG_RESULT($opt_guile_bindings)
 282
 283 AC_ARG_WITH([--with-guile-site-dir],
 284   [AS_HELP_STRING([--with-guile-site-dir],
 285      [use the given directory as the Guile site (use with care)])])
 286
 287 if test "$opt_guile_bindings" = "yes"; then
 288    AC_MSG_RESULT([***
 289 *** Detecting GNU Guile...
 290 ])
 291
 292    AC_PATH_PROG([guile_snarf], [guile-snarf])
 293    if test "x$guile_snarf" = "x"; then
 294       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 295       opt_guile_bindings=no
 296    else
 297       GUILE_PROGS
 298       GUILE_FLAGS
 299
 300       save_CFLAGS="$CFLAGS"
 301       save_LIBS="$LIBS"
 302       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 303       LIBS="$LIBS $GUILE_LDFLAGS"
 304       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 305       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 306         [], [opt_guile_bindings=no])
 307       CFLAGS="$save_CFLAGS"
 308       LIBS="$save_LIBS"
 309
 310       if test "$opt_guile_bindings" = "yes"; then
 311         AC_MSG_RESULT([yes])
 312         case "x$with_guile_site_dir" in
 313              xno)
 314                 # Use the default $(GUILE_SITE).
 315                 GUILE_SITE_DIR
 316                 ;;
 317              x|xyes)
 318                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 319                 # hack is used to allow `distcheck' to work (see
 320                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 321                 GUILE_SITE="\$(datadir)/guile/site"
 322                 AC_SUBST(GUILE_SITE)
 323                 ;;
 324              *)
 325                 # Use the user-specified directory as $(GUILE_SITE).
 326                 GUILE_SITE="$with_guile_site_dir"
 327                 AC_SUBST(GUILE_SITE)
 328                 ;;
 329         esac
 330         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 331         _gcc_cflags_save="$CFLAGS"
 332         CFLAGS="${CFLAGS} -fgnu89-inline"
 333         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 334                           gnu89_inline=yes, gnu89_inline=no)
 335         AC_MSG_RESULT($gnu89_inline)
 336         CFLAGS="$_gcc_cflags_save"
 337
 338         # Optional Guile functions.
 339         save_CFLAGS="$CFLAGS"
 340         save_LIBS="$LIBS"
 341         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 342         LIBS="$LIBS $GUILE_LDFLAGS"
 343         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 344         CFLAGS="$save_CFLAGS"
 345         LIBS="$save_LIBS"
 346
 347         # The place where guile-gnutls.la will go.
 348         AC_MSG_CHECKING([the Guile effective version])
 349         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 350         AC_MSG_RESULT([$guile_effective_version])
 351         guileextensiondir="$libdir/guile/$guile_effective_version"
 352         AC_SUBST([guileextensiondir])
 353       else
 354         AC_MSG_RESULT([no])
 355         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 356         opt_guile_bindings=no
 357       fi
 358    fi
 359 fi
 360 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 361
 362 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 363 LIBGNUTLS_CFLAGS="-I${includedir}"
 364 AC_SUBST(LIBGNUTLS_LIBS)
 365 AC_SUBST(LIBGNUTLS_CFLAGS)
 366
 367
 368 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 369 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 370
 371 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 372 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 373 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 374
 375 dnl Crywrap dependencies
 376    AC_MSG_RESULT([***
 377 *** Checking dependencies for crywrap...
 378 ])
 379
 380 crywrap=no
 381
 382 if test "$have_win" != "yes"; then
 383
 384 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 385
 386 dnl **********************
 387 dnl * Typedefs & co
 388 dnl **********************
 389 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 390 [AC_LANG_PROGRAM([#include <sys/types.h>
 391 #include <signal.h>
 392 ],
 393                  [return *(signal (0, 0)) (0) == 1;])],
 394                    [ac_cv_type_signal=int],
 395                    [ac_cv_type_signal=void])])
 396 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 397                     (`int' or `void').])
 398
 399 AC_FUNC_SELECT_ARGTYPES
 400 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 401                 putenv regcomp scandir select socket strcasecmp strchr \
 402                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 403
 404 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 405
 406  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
 407   crywrap=yes
 408  fi
 409
 410 fi
 411
 412 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 413 rm -f suppressions.valgrind
 414 dnl end of crywrap requirements
 415
 416 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 417 AC_CONFIG_FILES([
 418   Makefile
 419   doc/Makefile
 420   doc/credentials/Makefile
 421   doc/credentials/openpgp/Makefile
 422   doc/credentials/srp/Makefile
 423   doc/credentials/x509/Makefile
 424   doc/cyclo/Makefile
 425   doc/doxygen/Doxyfile
 426   doc/examples/Makefile
 427   doc/latex/Makefile
 428   doc/manpages/Makefile
 429   doc/reference/Makefile
 430   doc/reference/version.xml
 431   doc/scripts/Makefile
 432   extra/Makefile
 433   extra/includes/Makefile
 434   gl/Makefile
 435   gl/tests/Makefile
 436   guile/Makefile
 437   guile/modules/Makefile
 438   guile/src/Makefile
 439   guile/tests/Makefile
 440   lib/Makefile
 441   lib/accelerated/Makefile
 442   lib/accelerated/x86/Makefile
 443   lib/algorithms/Makefile
 444   lib/auth/Makefile
 445   lib/ext/Makefile
 446   lib/extras/Makefile
 447   lib/gnutls.pc
 448   lib/includes/Makefile
 449   lib/includes/gnutls/gnutls.h
 450   lib/minitasn1/Makefile
 451   lib/nettle/Makefile
 452   lib/opencdk/Makefile
 453   lib/openpgp/Makefile
 454   lib/x509/Makefile
 455   po/Makefile.in
 456   src/Makefile
 457   src/crywrap/Makefile
 458   tests/Makefile
 459   tests/cert-tests/Makefile
 460   tests/dsa/Makefile
 461   tests/dtls/Makefile
 462   tests/ecdsa/Makefile
 463   tests/key-id/Makefile
 464   tests/openpgp-certs/Makefile
 465   tests/pkcs1-padding/Makefile
 466   tests/pkcs12-decode/Makefile
 467   tests/pkcs8-decode/Makefile
 468   tests/rsa-md5-collision/Makefile
 469   tests/safe-renegotiation/Makefile
 470   tests/scripts/Makefile
 471   tests/sha2/Makefile
 472   tests/slow/Makefile
 473   tests/suite/Makefile
 474   tests/userid/Makefile
 475 ])
 476
 477 AC_OUTPUT
 478
 479 AC_MSG_NOTICE([summary of build options:
 480
 481   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 482   Host type:        ${host}
 483   Install prefix:   ${prefix}
 484   Compiler:         ${CC}
 485   CFlags:           ${CFLAGS}
 486   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 487   Library types:    Shared=${enable_shared}, Static=${enable_static}
 488   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 489 ])
 490
 491 AC_MSG_NOTICE([Optional features:
 492 (note that included applications might not compile properly
 493 if features are disabled)
 494
 495   OCSP support:     $ac_enable_ocsp
 496   OpenPGP support:  $ac_enable_openpgp
 497   SRP support:      $ac_enable_srp
 498   PSK support:      $ac_enable_psk
 499   Anon auth support:$ac_enable_anon
 500 ])
 501
 502 AC_MSG_NOTICE([Optional applications:
 503
 504   crywrap app:      $libidn
 505 ])
 506
 507 AC_MSG_NOTICE([Optional libraries:
 508
 509   Guile wrappers:   $opt_guile_bindings
 510   C++ library:      $use_cxx
 511   OpenSSL compat:   $enable_openssl
 512 ])
 513
 514 AC_MSG_NOTICE([Hardware acceleration/support:
 515
 516   /dev/crypto:      $enable_cryptodev
 517   Hardware accel:   $hw_accel
 518   PKCS#11 support:  $with_p11_kit
 519 ])