| blob | 605c348bab9dce7641d774478c8b0f0a1100509e |
1 -*- mode: m4 -*-
2 dnl We require Automake 1.7.2, which requires Autoconf 2.54.
3 dnl (It needs _AC_AM_CONFIG_HEADER_HOOK, for example.)
4 AC_PREREQ(2.54)
6 m4_define([gnumeric_version_epoch], [1])
7 m4_define([gnumeric_version_major], [12])
8 m4_define([gnumeric_version_minor], [19])
9 m4_define([gnumeric_version_extra], [])
10 m4_define([gnumeric_version_full],
11 [gnumeric_version_epoch.gnumeric_version_major.gnumeric_version_minor[]gnumeric_version_extra])
13 dnl Emphasize some of the checks.
14 m4_define([BIG_CHECKING], [AC_MSG_CHECKING([
15 ======== $1])])
17 AC_INIT([gnumeric], [gnumeric_version_full],
18 [http://bugzilla.gnome.org/enter_bug.cgi?product=gnumeric])
20 AC_CONFIG_SRCDIR(src/sheet.h)
21 AM_INIT_AUTOMAKE([dist-bzip2])
23 dnl Version info for libraries = CURRENT:REVISION:AGE
24 dnl
25 dnl Within each x.y.*, ABI is maintained backward and _forward_ compatible.
26 dnl (As a consequence, no exported function may be added.)
27 dnl So it's enough to have one interface number per each x.y.* branch.
28 dnl
29 dnl OTOH, we are not able to keep ABI strictly backward compatible throughout
30 dnl the whole x.*.*.
31 dnl The easiest way is to declare no ABI compatibility, ie. AGE is always 0.
32 dnl
33 m4_define([version_iface],
34 m4_eval(100 * gnumeric_version_epoch + gnumeric_version_major))
36 AC_SUBST([VERSION_INFO], [version_iface:gnumeric_version_minor:0])
37 AC_SUBST([VERSION_IFACE], [version_iface])
39 if test `expr gnumeric_version_major % 2` -eq 1; then
40 AC_MSG_NOTICE([NOTE: This is a development release])
41 gnumeric_devel=yes
42 gnumeric_api_ver=gnumeric_version_epoch.`expr gnumeric_version_major + 1`
43 dnl An explicit version number should be used in place of the above
44 dnl if the epoch is to change.
45 dnl gnumeric_api_ver=2.0
46 else
47 gnumeric_devel=no
48 gnumeric_api_ver=gnumeric_version_epoch.gnumeric_version_major
49 fi
50 gnumeric_api_ver_=`echo $gnumeric_api_ver | sed -e 's/\./_/g'`
52 dnl Almost like epoch.major but development versions look forward to the next
53 dnl stable release.
54 AC_SUBST([GNUMERIC_API_VER], [$gnumeric_api_ver])
55 AC_SUBST([GNUMERIC_API_VER_], [$gnumeric_api_ver_])
57 dnl This one is created by autoheader, ...
58 AC_CONFIG_HEADERS(gnumeric-config.h)
60 dnl ... and this one is a small subset, maintained manually,
61 dnl which will be installed.
62 AC_CONFIG_HEADERS(gnumeric-features.h)
63 dnl
64 dnl Make sure these two won't clash. Put the following to gnumeric-config.h:
65 AH_BOTTOM([/* Don't include gnumeric-features.h, it's a subset of gnumeric-config.h. */
66 #define GNUMERIC_FEATURES_H])
68 AM_MAINTAINER_MODE([enable])
70 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
72 dnl We use a LINGUAS file, so we need intltool >= 0.35:
73 IT_PROG_INTLTOOL([0.35.0])
74 IT_PO_SUBDIR(po-functions)
76 dnl We use $host and $host_os:
77 AC_CANONICAL_HOST
79 AC_ISC_POSIX
80 AC_PROG_CC
81 AC_PROG_YACC
82 AM_PROG_LEX
83 AC_PROG_LN_S
84 AC_HEADER_STDC
86 LT_PREREQ([2.2.6])
87 # Make --disable-static the default
88 LT_INIT([disable-static])
90 dnl Propagate Gnome-specific variable ACLOCAL_FLAGS to Makefile.
91 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
93 dnl *****************************
94 # Check for zlib.
95 dnl
96 dnl zlib is needed for the excel plugin; see plugins/excel/Makefile.am
97 dnl
98 _cppflags="${CPPFLAGS}"
99 _ldflags="${LDFLAGS}"
101 AC_ARG_WITH(zlib,
102 AS_HELP_STRING([--with-zlib=DIR], [use libz in DIR]),
103 [case $withval in
104 yes|no) ;;
105 *) Z_DIR=$withval
106 CPPFLAGS="${CPPFLAGS} -I$withval/include"
107 LDFLAGS="${LDFLAGS} -L$withval/lib"
108 ;;
109 esac])
111 if test "x$with_zlib" != xno; then
112 with_zlib=no
113 AC_CHECK_HEADER(zlib.h, [AC_CHECK_LIB(z, gzread, [with_zlib=yes])])
114 fi
116 if test "$with_zlib" = no; then
117 AC_MSG_ERROR([*** zlib is required])
118 fi
120 if test "x${Z_DIR}" != "x"; then
121 Z_CPPFLAGS="-I${Z_DIR}/include"
122 case ${host} in
123 *-*-solaris*) Z_LIBS="-L${Z_DIR}/lib -R${Z_DIR}/lib -lz" ;;
124 *) Z_LIBS="-L${Z_DIR}/lib -lz" ;;
125 esac
126 else
127 Z_LIBS="-lz"
128 fi
129 AC_SUBST(Z_CPPFLAGS)
130 AC_SUBST(Z_LIBS)
132 CPPFLAGS=${_cppflags}
133 LDFLAGS=${_ldflags}
135 dnl **********
136 dnl * Goffice
137 dnl **********
138 # Goffice releases are parallel installable, which do we depend on
139 GOFFICE_API_VER="0.10"
140 AC_SUBST(GOFFICE_API_VER)
141 # Components
142 GOFFICE_PLUGINS_DIR=`pkg-config --variable=PluginDir libgoffice-${GOFFICE_API_VER}`
143 AC_SUBST(GOFFICE_PLUGINS_DIR)
144 GOFFICE_VERSION=`pkg-config --modversion libgoffice-${GOFFICE_API_VER}`
145 AC_SUBST(GOFFICE_VERSION)
148 dnl PKG_PROG_PKG_CONFIG is expanded just before the first occurrence of
149 dnl PKG_CHECK_MODULES. Since this is inside an `if,' it can escape
150 dnl execution. Thus we need an explicit call:
151 PKG_PROG_PKG_CONFIG(0.18)
153 dnl *****************************
154 libspreadsheet_reqs="
155 libgoffice-${GOFFICE_API_VER} >= 0.10.14
156 libgsf-1 >= 1.14.24
157 libxml-2.0 >= 2.4.12
158 "
159 gnumeric_reqs="$libspreadsheet_reqs
160 glib-2.0 >= 2.38.0
161 gobject-2.0 >= 2.38.0
162 gmodule-2.0 >= 2.38.0
163 gthread-2.0 >= 2.38.0
164 pango >= 1.24.0
165 pangocairo >= 1.24.0
166 "
167 libspreadsheet_gtk_reqs="
168 gtk+-3.0 >= 3.8.7
169 "
171 gnumeric_gtk_reqs="$libspreadsheet_gtk_reqs"
173 ui_msg=
175 with_win32=no
176 case $host_os in
177 mingw* | pw32* | cygwin*)
178 with_win32=yes
179 ;;
180 esac
182 dnl *******************
183 dnl Should we use gtk ?
184 dnl *******************
185 gnumeric_with_gtk=true
186 AC_ARG_WITH(gtk, AS_HELP_STRING([--without-gtk], [Build without UI]))
187 if test "x$with_gtk" = xno; then
188 ui_msg="None (Gtk disabled by request)"
189 gnumeric_with_gtk=false
190 else
191 dnl We shouldn't silently default to --without-gtk.
192 dnl If the requirements are not met, fail.
193 ui_msg="Gtk"
194 PKG_CHECK_MODULES(GTK, [$libspreadsheet_gtk_reqs])
195 PKG_CHECK_MODULES(GTK, [$gnumeric_gtk_reqs])
196 fi
198 if test "x$gnumeric_with_gtk" = xtrue ; then
199 AC_DEFINE(GNM_WITH_GTK, 1, [Define if UI is built])
200 libspreadsheet_reqs="$libspreadsheet_reqs $libspreadsheet_gtk_reqs"
201 gnumeric_reqs="$gnumeric_reqs $gnumeric_gtk_reqs"
202 fi
204 AM_CONDITIONAL(WITH_GTK, $gnumeric_with_gtk)
206 dnl ****************************
207 dnl now that we have selected out libraries the whole collection in one
208 dnl shot so that we can have a nice neat compile/link line
209 dnl ****************************
211 PKG_CHECK_MODULES(LIBSPREADSHEET, $libspreadsheet_reqs)
212 AC_SUBST(LIBSPREADSHEET_LIBS)
213 AC_SUBST(LIBSPREADSHEET_CFLAGS)
215 PKG_CHECK_MODULES(GNUMERIC, $gnumeric_reqs)
216 AC_SUBST(GNUMERIC_LIBS)
217 AC_SUBST(GNUMERIC_CFLAGS)
219 with_native_win32=no
220 case $host_os in
221 mingw* | pw32*)
222 with_native_win32=yes
223 AC_ARG_VAR(WINDRES, [The windres executable (used by win32 builds only).])
224 AC_CHECK_TOOL(WINDRES, windres, :)
225 ;;
226 esac
227 AM_CONDITIONAL(WITH_WIN32, test $with_win32 = yes)
228 AM_CONDITIONAL(WITH_NATIVE_WIN32, test $with_native_win32 = yes)
229 AM_CONDITIONAL(CROSS_COMPILING, test x"$cross_compiling" != xno)
231 if test "x$with_win32" = "xyes"; then
232 GNUMERIC_PLUGIN_LDFLAGS="-avoid-version -no-undefined $GNUMERIC_LIBS -Wl,--enable-runtime-pseudo-reloc,--export-all-symbols \$(top_builddir)/src/libspreadsheet.la -s"
233 else
234 GNUMERIC_PLUGIN_LDFLAGS="-avoid-version"
235 fi
236 AC_SUBST(GNUMERIC_PLUGIN_LDFLAGS)
238 dnl **************************************************
239 dnl This needs to be done before we add aggressive -Werror=foo flags
240 dnl below.
241 AC_SUBST(GETTEXT_PACKAGE, gnumeric-${VERSION})
242 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",
243 [The package name, for gettext])
244 AM_GLIB_GNU_GETTEXT
246 dnl ****************************
247 dnl prep the pixmap generator
248 dnl ****************************
250 AC_ARG_VAR(GLIB_GENMARSHAL, [The glib-genmarshal executable.])
251 AC_CHECK_PROG(GLIB_GENMARSHAL, glib-genmarshal$ac_exeext, glib-genmarshal$ac_exeext)
253 AC_ARG_VAR(GDK_PIXBUF_CSOURCE, [The gdk-pixbuf-csource executable.])
254 AC_CHECK_PROG(GDK_PIXBUF_CSOURCE, gdk-pixbuf-csource$ac_exeext, gdk-pixbuf-csource$ac_exeext)
256 ## this should come after `AC_PROG_CC'
257 ifdef([GNOME_COMPILE_WARNINGS],
258 [GNOME_COMPILE_WARNINGS] CFLAGS="$CFLAGS $WARN_CFLAGS",
259 []
260 )
261 set_more_warnings=yes
262 if test "$GCC" = yes -a "x$set_more_warnings" != xno; then
263 dnl Clang needs this option, or else it will appear to support any
264 dnl warning option, only to spew warnings about them later.
265 uwoption="-Werror=unknown-warning-option"
266 SAVE_CFLAGS="$CFLAGS"
267 CFLAGS="$CFLAGS $uwoption"
268 AC_MSG_CHECKING([whether gcc understands $uwoption])
269 AC_COMPILE_IFELSE(
270 [AC_LANG_PROGRAM([], [])],
271 [has_unknown_warning_option=yes],
272 [has_unknown_warning_option=no; uwoption=""])
273 AC_MSG_RESULT($has_unknown_warning_option)
274 CFLAGS="$SAVE_CFLAGS"
276 warning_options="-Wsign-compare -Wpointer-arith \
277 -Wchar-subscripts -Wwrite-strings \
278 -Wdeclaration-after-statement -Wnested-externs \
279 -Wmissing-noreturn \
280 -Werror=missing-prototypes -Werror=nested-externs \
281 -Werror=implicit-function-declaration \
282 -Wmissing-declarations -Wno-pointer-sign \
283 -Werror=format-security -Wbitwise -Wcast-to-as \
284 -Wdefault-bitfield-sign -Wdo-while -Wparen-string \
285 -Wptr-subtraction-blows -Wreturn-void -Wtypesign \
286 -Wstrict-prototypes"
287 for option in $warning_options ; do
288 SAVE_CFLAGS="$CFLAGS"
289 CFLAGS="$CFLAGS $uwoption $option"
290 AC_MSG_CHECKING([whether gcc understands $option])
291 dnl Include a system header so we ignore Werror=... flags
292 dnl that cause trouble.
293 AC_COMPILE_IFELSE(
294 [AC_LANG_PROGRAM([[#include <stdio.h>]], [])],
295 [has_option=yes],
296 [has_option=no])
297 CFLAGS="$SAVE_CFLAGS"
298 if test $has_option = yes; then
299 CFLAGS="$CFLAGS $option"
300 fi
301 AC_MSG_RESULT($has_option)
302 unset has_option
303 unset SAVE_CFLAGS
304 done
305 unset option
306 fi
307 AC_SUBST(WARN_CFLAGS)
309 AC_ARG_ENABLE(component,
310 AS_HELP_STRING([--disable-component], [Do not build the goffice component]),
311 [], [enable_component=yes])
312 component_dir=""
313 if test x"$enable_component" = xyes; then
314 component_dir="component"
315 else
316 component_dir=""
317 fi
318 AC_SUBST(COMPONENT_DIR, $component_dir)
320 dnl ****************************
321 dnl GDA Plugin
322 dnl ****************************
323 try_gda=true
324 gda_msg=yes
325 gnomedb_msg=no
326 AC_ARG_WITH(gda,
327 AS_HELP_STRING([--with-gda], [Compile the Gnome Database Access plugin]),
328 if test "x$withval" != xyes; then
329 try_gda=false
330 gda_msg="Disabled by request"
331 fi
332 )
333 if test "$try_gda" = true; then
334 PKG_CHECK_MODULES(GDA, [libgda-5.0 >= 5.0.0, libgda-ui-5.0 >= 5.0.0],
335 [gda_msg=yes],
336 [gda_msg="NO. libgda problem"])
337 if test "$gda_msg" = yes; then
338 PKG_CHECK_MODULES(GNOMEDB, [libgnomedb-4.0 >= 3.99.6],
339 [gnomedb_msg="yes"],
340 [gnomedb_msg="NO. libgnomedb problem"])
341 if test "$gnomedb_msg" = yes; then
342 AC_DEFINE(HAVE_LIBGNOMEDB, 1, [ Define if libgnomedb support is compiled in])
343 fi
344 fi
345 fi
346 AM_CONDITIONAL(WITH_GDA, test x"$gda_msg" = xyes)
347 AC_SUBST(GDA_CFLAGS)
348 AC_SUBST(GDA_LIBS)
350 AM_CONDITIONAL(WITH_GNOMEDB, test x"$gnomedb_msg" = xyes)
351 AC_SUBST(GNOMEDB_CFLAGS)
352 AC_SUBST(GNOMEDB_LIBS)
354 dnl ****************************
356 AC_CHECK_DECL(fdopen, fdopen_works=yes, fdopen_works=no)
358 if test $fdopen_works = no ; then
359 unset ac_cv_have_decl_fdopen
360 CFLAGS="$CFLAGS -D_POSIX_SOURCE"
361 AC_MSG_NOTICE([adding -D_POSIX_SOURCE to CFLAGS])
362 AC_CHECK_DECL(fdopen, fdopen_works=yes, fdopen_works=no)
363 if test $fdopen_works = no ; then
364 AC_MSG_ERROR([fdopen is not available])
365 fi
366 fi
368 # Unfortunately, -D_POSIX_SOURCE turns off struct timeval on Solaris
369 AC_MSG_CHECKING([whether struct timeval is available])
370 AC_COMPILE_IFELSE(
371 [AC_LANG_PROGRAM([[#include <sys/time.h>]], [[struct timeval tv;]])],
372 [struct_timeval_works=yes],
373 [struct_timeval_works=no])
374 AC_MSG_RESULT($struct_timeval_works)
376 if test $struct_timeval_works = no ; then
377 CFLAGS="$CFLAGS -D__EXTENSIONS__"
378 AC_MSG_CHECKING([whether struct timeval is available with -D__EXTENSIONS__])
379 AC_COMPILE_IFELSE(
380 [AC_LANG_PROGRAM([[#include <sys/time.h>]], [[struct timeval tv;]])],
381 [struct_timeval_works=yes],
382 [struct_timeval_works=no])
383 AC_MSG_RESULT($struct_timeval_works)
384 if test $struct_timeval_works = no ; then
385 AC_MSG_ERROR([struct timeval is not available])
386 fi
387 fi
389 dnl src/functions/fn-math.c uses M_PI
391 AC_MSG_CHECKING([whether M_PI is available])
392 AC_COMPILE_IFELSE(
393 [AC_LANG_PROGRAM([[#include <math.h>]], [[double f = M_PI]])],
394 [works_without_bsd_source=yes],
395 [works_without_bsd_source=no])
396 AC_MSG_RESULT($works_without_bsd_source)
398 if test $works_without_bsd_source = no ; then
399 CFLAGS="$CFLAGS -D_BSD_SOURCE"
400 AC_MSG_CHECKING([whether M_PI is available with -D_BSD_SOURCE])
401 AC_COMPILE_IFELSE(
402 [AC_LANG_PROGRAM([[#include <math.h>]], [[double f = M_PI]])],
403 [m_pi_works=yes],
404 [m_pi_works=no])
405 AC_MSG_RESULT($m_pi_works)
406 if test $m_pi_works = no ; then
407 AC_MSG_ERROR([M_PI is not available])
408 fi
409 fi
411 AC_SUBST(GUILE_LIBS)
412 AC_SUBST(GUILE_INCS)
414 dnl Comment out the guile block:
415 ifelse([
416 dnl check for guile 1.5
417 try_guile=false
418 guile_msg="disabled pending some guile developer interest"
419 enable_guile=false
420 AC_ARG_WITH(guile,
421 AS_HELP_STRING([--with-guile], [Compile with Guile support or without it]),
422 if test "x$withval" = xyes; then
423 try_guile=true
424 fi
425 )
426 if $try_guile; then
427 AC_MSG_CHECKING(for guile >= 1.5)
428 if test "`guile -c '(display (string>=? (version) "1.4.1"))'`" != "#t"; then
429 AC_MSG_RESULT([Your Guile is too old. You need Guile 1.5 or later.])
430 else
431 AC_MSG_RESULT(found)
432 guile_msg="yes"
433 enable_guile=true
434 fi
435 fi
436 if $enable_guile; then
437 GNOME_CHECK_GUILE
438 fi
439 AM_CONDITIONAL(WITH_GUILE, $enable_guile)
440 ])
442 dnl **************************************************
443 dnl * psiconv support
444 dnl **************************************************
446 AC_ARG_WITH(psiconv,
447 AS_HELP_STRING([--without-psiconv], [Compile without Psiconv support]))
448 AC_ARG_VAR(PSICONV_CONFIG, [The psiconv-config executable.])
449 if test "x$with_psiconv" != xno; then
450 AC_CHECK_PROG(PSICONV_CONFIG,psiconv-config,psiconv-config)
451 if test x"$PSICONV_CONFIG" = x; then
452 psiconv_msg="missing dependencies"
453 else
454 AC_MSG_CHECKING(for psiconv >= 0.9.3)
455 if $PSICONV_CONFIG --version | awk -F. \
456 '{exit !($1 > 0 || $2 > 9 || ($2 == 9 && $3 >= 3))}'
457 then
458 PSICONV_CFLAGS=`$PSICONV_CONFIG --cflags`
459 PSICONV_LIBS=`$PSICONV_CONFIG --libs`
460 psiconv_msg=yes
461 else
462 psiconv_msg=no
463 fi
464 AC_MSG_RESULT($psiconv_msg)
465 fi
466 else
467 psiconv_msg=no
468 fi
469 AM_CONDITIONAL(WITH_PSICONV, test "x$psiconv_msg" = xyes)
470 AC_SUBST(PSICONV_LIBS)
471 AC_SUBST(PSICONV_CFLAGS)
473 try_paradox=true
474 enable_paradox=false
475 AC_ARG_WITH(paradox,
476 AS_HELP_STRING([--without-paradox], [Compile without Paradox support]),
477 if test "x$withval" = xno; then
478 try_paradox=false
479 fi
480 )
482 if $try_paradox; then
483 PKG_CHECK_MODULES(PARADOX,
484 [pxlib >= 0.4.0],
485 [paradox_msg="yes"],
486 [paradox_msg="missing dependencies"])
487 fi
489 if test "x$paradox_msg" = xyes; then
490 enable_paradox=true
491 fi
492 AM_CONDITIONAL(WITH_PARADOX, $enable_paradox)
493 AC_SUBST(PARADOX_LIBS)
494 AC_SUBST(PARADOX_CFLAGS)
496 plugin_list_given=false
497 PLUGIN_LIST=""
498 AC_ARG_ENABLE(plugins,
499 AS_HELP_STRING([--enable-plugins="text html"], [Compile only the listed plugins]),
500 [plugin_list_given=true
501 test "x$enableval" != xno && PLUGIN_LIST=$enableval
502 ])
503 AM_CONDITIONAL(PLUGIN_LIST_GIVEN, $plugin_list_given)
504 AC_SUBST(PLUGIN_LIST)
506 POFILES_FULL=
507 for lang in $ALL_LINGUAS; do
508 POFILES_FULL="$POFILES_FULL \$(top_srcdir)/po/$lang.po"
509 done
510 AC_SUBST(POFILES_FULL)
512 dnl
513 dnl Code to handle po-functions/Makefile* and po-functions/POTFILES*
514 dnl
515 dnl First, let me document how the po/ directory is dealt with.
516 dnl Dark mysteries here, so skip the next paragraph if you don't have enough
517 dnl holy water at your hand. You have been warned.
518 dnl
519 dnl AM_GLIB_GNU_GETTEXT creates an incorrect incarnation of po/POTFILES, as
520 dnl glib-gettext.m4 doesn't know about intltool tags. Later on, just before
521 dnl config.status is created, a code originating from intltool.m4 creates
522 dnl POTFILES again, this time correctly removing the intltool tags.
523 dnl config.status then creates po/Makefile, again in two steps. First,
524 dnl po/Makefile.in is created from po/Makefile.in.in the usual way, and then
525 dnl a code registered via the obsolete macro AC_OUTPUT_COMMANDS insterts the
526 dnl contents of file POTFILES to po/Makefile.
527 dnl
528 dnl But both glib-gettext and intltool have the dirname "po/" hardwired, so
529 dnl we are on our own with po-functions.
530 dnl
531 dnl We use a more straightforward approach for po-functions:
532 dnl 1) We create POTFILES immediately here.
533 dnl 2) We let config.status to create Makefile.in.
534 dnl 3) We use AC_CONFIG_COMMANDS to create Makefile.
535 dnl
536 [# Create po-functions/POTFILES:
537 if test -d po-functions; then
538 rm -f po-functions/POTFILES
539 else
540 mkdir po-functions
541 fi
542 case "$srcdir" in
543 .) top_srcdir=.. ;;
544 [\\/]* | ?:[\\/]* ) # Absolute name.
545 top_srcdir="$srcdir" ;;
546 *) top_srcdir="../$srcdir" ;;
547 esac
548 sed <$srcdir/po-functions/POTFILES.in -e '/^#/d' -e 's/^[[].*[]] *//' \
549 -e '/^[ ]*$/d' -e "s,^, $top_srcdir/," | \
550 sed -e '$!s/$/ \\/' >po-functions/POTFILES
551 ]
552 dnl Finally, register for creation of po-functions/Makefile:
553 dnl We do not currently do anything here.
554 AC_CONFIG_COMMANDS(po-functions/Makefile,
555 [cp po-functions/Makefile.in po-functions/Makefile])
557 SAVE_LIBS="$LIBS"
558 LIBS="$LIBS $GNUMERIC_LIBS"
559 AC_CHECK_FUNCS(mkfifo)
560 LIBS="$SAVE_LIBS"
561 unset SAVE_LIBS
563 AC_HEADER_SYS_WAIT
565 dnl Check for some functions
566 AC_CHECK_FUNCS(uname)
568 dnl FIXME: Does this really belong here?
569 AC_CHECK_FUNC(bind_textdomain_codeset,,[AC_CHECK_LIB(intl,bind_textdomain_codeset)])
571 dnl check for complete locale implementation
572 AC_CHECK_HEADERS(langinfo.h)
574 dnl check for rlimit
575 AC_CHECK_HEADERS(sys/resource.h)
577 SAVE_CFLAGS=$CFLAGS
578 SAVE_LIBS=$LIBS
579 CFLAGS="$CFLAGS $GNUMERIC_CFLAGS"
580 LIBS="$GNUMERIC_LIBS $LIBS"
582 AC_CHECK_FUNCS(gtk_cell_renderer_text_get_background_set gtk_cell_renderer_text_get_foreground_set gtk_cell_renderer_text_get_editable)
583 AC_CHECK_FUNCS(gtk_entry_set_editing_cancelled)
585 AC_MSG_CHECKING([for PANGO_WEIGHT_THIN etc.])
586 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pango/pango.h>]],
587 [[(void)(PANGO_WEIGHT_THIN == 42);
588 (void)(PANGO_WEIGHT_MEDIUM == 42);
589 (void)(PANGO_WEIGHT_ULTRAHEAVY == 42);]])],
590 [AC_DEFINE(HAVE_PANGO_WEIGHT_THIN_ETC, 1, [Define if PANGO_WEIGHT_THIN etc are available])
591 AC_MSG_RESULT(yes)],
592 [AC_MSG_RESULT(no)])
594 CFLAGS=$SAVE_CFLAGS
595 LIBS=$SAVE_LIBS
597 dnl We supply our own lgamma and lgamma_r when missing.
598 supply_lgamma_r=yes
599 AC_CHECK_FUNCS(lgamma_r)
600 if test $ac_cv_func_lgamma_r = no; then
601 AC_CHECK_LIB(m, lgamma_r,
602 [AC_DEFINE(HAVE_LGAMMA_R, 1,
603 [Define if the lgamma_r function is available]
604 )
605 supply_lgamma_r=no
606 LIBS="$LIBS -lm"])
607 else
608 supply_lgamma_r=no
609 fi
610 if test $supply_lgamma_r = yes; then
611 AC_DEFINE(GNM_SUPPLIES_LGAMMA_R, 1,
612 [Define if Gnumeric supplies the lgamma_r function]
613 )
614 fi
615 AC_CHECK_FUNCS(lgamma)
616 if test $ac_cv_func_lgamma = no; then
617 AC_DEFINE(GNM_SUPPLIES_LGAMMA, 1,
618 [Define if Gnumeric supplies the lgamma function]
619 )
620 fi
622 if test "x$with_win32" = "xyes"; then
623 AC_DEFINE(GNM_REDUCES_TRIG_RANGE, 1,
624 [Define if Gnumeric reduces the argument range of sin/cos/tan]
625 )
626 fi
628 float_msg=double
629 AC_ARG_WITH(long_double,
630 AS_HELP_STRING([--with-long-double], [Use long double for floating point]),
631 [if test "x$withval" = xyes; then
632 SAVE_CFLAGS="$CFLAGS"
633 SAVE_LIBS="$LIBS"
634 CFLAGS="$GNUMERIC_CFLAGS"
635 LIBS="$GNUMERIC_LIBS -lm"
637 AC_CHECK_HEADERS(sunmath.h)
639 AC_CHECK_FUNCS(go_render_generall,
640 ,
641 AC_MSG_ERROR([libgoffice needs to be compiled with long double support.]))
643 AC_CHECK_FUNCS(fabsl sqrtl expl expm1l logl log2l log10l log1pl ceill floorl powl hypotl \
644 sinl cosl tanl asinl acosl atanl atan2l fmodl lgammal lgammal_r \
645 sinhl coshl tanhl asinhl acoshl atanhl \
646 isnanl finitel,
647 ,
648 AC_MSG_ERROR([Long doubles require the $ldfunc function.]))
650 AC_MSG_CHECKING([checking for working erfl and erfcl])
651 have_erfl=no
652 have_erfcl=no
653 AC_RUN_IFELSE(
654 [AC_LANG_PROGRAM([[
655 #include <math.h>
656 #ifdef HAVE_SUNMATH_H
657 #include <sunmath.h>
658 #endif
659 ]],
660 [[
661 long double l1 = erfl (1.2L);
662 long double l2 = erfcl (1.2L);
663 return !(l1 >= 0.91 && l1 <= 0.92 &&
664 l2 >= 0.08 && l2 <= 0.09);
665 ]])],
666 [AC_DEFINE(HAVE_ERFL)
667 have_erfl=yes
668 AC_DEFINE(HAVE_ERFCL)
669 have_erfcl=yes
670 AC_MSG_RESULT(yes)],
671 AC_MSG_RESULT(no),
672 [AC_CHECK_FUNCS(erfl erfcl)
673 have_erfl=$ac_cv_func_erfl
674 have_erfcl=$ac_cv_func_erfcl
675 ])
677 if $have_erfl = no; then
678 AC_DEFINE(GNM_SUPPLIES_ERFL, 1,
679 [Define if Gnumeric supplies the erfl function]
680 )
681 fi
682 if $have_erfcl = no; then
683 AC_DEFINE(GNM_SUPPLIES_ERFCL, 1,
684 [Define if Gnumeric supplies the erfcl function]
685 )
686 fi
688 CFLAGS="$SAVE_CFLAGS"
689 LIBS="$SAVE_LIBS"
691 float_msg="long double (EXPERIMENTAL)"
692 AC_MSG_WARN([Long double support is experimental -- expect problems])
693 AC_DEFINE(GNM_WITH_LONG_DOUBLE, 1,
694 [Define if the long double type is to be used]
695 )
696 fi]
697 )
699 dnl **************************************************
700 dnl * Check for GSettings
701 dnl **************************************************
702 have_gsettings=no
703 AC_CHECK_LIB(gio-2.0,[g_settings_new],
704 [AC_DEFINE(HAVE_G_SETTINGS_NEW, 1,
705 [Define if the g_settings_new function is available])
706 GLIB_GSETTINGS
707 have_gsettings=yes],
708 [GSETTINGS_RULES=""
709 AC_SUBST(GSETTINGS_RULES)])
710 AM_CONDITIONAL(HAVE_GSETTINGS, test $have_gsettings=yes)
712 dnl **************************************************
713 dnl * Check for Perl
714 dnl **************************************************
716 AC_ARG_VAR(PERL, [The Perl executable.])
717 AC_CHECK_PROG(PERL, perl, perl)
719 want_perl=auto
720 have_perl=no
721 perl_reason=""
722 AC_ARG_WITH(perl, AS_HELP_STRING([--without-perl], [Do not build the Perl plugin loader]),
723 [case $withval in
724 yes) want_perl=yes;;
725 no) want_perl=no;;
726 esac])
727 if test "x$want_perl" = xno ; then
728 perl_reason="disabled by request"
729 else
730 if test "x$PERL" != x; then
731 BIG_CHECKING([for perl ExtUtils::Embed module])
732 if $PERL -e 'eval { require ExtUtils::Embed }; if ($@) { exit(1); } else { exit(0); }'
733 then
734 AC_MSG_RESULT(yes)
736 dnl Use ExtUtils::Embed to figure out the other options.
737 PERL_CCCDLFLAGS=`$PERL -MConfig -e 'print $Config{cccdlflags};'`
738 PERL_LDDLFLAGS=`$PERL -MConfig -e 'print $Config{lddlflags};'`
739 PERL_CC=`$PERL -MConfig -e 'print $Config{cc};'`
740 PERL_LD=`$PERL -MConfig -e 'print $Config{ld};'`
741 perlinc=`$PERL -MConfig -e 'print "$Config{archlib}/CORE";'`
742 PERL_CCOPTS="`$PERL -MExtUtils::Embed -e ccopts` -I$perlinc"
743 PERL_LDOPTS=`$PERL -MExtUtils::Embed -e ldopts`
745 AC_MSG_CHECKING([Checking for perl compiler, linker, libraries and headers])
746 rm -f testperl$ac_exeext testperl.$ac_objext testperl.c testperl.err
747 cat > testperl.c <<EOF
748 #include "EXTERN.h"
749 #include "perl.h"
750 #include "XSUB.h"
751 int main () { (void)&perl_construct; return 0; }
752 EOF
753 $PERL_CC $PERL_CCOPTS -c testperl.c >testperl.err 2>&1 &&
754 $PERL_LD -o testperl testperl.$ac_objext $PERL_LDOPTS >testperl.err 2>&1 &&
755 test -x testperl &&
756 have_perl=yes
757 AC_MSG_RESULT($have_perl)
759 if test "x$have_perl" != xyes; then
760 perl_reason="failed to compile test program"
761 cat testperl.err testperl.c >&AS_MESSAGE_LOG_FD
762 fi
764 rm -f testperl$ac_exeext testperl.$ac_objext testperl.c testperl.err
766 else
767 AC_MSG_RESULT(no)
768 perl_reason="missing parts of perl"
769 fi
770 else
771 perl_reason="missing perl"
772 fi
773 fi
775 if test "$want_perl" = xyes -a "x$have_perl" != xyes; then
776 AC_MSG_ERROR([Perl requested, but not available: $perl_reason])
777 fi
779 AM_CONDITIONAL(WITH_PERL, test "x$have_perl" = xyes)
780 if test "x$have_perl" = xyes ; then
781 perl_msg="yes (using $PERL)"
782 else
783 perl_msg="no ($perl_reason)"
784 fi
785 AC_SUBST(PERL_CCCDLFLAGS)
786 AC_SUBST(PERL_LDDLFLAGS)
787 AC_SUBST(PERL_CC)
788 AC_SUBST(PERL_LD)
789 AC_SUBST(PERL_CCOPTS)
790 AC_SUBST(PERL_LDOPTS)
792 dnl **************************************************
793 dnl * Check for Python
794 dnl **************************************************
795 python_msg="yes"
796 GNM_PY_CFLAGS=
797 GNM_PY_LDFLAGS=
798 GNM_PY_LIBADD=
800 AC_ARG_WITH(python, AS_HELP_STRING([--without-python], [Do not build the Python plugin loader]))
801 AC_ARG_VAR(PYTHON, [The Python executable.])
802 case $with_python in
803 yes|no) ;;
804 ?*) AC_MSG_ERROR([You cannot use --with-python with an argument.
805 If you want to specify a path to your Python executable, use:
806 $srcdir/configure PYTHON=/path/to/your/python ...]);;
807 esac
808 if test "x$with_python" != xno; then
809 AC_CHECK_PROGS(PYTHON, python python2 python2.5 python2.4 python2.3 python2.2 python2.1 python2.0)
810 if test "x$PYTHON" = x; then
811 python_msg="could not find python"
812 fi
813 else
814 python_msg="Disabled by request"
815 fi
817 if test "x$python_msg" = xyes; then
818 BIG_CHECKING([for python = 2.x])
819 [PY_VERSION=`$PYTHON -c 'import sys ; sys.stdout.write(sys.version[0:3])'`
820 major_ver=`$PYTHON -c 'import sys ; sys.stdout.write(sys.version[0:1])'`]
821 if test "x$major_ver" = "x2"; then
822 AC_MSG_RESULT(yes)
823 if test "x$with_native_win32" = xyes ; then
824 # 2.x on linux, 2x on win32
825 PY_VERSION=`echo $PY_VERSION | sed -e 's/\\.//'`
826 fi
827 else
828 AC_MSG_RESULT(no)
829 python_msg="NO. Python version \"${PY_VERSION}\" is too old."
830 fi
831 fi
833 if test "x$python_msg" = xyes; then
834 if test "x$PY_PREFIX" = x; then
835 PY_PREFIX=`$PYTHON -c 'import sys ; sys.stdout.write(sys.prefix)'`
836 fi
837 if test "x$PY_INCLUDE_DIR" = x; then
838 if test "x$with_native_win32" = xyes ; then
839 PY_INCLUDES="-I$PY_PREFIX/include"
840 else
841 PY_INCLUDES=`$PYTHON -c 'import sys ; import distutils.sysconfig ; sys.stdout.write("-I" + distutils.sysconfig.get_python_inc()) ; sys.stdout.write(" -I" + distutils.sysconfig.get_python_inc(plat_specific=True))'`
842 fi
843 else
844 PY_INCLUDES="-I$PY_INCLUDE_DIR"
845 fi
847 python_msg="unable to find Python.h"
848 for py_include in $PY_INCLUDES; do
849 py_include_dir="${py_include#-I}"
850 BIG_CHECKING(Look for $py_include_dir/Python.h)
851 if test -f $py_include_dir/Python.h; then
852 AC_MSG_RESULT(yes)
853 python_msg="yes"
854 break
855 else
856 AC_MSG_RESULT(no)
857 fi
858 done
859 fi
861 if test "x$python_msg" = xyes; then
862 m4_define([pygobject_required_version], [3.0.0])
863 PKG_CHECK_MODULES(PYGOBJECT, pygobject-3.0 >= pygobject_required_version,,
864 [python_msg="Missing pygobject"])
865 fi
867 AM_CONDITIONAL(WITH_PYTHON, test "x$python_msg" = xyes)
868 if test "x$python_msg" = xyes; then
869 if test "x$PY_LIB_DIR" = x; then
870 if test "x$with_native_win32" = xyes ; then
871 PY_LIB_DIR="$PY_PREFIX/libs"
872 else
873 PY_LIB_DIR=`$PYTHON -c 'import sys ; import distutils.sysconfig ; sys.stdout.write(distutils.sysconfig.get_config_var("LIBPL"))'`
874 fi
875 fi
877 GNM_PY_CFLAGS="$PY_INCLUDES $PYGOBJECT_CFLAGS"
878 GNM_PY_LDFLAGS="-L$PY_LIB_DIR -lpython$PY_VERSION $PYGOBJECT_LIBS"
879 python_msg="yes (using $PYTHON)"
880 elif test "x$with_python" = "xyes"; then
881 AC_MSG_ERROR([$python_msg])
882 fi
884 AC_SUBST(GNM_PY_CFLAGS)
885 AC_SUBST(GNM_PY_LDFLAGS)
886 AC_SUBST(GNM_PY_LIBADD)
888 AC_CHECK_PROG(SCROLLKEEPER_PREINSTALL,scrollkeeper-preinstall,yes,no)
889 AM_CONDITIONAL(WITH_SCROLLKEEPER, test "x$SCROLLKEEPER_PREINSTALL" = xyes -a "x$with_win32" != "xyes")
891 # Support for PDF docs
892 AC_ARG_ENABLE(pdfdocs,
893 AS_HELP_STRING([--enable-pdfdocs],[Generate documentation in Portable Document Format]),
894 [enable_pdfdocs=$enableval],
895 [enable_pdfdocs=no])
896 pdf_msg="No, not requested.";
897 if test x"$enable_pdfdocs" = xyes; then
898 pdfroute=""
899 AC_CHECK_PROG(DBCONTEXT, [dbcontext], [dbcontext], [])
900 AC_CHECK_PROG(DBLATEX, [dblatex], [dblatex], [])
901 if test x"$DBCONTEXT" = x"dbcontext"; then
902 pdfroute=dbcontext
903 else
904 if test x"$DBLATEX" = x"dblatex"; then
905 pdfroute=dblatex
906 fi
907 fi
908 if test x"$pdfroute" != x""; then
909 pdf_msg="Yes, through $pdfroute."
910 else
911 AC_MSG_ERROR([
912 Did not find a suitable tool for generating Portable Document Format from
913 DocBook XML - aborting.
915 Both the DocBook to ConTeXt and the DocBook to LaTeX conversion tool can be
916 obtained from
917 http://dblatex.sourceforge.net/
918 ])
919 exit 1
920 fi
921 fi
922 AM_CONDITIONAL(ENABLE_PDFDOCS, test x"$enable_pdfdocs" = xyes)
923 AM_CONDITIONAL(ENABLE_PDF_VIA_DBCONTEXT, test x"$pdfroute" = x"dbcontext")
924 AM_CONDITIONAL(ENABLE_PDF_VIA_DBLATEX, test x"$pdfroute" = x"dblatex")
927 dnl A tricky way to comment out in m4:
928 ifelse([
929 dnl **************************************************
930 dnl * Check for mono
931 dnl **************************************************
932 with_mono=no
933 mono_msg="disabled, still experimental"
935 AC_ARG_WITH(mono, AS_HELP_STRING([--with-mono], [Compile the mono scripting engine]))
936 case $with_mono in
937 no) mono_msg="Disabled by request";;
938 *)
939 PKG_CHECK_MODULES(MONO, mono,
940 [with_mono=yes
941 AC_DEFINE(WITH_MONO, 1, [Define if mono .NET engine is available])],
942 [with_mono=no])
943 mono_msg=$with_mono
944 ;;
945 esac
946 AM_CONDITIONAL(WITH_MONO, test "x$with_mono" = xyes)
947 AC_SUBST(MONO_CFLAGS)
948 AC_SUBST(MONO_LIBS)
949 ])
951 # GObject Introspection
952 GIR_REQ=1.0.0
953 AC_ARG_ENABLE(introspection,
954 AS_HELP_STRING([--enable-introspection[=@<:@no/auto/yes@:>@]],
955 [Enable introspection for this build]),,
956 [enable_introspection=no])
958 AC_MSG_CHECKING([for gobject-introspection])
960 dnl presence/version checking
961 AS_CASE([$enable_introspection],
962 [no], [
963 found_introspection="no (disabled, use --enable-introspection to enable)"
964 ],
965 [yes],[
966 PKG_CHECK_EXISTS([gobject-introspection-1.0],,
967 AC_MSG_ERROR([gobject-introspection-1.0 is not installed]))
968 PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $GIR_REQ],
969 found_introspection=yes,
970 AC_MSG_ERROR([You need to have gobject-introspection >= $1 installed to build AC_PACKAGE_NAME]))
971 ],
972 [auto],[
973 PKG_CHECK_EXISTS([gobject-introspection-1.0 >= $GIR_REQ], found_introspection=yes, found_introspection=no)
974 dnl Canonicalize enable_introspection
975 enable_introspection=$found_introspection
976 ],
977 [
978 AC_MSG_ERROR([invalid argument passed to --enable-introspection, should be one of @<:@no/auto/yes@:>@])
979 ])
981 AC_MSG_RESULT([$found_introspection])
983 if test "x$found_introspection" = "xyes"; then
984 dnl You can override INTROSPECTION_GIRDIR and INTROSPECTION_TYPELIBDIR
985 dnl if you wish. If you override the latter, you might want to set
986 dnl GI_TYPELIB_PATH to include the same directory. For example
987 dnl
988 dnl GI_TYPELIB_PATH=$PREFIX/lib64/girepository-1.0
989 dnl INTROSPECTION_TYPELIBDIR=$GI_TYPELIB_PATH
990 dnl INTROSPECTION_GIRDIR=$PREFIX/share/gir-1.0
991 dnl
992 dnl Note, that unlike gnumeric's binaries, nothing tells python where
993 dnl to find gnumeric libraries, so you might also need to set
994 dnl LD_LIBRARY_PATH.
996 INTROSPECTION_SCANNER=`$PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0`
997 INTROSPECTION_COMPILER=`$PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0`
998 INTROSPECTION_GENERATE=`$PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0`
999 if test "x$INTROSPECTION_GIRDIR" = x; then
1000 INTROSPECTION_GIRDIR=`$PKG_CONFIG --variable=girdir gobject-introspection-1.0`
1001 fi
1002 if test "x$INTROSPECTION_TYPELIBDIR" = x; then
1003 INTROSPECTION_TYPELIBDIR="$($PKG_CONFIG --variable=typelibdir gobject-introspection-1.0)"
1004 fi
1005 INTROSPECTION_CFLAGS=`$PKG_CONFIG --cflags gobject-introspection-1.0`
1006 INTROSPECTION_LIBS=`$PKG_CONFIG --libs gobject-introspection-1.0`
1007 INTROSPECTION_MAKEFILE=`$PKG_CONFIG --variable=datadir gobject-introspection-1.0`/gobject-introspection-1.0/Makefile.introspection
1008 else
1009 INTROSPECTION_SCANNER=
1010 INTROSPECTION_COMPILER=
1011 INTROSPECTION_GENERATE=
1012 INTROSPECTION_GIRDIR=
1013 INTROSPECTION_TYPELIBDIR=
1014 INTROSPECTION_CFLAGS=
1015 INTROSPECTION_LIBS=
1016 INTROSPECTION_MAKEFILE=
1017 fi
1018 AC_SUBST(INTROSPECTION_SCANNER)
1019 AC_SUBST(INTROSPECTION_COMPILER)
1020 AC_SUBST(INTROSPECTION_GENERATE)
1021 AC_SUBST(INTROSPECTION_GIRDIR)
1022 AC_SUBST(INTROSPECTION_TYPELIBDIR)
1023 AC_SUBST(INTROSPECTION_CFLAGS)
1024 AC_SUBST(INTROSPECTION_LIBS)
1025 AC_SUBST(INTROSPECTION_MAKEFILE)
1027 AM_CONDITIONAL(HAVE_INTROSPECTION, test "x$found_introspection" = "xyes")
1028 dnl we need to change the install directories for distcheck
1029 AC_ARG_WITH([gir-dir],
1030 AS_HELP_STRING(
1031 [--with-gir-dir],
1032 [
1033 path to gir repository
1034 (automatically detected via pkg-config)
1035 ]
1036 ),
1037 [GIRDIR=$withval],
1038 [GIRDIR=$INTROSPECTION_GIRDIR]
1039 )
1040 AC_SUBST(GIRDIR)
1041 AC_ARG_WITH([typelib-dir],
1042 AS_HELP_STRING(
1043 [--with-typelib-dir],
1044 [
1045 path to typelibs repository
1046 (automatically detected via pkg-config)
1047 ]
1048 ),
1049 [TYPELIBDIR=$withval],
1050 [TYPELIBDIR=$INTROSPECTION_TYPELIBDIR]
1051 )
1052 AC_SUBST(TYPELIBDIR)
1054 dnl **************************************************
1055 dnl * Config defaults
1056 dnl **************************************************
1057 dnl
1058 dnl These are changed in gutils.c for WIN32 packages
1059 AC_SUBST(gnumeric_datadir, '${datadir}/gnumeric/${VERSION}')
1060 AC_SUBST(gnumeric_libdir, '${libdir}/gnumeric/${VERSION}')
1061 AC_SUBST(gnumeric_icondir, '${datadir}/pixmaps/gnumeric')
1062 AC_SUBST(gnumeric_localedir, '${prefix}/${DATADIRNAME}/locale')
1063 dnl
1064 AC_SUBST(gnumeric_plugindir, '${gnumeric_libdir}/plugins')
1065 AC_SUBST(gnumeric_externplugindir, '${libdir}/gnumeric/${GNUMERIC_API_VER}/plugins')
1067 AC_SUBST(YYYYMMDD, `date +%Y%m%d`)
1069 dnl Export to gnumeric-config.h
1070 AC_DEFINE(GNM_VERSION_FULL, "gnumeric_version_full",
1071 [The version number of this release, with optional extra suffix])
1072 AC_DEFINE(GNM_VERSION_EPOCH, gnumeric_version_epoch,
1073 [The Epoch of this release])
1074 AC_DEFINE(GNM_VERSION_MAJOR, gnumeric_version_major,
1075 [The Major version number of this release])
1076 AC_DEFINE(GNM_VERSION_MINOR, gnumeric_version_minor,
1077 [The Minor version number of this release])
1078 AC_DEFINE(GNM_VERSION_EXTRA, "gnumeric_version_extra",
1079 [Extra, possibly empty tag for this release])
1080 AC_DEFINE(GNM_API_VERSION, "GNUMERIC_API_VER",
1081 [The API version number of this release])
1083 AC_OUTPUT([
1084 gnumeric.spec
1085 Makefile
1086 libspreadsheet.pc
1087 icons/Makefile
1088 icons/16x16/Makefile
1089 icons/22x22/Makefile
1090 icons/24x24/Makefile
1091 icons/32x32/Makefile
1092 icons/48x48/Makefile
1093 icons/256x256/Makefile
1094 src/Makefile
1095 src/dialogs/Makefile
1096 src/widgets/Makefile
1097 src/tools/Makefile
1098 src/cut-n-paste-code/Makefile
1099 doc/Makefile
1100 doc/C/Makefile
1101 doc/C/figures/Makefile
1102 doc/C/figures/icons/Makefile
1103 doc/developer/Makefile
1104 plugins/Makefile
1105 plugins/fn-christian-date/Makefile
1106 plugins/fn-complex/Makefile
1107 plugins/fn-database/Makefile
1108 plugins/fn-date/Makefile
1109 plugins/fn-derivatives/Makefile
1110 plugins/fn-eng/Makefile
1111 plugins/fn-erlang/Makefile
1112 plugins/fn-financial/Makefile
1113 plugins/fn-hebrew-date/Makefile
1114 plugins/fn-info/Makefile
1115 plugins/fn-logical/Makefile
1116 plugins/fn-lookup/Makefile
1117 plugins/fn-math/Makefile
1118 plugins/fn-numtheory/Makefile
1119 plugins/fn-r/Makefile
1120 plugins/fn-stat/Makefile
1121 plugins/fn-string/Makefile
1122 plugins/fn-random/Makefile
1123 plugins/fn-tsa/Makefile
1124 plugins/applix/Makefile
1125 plugins/dif/Makefile
1126 plugins/excel/Makefile
1127 plugins/excelplugins/Makefile
1128 plugins/gda/Makefile
1129 plugins/gnome-db/Makefile
1130 plugins/gnome-glossary/Makefile
1131 plugins/html/Makefile
1132 plugins/lotus-123/Makefile
1133 plugins/lpsolve/Makefile
1134 plugins/nlsolve/Makefile
1135 plugins/glpk/Makefile
1136 plugins/mps/Makefile
1137 plugins/oleo/Makefile
1138 plugins/openoffice/Makefile
1139 plugins/paradox/Makefile
1140 plugins/perl-func/Makefile
1141 plugins/perl-loader/Makefile
1142 plugins/plan-perfect/Makefile
1143 plugins/psiconv/Makefile
1144 plugins/py-func/Makefile
1145 plugins/python-loader/Makefile
1146 plugins/qpro/Makefile
1147 plugins/sample_datasource/Makefile
1148 plugins/sc/Makefile
1149 plugins/sylk/Makefile
1150 plugins/uihello/Makefile
1151 plugins/xbase/Makefile
1152 po/Makefile.in
1153 po-functions/Makefile.in
1154 schemas/Makefile
1155 schemas/org.gnome.gnumeric.gschema.xml.in
1156 schemas/org.gnome.gnumeric.dialogs.gschema.xml.in
1157 schemas/org.gnome.gnumeric.plugin.gschema.xml.in
1158 templates/Makefile
1159 templates/english/Makefile
1160 templates/autoformat/Makefile
1161 test/Makefile
1162 tools/Makefile
1163 tools/win32/Makefile
1164 tools/win32/moduleset
1165 tools/win32/gnumeric.nsi
1166 component/Makefile
1167 ])
1169 echo "
1171 Configuration:
1173 Source code location: ${srcdir}
1174 Compiler: ${CC}
1175 Compiler flags: ${CFLAGS}
1176 Floating point type: ${float_msg}
1178 UI: ${ui_msg}
1180 Perl Support: ${perl_msg}
1181 Python Support: ${python_msg}
1183 GDA support: ${gda_msg}
1184 GNOME-DB support: ${gnomedb_msg}
1185 Psiconv support: ${psiconv_msg}
1187 PDF documentation: ${pdf_msg}
1188 "
1189 # Mono support: ${mono_msg}
1190 # Guile Support: ${guile_msg}