configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.0.16], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *darwin*)
  71     have_macosx=yes
  72   ;;
  73   *)
  74     have_elf=yes
  75   ;;
  76 esac
  77
  78 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  79 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
  80 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
  81
  82 dnl Hardware Acceleration
  83 AC_ARG_ENABLE(hardware-acceleration,
  84   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  85     use_accel=$enableval, use_accel=yes)
  86 hw_accel=none
  87
  88
  89 if test "$use_accel" != "no"; then
  90 case $host_cpu in
  91   i?86 | x86_64 | amd64)
  92 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  93 dnl    if test "x$X86" = "xyes";then
  94       AC_CHECK_HEADERS(cpuid.h)
  95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  96         hw_accel="x86-64"
  97       else
  98         hw_accel="x86"
  99       fi
 100 dnl    fi
 101   ;;
 102   *)
 103   ;;
 104 esac
 105
 106 fi
 107
 108 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 109 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 110 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 111 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 112 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 113
 114 dnl Try the hooks.m4
 115 LIBGNUTLS_HOOKS
 116 LIBGNUTLS_EXTRA_HOOKS
 117
 118 GTK_DOC_CHECK(1.1)
 119 AM_GNU_GETTEXT([external])
 120 AM_GNU_GETTEXT_VERSION([0.18])
 121
 122 AC_C_BIGENDIAN
 123
 124
 125
 126 dnl No fork on MinGW, disable some self-tests until we fix them.
 127 AC_CHECK_FUNCS([fork getrusage getpwuid_r daemon fchmod],,)
 128 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 129 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 130
 131 dnl Check for p11-kit
 132 AC_ARG_WITH(p11-kit,
 133         AS_HELP_STRING([--without-p11-kit],
 134                 [Build without p11-kit and PKCS#11 support]))
 135 if test "$with_p11_kit" != "no"; then
 136         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
 137         if test "$with_p11_kit" != "no";then
 138                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 139                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 140                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 141                 else
 142                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 143                 fi
 144         else
 145                 with_p11_kit=no
 146                 AC_MSG_WARN([[
 147 ***
 148 *** p11-kit was not found. PKCS #11 support will be disabled.
 149 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 150 *** ]])
 151         fi
 152 fi
 153
 154 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 155
 156 dnl Checks for programs in src/
 157 PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
 158
 159 NEED_LIBOPTS_DIR=true
 160 LIBOPTS_CHECK([src/libopts])
 161
 162 AC_CHECK_TYPE(ssize_t,
 163   [
 164     DEFINE_SSIZE_T="#include <sys/types.h>"
 165     AC_SUBST(DEFINE_SSIZE_T)
 166   ], [
 167     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 168     DEFINE_SSIZE_T="typedef int ssize_t;"
 169     AC_SUBST(DEFINE_SSIZE_T)
 170   ], [
 171     #include <sys/types.h>
 172   ])
 173
 174 # For minitasn1.
 175 AC_CHECK_SIZEOF(unsigned long int, 4)
 176 AC_CHECK_SIZEOF(unsigned int, 4)
 177
 178 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 179                                  [disable zlib compression support]),
 180             ac_zlib=$withval, ac_zlib=yes)
 181 AC_MSG_CHECKING([whether to include zlib compression support])
 182 if test x$ac_zlib != xno; then
 183  AC_MSG_RESULT(yes)
 184  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 185  if test x$ac_cv_libz != xyes; then
 186    AC_MSG_WARN(
 187 ***
 188 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 189  fi
 190 else
 191  AC_MSG_RESULT(no)
 192 fi
 193
 194 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 195
 196 if test x$ac_zlib != xno; then
 197   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 198     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 199       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 200     else
 201       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 202     fi
 203   else
 204     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 205   fi
 206 fi
 207 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 208 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 209
 210
 211 gl_INIT
 212
 213 dnl GCC warnings to enable
 214
 215 AC_ARG_ENABLE([gcc-warnings],
 216   [AS_HELP_STRING([--enable-gcc-warnings],
 217                   [turn on lots of GCC warnings (for developers)])],
 218   [case $enableval in
 219      yes|no) ;;
 220      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 221    esac
 222    gl_gcc_warnings=$enableval],
 223   [gl_gcc_warnings=no]
 224 )
 225
 226 if test "$gl_gcc_warnings" = yes; then
 227   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 228   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 229
 230   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 231   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 232   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 233   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 234   nw="$nw -Wlogical-op"             # Too many false positives
 235   nw="$nw -Wold-style-definition"   #
 236   nw="$nw -Wpadded"                 # Our structs are not padded
 237   nw="$nw -Wunreachable-code"       # Too many false positives
 238   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 239   nw="$nw -Wcast-qual"              # Too many warnings for now
 240   nw="$nw -Waggregate-return"       # Too many warnings for now
 241   nw="$nw -Wshadow"                 # Too many warnings for now
 242   nw="$nw -Wswitch-default"         # Too many warnings for now
 243   nw="$nw -Wswitch-enum"            # Too many warnings for now
 244   nw="$nw -Wconversion"             # Too many warnings for now
 245   nw="$nw -Wsign-conversion"        # Too many warnings for now
 246   nw="$nw -Wformat-y2k"             # Too many warnings for now
 247   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 248   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 249   nw="$nw -Wunsafe-loop-optimizations"
 250   nw="$nw -Wstrict-overflow"
 251   nw="$nw -Wmissing-noreturn"
 252
 253   gl_MANYWARN_ALL_GCC([ws])
 254   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 255   for w in $ws; do
 256     gl_WARN_ADD([$w])
 257   done
 258
 259   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 260   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 261   gl_WARN_ADD([-Wno-suggest-attribute=pure])     # Too many warnings for now
 262   gl_WARN_ADD([-Wno-suggest-attribute=const])     # Too many warnings for now
 263   gl_WARN_ADD([-Wno-suggest-attribute=noreturn])     # Too many warnings for now
 264   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 265   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 266   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 267   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 268   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 269   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 270   gl_WARN_ADD([-Wno-redundant-decls])  # Some files cannot be compiled with that (gl_fd_to_handle)
 271   gl_WARN_ADD([-fdiagnostics-show-option])
 272 fi
 273
 274 AC_SUBST([WERROR_CFLAGS])
 275 AC_SUBST([WSTACK_CFLAGS])
 276 AC_SUBST([WARN_CFLAGS])
 277
 278 dnl Programs for compilation or development
 279 AC_PROG_LN_S
 280 AC_LIBTOOL_WIN32_DLL
 281 AC_PROG_LIBTOOL
 282
 283 dnl Guile bindings.
 284 opt_guile_bindings=yes
 285 AC_MSG_CHECKING([whether building Guile bindings])
 286 AC_ARG_ENABLE(guile,
 287         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 288 opt_guile_bindings=$enableval)
 289 AC_MSG_RESULT($opt_guile_bindings)
 290
 291 AC_ARG_WITH([--with-guile-site-dir],
 292   [AS_HELP_STRING([--with-guile-site-dir],
 293      [use the given directory as the Guile site (use with care)])])
 294
 295 if test "$opt_guile_bindings" = "yes"; then
 296    AC_MSG_RESULT([***
 297 *** Detecting GNU Guile...
 298 ])
 299
 300    AC_PATH_PROG([guile_snarf], [guile-snarf])
 301    if test "x$guile_snarf" = "x"; then
 302       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 303       opt_guile_bindings=no
 304    else
 305       GUILE_PROGS
 306       GUILE_FLAGS
 307
 308       save_CFLAGS="$CFLAGS"
 309       save_LIBS="$LIBS"
 310       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 311       LIBS="$LIBS $GUILE_LDFLAGS"
 312       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 313       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 314         [], [opt_guile_bindings=no])
 315       CFLAGS="$save_CFLAGS"
 316       LIBS="$save_LIBS"
 317
 318       if test "$opt_guile_bindings" = "yes"; then
 319         AC_MSG_RESULT([yes])
 320         case "x$with_guile_site_dir" in
 321              xno)
 322                 # Use the default $(GUILE_SITE).
 323                 GUILE_SITE_DIR
 324                 ;;
 325              x|xyes)
 326                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 327                 # hack is used to allow `distcheck' to work (see
 328                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 329                 GUILE_SITE="\$(datadir)/guile/site"
 330                 AC_SUBST(GUILE_SITE)
 331                 ;;
 332              *)
 333                 # Use the user-specified directory as $(GUILE_SITE).
 334                 GUILE_SITE="$with_guile_site_dir"
 335                 AC_SUBST(GUILE_SITE)
 336                 ;;
 337         esac
 338         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 339         _gcc_cflags_save="$CFLAGS"
 340         CFLAGS="${CFLAGS} -fgnu89-inline"
 341         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 342                           gnu89_inline=yes, gnu89_inline=no)
 343         AC_MSG_RESULT($gnu89_inline)
 344         CFLAGS="$_gcc_cflags_save"
 345
 346         # Optional Guile functions.
 347         save_CFLAGS="$CFLAGS"
 348         save_LIBS="$LIBS"
 349         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 350         LIBS="$LIBS $GUILE_LDFLAGS"
 351         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 352         CFLAGS="$save_CFLAGS"
 353         LIBS="$save_LIBS"
 354
 355         # The place where guile-gnutls.la will go.
 356         AC_MSG_CHECKING([the Guile effective version])
 357         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 358         AC_MSG_RESULT([$guile_effective_version])
 359         guileextensiondir="$libdir/guile/$guile_effective_version"
 360         AC_SUBST([guileextensiondir])
 361       else
 362         AC_MSG_RESULT([no])
 363         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 364         opt_guile_bindings=no
 365       fi
 366    fi
 367 fi
 368 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 369
 370 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 371 LIBGNUTLS_CFLAGS="-I${includedir}"
 372 AC_SUBST(LIBGNUTLS_LIBS)
 373 AC_SUBST(LIBGNUTLS_CFLAGS)
 374
 375
 376 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 377 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 378
 379 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 380 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 381 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 382
 383 dnl Crywrap dependencies
 384    AC_MSG_RESULT([***
 385 *** Checking dependencies for crywrap...
 386 ])
 387
 388 crywrap=no
 389
 390 if test "$have_win" != "yes"; then
 391
 392 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 393
 394 dnl **********************
 395 dnl * Typedefs & co
 396 dnl **********************
 397 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 398 [AC_LANG_PROGRAM([#include <sys/types.h>
 399 #include <signal.h>
 400 ],
 401                  [return *(signal (0, 0)) (0) == 1;])],
 402                    [ac_cv_type_signal=int],
 403                    [ac_cv_type_signal=void])])
 404 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 405                     (`int' or `void').])
 406
 407 AC_FUNC_SELECT_ARGTYPES
 408 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 409                 putenv regcomp scandir select socket strcasecmp strchr \
 410                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 411
 412 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 413
 414  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
 415   crywrap=yes
 416  fi
 417
 418 fi
 419
 420 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 421 rm -f suppressions.valgrind
 422 dnl end of crywrap requirements
 423
 424 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 425 AC_CONFIG_FILES([
 426   Makefile
 427   doc/Makefile
 428   doc/credentials/Makefile
 429   doc/credentials/openpgp/Makefile
 430   doc/credentials/srp/Makefile
 431   doc/credentials/x509/Makefile
 432   doc/cyclo/Makefile
 433   doc/doxygen/Doxyfile
 434   doc/examples/Makefile
 435   doc/latex/Makefile
 436   doc/manpages/Makefile
 437   doc/reference/Makefile
 438   doc/reference/version.xml
 439   doc/scripts/Makefile
 440   extra/Makefile
 441   extra/includes/Makefile
 442   gl/Makefile
 443   gl/tests/Makefile
 444   guile/Makefile
 445   guile/modules/Makefile
 446   guile/src/Makefile
 447   guile/tests/Makefile
 448   lib/Makefile
 449   lib/accelerated/Makefile
 450   lib/accelerated/x86/Makefile
 451   lib/algorithms/Makefile
 452   lib/auth/Makefile
 453   lib/ext/Makefile
 454   lib/extras/Makefile
 455   lib/gnutls.pc
 456   lib/includes/Makefile
 457   lib/includes/gnutls/gnutls.h
 458   lib/minitasn1/Makefile
 459   lib/nettle/Makefile
 460   lib/opencdk/Makefile
 461   lib/openpgp/Makefile
 462   lib/x509/Makefile
 463   po/Makefile.in
 464   src/Makefile
 465   src/crywrap/Makefile
 466   tests/Makefile
 467   tests/cert-tests/Makefile
 468   tests/dsa/Makefile
 469   tests/dtls/Makefile
 470   tests/srp/Makefile
 471   tests/ecdsa/Makefile
 472   tests/key-id/Makefile
 473   tests/openpgp-certs/Makefile
 474   tests/pkcs1-padding/Makefile
 475   tests/pkcs12-decode/Makefile
 476   tests/pkcs8-decode/Makefile
 477   tests/rsa-md5-collision/Makefile
 478   tests/safe-renegotiation/Makefile
 479   tests/scripts/Makefile
 480   tests/sha2/Makefile
 481   tests/slow/Makefile
 482   tests/suite/Makefile
 483   tests/userid/Makefile
 484 ])
 485
 486 AC_OUTPUT
 487
 488 AC_MSG_NOTICE([summary of build options:
 489
 490   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 491   Host type:        ${host}
 492   Install prefix:   ${prefix}
 493   Compiler:         ${CC}
 494   CFlags:           ${CFLAGS}
 495   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 496   Library types:    Shared=${enable_shared}, Static=${enable_static}
 497   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 498 ])
 499
 500 AC_MSG_NOTICE([Optional features:
 501 (note that included applications might not compile properly
 502 if features are disabled)
 503
 504   OCSP support:     $ac_enable_ocsp
 505   OpenPGP support:  $ac_enable_openpgp
 506   SRP support:      $ac_enable_srp
 507   PSK support:      $ac_enable_psk
 508   Anon auth support:$ac_enable_anon
 509 ])
 510
 511 AC_MSG_NOTICE([Optional applications:
 512
 513   crywrap app:      $libidn
 514   local libopts:    $enable_local_libopts
 515 ])
 516
 517 AC_MSG_NOTICE([Optional libraries:
 518
 519   Guile wrappers:   $opt_guile_bindings
 520   C++ library:      $use_cxx
 521   OpenSSL compat:   $enable_openssl
 522 ])
 523
 524 AC_MSG_NOTICE([Hardware acceleration/support:
 525
 526   /dev/crypto:      $enable_cryptodev
 527   Hardware accel:   $hw_accel
 528   PKCS#11 support:  $with_p11_kit
 529 ])