configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.0.12], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *)
  71   ;;
  72 esac
  73
  74 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  75
  76 dnl Hardware Acceleration
  77 AC_ARG_ENABLE(hardware-acceleration,
  78   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  79     use_accel=$enableval, use_accel=yes)
  80 hw_accel=none
  81
  82
  83 if test "$use_accel" != "no"; then
  84 case $host_cpu in
  85   i?86 | x86_64 | amd64)
  86 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  87 dnl    if test "x$X86" = "xyes";then
  88       AC_CHECK_HEADERS(cpuid.h)
  89       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  90         hw_accel="x86-64"
  91       else
  92         hw_accel="x86"
  93       fi
  94 dnl    fi
  95   ;;
  96   *)
  97   ;;
  98 esac
  99
 100 fi
 101
 102 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 103 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 104 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 105 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 106 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 107
 108 dnl Try the hooks.m4
 109 LIBGNUTLS_HOOKS
 110 LIBGNUTLS_EXTRA_HOOKS
 111
 112 GTK_DOC_CHECK(1.1)
 113 AM_GNU_GETTEXT([external])
 114 AM_GNU_GETTEXT_VERSION([0.18])
 115
 116 AC_C_BIGENDIAN
 117
 118
 119
 120 dnl No fork on MinGW, disable some self-tests until we fix them.
 121 AC_CHECK_FUNCS([fork getrusage getpwuid_r],,)
 122 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 123 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 124
 125 dnl Check for p11-kit
 126 AC_ARG_WITH(p11-kit,
 127         AS_HELP_STRING([--without-p11-kit],
 128                 [Build without p11-kit and PKCS#11 support]))
 129 if test "$with_p11_kit" != "no"; then
 130         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.4], [with_p11_kit=yes], [with_p11_kit=no])
 131         if test "$with_p11_kit" != "no";then
 132                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 133                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 134                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 135                 else
 136                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 137                 fi
 138         else
 139                 with_p11_kit=no
 140                 AC_MSG_WARN([[
 141 ***
 142 *** p11-kit was not found. PKCS #11 support will be disabled.
 143 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 144 *** ]])
 145         fi
 146 fi
 147
 148 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 149
 150 dnl Checks for programs in src/
 151 LIBOPTS_CHECK([src/libopts])
 152
 153 AC_CHECK_TYPE(ssize_t,
 154   [
 155     DEFINE_SSIZE_T="#include <sys/types.h>"
 156     AC_SUBST(DEFINE_SSIZE_T)
 157   ], [
 158     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 159     DEFINE_SSIZE_T="typedef int ssize_t;"
 160     AC_SUBST(DEFINE_SSIZE_T)
 161   ], [
 162     #include <sys/types.h>
 163   ])
 164
 165 # For minitasn1.
 166 AC_CHECK_SIZEOF(unsigned long int, 4)
 167 AC_CHECK_SIZEOF(unsigned int, 4)
 168
 169 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 170                                  [disable zlib compression support]),
 171             ac_zlib=$withval, ac_zlib=yes)
 172 AC_MSG_CHECKING([whether to include zlib compression support])
 173 if test x$ac_zlib != xno; then
 174  AC_MSG_RESULT(yes)
 175  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 176  if test x$ac_cv_libz != xyes; then
 177    AC_MSG_WARN(
 178 ***
 179 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 180  fi
 181 else
 182  AC_MSG_RESULT(no)
 183 fi
 184
 185 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 186
 187 if test x$ac_zlib != xno; then
 188   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 189     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 190       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 191     else
 192       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 193     fi
 194   else
 195     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 196   fi
 197 fi
 198 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 199 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 200
 201
 202 gl_INIT
 203
 204 dnl GCC warnings to enable
 205
 206 AC_ARG_ENABLE([gcc-warnings],
 207   [AS_HELP_STRING([--enable-gcc-warnings],
 208                   [turn on lots of GCC warnings (for developers)])],
 209   [case $enableval in
 210      yes|no) ;;
 211      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 212    esac
 213    gl_gcc_warnings=$enableval],
 214   [gl_gcc_warnings=no]
 215 )
 216
 217 if test "$gl_gcc_warnings" = yes; then
 218   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 219   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 220
 221   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 222   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 223   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 224   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 225   nw="$nw -Wlogical-op"             # Too many false positives
 226   nw="$nw -Wold-style-definition"   #
 227   nw="$nw -Wpadded"                 # Our structs are not padded
 228   nw="$nw -Wunreachable-code"       # Too many false positives
 229   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 230   nw="$nw -Wcast-qual"              # Too many warnings for now
 231   nw="$nw -Waggregate-return"       # Too many warnings for now
 232   nw="$nw -Wshadow"                 # Too many warnings for now
 233   nw="$nw -Wswitch-default"         # Too many warnings for now
 234   nw="$nw -Wswitch-enum"            # Too many warnings for now
 235   nw="$nw -Wconversion"             # Too many warnings for now
 236   nw="$nw -Wsign-conversion"        # Too many warnings for now
 237   nw="$nw -Wformat-y2k"             # Too many warnings for now
 238   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 239   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 240   nw="$nw -Wunsafe-loop-optimizations"
 241   nw="$nw -Wstrict-overflow"
 242   nw="$nw -Wmissing-noreturn"
 243
 244   gl_MANYWARN_ALL_GCC([ws])
 245   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 246   for w in $ws; do
 247     gl_WARN_ADD([$w])
 248   done
 249
 250   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 251   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 252   gl_WARN_ADD([-Wno-suggest-attribute=pure])     # Too many warnings for now
 253   gl_WARN_ADD([-Wno-suggest-attribute=const])     # Too many warnings for now
 254   gl_WARN_ADD([-Wno-suggest-attribute=noreturn])     # Too many warnings for now
 255   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 256   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 257   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 258   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 259   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 260   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 261   gl_WARN_ADD([-Wno-redundant-decls])  # Some files cannot be compiled with that (gl_fd_to_handle)
 262   gl_WARN_ADD([-fdiagnostics-show-option])
 263 fi
 264
 265 AC_SUBST([WERROR_CFLAGS])
 266 AC_SUBST([WSTACK_CFLAGS])
 267 AC_SUBST([WARN_CFLAGS])
 268
 269 dnl Programs for compilation or development
 270 AC_PROG_LN_S
 271 AC_LIBTOOL_WIN32_DLL
 272 AC_PROG_LIBTOOL
 273
 274 dnl Guile bindings.
 275 opt_guile_bindings=yes
 276 AC_MSG_CHECKING([whether building Guile bindings])
 277 AC_ARG_ENABLE(guile,
 278         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 279 opt_guile_bindings=$enableval)
 280 AC_MSG_RESULT($opt_guile_bindings)
 281
 282 AC_ARG_WITH([--with-guile-site-dir],
 283   [AS_HELP_STRING([--with-guile-site-dir],
 284      [use the given directory as the Guile site (use with care)])])
 285
 286 if test "$opt_guile_bindings" = "yes"; then
 287    AC_MSG_RESULT([***
 288 *** Detecting GNU Guile...
 289 ])
 290
 291    AC_PATH_PROG([guile_snarf], [guile-snarf])
 292    if test "x$guile_snarf" = "x"; then
 293       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 294       opt_guile_bindings=no
 295    else
 296       GUILE_PROGS
 297       GUILE_FLAGS
 298
 299       save_CFLAGS="$CFLAGS"
 300       save_LIBS="$LIBS"
 301       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 302       LIBS="$LIBS $GUILE_LDFLAGS"
 303       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 304       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 305         [], [opt_guile_bindings=no])
 306       CFLAGS="$save_CFLAGS"
 307       LIBS="$save_LIBS"
 308
 309       if test "$opt_guile_bindings" = "yes"; then
 310         AC_MSG_RESULT([yes])
 311         case "x$with_guile_site_dir" in
 312              xno)
 313                 # Use the default $(GUILE_SITE).
 314                 GUILE_SITE_DIR
 315                 ;;
 316              x|xyes)
 317                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 318                 # hack is used to allow `distcheck' to work (see
 319                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 320                 GUILE_SITE="\$(datadir)/guile/site"
 321                 AC_SUBST(GUILE_SITE)
 322                 ;;
 323              *)
 324                 # Use the user-specified directory as $(GUILE_SITE).
 325                 GUILE_SITE="$with_guile_site_dir"
 326                 AC_SUBST(GUILE_SITE)
 327                 ;;
 328         esac
 329         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 330         _gcc_cflags_save="$CFLAGS"
 331         CFLAGS="${CFLAGS} -fgnu89-inline"
 332         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 333                           gnu89_inline=yes, gnu89_inline=no)
 334         AC_MSG_RESULT($gnu89_inline)
 335         CFLAGS="$_gcc_cflags_save"
 336
 337         # Optional Guile functions.
 338         save_CFLAGS="$CFLAGS"
 339         save_LIBS="$LIBS"
 340         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 341         LIBS="$LIBS $GUILE_LDFLAGS"
 342         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 343         CFLAGS="$save_CFLAGS"
 344         LIBS="$save_LIBS"
 345
 346         # The place where guile-gnutls.la will go.
 347         AC_MSG_CHECKING([the Guile effective version])
 348         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 349         AC_MSG_RESULT([$guile_effective_version])
 350         guileextensiondir="$libdir/guile/$guile_effective_version"
 351         AC_SUBST([guileextensiondir])
 352       else
 353         AC_MSG_RESULT([no])
 354         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 355         opt_guile_bindings=no
 356       fi
 357    fi
 358 fi
 359 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 360
 361 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 362 LIBGNUTLS_CFLAGS="-I${includedir}"
 363 AC_SUBST(LIBGNUTLS_LIBS)
 364 AC_SUBST(LIBGNUTLS_CFLAGS)
 365
 366
 367 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 368 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 369
 370 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 371 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 372 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 373
 374 dnl Crywrap dependencies
 375    AC_MSG_RESULT([***
 376 *** Checking dependencies for crywrap...
 377 ])
 378
 379 if test "$have_win" != "yes"; then
 380
 381 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 382
 383 dnl **********************
 384 dnl * Typedefs & co
 385 dnl **********************
 386 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 387 [AC_LANG_PROGRAM([#include <sys/types.h>
 388 #include <signal.h>
 389 ],
 390                  [return *(signal (0, 0)) (0) == 1;])],
 391                    [ac_cv_type_signal=int],
 392                    [ac_cv_type_signal=void])])
 393 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 394                     (`int' or `void').])
 395
 396 AC_FUNC_SELECT_ARGTYPES
 397 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 398                 putenv regcomp scandir select socket strcasecmp strchr \
 399                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 400
 401 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 402
 403 else
 404 libidn=no
 405 fi
 406
 407 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$libidn" != "xno")
 408 rm -f suppressions.valgrind
 409 dnl end of crywrap requirements
 410
 411 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 412 AC_CONFIG_FILES([
 413   Makefile
 414   doc/Makefile
 415   doc/credentials/Makefile
 416   doc/credentials/openpgp/Makefile
 417   doc/credentials/srp/Makefile
 418   doc/credentials/x509/Makefile
 419   doc/cyclo/Makefile
 420   doc/doxygen/Doxyfile
 421   doc/examples/Makefile
 422   doc/latex/Makefile
 423   doc/manpages/Makefile
 424   doc/reference/Makefile
 425   doc/reference/version.xml
 426   doc/scripts/Makefile
 427   extra/Makefile
 428   extra/includes/Makefile
 429   gl/Makefile
 430   gl/tests/Makefile
 431   guile/Makefile
 432   guile/modules/Makefile
 433   guile/src/Makefile
 434   guile/tests/Makefile
 435   lib/Makefile
 436   lib/accelerated/Makefile
 437   lib/accelerated/x86/Makefile
 438   lib/algorithms/Makefile
 439   lib/auth/Makefile
 440   lib/ext/Makefile
 441   lib/extras/Makefile
 442   lib/gnutls.pc
 443   lib/includes/Makefile
 444   lib/includes/gnutls/gnutls.h
 445   lib/minitasn1/Makefile
 446   lib/nettle/Makefile
 447   lib/opencdk/Makefile
 448   lib/openpgp/Makefile
 449   lib/x509/Makefile
 450   po/Makefile.in
 451   src/Makefile
 452   src/crywrap/Makefile
 453   tests/Makefile
 454   tests/cert-tests/Makefile
 455   tests/dsa/Makefile
 456   tests/ecdsa/Makefile
 457   tests/key-id/Makefile
 458   tests/openpgp-certs/Makefile
 459   tests/pkcs1-padding/Makefile
 460   tests/pkcs12-decode/Makefile
 461   tests/pkcs8-decode/Makefile
 462   tests/rsa-md5-collision/Makefile
 463   tests/safe-renegotiation/Makefile
 464   tests/scripts/Makefile
 465   tests/sha2/Makefile
 466   tests/slow/Makefile
 467   tests/suite/Makefile
 468   tests/userid/Makefile
 469 ])
 470
 471 AC_OUTPUT
 472
 473 AC_MSG_NOTICE([summary of build options:
 474
 475   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 476   Host type:        ${host}
 477   Install prefix:   ${prefix}
 478   Compiler:         ${CC}
 479   CFlags:           ${CFLAGS}
 480   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 481   Library types:    Shared=${enable_shared}, Static=${enable_static}
 482   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 483   Guile wrappers:   $opt_guile_bindings
 484   C++ library:      $use_cxx
 485   OpenSSL compat:   $enable_openssl
 486   /dev/crypto:      $enable_cryptodev
 487   Hardware accel:   $hw_accel
 488   Crypto library:   $cryptolib
 489   PKCS#11 support:  $with_p11_kit
 490   crywrap app:      $libidn
 491   OCSP support:     $ac_enable_ocsp
 492 ])