configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000-2012 Free Software Foundation, Inc.
   3 #
   4 # Author: Nikos Mavrogiannopoulos, Simon Josefsson
   5 #
   6 # This file is part of GnuTLS.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301
  21 # USA
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [3.1.0], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 AM_INIT_AUTOMAKE([1.11.3 no-dist-gzip dist-xz dist-lzip -Wall -Werror -Wno-override])
  29 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AC_MSG_RESULT([***
  33 *** Checking for compilation programs...
  34 ])
  35
  36 dnl Checks for programs.
  37 AC_PROG_CC
  38 AM_PROG_AS
  39 AC_PROG_CXX
  40 gl_EARLY
  41
  42 # For includes/gnutls/gnutls.h.in.
  43 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  44 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  45 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  46 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  47
  48 touch suppressions.valgrind
  49 dnl C and C++ capabilities
  50 AC_C_INLINE
  51 AC_HEADER_STDC
  52
  53 # For the C++ code
  54 AC_ARG_ENABLE(cxx,
  55   AS_HELP_STRING([--disable-cxx], [unconditionally disable the C++ library]),
  56     use_cxx=$enableval, use_cxx=yes)
  57 if test "$use_cxx" != "no"; then
  58   AC_LANG_PUSH(C++)
  59   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
  60   AC_LANG_POP(C++)
  61 fi
  62 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
  63 AM_CONDITIONAL(WANT_TEST_SUITE, [test -f tests/suite/mini-eagain2.c])
  64
  65 dnl Detect windows build
  66 case "$host" in
  67   *mingw32* | *mingw64*)
  68     have_win=yes
  69   ;;
  70   *darwin*)
  71     have_macosx=yes
  72   ;;
  73   *)
  74     have_elf=yes
  75   ;;
  76 esac
  77
  78 AM_CONDITIONAL(WINDOWS, test "$have_win" = yes)
  79 AM_CONDITIONAL(MACOSX, test "$have_macosx" = yes)
  80 AM_CONDITIONAL(ELF, test "$have_elf" = yes)
  81
  82 dnl Hardware Acceleration
  83 AC_ARG_ENABLE(hardware-acceleration,
  84   AS_HELP_STRING([--disable-hardware-acceleration], [unconditionally disable hardware acceleration]),
  85     use_accel=$enableval, use_accel=yes)
  86 hw_accel=none
  87
  88
  89 if test "$use_accel" != "no"; then
  90 case $host_cpu in
  91   i?86 | x86_64 | amd64)
  92 dnl    GCC_FLAG_ADD([-maes -mpclmul],[X86])
  93 dnl    if test "x$X86" = "xyes";then
  94       AC_CHECK_HEADERS(cpuid.h)
  95       if test "$host_cpu" = "x86_64" || test "$host_cpu" = "amd64"; then
  96         hw_accel="x86-64"
  97       else
  98         hw_accel="x86"
  99       fi
 100 dnl    fi
 101   ;;
 102   *)
 103   ;;
 104 esac
 105
 106 fi
 107
 108 AM_CONDITIONAL(ASM_X86_64, test x"$hw_accel" = x"x86-64")
 109 AM_CONDITIONAL(ASM_X86_32, test x"$hw_accel" = x"x86")
 110 AM_CONDITIONAL(ASM_X86, test x"$hw_accel" = x"x86" || test x"$hw_accel" = x"x86-64")
 111 AM_CONDITIONAL(HAVE_GCC_GNU89_INLINE_OPTION, test "$gnu89_inline" = "yes"])
 112 AM_CONDITIONAL(HAVE_GCC, test "$GCC" = "yes")
 113
 114 dnl Try the hooks.m4
 115 LIBGNUTLS_HOOKS
 116 LIBGNUTLS_EXTRA_HOOKS
 117
 118 GTK_DOC_CHECK(1.1)
 119 AM_GNU_GETTEXT([external])
 120 AM_GNU_GETTEXT_VERSION([0.18])
 121
 122 AC_C_BIGENDIAN
 123
 124
 125
 126 dnl No fork on MinGW, disable some self-tests until we fix them.
 127 AC_CHECK_FUNCS([fork getrusage getpwuid_r daemon],,)
 128 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 129 AC_LIB_HAVE_LINKFLAGS(pthread,, [#include <pthread.h>], [pthread_mutex_lock (0);])
 130
 131 dnl Check for p11-kit
 132 AC_ARG_WITH(p11-kit,
 133         AS_HELP_STRING([--without-p11-kit],
 134                 [Build without p11-kit and PKCS#11 support]))
 135 if test "$with_p11_kit" != "no"; then
 136         PKG_CHECK_MODULES(P11_KIT, [p11-kit-1 >= 0.11], [with_p11_kit=yes], [with_p11_kit=no])
 137         if test "$with_p11_kit" != "no";then
 138                 AC_DEFINE([ENABLE_PKCS11], 1, [Build PKCS#11 support])
 139                 if test "x$GNUTLS_REQUIRES_PRIVATE" = "x"; then
 140                         GNUTLS_REQUIRES_PRIVATE="Requires.private: p11-kit-1"
 141                 else
 142                         GNUTLS_REQUIRES_PRIVATE="${GNUTLS_REQUIRES_PRIVATE}, p11-kit-1"
 143                 fi
 144         else
 145                 with_p11_kit=no
 146                 AC_MSG_WARN([[
 147 ***
 148 *** p11-kit was not found. PKCS #11 support will be disabled.
 149 *** You may get it from http://p11-glue.freedesktop.org/p11-kit.html
 150 *** ]])
 151         fi
 152 fi
 153
 154 AM_CONDITIONAL(ENABLE_PKCS11, test "$with_p11_kit" != "no")
 155
 156 enable_local_libopts=yes
 157 dnl PKG_CHECK_MODULES([autoopts], autoopts >= 36.2.11,, [enable_local_libopts=yes])
 158
 159 NEED_LIBOPTS_DIR=true
 160 LIBOPTS_CHECK([src/libopts])
 161
 162 AC_CHECK_TYPE(ssize_t,
 163   [
 164     DEFINE_SSIZE_T="#include <sys/types.h>"
 165     AC_SUBST(DEFINE_SSIZE_T)
 166   ], [
 167     AC_DEFINE([NO_SSIZE_T], 1, [no ssize_t type was found])
 168     DEFINE_SSIZE_T="typedef int ssize_t;"
 169     AC_SUBST(DEFINE_SSIZE_T)
 170   ], [
 171     #include <sys/types.h>
 172   ])
 173
 174 # For minitasn1.
 175 AC_CHECK_SIZEOF(unsigned long int, 4)
 176 AC_CHECK_SIZEOF(unsigned int, 4)
 177
 178 AC_ARG_WITH(zlib, AS_HELP_STRING([--without-zlib],
 179                                  [disable zlib compression support]),
 180             ac_zlib=$withval, ac_zlib=yes)
 181 AC_MSG_CHECKING([whether to include zlib compression support])
 182 if test x$ac_zlib != xno; then
 183  AC_MSG_RESULT(yes)
 184  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 185  if test x$ac_cv_libz != xyes; then
 186    AC_MSG_WARN(
 187 ***
 188 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 189  fi
 190 else
 191  AC_MSG_RESULT(no)
 192 fi
 193
 194 PKG_CHECK_EXISTS(zlib, ZLIB_HAS_PKGCONFIG=y, ZLIB_HAS_PKGCONFIG=n)
 195
 196 if test x$ac_zlib != xno; then
 197   if test "$ZLIB_HAS_PKGCONFIG" = "y" ; then
 198     if test "x$GNUTLS_REQUIRES_PRIVATE" = x; then
 199       GNUTLS_REQUIRES_PRIVATE="Requires.private: zlib"
 200     else
 201       GNUTLS_REQUIRES_PRIVATE="$GNUTLS_REQUIRES_PRIVATE, zlib"
 202     fi
 203   else
 204     GNUTLS_ZLIB_LIBS_PRIVATE="$LTLIBZ"
 205   fi
 206 fi
 207 AC_SUBST(GNUTLS_REQUIRES_PRIVATE)
 208 AC_SUBST(GNUTLS_ZLIB_LIBS_PRIVATE)
 209
 210
 211 gl_INIT
 212
 213 dnl GCC warnings to enable
 214
 215 AC_ARG_ENABLE([gcc-warnings],
 216   [AS_HELP_STRING([--enable-gcc-warnings],
 217                   [turn on lots of GCC warnings (for developers)])],
 218   [case $enableval in
 219      yes|no) ;;
 220      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 221    esac
 222    gl_gcc_warnings=$enableval],
 223   [gl_gcc_warnings=no]
 224 )
 225
 226 if test "$gl_gcc_warnings" = yes; then
 227   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 228   gl_WARN_ADD([-Wframe-larger-than=5120], [WSTACK_CFLAGS])
 229
 230   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 231   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 232   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 233   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 234   nw="$nw -Wlogical-op"             # Too many false positives
 235   nw="$nw -Wold-style-definition"   #
 236   nw="$nw -Wpadded"                 # Our structs are not padded
 237   nw="$nw -Wunreachable-code"       # Too many false positives
 238   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 239   nw="$nw -Wcast-qual"              # Too many warnings for now
 240   nw="$nw -Waggregate-return"       # Too many warnings for now
 241   nw="$nw -Wshadow"                 # Too many warnings for now
 242   nw="$nw -Wswitch-default"         # Too many warnings for now
 243   nw="$nw -Wswitch-enum"            # Too many warnings for now
 244   nw="$nw -Wconversion"             # Too many warnings for now
 245   nw="$nw -Wsign-conversion"        # Too many warnings for now
 246   nw="$nw -Wformat-y2k"             # Too many warnings for now
 247   nw="$nw -Wvla"                    # There is no point to avoid C99 variable length arrays
 248   nw="$nw -Wformat-nonliteral"      # Incompatible with gettext _()
 249   nw="$nw -Wunsafe-loop-optimizations"
 250   nw="$nw -Wstrict-overflow"
 251   nw="$nw -Wmissing-noreturn"
 252
 253   gl_MANYWARN_ALL_GCC([ws])
 254   gl_MANYWARN_COMPLEMENT(ws, [$ws], [$nw])
 255   for w in $ws; do
 256     gl_WARN_ADD([$w])
 257   done
 258
 259   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 260   gl_WARN_ADD([-Wno-format-y2k])     # Too many warnings for now
 261   gl_WARN_ADD([-Wno-suggest-attribute=pure])     # Too many warnings for now
 262   gl_WARN_ADD([-Wno-suggest-attribute=const])     # Too many warnings for now
 263   gl_WARN_ADD([-Wno-suggest-attribute=noreturn])     # Too many warnings for now
 264   gl_WARN_ADD([-Wno-unused-value]) # warnings for things we don't want to get
 265   gl_WARN_ADD([-Wno-unused-result]) # warnings for things we don't want to get
 266   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 267   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 268   gl_WARN_ADD([-Wno-stack-protector])  # Some functions cannot be protected
 269   gl_WARN_ADD([-Wno-int-to-pointer-cast])  # Some files cannot be compiled with that (gl_fd_to_handle)
 270   gl_WARN_ADD([-Wno-redundant-decls])  # Some files cannot be compiled with that (gl_fd_to_handle)
 271   gl_WARN_ADD([-fdiagnostics-show-option])
 272 fi
 273
 274 AC_SUBST([WERROR_CFLAGS])
 275 AC_SUBST([WSTACK_CFLAGS])
 276 AC_SUBST([WARN_CFLAGS])
 277
 278 dnl Programs for compilation or development
 279 AC_PROG_LN_S
 280 AC_LIBTOOL_WIN32_DLL
 281 AC_PROG_LIBTOOL
 282
 283 AC_ARG_WITH([default-trust-store-pkcs11],
 284   [AS_HELP_STRING([--with-default-trust-store-pkcs11=URI],
 285     [use the given pkcs11 uri as default trust store])])
 286
 287 if test "x$with_default_trust_store_pkcs11" != x; then
 288   if test "x$with_p11_kit" = xno; then
 289     AC_MSG_ERROR([cannot use pkcs11 store without p11-kit])
 290   fi
 291   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_PKCS11],
 292     ["$with_default_trust_store_pkcs11"], [use the given pkcs11 uri as default trust store])
 293 fi
 294
 295 AC_ARG_WITH([default-trust-store-file],
 296   [AS_HELP_STRING([--with-default-trust-store-file=FILE],
 297     [use the given file default trust store])])
 298
 299 AC_ARG_WITH([default-crl-file],
 300   [AS_HELP_STRING([--with-default-crl-file=FILE],
 301     [use the given CRL file as default])])
 302
 303 if test "x$with_default_trust_store_pkcs11" = x -a "x$with_default_trust_store_file" = x; then
 304   # auto detect http://lists.gnu.org/archive/html/help-gnutls/2012-05/msg00004.html
 305   for i in \
 306     /etc/ssl/certs/ca-certificates.crt \
 307     /etc/pki/tls/cert.pem \
 308     /usr/local/share/certs/ca-root-nss.crt
 309     do
 310     if test -e $i; then
 311       with_default_trust_store_file="$i"
 312       break
 313     fi
 314   done
 315 fi
 316
 317 if test "x$with_default_trust_store_file" != x; then
 318   AC_DEFINE_UNQUOTED([DEFAULT_TRUST_STORE_FILE],
 319     ["$with_default_trust_store_file"], [use the given file default trust store])
 320 fi
 321
 322 if test "x$with_default_crl_file" != x; then
 323   AC_DEFINE_UNQUOTED([DEFAULT_CRL_FILE],
 324     ["$with_default_crl_file"], [use the given CRL file])
 325 fi
 326
 327 dnl Guile bindings.
 328 opt_guile_bindings=yes
 329 AC_MSG_CHECKING([whether building Guile bindings])
 330 AC_ARG_ENABLE(guile,
 331         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 332 opt_guile_bindings=$enableval)
 333 AC_MSG_RESULT($opt_guile_bindings)
 334
 335 AC_ARG_WITH([--with-guile-site-dir],
 336   [AS_HELP_STRING([--with-guile-site-dir],
 337      [use the given directory as the Guile site (use with care)])])
 338
 339 if test "$opt_guile_bindings" = "yes"; then
 340    AC_MSG_RESULT([***
 341 *** Detecting GNU Guile...
 342 ])
 343
 344    AC_PATH_PROG([guile_snarf], [guile-snarf])
 345    if test "x$guile_snarf" = "x"; then
 346       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 347       opt_guile_bindings=no
 348    else
 349       GUILE_PROGS
 350       GUILE_FLAGS
 351
 352       save_CFLAGS="$CFLAGS"
 353       save_LIBS="$LIBS"
 354       CFLAGS="$CFLAGS $GUILE_CFLAGS"
 355       LIBS="$LIBS $GUILE_LDFLAGS"
 356       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 357       AC_LINK_IFELSE(AC_LANG_CALL([], [scm_from_locale_string]),
 358         [], [opt_guile_bindings=no])
 359       CFLAGS="$save_CFLAGS"
 360       LIBS="$save_LIBS"
 361
 362       if test "$opt_guile_bindings" = "yes"; then
 363         AC_MSG_RESULT([yes])
 364         case "x$with_guile_site_dir" in
 365              xno)
 366                 # Use the default $(GUILE_SITE).
 367                 GUILE_SITE_DIR
 368                 ;;
 369              x|xyes)
 370                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 371                 # hack is used to allow `distcheck' to work (see
 372                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 373                 GUILE_SITE="\$(datadir)/guile/site"
 374                 AC_SUBST(GUILE_SITE)
 375                 ;;
 376              *)
 377                 # Use the user-specified directory as $(GUILE_SITE).
 378                 GUILE_SITE="$with_guile_site_dir"
 379                 AC_SUBST(GUILE_SITE)
 380                 ;;
 381         esac
 382         AC_MSG_CHECKING([whether gcc supports -fgnu89-inline])
 383         _gcc_cflags_save="$CFLAGS"
 384         CFLAGS="${CFLAGS} -fgnu89-inline"
 385         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 386                           gnu89_inline=yes, gnu89_inline=no)
 387         AC_MSG_RESULT($gnu89_inline)
 388         CFLAGS="$_gcc_cflags_save"
 389
 390         # Optional Guile functions.
 391         save_CFLAGS="$CFLAGS"
 392         save_LIBS="$LIBS"
 393         CFLAGS="$CFLAGS $GUILE_CFLAGS"
 394         LIBS="$LIBS $GUILE_LDFLAGS"
 395         AC_CHECK_FUNCS([scm_gc_malloc_pointerless])
 396         CFLAGS="$save_CFLAGS"
 397         LIBS="$save_LIBS"
 398
 399         # The place where guile-gnutls.la will go.
 400         AC_MSG_CHECKING([the Guile effective version])
 401         guile_effective_version="`$GUILE -c '(display (effective-version))'`"
 402         AC_MSG_RESULT([$guile_effective_version])
 403         guileextensiondir="$libdir/guile/$guile_effective_version"
 404         AC_SUBST([guileextensiondir])
 405       else
 406         AC_MSG_RESULT([no])
 407         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 408         opt_guile_bindings=no
 409       fi
 410    fi
 411 fi
 412 AM_CONDITIONAL(HAVE_GUILE, test "$opt_guile_bindings" = "yes")
 413
 414 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBS"
 415 LIBGNUTLS_CFLAGS="-I${includedir}"
 416 AC_SUBST(LIBGNUTLS_LIBS)
 417 AC_SUBST(LIBGNUTLS_CFLAGS)
 418
 419
 420 AC_DEFINE([GNUTLS_COMPAT_H], 1, [Make sure we don't use old features in code.])
 421 AC_DEFINE([GNUTLS_INTERNAL_BUILD], 1, [We allow temporarily usage of deprecated functions - until they are removed.])
 422
 423 AC_DEFINE([fread_file], [_gnutls_fread_file], [static lib rename])
 424 AC_DEFINE([read_file], [_gnutls_read_file], [static lib rename])
 425 AC_DEFINE([read_binary_file], [_gnutls_read_binary_file], [static lib rename])
 426
 427 dnl Crywrap dependencies
 428    AC_MSG_RESULT([***
 429 *** Checking dependencies for crywrap...
 430 ])
 431
 432 crywrap=no
 433
 434 if test "$have_win" != "yes"; then
 435
 436 AC_CHECK_HEADERS([arpa/inet.h netinet/in.h sys/select.h sys/types.h sys/wait.h])
 437
 438 dnl **********************
 439 dnl * Typedefs & co
 440 dnl **********************
 441 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 442 [AC_LANG_PROGRAM([#include <sys/types.h>
 443 #include <signal.h>
 444 ],
 445                  [return *(signal (0, 0)) (0) == 1;])],
 446                    [ac_cv_type_signal=int],
 447                    [ac_cv_type_signal=void])])
 448 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 449                     (`int' or `void').])
 450
 451 AC_FUNC_SELECT_ARGTYPES
 452 AC_CHECK_FUNCS([alarm atexit dup2 epoll_create kqueue memchr memset munmap \
 453                 putenv regcomp scandir select socket strcasecmp strchr \
 454                 strdup strerror strncasecmp strrchr strstr strtoul uname])
 455
 456 AC_ARG_ENABLE(crywrap,
 457         AS_HELP_STRING([--disable-crywrap], [unconditionally disable the crywrap TLS proxy service]))
 458
 459  libidn=no
 460
 461  if test "x$enable_crywrap" != "xno" ; then
 462         PKG_CHECK_MODULES(LIBIDN, libidn >= 0.0.0, [libidn=yes], [libidn=no])
 463  fi
 464
 465  if test "x$libidn" != "xno" && test "$ac_cv_func_daemon" != "no";then
 466   crywrap=yes
 467  fi
 468
 469 fi
 470
 471 AM_CONDITIONAL(ENABLE_CRYWRAP, test "x$crywrap" != "xno")
 472 rm -f suppressions.valgrind
 473 dnl end of crywrap requirements
 474
 475 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 476 AC_CONFIG_FILES([
 477   Makefile
 478   doc/Makefile
 479   doc/credentials/Makefile
 480   doc/credentials/openpgp/Makefile
 481   doc/credentials/srp/Makefile
 482   doc/credentials/x509/Makefile
 483   doc/cyclo/Makefile
 484   doc/doxygen/Doxyfile
 485   doc/examples/Makefile
 486   doc/latex/Makefile
 487   doc/manpages/Makefile
 488   doc/reference/Makefile
 489   doc/reference/version.xml
 490   doc/scripts/Makefile
 491   extra/Makefile
 492   extra/includes/Makefile
 493   gl/Makefile
 494   gl/tests/Makefile
 495   guile/Makefile
 496   guile/modules/Makefile
 497   guile/src/Makefile
 498   guile/tests/Makefile
 499   lib/Makefile
 500   lib/accelerated/Makefile
 501   lib/accelerated/x86/Makefile
 502   lib/algorithms/Makefile
 503   lib/auth/Makefile
 504   lib/ext/Makefile
 505   lib/extras/Makefile
 506   lib/gnutls.pc
 507   lib/includes/Makefile
 508   lib/includes/gnutls/gnutls.h
 509   lib/minitasn1/Makefile
 510   lib/nettle/Makefile
 511   lib/opencdk/Makefile
 512   lib/openpgp/Makefile
 513   lib/x509/Makefile
 514   po/Makefile.in
 515   src/Makefile
 516   src/crywrap/Makefile
 517   tests/Makefile
 518   tests/cert-tests/Makefile
 519   tests/dsa/Makefile
 520   tests/dtls/Makefile
 521   tests/srp/Makefile
 522   tests/ecdsa/Makefile
 523   tests/key-id/Makefile
 524   tests/openpgp-certs/Makefile
 525   tests/pkcs1-padding/Makefile
 526   tests/pkcs12-decode/Makefile
 527   tests/pkcs8-decode/Makefile
 528   tests/rsa-md5-collision/Makefile
 529   tests/safe-renegotiation/Makefile
 530   tests/scripts/Makefile
 531   tests/sha2/Makefile
 532   tests/slow/Makefile
 533   tests/suite/Makefile
 534   tests/userid/Makefile
 535 ])
 536
 537 AC_OUTPUT
 538
 539 AC_MSG_NOTICE([summary of build options:
 540
 541   version:          ${VERSION} shared $LT_CURRENT:$LT_REVISION:$LT_AGE
 542   Host type:        ${host}
 543   Install prefix:   ${prefix}
 544   Compiler:         ${CC}
 545   CFlags:           ${CFLAGS}
 546   Warning flags:    errors: ${WERROR_CFLAGS} warnings: ${WARN_CFLAGS}
 547   Library types:    Shared=${enable_shared}, Static=${enable_static}
 548   Valgrind:         $opt_valgrind_tests ${VALGRIND}
 549 ])
 550
 551 AC_MSG_NOTICE([Optional features:
 552 (note that included applications might not compile properly
 553 if features are disabled)
 554
 555   OCSP support:     $ac_enable_ocsp
 556   OpenPGP support:  $ac_enable_openpgp
 557   SRP support:      $ac_enable_srp
 558   PSK support:      $ac_enable_psk
 559   Anon auth support:$ac_enable_anon
 560
 561   Trust store pkcs: $with_default_trust_store_pkcs11
 562   Trust store file: $with_default_trust_store_file
 563   CRL file: $with_default_crl_file
 564 ])
 565
 566 AC_MSG_NOTICE([Optional applications:
 567
 568   crywrap app:      $libidn
 569   local libopts:    $enable_local_libopts
 570 ])
 571
 572 AC_MSG_NOTICE([Optional libraries:
 573
 574   Guile wrappers:   $opt_guile_bindings
 575   C++ library:      $use_cxx
 576   OpenSSL compat:   $enable_openssl
 577 ])
 578
 579 AC_MSG_NOTICE([Hardware acceleration/support:
 580
 581   /dev/crypto:      $enable_cryptodev
 582   Hardware accel:   $hw_accel
 583   PKCS#11 support:  $with_p11_kit
 584 ])