configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.50)
   3 AC_INIT
   4
   5 AC_PREFIX_DEFAULT(/usr/local)
   6
   7 AC_CANONICAL_TARGET([])
   8 AC_DEFINE_UNQUOTED(T_CPU, "$target_cpu")
   9 AC_DEFINE_UNQUOTED(T_VENDOR, "$target_vendor")
  10 AC_DEFINE_UNQUOTED(T_OS, "$target_os")
  11
  12 dnl Gnutls Version
  13 GNUTLS_MAJOR_VERSION=0
  14 GNUTLS_MINOR_VERSION=4
  15 GNUTLS_MICRO_VERSION=2
  16 GNUTLS_VERSION=$GNUTLS_MAJOR_VERSION.$GNUTLS_MINOR_VERSION.$GNUTLS_MICRO_VERSION
  17
  18 AC_DEFINE_UNQUOTED(GNUTLS_VERSION, "$GNUTLS_VERSION")
  19
  20 AM_INIT_AUTOMAKE(gnutls, $GNUTLS_VERSION)
  21 AM_CONFIG_HEADER(config.h)
  22
  23 dnl This is the library version
  24 GNUTLS_MOST_RECENT_INTERFACE=5
  25 GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER=$GNUTLS_MICRO_VERSION
  26 GNUTLS_OLDEST_INTERFACE=4
  27
  28
  29 AC_SUBST(GNUTLS_MAJOR_VERSION)
  30 AC_SUBST(GNUTLS_MINOR_VERSION)
  31 AC_SUBST(GNUTLS_MICRO_VERSION)
  32 AC_SUBST(GNUTLS_VERSION)
  33
  34 AC_SUBST(GNUTLS_MOST_RECENT_INTERFACE)
  35 AC_SUBST(GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER)
  36 AC_SUBST(GNUTLS_OLDEST_INTERFACE)
  37
  38 LT_CURRENT=$GNUTLS_MOST_RECENT_INTERFACE
  39 LT_REVISION=$GNUTLS_CURRENT_INTERFACE_IMPLEMENTATION_NUMBER
  40 LT_AGE=`expr $GNUTLS_MOST_RECENT_INTERFACE - $GNUTLS_OLDEST_INTERFACE`
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 opt_dmalloc_mode=no
  46 AC_MSG_CHECKING([whether in dmalloc mode])
  47 AC_ARG_ENABLE(dmalloc-mode,
  48 [  --enable-dmalloc-mode      enable dmalloc mode],
  49 opt_dmalloc_mode=$enableval)
  50 AC_MSG_RESULT($opt_dmalloc_mode)
  51
  52 opt_efence_mode=no
  53 AC_MSG_CHECKING([whether in electric fence mode])
  54 AC_ARG_ENABLE(efence-mode,
  55 [  --enable-efence-mode       enable electric fence mode],
  56 opt_efence_mode=$enableval)
  57 AC_MSG_RESULT($opt_efence_mode)
  58
  59 opt_maintainer_mode=no
  60 AC_MSG_CHECKING([whether in maintanance mode])
  61 AC_ARG_ENABLE(maintainer-mode,
  62 [  --enable-maintainer-mode   enable maintainer mode],
  63 opt_maintainer_mode=$enableval)
  64 AC_MSG_RESULT($opt_maintainer_mode)
  65
  66 opt_profiler_mode=no
  67 AC_MSG_CHECKING([whether in profile mode])
  68 AC_ARG_ENABLE(profile-mode,
  69 [  --enable-profile-mode      enable profiler],
  70 opt_profiler_mode=$enableval)
  71 AC_MSG_RESULT($opt_profiler_mode)
  72
  73 AC_MSG_RESULT([***
  74 *** Checking for compilation programs...
  75 ])
  76
  77 AC_PROG_CC
  78
  79 AC_PROG_YACC
  80
  81 AC_PROG_LN_S
  82
  83
  84 dnl Checks for programs.
  85 AC_PROG_INSTALL
  86
  87 dnl AC_PROG_MAKE_SET
  88
  89
  90 AC_MSG_RESULT([***
  91 *** Detecting compiler options...
  92 ])
  93
  94
  95 AC_C_CONST
  96 AC_C_INLINE
  97
  98
  99 if test $ac_cv_c_compiler_gnu != no; then
 100
 101         if test x$opt_maintainer_mode = xyes; then
 102
 103           CFLAGS="${CFLAGS} -O0 -ggdb3 -Wall -Wpointer-arith -Wstrict-prototypes" # -Werror
 104         else
 105           CFLAGS="${CFLAGS} -O2 -fexpensive-optimizations -fomit-frame-pointer"
 106         fi
 107
 108         if test x$opt_dmalloc_mode = xyes; then
 109           AC_CHECK_LIB( dmalloc, main)
 110           AC_DEFINE(USE_DMALLOC)
 111           AC_DEFINE(USE_LIBCALLOC)
 112         else
 113                 if test x$opt_efence_mode = xyes; then
 114                   AC_CHECK_LIB( efence, main)
 115                   AC_DEFINE(USE_EFENCE)
 116                   AC_DEFINE(USE_LIBCALLOC)
 117                 fi
 118         fi
 119
 120
 121         AC_MSG_CHECKING([whether we have GNU assembler])
 122
 123         GAS=`as --version < /dev/null|grep GNU`
 124         if test "$GAS"; then
 125           CFLAGS="${CFLAGS} -pipe"
 126           AC_MSG_RESULT(yes)
 127         else
 128           AC_MSG_RESULT(no)
 129         fi
 130 fi
 131
 132
 133 AC_MSG_RESULT([***
 134 *** Detecting C library capabilities...
 135 ])
 136
 137 AC_HEADER_STDC
 138 AC_HEADER_TIME
 139 AC_CHECK_HEADERS(unistd.h pwd.h locale.h strings.h stdarg.h)
 140 AC_CHECK_HEADERS(sys/stat.h sys/types.h sys/socket.h)
 141 AC_CHECK_HEADERS(errno.h sys/time.h time.h)
 142 AC_CHECK_FUNCS(bzero memset memmove bcopy,,)
 143 AC_FUNC_ALLOCA
 144
 145
 146 AC_MSG_RESULT([***
 147 *** Detecting system's parameters...
 148 ])
 149
 150 AC_CHECK_SIZEOF(unsigned long long, 8)
 151 AC_CHECK_SIZEOF(unsigned long int, 4)
 152 AC_CHECK_SIZEOF(unsigned int, 4)
 153 AC_CHECK_SIZEOF(unsigned short int, 2)
 154 AC_CHECK_SIZEOF(unsigned char, 1)
 155
 156 AC_CHECK_TYPE(size_t,
 157 DEFINE_SIZE_T="#include <sys/types.h>"
 158 AC_SUBST( DEFINE_SIZE_T)
 159 ,
 160 AC_DEFINE(NO_SIZE_T)
 161 DEFINE_SIZE_T="typedef unsigned int size_t; typedef int ssize_t;"
 162 AC_SUBST( DEFINE_SIZE_T)
 163 ,[
 164 #ifdef HAVE_SYS_TYPES_H
 165 # include <sys/types.h>
 166 #endif
 167 #ifdef HAVE_UNISTD_H
 168 # include <unistd.h>
 169 #endif
 170 ])
 171
 172
 173 AC_CHECK_TYPE(time_t,
 174  DEFINE_TIME_T="#include <time.h>"
 175  AC_SUBST( DEFINE_TIME_T)
 176  ,
 177   AC_CHECK_TYPE(time_t,
 178    DEFINE_TIME_T="#include <sys/time.h>"
 179    AC_SUBST( DEFINE_TIME_T)
 180    ,
 181     DEFINE_TIME_T="typedef unsigned int time_t;"
 182     AC_SUBST( DEFINE_TIME_T)
 183     AC_DEFINE(NO_TIME_T),
 184   [
 185    #include <sys/time.h>
 186   ]
 187   )
 188 ,
 189 [
 190  #include <time.h>
 191 ]
 192 )
 193
 194 AC_C_BIGENDIAN
 195
 196
 197 AC_MSG_RESULT([***
 198 *** Checking for external libraries...
 199 ])
 200
 201 AM_PATH_LIBGCRYPT(1.1.7,,
 202         AC_MSG_ERROR([[
 203 ***
 204 *** libgcrypt was not found. You may want to get it from
 205 *** ftp://ftp.gnupg.org/pub/gcrypt/alpha/libgcrypt/
 206 ***
 207 ]]))
 208 dnl Can't disable - gnutls depends on gcrypt
 209 AC_DEFINE(USE_GCRYPT)
 210
 211 dnl MCRYPT
 212
 213 AC_ARG_WITH( mcrypt, [  --with-mcrypt           enable libmcrypt support],
 214  [AM_PATH_LIBMCRYPT( 2.4.0,,
 215         AC_MSG_ERROR([[*** libmcrypt was not found]])
 216     AC_MSG_ERROR([[*** You need libmcrypt 2.4.x to compile this program. http://mcrypt.hellug.gr]])
 217  )
 218  ]
 219 )
 220
 221 LIBS="${LIBS} ${LIBMCRYPT_LIBS}"
 222
 223 AC_ARG_WITH( mhash, [  --with-mhash            enable libmhash support],
 224  [AC_CHECK_LIB(mhash, mhash_init, AC_DEFINE(USE_MHASH)
 225 LIBS="${LIBS} -lmhash")])
 226
 227 AC_MSG_CHECKING([whether to check for external libraries])
 228
 229 dnl if used --without-ext-libraries then we will not check
 230 dnl for any library (libz, libgdbm)
 231
 232 AC_ARG_WITH( ext-libraries, [  --without-ext-libraries disable external libraries support],
 233  ac_ext_libraries=$withval
 234 )
 235
 236 if test x$ac_ext_libraries != xno; then
 237  AC_MSG_RESULT(yes)
 238  AC_CHECK_LIB(gdbm, gdbm_open,, AC_MSG_WARN(
 239 ***
 240 *** GDBM was not found. You will not be able to use the default gdbm session resumption backend.))
 241  AC_CHECK_LIB(z, compress,,AC_MSG_WARN(
 242 ***
 243 *** ZLIB was not found. You will not be able to use ZLIB compression.))
 244 else
 245  AC_MSG_RESULT()
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable SRP authentication support])
 249 AC_ARG_ENABLE( srp-authentication, [  --disable-srp-authentication     disable the SRP authentication support],
 250  ac_enable_srp=no
 251 )
 252 if test x$ac_enable_srp != xno; then
 253  AC_MSG_RESULT(no)
 254  AC_DEFINE(ENABLE_SRP)
 255 else
 256  AC_MSG_RESULT(yes)
 257 fi
 258
 259 AC_MSG_CHECKING([whether to disable anonymous authentication support])
 260 AC_ARG_ENABLE( anon-authentication, [  --disable-anon-authentication    disable the anonymous authentication support],
 261  ac_enable_anon=no
 262 )
 263 if test x$ac_enable_anon != xno; then
 264  AC_MSG_RESULT(no)
 265  AC_DEFINE(ENABLE_ANON)
 266 else
 267  AC_MSG_RESULT(yes)
 268 fi
 269
 270
 271 AC_MSG_CHECKING([whether to disable OpenPGP Certificate authentication support])
 272 AC_ARG_ENABLE( openpgp-authentication, [  --disable-openpgp-authentication disable the OpenPGP authentication support],
 273  ac_enable_openpgp=no
 274 )
 275 if test x$ac_enable_openpgp != xno; then
 276  AC_MSG_RESULT(no)
 277  AM_PATH_LIBOPENCDK( 0.1.0, AC_DEFINE(HAVE_LIBOPENCDK),
 278  AC_MSG_WARN([[
 279 ***
 280 *** libopencdk was not found. You will not be able to use OpenPGP keys with gnutls.
 281 ]]))
 282 else
 283  AC_MSG_RESULT(yes)
 284 fi
 285
 286
 287
 288
 289
 290 AC_MSG_RESULT([***
 291 *** Detecting options for shared libraries...
 292 ])
 293 AM_PROG_LIBTOOL
 294
 295 LIBGNUTLS_LIBS="$LIBS -L${libdir} -lgnutls $LIBGCRYPT_LIBS"
 296 LIBGNUTLS_CFLAGS="$LIBGCRYPT_CFLAGS -I${includedir}"
 297
 298 AC_SUBST(LIBGNUTLS_LIBS)
 299 AC_SUBST(LIBGNUTLS_CFLAGS)
 300
 301
 302 LIBGNUTLS_EXTRA_LIBS="-L${libdir} -lgnutls-extra -lgnutls $LIBOPENCDK_LIBS"
 303 LIBGNUTLS_EXTRA_CFLAGS="$LIBOPENCDK_CFLAGS -I${includedir}"
 304
 305 AC_SUBST(LIBGNUTLS_EXTRA_LIBS)
 306 AC_SUBST(LIBGNUTLS_EXTRA_CFLAGS)
 307
 308 if test $ac_cv_c_compiler_gnu != no; then
 309
 310         if test x$opt_profiler_mode = xyes; then
 311           CFLAGS="${CFLAGS} -O0 `fc-config --cflags`"
 312           AC_CHECK_PROG(FC_OK, fc-config, yes, no)
 313           if test x$FC_OK = xyes; then
 314                 LIBS="$LIBS `fc-config --libs`"
 315           else
 316 AC_MSG_WARN(***
 317 *** You must install libfc in order to enable profiling. http://www710.univ-lyon1.fr/~yperret/fnccheck/profiler.html
 318 )
 319           fi
 320         fi
 321 fi
 322
 323 AC_CONFIG_FILES(lib/gnutls.h.in)
 324
 325 AC_CONFIG_COMMANDS([lib/gnutls.h],[[
 326  test -f lib/gnutls.h.in || (echo "Could not generate lib/gnutls.h" && exit 1)
 327  cat lib/gnutls.h.in > lib/gnutls.h
 328  cat lib/gnutls_ui.h >> lib/gnutls.h
 329  echo "" >> lib/gnutls.h
 330  cat lib/gnutls_errors_int.h | grep -v _INT_ >> lib/gnutls.h
 331  echo "" >> lib/gnutls.h
 332  cat lib/x509_asn1.h >> lib/gnutls.h
 333  echo "" >> lib/gnutls.h
 334  echo "#ifdef __cplusplus" >> lib/gnutls.h
 335  echo "}" >> lib/gnutls.h
 336  echo "#endif" >> lib/gnutls.h
 337  echo "#endif /* GNUTLS_H */" >> lib/gnutls.h
 338  echo "" >> lib/gnutls.h
 339  chmod +x lib/libgnutls-config
 340  chmod +x libextra/libgnutls-extra-config
 341 ]],[[]])
 342
 343 AC_CONFIG_FILES([Makefile src/Makefile libextra/Makefile lib/Makefile \
 344 lib/libgnutls-config libextra/libgnutls-extra-config \
 345 doc/Makefile src/x509/Makefile src/srp/Makefile src/openpgp/Makefile \
 346 doc/tex/Makefile doc/tex/cover.tex doc/scripts/Makefile ])
 347
 348
 349 AC_OUTPUT
 350