sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=5.
   3    Copyright (C) 1996, 1997, 2000 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <sysdep.h>
  23 #include "asm-syntax.h"
  24 #include "bp-sym.h"
  25 #include "bp-asm.h"
  26
  27 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  28 #define BZERO_P (defined memset)
  29
  30 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  31 #define RTN     PARMS
  32 #define DEST    RTN+RTN_SIZE
  33 #if BZERO_P
  34 # define LEN    DEST+PTR_SIZE
  35 #else
  36 # define CHR    DEST+PTR_SIZE
  37 # define LEN    CHR+4
  38 #endif
  39
  40         .text
  41 ENTRY (BP_SYM (memset))
  42         ENTER
  43
  44         pushl   %edi
  45
  46         movl    DEST(%esp), %edi
  47         movl    LEN(%esp), %edx
  48         CHECK_BOUNDS_BOTH_WIDE (%edi, DEST(%esp), %edx)
  49 #if BZERO_P
  50         xorl    %eax, %eax      /* we fill with 0 */
  51 #else
  52         movb    CHR(%esp), %al
  53         movb    %al, %ah
  54         movl    %eax, %ecx
  55         shll    $16, %eax
  56         movw    %cx, %ax
  57 #endif
  58         cld
  59
  60 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  61         cmpl    $36, %edx
  62         movl    %edx, %ecx      /* needed when branch is taken! */
  63         jl      L(2)
  64
  65 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  66         movl    %edi, %ecx      /* Copy ptr to ecx... */
  67         negl    %ecx            /* ...and negate that and... */
  68         andl    $3, %ecx        /* ...mask to get byte count.  */
  69         subl    %ecx, %edx      /* adjust global byte count */
  70         rep
  71         stosb
  72
  73         subl    $32, %edx       /* offset count for unrolled loop */
  74         movl    (%edi), %ecx    /* Fetch destination cache line */
  75
  76         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  77 L(1):   movl    28(%edi), %ecx  /* allocate cache line for destination */
  78         subl    $32, %edx       /* decr loop count */
  79         movl    %eax, 0(%edi)   /* store words pairwise */
  80         movl    %eax, 4(%edi)
  81         movl    %eax, 8(%edi)
  82         movl    %eax, 12(%edi)
  83         movl    %eax, 16(%edi)
  84         movl    %eax, 20(%edi)
  85         movl    %eax, 24(%edi)
  86         movl    %eax, 28(%edi)
  87         leal    32(%edi), %edi  /* update destination pointer */
  88         jge     L(1)
  89
  90         leal    32(%edx), %ecx  /* reset offset count */
  91
  92 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
  93 L(2):   shrl    $2, %ecx        /* convert byte count to longword count */
  94         rep
  95         stosl
  96
  97 /* Finally write the last 0-3 bytes.  */
  98         movl    %edx, %ecx
  99         andl    $3, %ecx
 100         rep
 101         stosb
 102
 103 #if !BZERO_P
 104         /* Load result (only if used as memset).  */
 105         movl DEST(%esp), %eax   /* start address of destination is result */
 106         RETURN_BOUNDED_POINTER (DEST(%esp))
 107 #endif
 108         popl    %edi
 109
 110         LEAVE
 111 #if BZERO_P
 112         ret
 113 #else
 114         RET_PTR
 115 #endif
 116 END (BP_SYM (memset))