configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2011 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.0.5], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52 AC_DEFINE([HAVE_STRINGS_H], 1, [Hard-code for src/cfg/.])
  53 AC_DEFINE([HAVE_FLOAT_H], 1, [Hard-code for src/cfg/.])
  54 AC_DEFINE([HAVE_LIMITS_H], 1, [Hard-code for src/cfg/.])
  55 AC_DEFINE([HAVE_MATH_H], 1, [Hard-code for src/cfg/.])
  56 AC_DEFINE([HAVE_CTYPE_H], 1, [Hard-code for src/cfg/.])
  57 AC_DEFINE([HAVE_ERRNO_H], 1, [Hard-code for src/cfg/.])
  58
  59 # For the C++ code
  60 AC_ARG_ENABLE(cxx,
  61   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  62     use_cxx=$enableval, use_cxx=yes)
  63 if test "$use_cxx" != "no"; then
  64   AC_LANG_PUSH(C++)
  65   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  66   AC_LANG_POP(C++)
  67 fi
  68 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  69 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  70
  71 dnl Detect windows build
  72 case "$host" in
  73   *mingw32* | *mingw64*)
  74     have_win=yes
  75   ;;
  76   *)
  77   ;;
  78 esac
  79
  80 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  81
  82 dnl Hardware Acceleration
  83 AC_ARG_ENABLE(hardware-acceleration,
  84   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  85     use_accel=$enableval, use_accel=yes)
  86 hw_accel=none
  87
  88
  89 if test "$use_accel" != "no"; then
  90 case $host_cpu in
  91   i?86 | x86_64 | amd64)
  92 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  93 dnl    if test "x$X86" = "xyes";then
  94       AC_CHECK_HEADERS(cpuid.h)
  95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  96         hw_accel="x86-64"
  97       else
  98         hw_accel="x86"
  99       fi
 100 dnl    fi
 101   ;;
 102   *)
 103   ;;
 104 esac
 105
 106 fi
 107
 108 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 109 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 110 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" -o x"$hw_accel" = x"x86-64")
 111 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 112 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 113
 114 dnl Try the hooks.m4
 115 LIBGNUTLS_HOOKS
 116 LIBGNUTLS_EXTRA_HOOKS
 117
 118 GTK_DOC_CHECK(1.1)
 119 AM_GNU_GETTEXT([external])
 120 AM_GNU_GETTEXT_VERSION([0.17])
 121
 122 AC_C_BIGENDIAN
 123
 124
 125
 126 dnl Checks for functions
 127
 128 dnl No fork on MinGW, disable some self-tests until we fix them.
 129 AC_CHECK_FUNCS(fork,,)
 130 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 131 AC_CHECK_FUNCS(getrusage,,)
 132 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 133
 134 dnl Check for p11-kit
 135 AC_ARG_WITH(p11-kit,
 136         AS_HELP_STRING([--without-p11-kit],
 137                 [Build without p11-kit and PKCS#11 support]))
 138 if test "$with_p11_kit" != "no"; then
 139         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.4], [with_p11_kit=yes], [with_p11_kit=no])
 140         if test "$with_p11_kit" != "no";then
 141                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 142                 CFLAGS="$CFLAGS $P11_KIT_CFLAGS"
 143                 LIBS="$LIBS $P11_KIT_LIBS"
 144                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 145                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 146                 else
 147                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 148                 fi
 149         else
 150                 with_p11_kit=no
 151                 AC_MSG_WARN([[
 152 ***
 153 *** p11-kit was not found. PKCS #11 support will be disabled.
 154 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 155 *** ]])
 156         fi
 157 fi
 158
 159 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 160
 161 dnl Check for libcfg+
 162 SAVED_LIBS=$LIBS
 163 AC_ARG_WITH(included-libcfg,
 164         AS_HELP_STRING([--with-included-libcfg],
 165                 [use the included libcfg+ (certtool only)]),
 166         libcfg_enabled=$withval,
 167         libcfg_enabled=no
 168 dnl We search for libcfg+ which is used by certtool
 169 dnl
 170         AC_CHECK_LIB(cfg+, cfg_get_context,:,
 171                      libcfg_enabled=yes
 172                      AC_MSG_WARN([[
 173 ***
 174 *** Libcfg+ was not found. Will use the included one.]])))
 175
 176 AM_CONDITIONAL(HAVE_LIBCFG, test "$libcfg_enabled" = "no")
 177 LIBS=$SAVED_LIBS
 178
 179 AC_MSG_CHECKING([whether to use the included libcfg])
 180 AC_MSG_RESULT($libcfg_enabled)
 181
 182 AC_CHECK_TYPE(ssize_t,
 183   [
 184     DEFINE_SSIZE_T="#include <sys/types.h>"
 185     AC_SUBST(DEFINE_SSIZE_T)
 186   ], [
 187     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 188     DEFINE_SSIZE_T="typedef int ssize_t;"
 189     AC_SUBST(DEFINE_SSIZE_T)
 190   ], [
 191     #include <sys/types.h>
 192   ])
 193
 194 # For minitasn1.
 195 AC_CHECK_SIZEOF(unsigned long int, 4)
 196 AC_CHECK_SIZEOF(unsigned int, 4)
 197
 198 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 199                                  [disable zlib compression support]),
 200             ac_zlib=$withval, ac_zlib=yes)
 201 AC_MSG_CHECKING([whether to include zlib compression support])
 202 if test x$ac_zlib != xno; then
 203  AC_MSG_RESULT(yes)
 204  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 205  if test x$ac_cv_libz != xyes; then
 206    AC_MSG_WARN(
 207 ***
 208 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 209  fi
 210 else
 211  AC_MSG_RESULT(no)
 212 fi
 213
 214 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 215
 216 if test x$ac_zlib != xno; then
 217   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 218     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 219       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 220     else
 221       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE , zlib"
 222     fi
 223   else
 224     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 225   fi
 226 fi
 227 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 228 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 229
 230
 231 gl_INIT
 232
 233 dnl GCC warnings to enable
 234
 235 AC_ARG_ENABLE([gcc-warnings],
 236   [AS_HELP_STRING([--enable-gcc-warnings],
 237                   [turn on lots of GCC warnings (for developers)])],
 238   [case $enableval in
 239      yes|no) ;;
 240      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 241    esac
 242    gl_gcc_warnings=$enableval],
 243   [gl_gcc_warnings=no]
 244 )
 245
 246 if test "$gl_gcc_warnings" = yes; then
 247   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 248   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 249
 250   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 251   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 252   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 253   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 254   nw="$nw -Wlogical-op"             # Too many false positives
 255   nw="$nw -Wold-style-definition"   #
 256   nw="$nw -Wpadded"                 # Our structs are not padded
 257   nw="$nw -Wunreachable-code"       # Too many false positives
 258   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 259   nw="$nw -Wcast-qual"              # Too many warnings for now
 260   nw="$nw -Waggregate-return"       # Too many warnings for now
 261   nw="$nw -Wshadow"                 # Too many warnings for now
 262   nw="$nw -Wswitch-default"         # Too many warnings for now
 263   nw="$nw -Wswitch-enum"            # Too many warnings for now
 264   nw="$nw -Wconversion"             # Too many warnings for now
 265   nw="$nw -Wsign-conversion"        # Too many warnings for now
 266   nw="$nw -Wformat-y2k"             # Too many warnings for now
 267   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 268   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 269   nw="$nw -Wunsafe-loop-optimizations"
 270   nw="$nw -Wstrict-overflow"
 271   nw="$nw -Wmissing-noreturn"
 272
 273   gl_MANYWARN_ALL_GCC([ws])
 274   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 275   for w in $ws; do
 276     gl_WARN_ADD([$w])
 277   done
 278
 279   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 280   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 281   gl_WARN_ADD([-Wno-pointer-sign])     # Too many warnings for now
 282   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 283   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 284   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 285   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 286   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 287   gl_WARN_ADD([-fdiagnostics-show-option])
 288 fi
 289
 290 AC_SUBST([WERROR_CFLAGS])
 291 AC_SUBST([WSTACK_CFLAGS])
 292 AC_SUBST([WARN_CFLAGS])
 293
 294 dnl Programs for compilation or development
 295 AC_PROG_LN_S
 296 AC_LIBTOOL_WIN32_DLL
 297 AC_PROG_LIBTOOL
 298 AC_PATH_PROG([GAA], [gaa])
 299 if test "x$GAA" = "x"; then
 300    AC_MSG_WARN([[***
 301 *** GAA was not found.  It is only needed if you wish to modify
 302 *** the source code or command-line description files.  In this case,
 303 *** you may want to get it from http://gaa.sourceforge.net/ and
 304 *** read doc/README.gaa.
 305 ***]])
 306 fi
 307
 308
 309 dnl Guile bindings.
 310 opt_guile_bindings=yes
 311 AC_MSG_CHECKING([whether building Guile bindings])
 312 AC_ARG_ENABLE(guile,
 313         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 314 opt_guile_bindings=$enableval)
 315 AC_MSG_RESULT($opt_guile_bindings)
 316
 317 AC_ARG_WITH([--with-guile-site-dir],
 318   [AS_HELP_STRING([--with-guile-site-dir],
 319      [use the given directory as the Guile site (use with care)])])
 320
 321 if test "$opt_guile_bindings" = "yes"; then
 322    AC_MSG_RESULT([***
 323 *** Detecting GNU Guile...
 324 ])
 325
 326    AC_PATH_PROG([guile_snarf], [guile-snarf])
 327    if test "x$guile_snarf" = "x"; then
 328       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 329       opt_guile_bindings=no
 330    else
 331       GUILE_PROGS
 332       GUILE_FLAGS
 333
 334       save_CFLAGS="$CFLAGS"
 335       save_LIBS="$LIBS"
 336       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 337       LIBS="$LIBS $GUILE_LDFLAGS"
 338       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 339       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 340         [], [opt_guile_bindings=no])
 341       CFLAGS="$save_CFLAGS"
 342       LIBS="$save_LIBS"
 343
 344       if test "$opt_guile_bindings" = "yes"; then
 345         AC_MSG_RESULT([yes])
 346         case "x$with_guile_site_dir" in
 347              xno)
 348                 # Use the default $(GUILE_SITE).
 349                 GUILE_SITE_DIR
 350                 ;;
 351              x|xyes)
 352                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 353                 # hack is used to allow `distcheck' to work (see
 354                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 355                 GUILE_SITE="\$(datadir)/guile/site"
 356                 AC_SUBST(GUILE_SITE)
 357                 ;;
 358              *)
 359                 # Use the user-specified directory as $(GUILE_SITE).
 360                 GUILE_SITE="$with_guile_site_dir"
 361                 AC_SUBST(GUILE_SITE)
 362                 ;;
 363         esac
 364         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 365         _gcc_cflags_save="$CFLAGS"
 366         CFLAGS="${CFLAGS} -fgnu89-inline"
 367         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 368                           gnu89_inline=yes, gnu89_inline=no)
 369         AC_MSG_RESULT($gnu89_inline)
 370         CFLAGS="$_gcc_cflags_save"
 371
 372         # Optional Guile functions.
 373         save_CFLAGS="$CFLAGS"
 374         save_LIBS="$LIBS"
 375         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 376         LIBS="$LIBS $GUILE_LDFLAGS"
 377         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 378         CFLAGS="$save_CFLAGS"
 379         LIBS="$save_LIBS"
 380       else
 381         AC_MSG_RESULT([no])
 382         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 383         opt_guile_bindings=no
 384       fi
 385    fi
 386 fi
 387 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 388
 389 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 390 LIBGNUTLS_CFLAGS="-I${includedir}"
 391 AC_SUBST(LIBGNUTLS_LIBS)
 392 AC_SUBST(LIBGNUTLS_CFLAGS)
 393
 394
 395 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 396 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 397
 398 dnl Crywrap dependencies
 399    AC_MSG_RESULT([***
 400 *** Checking dependencies for crywrap...
 401 ])
 402
 403 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 404
 405 dnl **********************
 406 dnl * Typedefs & co
 407 dnl **********************
 408 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 409 [AC_LANG_PROGRAM([#include <sys/types.h>
 410 #include <signal.h>
 411 ],
 412                  [return *(signal (0, 0)) (0) == 1;])],
 413                    [ac_cv_type_signal=int],
 414                    [ac_cv_type_signal=void])])
 415 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 416                     (`int' or `void').])
 417
 418 AC_FUNC_SELECT_ARGTYPES
 419 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 420                 putenv regcomp scandir select socket strcasecmp strchr \
 421                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 422
 423 PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 424
 425 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$libidn" != "xno")
 426
 427 dnl end of crywrap requirements
 428
 429 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 430 AC_CONFIG_FILES([
 431   Makefile
 432   doc/Makefile
 433   doc/credentials/Makefile
 434   doc/credentials/openpgp/Makefile
 435   doc/credentials/srp/Makefile
 436   doc/credentials/x509/Makefile
 437   doc/cyclo/Makefile
 438   doc/latex/Makefile
 439   doc/doxygen/Doxyfile
 440   doc/examples/Makefile
 441   doc/manpages/Makefile
 442   doc/reference/Makefile
 443   doc/scripts/Makefile
 444   gl/Makefile
 445   gl/tests/Makefile
 446   guile/Makefile
 447   guile/modules/Makefile
 448   guile/src/Makefile
 449   guile/tests/Makefile
 450   src/Makefile
 451   src/crywrap/Makefile
 452   src/cfg/Makefile
 453   src/cfg/platon/Makefile
 454   src/cfg/platon/str/Makefile
 455   tests/Makefile
 456   tests/key-id/Makefile
 457   tests/dsa/Makefile
 458   tests/scripts/Makefile
 459   tests/openpgp-certs/Makefile
 460   tests/safe-renegotiation/Makefile
 461   tests/pathlen/Makefile
 462   tests/pkcs1-padding/Makefile
 463   tests/pkcs12-decode/Makefile
 464   tests/pkcs8-decode/Makefile
 465   tests/rsa-md5-collision/Makefile
 466   tests/sha2/Makefile
 467   tests/userid/Makefile
 468   extra/Makefile
 469   extra/includes/Makefile
 470   lib/Makefile
 471   lib/gnutls.pc
 472   lib/includes/Makefile
 473   lib/includes/gnutls/gnutls.h
 474   lib/minitasn1/Makefile
 475   lib/opencdk/Makefile
 476   lib/openpgp/Makefile
 477   po/Makefile.in
 478   lib/x509/Makefile
 479   lib/gcrypt/Makefile
 480   lib/nettle/Makefile
 481   tests/suite/Makefile
 482   lib/accelerated/Makefile
 483   lib/accelerated/x86/Makefile
 484   lib/ext/Makefile
 485   lib/algorithms/Makefile
 486   lib/auth/Makefile
 487 ])
 488
 489 AC_OUTPUT
 490
 491 AC_MSG_NOTICE([summary of build options:
 492
 493   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 494   Host type:        ${host}
 495   Install prefix:   ${prefix}
 496   Compiler:         ${CC}
 497   CFlags:           ${CFLAGS}
 498   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 499   Library types:    Shared=${enable_shared}, Static=${enable_static}
 500   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 501   Guile wrappers:   $opt_guile_bindings
 502   C++ library:      $use_cxx
 503   OpenSSL compat:   $enable_openssl
 504   /dev/crypto:      $enable_cryptodev
 505   Hardware accel:   $hw_accel
 506   Crypto library:   $cryptolib
 507   PKCS#11 support:  $with_p11_kit
 508   crywrap app:      $libidn
 509 ])