macros/pkg.m4

   1 # pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
   2 #
   3 # Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18 #
  19 # As a special exception to the GNU General Public License, if you
  20 # distribute this file as part of a program that contains a
  21 # configuration script generated by Autoconf, you may include it under
  22 # the same distribution terms that you use for the rest of that program.
  23
  24
  25 # PKG_PROG_PKG_CONFIG([MIN-VERSION])
  26 # ----------------------------------
  27 AC_DEFUN([PKG_PROG_PKG_CONFIG],
  28 [m4_pattern_forbid([^_?PKG_[A-Z_]+$])
  29 m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
  30 AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
  31 if test x$cross_compiling = xno; then
  32   if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
  33     AC_PATH_TOOL([PKG_CONFIG], [pkg-config], ,[${pathlist}])
  34   fi
  35   if test -n "$PKG_CONFIG"; then
  36           _pkg_min_version=m4_ifval([$1], [$1], [0.9.0])
  37           AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
  38           if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
  39                   AC_MSG_RESULT([yes])
  40           else
  41                   AC_MSG_RESULT([no])
  42                   PKG_CONFIG=""
  43           fi
  44   fi
  45 else
  46   PKG_CONFIG=$ac_cv_env_PKG_CONFIG_value
  47 fi[]dnl
  48
  49 ])# PKG_PROG_PKG_CONFIG
  50
  51 # PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  52 #
  53 # Check to see whether a particular set of modules exists.  Similar
  54 # to PKG_CHECK_MODULES(), but does not set variables or print errors.
  55 #
  56 #
  57 # Similar to PKG_CHECK_MODULES, make sure that the first instance of
  58 # this or PKG_CHECK_MODULES is called, or make sure to call
  59 # PKG_CHECK_EXISTS manually
  60 # --------------------------------------------------------------
  61 AC_DEFUN([PKG_CHECK_EXISTS],
  62 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
  63 if test -n "$PKG_CONFIG" && \
  64     AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
  65   m4_ifval([$2], [$2], [:])
  66 m4_ifvaln([$3], [else
  67   $3])dnl
  68 fi])
  69
  70
  71 # _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
  72 # ---------------------------------------------
  73 m4_define([_PKG_CONFIG],
  74 [if test -n "$PKG_CONFIG"; then
  75         PKG_CHECK_EXISTS([$3],
  76                          [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
  77                          [pkg_failed=yes])
  78 else
  79         pkg_failed=untried
  80 fi[]dnl
  81 ])# _PKG_CONFIG
  82
  83 # PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
  84 # [ACTION-IF-NOT-FOUND])
  85 #
  86 #
  87 # Note that if there is a possibility the first call to
  88 # PKG_CHECK_MODULES might not happen, you should be sure to include an
  89 # explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
  90 #
  91 #
  92 # --------------------------------------------------------------
  93 AC_DEFUN([PKG_CHECK_MODULES],
  94 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
  95 AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
  96 AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
  97
  98 pkg_failed=no
  99 AC_MSG_CHECKING([for $1])
 100
 101 _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
 102 _PKG_CONFIG([$1][_LIBS], [libs], [$2])
 103
 104 if test $pkg_failed = yes; then
 105         $1[]_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 106         # Put the nasty error message in config.log where it belongs
 107         echo "$$1[]_PKG_ERRORS" 1>&AS_MESSAGE_LOG_FD
 108
 109         ifelse([$4], , [AC_MSG_ERROR(dnl
 110 [Package requirements ($2) were not met.
 111 Consider adjusting the PKG_CONFIG_PATH environment variable if you
 112 installed software in a non-standard prefix.
 113
 114 Alternatively you may set the $1_CFLAGS and $1_LIBS environment variables
 115 to avoid the need to call pkg-config.  See the pkg-config man page for
 116 more details.])],
 117                 [$4])
 118 elif test $pkg_failed = untried; then
 119         ifelse([$4], , [AC_MSG_FAILURE(dnl
 120 [The pkg-config script could not be found or is too old.  Make sure it
 121 is in your PATH or set the PKG_CONFIG environment variable to the full
 122 path to pkg-config.
 123
 124 Alternatively you may set the $1_CFLAGS and $1_LIBS environment variables
 125 to avoid the need to call pkg-config.  See the pkg-config man page for
 126 more details.
 127
 128 To get pkg-config, see <http://www.freedesktop.org/software/pkgconfig>.])],
 129                 [$4])
 130 else
 131         $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
 132         $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
 133         AC_MSG_RESULT([yes])
 134         ifelse([$3], , :, [$3])
 135 fi[]dnl
 136 ])# PKG_CHECK_MODULES
 137
 138 # Local Variables:
 139 # c-basic-offset: 2
 140 # tab-width: 2
 141 # indent-tabs-mode: nil
 142 # End: