m4/hypotl.m4

   1 # hypotl.m4 serial 6
   2 dnl Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_HYPOTL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_hypotl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_HYPOT])
  12
  13   dnl Persuade glibc <math.h> to declare hypotl().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether hypotl() exists. Assume that hypotl(), if it exists, is
  17   dnl defined in the same library as hypot().
  18   save_LIBS="$LIBS"
  19   LIBS="$LIBS $HYPOT_LIBM"
  20   AC_CHECK_FUNCS([hypotl])
  21   LIBS="$save_LIBS"
  22   if test $ac_cv_func_hypotl = yes; then
  23     HYPOTL_LIBM="$HYPOT_LIBM"
  24
  25     save_LIBS="$LIBS"
  26     LIBS="$LIBS $HYPOTL_LIBM"
  27     gl_FUNC_HYPOTL_WORKS
  28     LIBS="$save_LIBS"
  29     case "$gl_cv_func_hypotl_works" in
  30       *yes) ;;
  31       *) REPLACE_HYPOTL=1 ;;
  32     esac
  33
  34     m4_ifdef([gl_FUNC_HYPOTL_IEEE], [
  35       if test $gl_hypotl_required = ieee && test $REPLACE_HYPOTL = 0; then
  36         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  37         AC_CACHE_CHECK([whether hypotl works according to ISO C 99 with IEC 60559],
  38           [gl_cv_func_hypotl_ieee],
  39           [
  40             save_LIBS="$LIBS"
  41             LIBS="$LIBS $HYPOTL_LIBM"
  42             AC_RUN_IFELSE(
  43               [AC_LANG_SOURCE([[
  44 #ifndef __NO_MATH_INLINES
  45 # define __NO_MATH_INLINES 1 /* for glibc */
  46 #endif
  47 #include <math.h>
  48 /* Compare two numbers with ==.
  49    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  50    'x == x' test.  */
  51 static int
  52 numeric_equal (long double x, long double y)
  53 {
  54   return x == y;
  55 }
  56 static long double dummy (long double x, long double y) { return 0; }
  57 long double zero;
  58 long double one = 1.0L;
  59 int main (int argc, char *argv[])
  60 {
  61   long double (*my_hypotl) (long double, long double) = argc ? hypotl : dummy;
  62   long double f;
  63   /* Test hypotl(NaN,Infinity).
  64      This test fails on OSF/1 5.1 and native Windows.  */
  65   f = my_hypotl (zero / zero, one / zero);
  66   if (!numeric_equal (f, f))
  67     return 1;
  68   return 0;
  69 }
  70               ]])],
  71               [gl_cv_func_hypotl_ieee=yes],
  72               [gl_cv_func_hypotl_ieee=no],
  73               [case "$host_os" in
  74                          # Guess yes on glibc systems.
  75                  *-gnu*) gl_cv_func_hypotl_ieee="guessing yes" ;;
  76                          # If we don't know, assume the worst.
  77                  *)      gl_cv_func_hypotl_ieee="guessing no" ;;
  78                esac
  79               ])
  80             LIBS="$save_LIBS"
  81           ])
  82         case "$gl_cv_func_hypotl_ieee" in
  83           *yes) ;;
  84           *) REPLACE_HYPOTL=1 ;;
  85         esac
  86       fi
  87     ])
  88   else
  89     HAVE_HYPOTL=0
  90     dnl If the function is declared but does not appear to exist, it may be
  91     dnl defined as an inline function. In order to avoid a conflict, we have
  92     dnl to define rpl_hypotl, not hypotl.
  93     AC_CHECK_DECLS([hypotl], [REPLACE_HYPOTL=1], , [[#include <math.h>]])
  94   fi
  95   if test $HAVE_HYPOTL = 0 || test $REPLACE_HYPOTL = 1; then
  96     dnl Find libraries needed to link lib/hypotl.c.
  97     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
  98       HYPOTL_LIBM="$HYPOT_LIBM"
  99     else
 100       AC_REQUIRE([gl_FUNC_FABSL])
 101       AC_REQUIRE([gl_FUNC_FREXPL])
 102       AC_REQUIRE([gl_FUNC_LDEXPL])
 103       AC_REQUIRE([gl_FUNC_SQRTL])
 104       HYPOTL_LIBM=
 105       dnl Append $FABSL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 106       case " $HYPOTL_LIBM " in
 107         *" $FABSL_LIBM "*) ;;
 108         *) HYPOTL_LIBM="$HYPOTL_LIBM $FABSL_LIBM" ;;
 109       esac
 110       dnl Append $FREXPL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 111       case " $HYPOTL_LIBM " in
 112         *" $FREXPL_LIBM "*) ;;
 113         *) HYPOTL_LIBM="$HYPOTL_LIBM $FREXPL_LIBM" ;;
 114       esac
 115       dnl Append $LDEXPL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 116       case " $HYPOTL_LIBM " in
 117         *" $LDEXPL_LIBM "*) ;;
 118         *) HYPOTL_LIBM="$HYPOTL_LIBM $LDEXPL_LIBM" ;;
 119       esac
 120       dnl Append $SQRTL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 121       case " $HYPOTL_LIBM " in
 122         *" $SQRTL_LIBM "*) ;;
 123         *) HYPOTL_LIBM="$HYPOTL_LIBM $SQRTL_LIBM" ;;
 124       esac
 125     fi
 126   fi
 127   AC_SUBST([HYPOTL_LIBM])
 128 ])
 129
 130 dnl Test whether hypotl() works.
 131 dnl On OpenBSD 5.1/SPARC,
 132 dnl hypotl (2.5541394760659556563446062497337725156L, 7.7893454113437840832487794525518765265L)
 133 dnl has rounding errors that eat up the last 8 to 9 decimal digits.
 134 AC_DEFUN([gl_FUNC_HYPOTL_WORKS],
 135 [
 136   AC_REQUIRE([AC_PROG_CC])
 137   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 138   AC_CACHE_CHECK([whether hypotl works], [gl_cv_func_hypotl_works],
 139     [
 140       AC_RUN_IFELSE(
 141         [AC_LANG_SOURCE([[
 142 #include <float.h>
 143 #include <math.h>
 144 static long double
 145 my_ldexpl (long double x, int d)
 146 {
 147   for (; d > 0; d--)
 148     x *= 2.0L;
 149   for (; d < 0; d++)
 150     x *= 0.5L;
 151   return x;
 152 }
 153 volatile long double x;
 154 volatile long double y;
 155 volatile long double z;
 156 int main ()
 157 {
 158   long double err;
 159
 160   x = 2.5541394760659556563446062497337725156L;
 161   y = 7.7893454113437840832487794525518765265L;
 162   z = hypotl (x, y);
 163   err = z * z - (x * x + y * y);
 164   err = my_ldexpl (err, LDBL_MANT_DIG);
 165   if (err < 0)
 166     err = - err;
 167   if (err > 1000.0L)
 168     return 1;
 169   return 0;
 170 }
 171 ]])],
 172         [gl_cv_func_hypotl_works=yes],
 173         [gl_cv_func_hypotl_works=no],
 174         [case "$host_os" in
 175            openbsd*) gl_cv_func_hypotl_works="guessing no";;
 176            *)        gl_cv_func_hypotl_works="guessing yes";;
 177          esac
 178         ])
 179     ])
 180 ])