lisp/sieve-manage.el

   1 ;;; sieve-manage.el --- Implementation of the managesive protocol in elisp
   2
   3 ;; Copyright (C) 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; This library provides an elisp API for the managesieve network
  25 ;; protocol.
  26 ;;
  27 ;; It uses the SASL library for authentication, which means it
  28 ;; supports DIGEST-MD5, CRAM-MD5, SCRAM-MD5, NTLM, PLAIN and LOGIN
  29 ;; methods.  STARTTLS is not well tested, but should be easy to get to
  30 ;; work if someone wants.
  31 ;;
  32 ;; The API should be fairly obvious for anyone familiar with the
  33 ;; managesieve protocol, interface functions include:
  34 ;;
  35 ;; `sieve-manage-open'
  36 ;; open connection to managesieve server, returning a buffer to be
  37 ;; used by all other API functions.
  38 ;;
  39 ;; `sieve-manage-opened'
  40 ;; check if a server is open or not
  41 ;;
  42 ;; `sieve-manage-close'
  43 ;; close a server connection.
  44 ;;
  45 ;; `sieve-manage-listscripts'
  46 ;; `sieve-manage-deletescript'
  47 ;; `sieve-manage-getscript'
  48 ;; performs managesieve protocol actions
  49 ;;
  50 ;; and that's it.  Example of a managesieve session in *scratch*:
  51 ;;
  52 ;; (with-current-buffer (sieve-manage-open "mail.example.com")
  53 ;;   (sieve-manage-authenticate)
  54 ;;   (sieve-manage-listscripts))
  55 ;;
  56 ;; => ((active . "main") "vacation")
  57 ;;
  58 ;; References:
  59 ;;
  60 ;; draft-martin-managesieve-02.txt,
  61 ;; "A Protocol for Remotely Managing Sieve Scripts",
  62 ;; by Tim Martin.
  63 ;;
  64 ;; Release history:
  65 ;;
  66 ;; 2001-10-31 Committed to Oort Gnus.
  67 ;; 2002-07-27 Added DELETESCRIPT.  Suggested by Ned Ludd.
  68 ;; 2002-08-03 Use SASL library.
  69
  70 ;;; Code:
  71
  72 ;; For Emacs <22.2 and XEmacs.
  73 (eval-and-compile
  74   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  75
  76 (if (locate-library "password-cache")
  77     (require 'password-cache)
  78   (require 'password))
  79
  80 (eval-when-compile
  81   (require 'cl)                         ; caddr
  82   (require 'sasl)
  83   (require 'starttls))
  84 (autoload 'sasl-find-mechanism "sasl")
  85 (autoload 'starttls-open-stream "starttls")
  86 (autoload 'auth-source-user-or-password "auth-source")
  87
  88 ;; User customizable variables:
  89
  90 (defgroup sieve-manage nil
  91   "Low-level Managesieve protocol issues."
  92   :group 'mail
  93   :prefix "sieve-")
  94
  95 (defcustom sieve-manage-log "*sieve-manage-log*"
  96   "Name of buffer for managesieve session trace."
  97   :type 'string
  98   :group 'sieve-manage)
  99
 100 (defcustom sieve-manage-server-eol "\r\n"
 101   "The EOL string sent from the server."
 102   :type 'string
 103   :group 'sieve-manage)
 104
 105 (defcustom sieve-manage-client-eol "\r\n"
 106   "The EOL string we send to the server."
 107   :type 'string
 108   :group 'sieve-manage)
 109
 110 (defcustom sieve-manage-streams '(network starttls shell)
 111   "Priority of streams to consider when opening connection to server."
 112   :group 'sieve-manage)
 113
 114 (defcustom sieve-manage-stream-alist
 115   '((network   sieve-manage-network-p          sieve-manage-network-open)
 116     (shell     sieve-manage-shell-p            sieve-manage-shell-open)
 117     (starttls  sieve-manage-starttls-p         sieve-manage-starttls-open))
 118   "Definition of network streams.
 119
 120 \(NAME CHECK OPEN)
 121
 122 NAME names the stream, CHECK is a function returning non-nil if the
 123 server support the stream and OPEN is a function for opening the
 124 stream."
 125   :group 'sieve-manage)
 126
 127 (defcustom sieve-manage-authenticators '(digest-md5
 128                                          cram-md5
 129                                          scram-md5
 130                                          ntlm
 131                                          plain
 132                                          login)
 133   "Priority of authenticators to consider when authenticating to server."
 134   :group 'sieve-manage)
 135
 136 (defcustom sieve-manage-authenticator-alist
 137   '((cram-md5   sieve-manage-cram-md5-p       sieve-manage-cram-md5-auth)
 138     (digest-md5 sieve-manage-digest-md5-p     sieve-manage-digest-md5-auth)
 139     (scram-md5  sieve-manage-scram-md5-p      sieve-manage-scram-md5-auth)
 140     (ntlm       sieve-manage-ntlm-p           sieve-manage-ntlm-auth)
 141     (plain      sieve-manage-plain-p          sieve-manage-plain-auth)
 142     (login      sieve-manage-login-p          sieve-manage-login-auth))
 143   "Definition of authenticators.
 144
 145 \(NAME CHECK AUTHENTICATE)
 146
 147 NAME names the authenticator.  CHECK is a function returning non-nil if
 148 the server support the authenticator and AUTHENTICATE is a function
 149 for doing the actual authentication."
 150   :group 'sieve-manage)
 151
 152 (defcustom sieve-manage-default-port 2000
 153   "Default port number or service name for managesieve protocol."
 154   :type 'integer
 155   :group 'sieve-manage)
 156
 157 (defcustom sieve-manage-default-stream 'network
 158   "Default stream type to use for `sieve-manage'.
 159 Must be a name of a stream in `sieve-manage-stream-alist'."
 160   :type 'symbol
 161   :group 'sieve-manage)
 162
 163 ;; Internal variables:
 164
 165 (defconst sieve-manage-local-variables '(sieve-manage-server
 166                                          sieve-manage-port
 167                                          sieve-manage-auth
 168                                          sieve-manage-stream
 169                                          sieve-manage-process
 170                                          sieve-manage-client-eol
 171                                          sieve-manage-server-eol
 172                                          sieve-manage-capability))
 173 (defconst sieve-manage-coding-system-for-read 'binary)
 174 (defconst sieve-manage-coding-system-for-write 'binary)
 175 (defvar sieve-manage-stream nil)
 176 (defvar sieve-manage-auth nil)
 177 (defvar sieve-manage-server nil)
 178 (defvar sieve-manage-port nil)
 179 (defvar sieve-manage-state 'closed
 180   "Managesieve state.
 181 Valid states are `closed', `initial', `nonauth', and `auth'.")
 182 (defvar sieve-manage-process nil)
 183 (defvar sieve-manage-capability nil)
 184
 185 ;; Internal utility functions
 186
 187 (defmacro sieve-manage-disable-multibyte ()
 188   "Enable multibyte in the current buffer."
 189   (unless (featurep 'xemacs)
 190     '(set-buffer-multibyte nil)))
 191
 192 (defun sieve-manage-erase (&optional p buffer)
 193   (let ((buffer (or buffer (current-buffer))))
 194     (and sieve-manage-log
 195          (with-current-buffer (get-buffer-create sieve-manage-log)
 196            (sieve-manage-disable-multibyte)
 197            (buffer-disable-undo)
 198            (goto-char (point-max))
 199            (insert-buffer-substring buffer (with-current-buffer buffer
 200                                              (point-min))
 201                                     (or p (with-current-buffer buffer
 202                                             (point-max)))))))
 203   (delete-region (point-min) (or p (point-max))))
 204
 205 (defun sieve-manage-open-1 (buffer)
 206   (with-current-buffer buffer
 207     (sieve-manage-erase)
 208     (setq sieve-manage-state 'initial
 209           sieve-manage-process
 210           (condition-case ()
 211               (funcall (nth 2 (assq sieve-manage-stream
 212                                     sieve-manage-stream-alist))
 213                        "sieve" buffer sieve-manage-server sieve-manage-port)
 214             ((error quit) nil)))
 215     (when sieve-manage-process
 216       (while (and (eq sieve-manage-state 'initial)
 217                   (memq (process-status sieve-manage-process) '(open run)))
 218         (message "Waiting for response from %s..." sieve-manage-server)
 219         (accept-process-output sieve-manage-process 1))
 220       (message "Waiting for response from %s...done" sieve-manage-server)
 221       (and (memq (process-status sieve-manage-process) '(open run))
 222            sieve-manage-process))))
 223
 224 ;; Streams
 225
 226 (defun sieve-manage-network-p (buffer)
 227   t)
 228
 229 (defun sieve-manage-network-open (name buffer server port)
 230   (let* ((port (or port sieve-manage-default-port))
 231          (coding-system-for-read sieve-manage-coding-system-for-read)
 232          (coding-system-for-write sieve-manage-coding-system-for-write)
 233          (process (open-network-stream name buffer server port)))
 234     (when process
 235       (while (and (memq (process-status process) '(open run))
 236                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 237                   (goto-char (point-min))
 238                   (not (sieve-manage-parse-greeting-1)))
 239         (accept-process-output process 1)
 240         (sit-for 1))
 241       (sieve-manage-erase nil buffer)
 242       (when (memq (process-status process) '(open run))
 243         process))))
 244
 245 (defun sieve-manage-starttls-p (buffer)
 246   (condition-case ()
 247       (progn
 248         (require 'starttls)
 249         (call-process "starttls"))
 250     (error nil)))
 251
 252 (defun sieve-manage-starttls-open (name buffer server port)
 253   (let* ((port (or port sieve-manage-default-port))
 254          (coding-system-for-read sieve-manage-coding-system-for-read)
 255          (coding-system-for-write sieve-manage-coding-system-for-write)
 256          (process (starttls-open-stream name buffer server port))
 257          done)
 258     (when process
 259       (while (and (memq (process-status process) '(open run))
 260                   (set-buffer buffer) ;; XXX "blue moon" nntp.el bug
 261                   (goto-char (point-min))
 262                   (not (sieve-manage-parse-greeting-1)))
 263         (accept-process-output process 1)
 264         (sit-for 1))
 265       (sieve-manage-erase nil buffer)
 266       (sieve-manage-send "STARTTLS")
 267       (starttls-negotiate process))
 268     (when (memq (process-status process) '(open run))
 269       process)))
 270
 271 ;; Authenticators
 272 (defun sieve-sasl-auth (buffer mech)
 273   "Login to server using the SASL MECH method."
 274   (message "sieve: Authenticating using %s..." mech)
 275   (with-current-buffer buffer
 276     (let* ((user-password (auth-source-user-or-password
 277                            '("login" "password")
 278                            sieve-manage-server
 279                            "sieve" nil t))
 280            (client (sasl-make-client (sasl-find-mechanism (list mech))
 281                                      (car user-password) "sieve" sieve-manage-server))
 282            (sasl-read-passphrase
 283             ;; We *need* to copy the password, because sasl will modify it
 284             ;; somehow.
 285             `(lambda (prompt) ,(copy-sequence (cadr user-password))))
 286            (step (sasl-next-step client nil))
 287            (tag (sieve-manage-send
 288                  (concat
 289                   "AUTHENTICATE \""
 290                   mech
 291                   "\""
 292                   (and (sasl-step-data step)
 293                        (concat
 294                         " \""
 295                         (base64-encode-string
 296                          (sasl-step-data step)
 297                          'no-line-break)
 298                         "\"")))))
 299            data rsp)
 300       (catch 'done
 301         (while t
 302           (setq rsp nil)
 303           (goto-char (point-min))
 304           (while (null (or (progn
 305                              (setq rsp (sieve-manage-is-string))
 306                              (if (not (and rsp (looking-at
 307                                                 sieve-manage-server-eol)))
 308                                  (setq rsp nil)
 309                                (goto-char (match-end 0))
 310                                rsp))
 311                            (setq rsp (sieve-manage-is-okno))))
 312             (accept-process-output sieve-manage-process 1)
 313             (goto-char (point-min)))
 314           (sieve-manage-erase)
 315           (when (sieve-manage-ok-p rsp)
 316             (when (and (cadr rsp)
 317                        (string-match "^SASL \"\\([^\"]+\\)\"" (cadr rsp)))
 318               (sasl-step-set-data
 319                step (base64-decode-string (match-string 1 (cadr rsp)))))
 320             (if (and (setq step (sasl-next-step client step))
 321                      (setq data (sasl-step-data step)))
 322                 ;; We got data for server but it's finished
 323                 (error "Server not ready for SASL data: %s" data)
 324               ;; The authentication process is finished.
 325               (throw 'done t)))
 326           (unless (stringp rsp)
 327             (error "Server aborted SASL authentication: %s" (caddr rsp)))
 328           (sasl-step-set-data step (base64-decode-string rsp))
 329           (setq step (sasl-next-step client step))
 330           (sieve-manage-send
 331            (if (sasl-step-data step)
 332                (concat "\""
 333                        (base64-encode-string (sasl-step-data step)
 334                                              'no-line-break)
 335                        "\"")
 336              ""))))
 337       (message "sieve: Login using %s...done" mech))))
 338
 339 (defun sieve-manage-cram-md5-p (buffer)
 340   (sieve-manage-capability "SASL" "CRAM-MD5" buffer))
 341
 342 (defun sieve-manage-cram-md5-auth (buffer)
 343   "Login to managesieve server using the CRAM-MD5 SASL method."
 344   (sieve-sasl-auth buffer "CRAM-MD5"))
 345
 346 (defun sieve-manage-digest-md5-p (buffer)
 347   (sieve-manage-capability "SASL" "DIGEST-MD5" buffer))
 348
 349 (defun sieve-manage-digest-md5-auth (buffer)
 350   "Login to managesieve server using the DIGEST-MD5 SASL method."
 351   (sieve-sasl-auth buffer "DIGEST-MD5"))
 352
 353 (defun sieve-manage-scram-md5-p (buffer)
 354   (sieve-manage-capability "SASL" "SCRAM-MD5" buffer))
 355
 356 (defun sieve-manage-scram-md5-auth (buffer)
 357   "Login to managesieve server using the SCRAM-MD5 SASL method."
 358   (sieve-sasl-auth buffer "SCRAM-MD5"))
 359
 360 (defun sieve-manage-ntlm-p (buffer)
 361   (sieve-manage-capability "SASL" "NTLM" buffer))
 362
 363 (defun sieve-manage-ntlm-auth (buffer)
 364   "Login to managesieve server using the NTLM SASL method."
 365   (sieve-sasl-auth buffer "NTLM"))
 366
 367 (defun sieve-manage-plain-p (buffer)
 368   (sieve-manage-capability "SASL" "PLAIN" buffer))
 369
 370 (defun sieve-manage-plain-auth (buffer)
 371   "Login to managesieve server using the PLAIN SASL method."
 372   (sieve-sasl-auth buffer "PLAIN"))
 373
 374 (defun sieve-manage-login-p (buffer)
 375   (sieve-manage-capability "SASL" "LOGIN" buffer))
 376
 377 (defun sieve-manage-login-auth (buffer)
 378   "Login to managesieve server using the LOGIN SASL method."
 379   (sieve-sasl-auth buffer "LOGIN"))
 380
 381 ;; Managesieve API
 382
 383 (defun sieve-manage-open (server &optional port stream auth buffer)
 384   "Open a network connection to a managesieve SERVER (string).
 385 Optional argument PORT is port number (integer) on remote server.
 386 Optional argument STREAM is any of `sieve-manage-streams' (a symbol).
 387 Optional argument AUTH indicates authenticator to use, see
 388 `sieve-manage-authenticators' for available authenticators.
 389 If nil, chooses the best stream the server is capable of.
 390 Optional argument BUFFER is buffer (buffer, or string naming buffer)
 391 to work in."
 392   (or port (setq port sieve-manage-default-port))
 393   (setq buffer (or buffer (format " *sieve* %s:%s" server port)))
 394   (with-current-buffer (get-buffer-create buffer)
 395     (mapc 'make-local-variable sieve-manage-local-variables)
 396     (sieve-manage-disable-multibyte)
 397     (buffer-disable-undo)
 398     (setq sieve-manage-server (or server sieve-manage-server))
 399     (setq sieve-manage-port port)
 400     (setq sieve-manage-stream (or stream sieve-manage-stream))
 401     (message "sieve: Connecting to %s..." sieve-manage-server)
 402     (if (let ((sieve-manage-stream
 403                (or sieve-manage-stream sieve-manage-default-stream)))
 404           (sieve-manage-open-1 buffer))
 405         ;; Choose stream.
 406         (let (stream-changed)
 407           (message "sieve: Connecting to %s...done" sieve-manage-server)
 408           (when (null sieve-manage-stream)
 409             (let ((streams sieve-manage-streams))
 410               (while (setq stream (pop streams))
 411                 (if (funcall (nth 1 (assq stream
 412                                           sieve-manage-stream-alist)) buffer)
 413                     (setq stream-changed
 414                           (not (eq (or sieve-manage-stream
 415                                        sieve-manage-default-stream)
 416                                    stream))
 417                           sieve-manage-stream stream
 418                           streams nil)))
 419               (unless sieve-manage-stream
 420                 (error "Couldn't figure out a stream for server"))))
 421           (when stream-changed
 422             (message "sieve: Reconnecting with stream `%s'..."
 423                      sieve-manage-stream)
 424             (sieve-manage-close buffer)
 425             (if (sieve-manage-open-1 buffer)
 426                 (message "sieve: Reconnecting with stream `%s'...done"
 427                          sieve-manage-stream)
 428               (message "sieve: Reconnecting with stream `%s'...failed"
 429                        sieve-manage-stream))
 430             (setq sieve-manage-capability nil))
 431           (if (sieve-manage-opened buffer)
 432               ;; Choose authenticator
 433               (when (and (null sieve-manage-auth)
 434                          (not (eq sieve-manage-state 'auth)))
 435                 (let ((auths sieve-manage-authenticators))
 436                   (while (setq auth (pop auths))
 437                     (if (funcall (nth 1 (assq
 438                                          auth
 439                                          sieve-manage-authenticator-alist))
 440                                  buffer)
 441                         (setq sieve-manage-auth auth
 442                               auths nil)))
 443                   (unless sieve-manage-auth
 444                     (error "Couldn't figure out authenticator for server"))))))
 445       (message "sieve: Connecting to %s...failed" sieve-manage-server))
 446     (when (sieve-manage-opened buffer)
 447       (sieve-manage-erase)
 448       buffer)))
 449
 450 (defun sieve-manage-authenticate (&optional buffer)
 451   "Authenticate on server in BUFFER.
 452 Return `sieve-manage-state' value."
 453   (with-current-buffer (or buffer (current-buffer))
 454     (if (eq sieve-manage-state 'nonauth)
 455         (when (funcall (nth 2 (assq sieve-manage-auth
 456                                     sieve-manage-authenticator-alist))
 457                        (current-buffer))
 458           (setq sieve-manage-state 'auth))
 459       sieve-manage-state)))
 460
 461 (defun sieve-manage-opened (&optional buffer)
 462   "Return non-nil if connection to managesieve server in BUFFER is open.
 463 If BUFFER is nil then the current buffer is used."
 464   (and (setq buffer (get-buffer (or buffer (current-buffer))))
 465        (buffer-live-p buffer)
 466        (with-current-buffer buffer
 467          (and sieve-manage-process
 468               (memq (process-status sieve-manage-process) '(open run))))))
 469
 470 (defun sieve-manage-close (&optional buffer)
 471   "Close connection to managesieve server in BUFFER.
 472 If BUFFER is nil, the current buffer is used."
 473   (with-current-buffer (or buffer (current-buffer))
 474     (when (sieve-manage-opened)
 475       (sieve-manage-send "LOGOUT")
 476       (sit-for 1))
 477     (when (and sieve-manage-process
 478                (memq (process-status sieve-manage-process) '(open run)))
 479       (delete-process sieve-manage-process))
 480     (setq sieve-manage-process nil)
 481     (sieve-manage-erase)
 482     t))
 483
 484 (defun sieve-manage-capability (&optional name value buffer)
 485   "Check if capability NAME of server BUFFER match VALUE.
 486 If it does, return the server value of NAME. If not returns nil.
 487 If VALUE is nil, do not check VALUE and return server value.
 488 If NAME is nil, return the full server list of capabilities."
 489   (with-current-buffer (or buffer (current-buffer))
 490     (if (null name)
 491         sieve-manage-capability
 492       (let ((server-value (cadr (assoc name sieve-manage-capability))))
 493         (when (or (null value)
 494                   (and server-value
 495                        (string-match value server-value)))
 496           server-value)))))
 497
 498 (defun sieve-manage-listscripts (&optional buffer)
 499   (with-current-buffer (or buffer (current-buffer))
 500     (sieve-manage-send "LISTSCRIPTS")
 501     (sieve-manage-parse-listscripts)))
 502
 503 (defun sieve-manage-havespace (name size &optional buffer)
 504   (with-current-buffer (or buffer (current-buffer))
 505     (sieve-manage-send (format "HAVESPACE \"%s\" %s" name size))
 506     (sieve-manage-parse-okno)))
 507
 508 (defun sieve-manage-putscript (name content &optional buffer)
 509   (with-current-buffer (or buffer (current-buffer))
 510     (sieve-manage-send (format "PUTSCRIPT \"%s\" {%d+}%s%s" name
 511                                ;; Here we assume that the coding-system will
 512                                ;; replace each char with a single byte.
 513                                ;; This is always the case if `content' is
 514                                ;; a unibyte string.
 515                                (length content)
 516                                sieve-manage-client-eol content))
 517     (sieve-manage-parse-okno)))
 518
 519 (defun sieve-manage-deletescript (name &optional buffer)
 520   (with-current-buffer (or buffer (current-buffer))
 521     (sieve-manage-send (format "DELETESCRIPT \"%s\"" name))
 522     (sieve-manage-parse-okno)))
 523
 524 (defun sieve-manage-getscript (name output-buffer &optional buffer)
 525   (with-current-buffer (or buffer (current-buffer))
 526     (sieve-manage-send (format "GETSCRIPT \"%s\"" name))
 527     (let ((script (sieve-manage-parse-string)))
 528       (sieve-manage-parse-crlf)
 529       (with-current-buffer output-buffer
 530         (insert script))
 531       (sieve-manage-parse-okno))))
 532
 533 (defun sieve-manage-setactive (name &optional buffer)
 534   (with-current-buffer (or buffer (current-buffer))
 535     (sieve-manage-send (format "SETACTIVE \"%s\"" name))
 536     (sieve-manage-parse-okno)))
 537
 538 ;; Protocol parsing routines
 539
 540 (defun sieve-manage-ok-p (rsp)
 541   (string= (downcase (or (car-safe rsp) "")) "ok"))
 542
 543 (defsubst sieve-manage-forward ()
 544   (or (eobp) (forward-char)))
 545
 546 (defun sieve-manage-is-okno ()
 547   (when (looking-at (concat
 548                      "^\\(OK\\|NO\\)\\( (\\([^)]+\\))\\)?\\( \\(.*\\)\\)?"
 549                      sieve-manage-server-eol))
 550     (let ((status (match-string 1))
 551           (resp-code (match-string 3))
 552           (response (match-string 5)))
 553       (when response
 554         (goto-char (match-beginning 5))
 555         (setq response (sieve-manage-is-string)))
 556       (list status resp-code response))))
 557
 558 (defun sieve-manage-parse-okno ()
 559   (let (rsp)
 560     (while (null rsp)
 561       (accept-process-output (get-buffer-process (current-buffer)) 1)
 562       (goto-char (point-min))
 563       (setq rsp (sieve-manage-is-okno)))
 564     (sieve-manage-erase)
 565     rsp))
 566
 567 (defun sieve-manage-parse-capability-1 ()
 568   "Accept a managesieve greeting."
 569   (let (str)
 570     (while (setq str (sieve-manage-is-string))
 571       (if (eq (char-after) ? )
 572           (progn
 573             (sieve-manage-forward)
 574             (push (list str (sieve-manage-is-string))
 575                   sieve-manage-capability))
 576         (push (list str) sieve-manage-capability))
 577       (forward-line)))
 578   (when (re-search-forward (concat "^OK.*" sieve-manage-server-eol) nil t)
 579     (setq sieve-manage-state 'nonauth)))
 580
 581 (defalias 'sieve-manage-parse-greeting-1 'sieve-manage-parse-capability-1)
 582
 583 (defun sieve-manage-is-string ()
 584   (cond ((looking-at "\"\\([^\"]+\\)\"")
 585          (prog1
 586              (match-string 1)
 587            (goto-char (match-end 0))))
 588         ((looking-at (concat "{\\([0-9]+\\+?\\)}" sieve-manage-server-eol))
 589          (let ((pos (match-end 0))
 590                (len (string-to-number (match-string 1))))
 591            (if (< (point-max) (+ pos len))
 592                nil
 593              (goto-char (+ pos len))
 594              (buffer-substring pos (+ pos len)))))))
 595
 596 (defun sieve-manage-parse-string ()
 597   (let (rsp)
 598     (while (null rsp)
 599       (accept-process-output (get-buffer-process (current-buffer)) 1)
 600       (goto-char (point-min))
 601       (setq rsp (sieve-manage-is-string)))
 602     (sieve-manage-erase (point))
 603     rsp))
 604
 605 (defun sieve-manage-parse-crlf ()
 606   (when (looking-at sieve-manage-server-eol)
 607     (sieve-manage-erase (match-end 0))))
 608
 609 (defun sieve-manage-parse-listscripts ()
 610   (let (tmp rsp data)
 611     (while (null rsp)
 612       (while (null (or (setq rsp (sieve-manage-is-okno))
 613                        (setq tmp (sieve-manage-is-string))))
 614         (accept-process-output (get-buffer-process (current-buffer)) 1)
 615         (goto-char (point-min)))
 616       (when tmp
 617         (while (not (looking-at (concat "\\( ACTIVE\\)?"
 618                                         sieve-manage-server-eol)))
 619           (accept-process-output (get-buffer-process (current-buffer)) 1)
 620           (goto-char (point-min)))
 621         (if (match-string 1)
 622             (push (cons 'active tmp) data)
 623           (push tmp data))
 624         (goto-char (match-end 0))
 625         (setq tmp nil)))
 626     (sieve-manage-erase)
 627     (if (sieve-manage-ok-p rsp)
 628         data
 629       rsp)))
 630
 631 (defun sieve-manage-send (cmdstr)
 632   (setq cmdstr (concat cmdstr sieve-manage-client-eol))
 633   (and sieve-manage-log
 634        (with-current-buffer (get-buffer-create sieve-manage-log)
 635          (sieve-manage-disable-multibyte)
 636          (buffer-disable-undo)
 637          (goto-char (point-max))
 638          (insert cmdstr)))
 639   (process-send-string sieve-manage-process cmdstr))
 640
 641 (provide 'sieve-manage)
 642
 643 ;; sieve-manage.el ends here