configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   3 #    Free Software Foundation, Inc.
   4 #
   5 # Author: Nikos Mavroyanopoulos
   6 #
   7 # This file is part of GNUTLS.
   8 #
   9 # GNUTLS is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # GNUTLS is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with GNUTLS; if not, write to the Free Software Foundation,
  21 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  22
  23 AC_PREREQ(2.61)
  24 AC_INIT([GnuTLS], [1.7.15], [bug-gnutls@gnu.org])
  25 AC_CONFIG_AUX_DIR([build-aux])
  26
  27 AC_CANONICAL_TARGET
  28
  29 AM_INIT_AUTOMAKE([1.10 gnits dist-bzip2])
  30 AM_CONFIG_HEADER(config.h)
  31
  32 AB_INIT
  33
  34 # Library code modified:                              REVISION++
  35 # Interfaces changed/added/removed:   CURRENT++       REVISION=0
  36 # Interfaces added:                             AGE++
  37 # Interfaces removed:                           AGE=0
  38 AC_SUBST(LT_CURRENT, 20)
  39 AC_SUBST(LT_REVISION, 7)
  40 AC_SUBST(LT_AGE, 7)
  41 ac_full=1
  42
  43 # Used when creating the Windows libgnutls-XX.def files.
  44 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  45 AC_SUBST(SOVERSION)
  46
  47 GNUTLS_GCRYPT_VERSION=1:1.2.2
  48 GNUTLS_LIBTASN1_VERSION=0.3.4
  49 AC_DEFINE_UNQUOTED(GNUTLS_GCRYPT_VERSION, "$GNUTLS_GCRYPT_VERSION", [version of gcrypt])
  50 AC_DEFINE_UNQUOTED(GNUTLS_LIBTASN1_VERSION, "$GNUTLS_LIBTASN1_VERSION", [version of libtasn1])
  51
  52 # Compute numeric versions, used in includes/gnutls/gnutls.h.in.
  53 AC_SUBST(MAJOR_VERSION, `echo $PACKAGE_VERSION | sed 's/\(.*\)\..*\..*/\1/g'`)
  54 AC_SUBST(MINOR_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\.\(.*\)\..*/\1/g'`)
  55 AC_SUBST(PATCH_VERSION, `echo $PACKAGE_VERSION | sed 's/.*\..*\.\(.*\)/\1/g'`)
  56 AC_SUBST(NUMBER_VERSION, `printf "0x%02x%02x%02x" $MAJOR_VERSION $MINOR_VERSION $PATCH_VERSION`)
  57
  58 dnl In order to use the reentrant libc functions.
  59 dnl I hope it is portable enough.
  60 CFLAGS="${CFLAGS} -D_REENTRANT -D_THREAD_SAFE"
  61 AM_CFLAGS="${CFLAGS}"
  62
  63 opt_dmalloc_mode=no
  64 AC_MSG_CHECKING([whether in dmalloc mode])
  65 AC_ARG_ENABLE(dmalloc-mode,
  66         AS_HELP_STRING([--enable-dmalloc-mode], [enable dmalloc mode]),
  67         opt_dmalloc_mode=$enableval)
  68 AC_MSG_RESULT($opt_dmalloc_mode)
  69
  70 opt_efence_mode=no
  71 AC_MSG_CHECKING([whether in electric fence mode])
  72 AC_ARG_ENABLE(efence-mode,
  73         AS_HELP_STRING([--enable-efence-mode], [enable electric fence mode]),
  74 opt_efence_mode=$enableval)
  75 AC_MSG_RESULT($opt_efence_mode)
  76
  77 opt_developer_mode=no
  78 AC_MSG_CHECKING([whether in developer mode])
  79 AC_ARG_ENABLE(developer-mode,
  80         AS_HELP_STRING([--enable-developer-mode], [enable developer mode]),
  81 opt_developer_mode=$enableval)
  82 AC_MSG_RESULT($opt_developer_mode)
  83
  84 opt_profiler_mode=no
  85 AC_MSG_CHECKING([whether in profile mode])
  86 AC_ARG_ENABLE(profile-mode,
  87         AS_HELP_STRING([--enable-profile-mode], [enable profiler]),
  88 opt_profiler_mode=$enableval)
  89 AC_MSG_RESULT($opt_profiler_mode)
  90
  91 AC_MSG_RESULT([***
  92 *** Checking for compilation programs...
  93 ])
  94
  95 dnl Checks for programs.
  96 AM_GNU_GETTEXT([external])
  97 AM_GNU_GETTEXT_VERSION([0.16])
  98 AC_PROG_CC
  99 AC_PROG_CXX
 100 AC_PROG_LN_S
 101 GTK_DOC_CHECK(1.1)
 102 AC_PATH_PROG([GAA], [gaa])
 103 if test "x$GAA" = "x"; then
 104    AC_MSG_WARN([[***
 105 *** GAA was not found.  It is only needed if you wish to modify
 106 *** the source code or command-line description files.  In this case,
 107 *** you may want to get it from http://gaa.sourceforge.net/
 108 ***]])
 109 fi
 110 AM_CONDITIONAL(HAVE_GCC,   test "x$GCC" = "xyes")
 111
 112
 113 AC_MSG_RESULT([***
 114 *** Detecting compiler options...
 115 ])
 116
 117 gl_EARLY
 118 lgl_EARLY
 119 AC_C_CONST
 120 AC_C_INLINE
 121
 122 AC_ARG_ENABLE(cxx,
 123        AS_HELP_STRING([--disable-cxx],
 124                [unconditionally disable the C++ library]),
 125        use_cxx=$enableval, use_cxx=yes)
 126 if test "$use_cxx" != "no"; then
 127   AC_LANG_PUSH(C++)
 128   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[])], use_cxx=yes, use_cxx=no)
 129   AC_LANG_POP(C++)
 130 fi
 131 AM_CONDITIONAL(ENABLE_CXX, test "$use_cxx" != "no")
 132 AC_MSG_CHECKING([whether to build C++ library])
 133 AC_MSG_RESULT($use_cxx)
 134
 135 AC_MSG_CHECKING([whether C99 macros are supported])
 136 AC_TRY_COMPILE(,[
 137 #define test_mac(...)
 138 int z,y,x;
 139 test_mac(x,y,z);
 140 return 0;
 141 ],
 142         dnl ***** OK
 143         AC_DEFINE(C99_MACROS, 1, [C99 macros are supported])
 144         AC_MSG_RESULT(yes),
 145         dnl ***** NOT FOUND
 146         AC_MSG_RESULT(no)
 147         AC_MSG_WARN([C99 macros not supported. This may affect compiling.]))
 148
 149 if test $ac_cv_c_compiler_gnu != no; then
 150         if test x$opt_developer_mode = xyes; then
 151           AM_CFLAGS="${AM_CFLAGS} -g -Wall -Wcast-align -W -Wpointer-arith -Wchar-subscripts -Wformat-security -Wno-format-y2k -Wmissing-braces -Winline -Wstrict-prototypes -Wno-unused-parameter"
 152 #         AM_CFLAGS="${AM_CFLAGS} -g -W -Wall -Wcast-align -Wpointer-arith -Wchar-subscripts -Wformat-security -Wno-format-y2k -Wmissing-braces -Winline -Wstrict-prototypes -Wshadow -Wno-unused-parameter -Wimplicit -fno-common -Wno-sign-compare -Wbad-function-cast -Wendif-labels -Wmissing-declarations -Wno-missing-format-attribute -Wmissing-prototypes -Wnested-externs -Wpointer-arith -pedantic -Wlong-long -Wcast-qual -Wcast-align -Winline -Wredundant-decls -Wstrict-prototypes -Wwrite-strings -Wparentheses -Wsequence-point -Wpacked -Waggregate-return -Wfloat-equal -Wmultichar -Wunknown-pragmas -Wtrigraphs -Wswitch -Wreturn-type -Wmain -Wchar-subscripts -Wcomment -Wno-missing-noreturn"
 153         fi
 154
 155         AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
 156         _gcc_cflags_save=$CFLAGS
 157         CFLAGS="${CFLAGS} -Wno-pointer-sign"
 158         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
 159         AC_MSG_RESULT($_gcc_psign)
 160         if test x"$_gcc_psign" != xyes ; then
 161           CFLAGS=$_gcc_cflags_save;
 162         fi
 163
 164         AC_MSG_CHECKING([if gcc/ld supports -Wl,--output-def])
 165         _gcc_ldflags_save=$LDFLAGS
 166         LDFLAGS="-Wl,--output-def,foo.def"
 167         AC_LINK_IFELSE(AC_LANG_PROGRAM([]),output_def=yes,output_def=no)
 168         AC_MSG_RESULT($output_def)
 169         LDFLAGS="$_gcc_ldflags_save"
 170
 171         if test x$opt_dmalloc_mode = xyes; then
 172           AC_CHECK_LIB(dmalloc, main)
 173           AC_DEFINE(USE_DMALLOC, 1, [enable the use of dmalloc])
 174         else
 175                 if test x$opt_efence_mode = xyes; then
 176                   AC_CHECK_LIB(efence, main)
 177                   AC_DEFINE(USE_EFENCE, 1, [use electric fence])
 178                 fi
 179         fi
 180
 181         AC_MSG_CHECKING([whether we have GNU assembler])
 182         GAS=`as --version < /dev/null 2>/dev/null | grep GNU`
 183         if test "$GAS"; then
 184           AM_CFLAGS="${AM_CFLAGS} -pipe"
 185           AC_MSG_RESULT(yes)
 186         else
 187           AC_MSG_RESULT(no)
 188         fi
 189 fi
 190
 191 # Needs to be called outside of 'if' clause.
 192 AM_CONDITIONAL(HAVE_LD_OUTPUT_DEF, test "$output_def" = "yes")
 193
 194 AC_MSG_RESULT([***
 195 *** Detecting C library capabilities...
 196 ])
 197
 198 AC_HEADER_STDC
 199 AC_CHECK_HEADERS(strings.h alloca.h)
 200 AC_CHECK_HEADERS(errno.h)
 201 AC_CHECK_HEADERS(math.h limits.h float.h stdarg.h ctype.h)
 202 dnl opencdk
 203 AC_CHECK_HEADERS(netdb.h)
 204 AC_CHECK_FUNCS(umask vasprintf isascii fork,,)
 205 AC_FUNC_ALLOCA
 206
 207 # No fork on MinGW, disable some self-tests until we fix them.
 208 AM_CONDITIONAL(HAVE_FORK, test "$ac_cv_func_fork" != "no")
 209
 210 AC_MSG_RESULT([***
 211 *** Detecting system's parameters...
 212 ])
 213
 214 # Run self-tests under valgrind?
 215 if test "$cross_compiling" = no; then
 216   AC_CHECK_PROGS(VALGRIND, valgrind)
 217 fi
 218 if test -n "$VALGRIND" && $VALGRIND true > /dev/null 2>&1; then
 219   opt_valgrind_tests=yes
 220 else
 221   opt_valgrind_tests=no
 222   VALGRIND=
 223 fi
 224 AC_MSG_CHECKING([whether self tests are run under valgrind])
 225 AC_ARG_ENABLE(valgrind-tests,
 226         AS_HELP_STRING([--enable-valgrind-tests],
 227                        [run self tests under valgrind]),
 228   opt_valgrind_tests=$enableval)
 229 AC_MSG_RESULT($opt_valgrind_tests)
 230
 231 # For minitasn1.
 232 AC_CHECK_SIZEOF(unsigned long, 4)
 233 AC_CHECK_SIZEOF(unsigned int, 4)
 234
 235 # For storing integers in pointers without warnings
 236 # http://developer.gnome.org/doc/API/2.0/glib/glib-Type-Conversion-Macros.html#desc
 237 AC_CHECK_SIZEOF(void *)
 238 AC_CHECK_SIZEOF(long)
 239 AC_CHECK_SIZEOF(int)
 240 case $ac_cv_sizeof_void_p in
 241   $ac_cv_sizeof_long)
 242     AC_DEFINE(GNUTLS_POINTER_TO_INT_CAST, [(long)],
 243               [Additional cast to bring void* to a type castable to int.])
 244     ;;
 245   *)
 246     AC_DEFINE(GNUTLS_POINTER_TO_INT_CAST, [])
 247     ;;
 248 esac
 249
 250 # For some systems we know that we have ld_version scripts.
 251 # Use it then as default.
 252 have_ld_version_script=no
 253 case "${host}" in
 254     *-*-linux*)
 255         have_ld_version_script=yes
 256         ;;
 257     *-*-gnu*)
 258         have_ld_version_script=yes
 259         ;;
 260 esac
 261 AC_ARG_ENABLE([ld-version-script],
 262               AC_HELP_STRING([--enable-ld-version-script],
 263                              [enable/disable use of linker version script.
 264                               (default is system dependent)]),
 265               [have_ld_version_script=$enableval],
 266               [ : ] )
 267 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 268
 269 AC_CHECK_TYPES(uint,,, [
 270 # include <sys/types.h>
 271 ])
 272
 273 # Check for and replace ssize_t.
 274 AC_CHECK_TYPE(ssize_t,
 275         [DEFINE_SSIZE_T="#include <sys/types.h>"
 276         AC_SUBST(DEFINE_SSIZE_T)],
 277         [AC_DEFINE(NO_SSIZE_T, 1, [no ssize_t type was found])
 278         DEFINE_SSIZE_T="typedef int ssize_t;"
 279         AC_SUBST(DEFINE_SSIZE_T)],
 280         [#include <sys/types.h>])
 281
 282 AC_C_BIGENDIAN
 283
 284 AC_MSG_RESULT([***
 285 *** Checking for external libraries...
 286 ])
 287
 288 # For Guile bindings.
 289
 290 opt_guile_bindings=yes
 291 AC_MSG_CHECKING([whether building Guile bindings])
 292 AC_ARG_ENABLE(guile,
 293         AS_HELP_STRING([--enable-guile], [build GNU Guile bindings]),
 294 opt_guile_bindings=$enableval)
 295 AC_MSG_RESULT($opt_guile_bindings)
 296
 297 AC_ARG_WITH([--with-guile-site-dir],
 298   [AS_HELP_STRING([--with-guile-site-dir],
 299      [use the given directory as the Guile site (use with care)])])
 300
 301 if test "x$opt_guile_bindings" = "xyes"; then
 302    AC_MSG_RESULT([***
 303 *** Detecting GNU Guile...
 304 ])
 305
 306    AC_PATH_PROG([guile_snarf], [guile-snarf])
 307    if test "x$guile_snarf" = "x"; then
 308       AC_MSG_WARN([`guile-snarf' from Guile 1.8 not found.  Guile bindings not built.])
 309       opt_guile_bindings=no
 310    else
 311       GUILE_PROGS
 312       GUILE_FLAGS
 313
 314       AC_MSG_CHECKING([whether GNU Guile is recent enough])
 315       AC_COMPILE_IFELSE(AC_LANG_PROGRAM([
 316         #include <libguile.h>
 317 SCM_API scm_t_bits scm_tc16_gnutls_cipher_enum;]),
 318         recent_guile=yes,recent_guile=no)
 319
 320       if test "$recent_guile" = yes; then
 321         AC_MSG_RESULT([yes])
 322         case "x$with_guile_site_dir" in
 323              xno)
 324                 # Use the default $(GUILE_SITE).
 325                 GUILE_SITE_DIR
 326                 ;;
 327              x|xyes)
 328                 # Automatically derive $(GUILE_SITE) from $(pkgdatadir).  This
 329                 # hack is used to allow `distcheck' to work (see
 330                 # `DISTCHECK_CONFIGURE_FLAGS' in the top-level `Makefile.am').
 331                 GUILE_SITE="\$(datadir)/guile/site"
 332                 AC_SUBST(GUILE_SITE)
 333                 ;;
 334              *)
 335                 # Use the user-specified directory as $(GUILE_SITE).
 336                 GUILE_SITE="$with_guile_site_dir"
 337                 AC_SUBST(GUILE_SITE)
 338                 ;;
 339         esac
 340       else
 341         AC_MSG_RESULT([no])
 342         AC_MSG_WARN([A sufficiently recent GNU Guile not found.  Guile bindings not built.])
 343         opt_guile_bindings=no
 344       fi
 345    fi
 346 fi
 347 AM_CONDITIONAL(HAVE_GUILE, test "x$opt_guile_bindings" = "xyes")
 348
 349 AM_PATH_LIBGCRYPT($GNUTLS_GCRYPT_VERSION,,
 350 dnl Can't disable - gnutls depends on gcrypt
 351         AC_MSG_ERROR([[
 352 ***
 353 *** libgcrypt was not found. You may want to get it from
 354 *** ftp://ftp.gnupg.org/gcrypt/libgcrypt/
 355 ***
 356 ]]))
 357 libgcrypt=yes
 358
 359 # Hard-wire the gl/m4/gc.m4 test.
 360 AC_ARG_WITH(builtin-crypto,
 361         AS_HELP_STRING([--with-builtin-crypto],
 362                 [use internal crypto instead of libgcrypt (EXPERIMENTAL)]),
 363         ac_cv_libgcrypt=no,
 364         ac_cv_libgcrypt=yes)
 365 LTLIBGCRYPT=$LIBGCRYPT_LIBS
 366
 367 AC_MSG_CHECKING([whether to disable SRP authentication support])
 368 AC_ARG_ENABLE(srp-authentication,
 369         AS_HELP_STRING([--disable-srp-authentication],
 370                 [disable the SRP authentication support]),
 371         ac_enable_srp=no)
 372 if test x$ac_enable_srp != xno; then
 373  AC_MSG_RESULT(no)
 374  AC_DEFINE(ENABLE_SRP, 1, [enable SRP authentication])
 375 else
 376  ac_full=0
 377  AC_MSG_RESULT(yes)
 378 fi
 379 AM_CONDITIONAL(ENABLE_SRP, test "$ac_enable_srp" != "no")
 380
 381 AC_MSG_CHECKING([whether to disable PSK authentication support])
 382 AC_ARG_ENABLE(psk-authentication,
 383        AS_HELP_STRING([--disable-psk-authentication],
 384                [disable the PSK authentication support]),
 385        ac_enable_psk=no)
 386 if test x$ac_enable_psk != xno; then
 387  AC_MSG_RESULT(no)
 388  AC_DEFINE(ENABLE_PSK, 1, [enable PSK authentication])
 389 else
 390  ac_full=0
 391  AC_MSG_RESULT(yes)
 392 fi
 393
 394 AC_MSG_CHECKING([whether to disable anonymous authentication support])
 395 AC_ARG_ENABLE(anon-authentication,
 396         AS_HELP_STRING([--disable-anon-authentication],
 397                 [disable the anonymous authentication support]),
 398         ac_enable_anon=no)
 399 if test x$ac_enable_anon != xno; then
 400  AC_MSG_RESULT(no)
 401  AC_DEFINE(ENABLE_ANON, 1, [enable anonymous authentication])
 402 else
 403  ac_full=0
 404  AC_MSG_RESULT(yes)
 405 fi
 406 AM_CONDITIONAL(ENABLE_ANON, test "$ac_enable_anon" != "no")
 407
 408 AC_MSG_CHECKING([whether to disable authorization (tls-authz) support])
 409 AC_ARG_ENABLE(tls-authorization,
 410         AS_HELP_STRING([--disable-tls-authorization],
 411                 [disable tls authorization support]),
 412         ac_enable_authz=no)
 413 if test x$ac_enable_authz != xno; then
 414  AC_MSG_RESULT(no)
 415  AC_DEFINE(ENABLE_AUTHZ, 1, [enable tls authorization])
 416 else
 417  ac_full=0
 418  AC_MSG_RESULT(yes)
 419 fi
 420 AM_CONDITIONAL(ENABLE_AUTHZ, test "$ac_enable_authz" != "no")
 421
 422 AC_MSG_CHECKING([whether to disable extra PKI stuff])
 423 AC_ARG_ENABLE(extra-pki,
 424         AS_HELP_STRING([--disable-extra-pki],
 425                 [only enable the basic PKI stuff]),
 426         disable_pki=$enableval, disable_pki=no)
 427 if test "$disable_pki" != "no"; then
 428  ac_full=0
 429  AC_MSG_RESULT(yes)
 430 else
 431  AC_MSG_RESULT(no)
 432  AC_DEFINE(ENABLE_PKI, 1, [whether to include all the PKCS/PKI stuff])
 433 fi
 434 AM_CONDITIONAL(ENABLE_PKI, test "$disable_pki" = "no")
 435
 436 dnl Check whether to disable OpenPGP authentication completely
 437 dnl from libgnutls-extra.
 438
 439 ac_enable_openpgp=yes
 440 AC_MSG_CHECKING([whether to disable OpenPGP Certificate authentication support])
 441 AC_ARG_ENABLE(openpgp-authentication,
 442         AS_HELP_STRING([--disable-openpgp-authentication],
 443                 [disable the OpenPGP authentication support]),
 444         ac_enable_openpgp=no)
 445 if test x$ac_enable_openpgp = xno; then
 446  AC_MSG_RESULT(yes)
 447  ac_full=0
 448 else
 449  AC_DEFINE(ENABLE_OPENPGP, 1, [use openpgp authentication])
 450  AC_MSG_RESULT(no)
 451 fi
 452 AM_CONDITIONAL(ENABLE_OPENPGP, test "$ac_enable_openpgp" = "yes")
 453
 454 dnl Test whether to use the included opencdk library
 455 dnl
 456 if test x$ac_enable_openpgp = xyes; then
 457  AC_ARG_WITH(included-opencdk,
 458         AS_HELP_STRING([--with-included-opencdk], [use the included opencdk]),
 459                 ac_enable_included_opencdk=$withval,
 460                 ac_enable_included_opencdk=no)
 461  if test x$ac_enable_included_opencdk = xno;then
 462   AC_LIB_HAVE_LINKFLAGS(opencdk,, [
 463 #include <opencdk.h>], [cdk_armor_encode_buffer (NULL, 0, NULL, 0, NULL, 0);])
 464   if test "$ac_cv_libopencdk" != yes; then
 465    ac_enable_included_opencdk=yes
 466    AC_MSG_WARN([[
 467 ***
 468 *** libopencdk was not found. You may want to get it from
 469 *** ftp://ftp.gnutls.org/pub/gnutls/opencdk/
 470 ***
 471 *** Will use the included opencdk.
 472 ***
 473 ]])
 474   fi
 475   AC_MSG_CHECKING([whether to use the included opencdk])
 476   AC_MSG_RESULT($ac_enable_included_opencdk)
 477  fi
 478 fi
 479
 480 AM_CONDITIONAL(ENABLE_INCLUDED_OPENCDK, test "$ac_enable_included_opencdk" = "yes")
 481
 482 AC_MSG_CHECKING([whether to disable OpenSSL compatibility layer])
 483 AC_ARG_ENABLE(openssl-compatibility,
 484         AS_HELP_STRING([--disable-openssl-compatibility],
 485                 [disable the OpenSSL compatibility support]),
 486         ac_enable_openssl=$withval,
 487         ac_enable_openssl=yes)
 488 if test x$ac_enable_openssl != xno; then
 489  AC_MSG_RESULT(no)
 490 else
 491  AC_MSG_RESULT(yes)
 492 fi
 493
 494 AM_CONDITIONAL(ENABLE_OPENSSL, test "$ac_enable_openssl" = "yes")
 495
 496
 497 AC_ARG_WITH(included-libtasn1,
 498         AS_HELP_STRING([--with-included-libtasn1],
 499                 [use the included libtasn1]),
 500         minitasn1_enabled=$withval,
 501         minitasn1_enabled=no)
 502
 503 if test x$minitasn1_enabled = xno; then
 504 AM_PATH_LIBTASN1($GNUTLS_LIBTASN1_VERSION,,
 505  minitasn1_enabled=yes
 506  AC_MSG_WARN([[
 507 ***
 508 *** LibtASN1 ${GNUTLS_LIBTASN1_VERSION} was not found. Will use the included one.
 509 ]]))
 510 fi
 511
 512 AC_MSG_CHECKING([whether to use the included minitasn1])
 513 AC_MSG_RESULT($minitasn1_enabled)
 514
 515 AM_CONDITIONAL(ENABLE_MINITASN1, test "$minitasn1_enabled" = "yes")
 516
 517 dnl Check for libcfg+
 518
 519 SAVED_LIBS=$LIBS
 520 AC_ARG_WITH(included-libcfg,
 521         AS_HELP_STRING([--with-included-libcfg],
 522                 [use the included libcfg+ (certtool only)]),
 523         libcfg_enabled=$withval,
 524         libcfg_enabled=no
 525 dnl We search for libcfg+ which is used by certtool
 526 dnl
 527         AC_CHECK_LIB(cfg+, cfg_get_context,:,
 528                      libcfg_enabled=yes
 529                      AC_MSG_WARN([[
 530 ***
 531 *** Libcfg+ was not found. Will use the included one.]])))
 532
 533 AM_CONDITIONAL(HAVE_LIBCFG, test "$libcfg_enabled" = "no")
 534 LIBS=$SAVED_LIBS
 535
 536 AC_MSG_CHECKING([whether to use the included libcfg])
 537 AC_MSG_RESULT($libcfg_enabled)
 538
 539
 540 dnl CHECK FOR ZLIB SUPPORT
 541 dnl
 542
 543 AC_MSG_CHECKING([whether to include zlib compression support])
 544
 545 AC_ARG_WITH(zlib,
 546         AS_HELP_STRING([--without-zlib], [disable zlib compression support]),
 547         ac_zlib=$withval,
 548         ac_zlib=yes)
 549
 550 if test x$ac_zlib != xno; then
 551  AC_MSG_RESULT(yes)
 552  AC_LIB_HAVE_LINKFLAGS(z,, [#include <zlib.h>], [compress (0, 0, 0, 0);])
 553  if test "$ac_cv_libz" != yes; then
 554    AC_MSG_WARN(
 555 ***
 556 *** ZLIB was not found. You will not be able to use ZLIB compression.)
 557  fi
 558 else
 559  AC_MSG_RESULT(no)
 560 fi
 561
 562
 563
 564 dnl CHECK FOR LZO SUPPORT (whether to use the included one)
 565 dnl
 566
 567 minilzo_enabled=no
 568 use_lzo=yes
 569 AC_ARG_WITH(lzo,
 570         AS_HELP_STRING([--without-lzo], [do not use lzo compression]),
 571         use_lzo=$withval,
 572         use_lzo=yes)
 573
 574 AC_MSG_CHECKING([whether to include lzo compression support])
 575 AC_MSG_RESULT($use_lzo)
 576
 577 if test x$use_lzo = xyes; then
 578   AC_DEFINE(USE_LZO, 1, [whether to use the lzo compression])
 579
 580   AC_ARG_WITH(included-lzo,
 581         AS_HELP_STRING([--with-included-lzo],
 582                 [include minilzo in libgnutls-extra]),
 583         minilzo_enabled=$withval,
 584         minilzo_enabled=no)
 585
 586   AC_MSG_CHECKING([whether to use the included lzo compression library])
 587   AC_MSG_RESULT($minilzo_enabled)
 588
 589   LZO_LIBS=
 590   if test "$minilzo_enabled" != "yes"; then
 591     AC_CHECK_LIB(lzo2, lzo1x_1_compress, LZO_LIBS=-llzo2)
 592     if test "$LZO_LIBS" = ""; then
 593       AC_CHECK_LIB(lzo, lzo1x_1_compress, LZO_LIBS=-llzo, [
 594         minilzo_enabled=yes
 595         AC_MSG_WARN(
 596 ***
 597 *** Could not find liblzo or liblzo2. Will use the included minilzo.
 598 )
 599       ])
 600     fi
 601   fi
 602   AC_SUBST(LZO_LIBS)
 603
 604   if test "$LZO_LIBS" = "-llzo"; then
 605     AC_CHECK_HEADERS(lzo1x.h)
 606   elif test "$LZO_LIBS" = "-llzo2"; then
 607     AC_CHECK_HEADERS(lzo/lzo1x.h)
 608   fi
 609
 610   if test "$minilzo_enabled" = "yes"; then
 611     AC_DEFINE(USE_MINILZO, 1, [whether to use the included minilzo])
 612   fi
 613 fi
 614
 615 AM_CONDITIONAL(USE_LZO, test "$use_lzo" = "yes")
 616 AM_CONDITIONAL(ENABLE_INCLUDED_LZO, test "$minilzo_enabled" = "yes")
 617
 618 if test "$minilzo_enabled" = "yes"; then
 619   # See libextra/minilzo/README.LZO
 620   AC_CHECK_TYPE(ptrdiff_t,long)
 621   AC_TYPE_SIZE_T
 622   AC_CHECK_SIZEOF(short)
 623   AC_CHECK_SIZEOF(int)
 624   AC_CHECK_SIZEOF(long)
 625   AC_CHECK_SIZEOF(long long)
 626   AC_CHECK_SIZEOF(__int64)
 627   AC_CHECK_SIZEOF(void *)
 628   AC_CHECK_SIZEOF(size_t)
 629   AC_CHECK_SIZEOF(ptrdiff_t)
 630   AC_C_CONST
 631   AC_CHECK_FUNCS(memcmp memcpy memmove memset)
 632 fi
 633
 634 AC_MSG_RESULT([***
 635 *** Setting up gnulib compatibility files...
 636 ])
 637 gl_INIT
 638 lgl_INIT
 639
 640 AC_TRY_LINK([#include <winsock2.h>], [
 641   WORD wVersionRequested = MAKEWORD(2, 2);
 642   WSADATA wsaData;
 643   int err = WSAStartup(wVersionRequested, &wsaData);
 644   WSACleanup ();], wsastartup=yes, wsastartup=no)
 645 if test x$wsastartup = xyes; then
 646   AC_DEFINE(HAVE_WINSOCK, 1, [Call WSAStartup in gnutls_global_init])
 647 fi
 648 AC_MSG_CHECKING([if we have Windows sockets and WSAStartup/WSACleanup])
 649 AC_MSG_RESULT($wsastartup)
 650
 651 AC_MSG_RESULT([***
 652 *** Detecting options for shared libraries...
 653 ])
 654 AC_LIBTOOL_WIN32_DLL
 655 AC_PROG_LIBTOOL
 656
 657 LIBGNUTLS_LIBS="-L${libdir} -lgnutls $LIBTASN1_LIBS $LIBGCRYPT_LIBS $LIBS"
 658 LIBGNUTLS_CFLAGS="$LIBGCRYPT_CFLAGS $LIBTASN1_CFLAGS -I${includedir}"
 659 AC_SUBST(LIBGNUTLS_LIBS)
 660 AC_SUBST(LIBGNUTLS_CFLAGS)
 661
 662 LIBGNUTLS_EXTRA_LIBS="-L${libdir} -lgnutls-extra $LTLIBOPENCDK $LZO_LIBS $LIBGNUTLS_LIBS"
 663 LIBGNUTLS_EXTRA_CFLAGS="$INCOPENCDK -I${includedir}"
 664 AC_SUBST(LIBGNUTLS_EXTRA_LIBS)
 665 AC_SUBST(LIBGNUTLS_EXTRA_CFLAGS)
 666 export ac_full
 667
 668 AM_CFLAGS="${AM_CFLAGS} ${LIBGCRYPT_CFLAGS}"
 669
 670 if test $ac_cv_c_compiler_gnu != no; then
 671         if test x$opt_profiler_mode = xyes; then
 672           AC_CHECK_PROG(FC_OK, fc-config, yes, no)
 673           if test x$FC_OK = xyes; then
 674                 AM_CFLAGS="${AM_CFLAGS} `fc-config --cflags`"
 675                 LIBS="$LIBS `fc-config --libs`"
 676           else
 677 AC_MSG_WARN(***
 678 *** You must install libfc in order to enable profiling. http://www710.univ-lyon1.fr/~yperret/fnccheck/profiler.html
 679 )
 680           fi
 681         fi
 682 fi
 683
 684 if test $ac_full -eq 0; then
 685   AC_SUBST(POSSIBLY_WARN_ABOUT_MISSING_FEATURES, [[
 686 #ifdef __GNUC__
 687 #warning This is not the official GnuTLS library. Several features were disabled at compilation.
 688 #endif /* __GNUC__ */]])
 689 fi
 690
 691 AC_SUBST(AM_CFLAGS)
 692
 693 AC_CONFIG_COMMANDS([chmod-config],[[
 694  chmod +x lib/libgnutls-config
 695  chmod +x libextra/libgnutls-extra-config
 696 ]],[[]])
 697
 698 AC_CONFIG_FILES([Makefile po/Makefile.in \
 699         doc/Makefile doc/examples/Makefile doc/scripts/Makefile \
 700         doc/manpages/Makefile doc/reference/Makefile \
 701         gl/Makefile lgl/Makefile \
 702         tests/Makefile tests/rsa-md5-collision/Makefile tests/userid/Makefile \
 703         tests/pkcs1-padding/Makefile tests/pkcs8-decode/Makefile \
 704         tests/pkcs12-decode/Makefile tests/pathlen/Makefile \
 705         tests/key-id/Makefile tests/sha2/Makefile \
 706         tests/hostname-check/Makefile \
 707         includes/Makefile includes/gnutls/gnutls.h \
 708         lib/Makefile lib/minitasn1/Makefile lib/x509/Makefile \
 709         libextra/Makefile libextra/openpgp/Makefile libextra/opencdk/Makefile \
 710         libextra/minilzo/Makefile tests/openpgp/Makefile \
 711         src/Makefile src/x509/Makefile src/srp/Makefile src/openpgp/Makefile \
 712         src/cfg/Makefile src/cfg/platon/Makefile src/cfg/platon/str/Makefile \
 713         lib/libgnutls-config libextra/libgnutls-extra-config \
 714         lib/gnutls.pc libextra/gnutls-extra.pc
 715         guile/Makefile guile/modules/Makefile
 716         guile/src/Makefile guile/tests/Makefile])
 717
 718 AC_CONFIG_FILES([guile/pre-inst-guile], [chmod +x guile/pre-inst-guile])
 719
 720
 721 AC_OUTPUT