configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 dnl I've disabled this for now since we cannot build glibc without static
  74 dnl libraries built in the moment.
  75 dnl AC_ARG_ENABLE(static, dnl
  76 dnl [  --enable-static         build static library [default=yes]],
  77 dnl           static=$enableval, static=yes)
  78 static=yes
  79 AC_ARG_ENABLE(shared, dnl
  80 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  81               shared=$enableval, shared=default)
  82 AC_ARG_ENABLE(profile, dnl
  83 [  --enable-profile        build profiled library [default=yes]],
  84               profile=$enableval, profile=yes)
  85 AC_ARG_ENABLE(omitfp, dnl
  86 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  87               omitfp=$enableval, omitfp=no)
  88 AC_ARG_ENABLE(bounded, dnl
  89 [  --enable-bounded        build with runtime bounds checking [default=no]],
  90               bounded=$enableval, bounded=no)
  91 AC_ARG_ENABLE(versioning, dnl
  92 [  --disable-versioning    do not include versioning information in the
  93                           library objects [default=yes if supported]],
  94              enable_versioning=$enableval, enable_versioning=yes)
  95
  96 dnl Generic infrastructure for drop-in additions to libc.
  97 AC_ARG_ENABLE(add-ons, dnl
  98 [  --enable-add-ons[=DIR1,DIR2]...
  99                           configure and build add-ons in DIR1,DIR2,...
 100                           search for add-ons if no parameter given],
 101   [case "$enableval" in
 102     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 103          test "$add_ons" = "*" && add_ons= ;;
 104     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 105    esac],
 106   [add_ons=])
 107
 108 AC_CONFIG_SUBDIRS($add_ons)
 109 add_ons_pfx=
 110 if test x"$add_ons" != x; then
 111   for f in $add_ons; do
 112     # Test whether such a subdir really exists.
 113     if test -d $srcdir/$f; then
 114       add_ons_pfx="$add_ons_pfx $f/"
 115     else
 116       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 117     fi
 118   done
 119 fi
 120
 121 dnl On some platforms we cannot use dynamic loading.  We must provide
 122 dnl static NSS modules.
 123 AC_ARG_ENABLE(static-nss, dnl
 124 [  --enable-static-nss     build static NSS modules [default=no]],
 125               static_nss=$enableval, static_nss=no)
 126 if test x"$static_nss" = xyes; then
 127   AC_DEFINE(DO_STATIC_NSS)
 128 fi
 129
 130 AC_ARG_ENABLE(force-install,
 131 [  --disable-force-install don't force installation of files from this package,
 132                           even if they are older than the installed files],
 133               force_install=$enableval, force_install=yes)
 134 AC_SUBST(force_install)
 135
 136 dnl On some platforms we allow dropping compatibility with all kernel
 137 dnl versions.
 138 AC_ARG_ENABLE(kernel,
 139 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 140                            than VERSION],
 141               minimum_kernel=$enableval)
 142
 143 AC_CANONICAL_HOST
 144
 145 # The way shlib-versions is used to generate soversions.mk uses a
 146 # fairly simplistic model for name recognition that can't distinguish
 147 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 148 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 149 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 150 case "$host_os" in
 151 linux*)
 152   ;;
 153 gnu*)
 154   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 155   ;;
 156 esac
 157
 158 # We keep the original values in `$config_*' and never modify them, so we
 159 # can write them unchanged into config.make.  Everything else uses
 160 # $machine, $vendor, and $os, and changes them whenever convenient.
 161 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 162
 163 # Some configurations imply other options.
 164 case "$host_os" in
 165 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 166   # These systems always use GNU tools.
 167   gnu_ld=yes gnu_as=yes ;;
 168 esac
 169 case "$host_os" in
 170 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 171 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 172   ;;
 173 gnu* | linux* | sysv4* | solaris2* | irix6*)
 174   # These systems (almost) always use the ELF format.
 175   elf=yes
 176   ;;
 177 esac
 178
 179 machine=$config_machine
 180 vendor=$config_vendor
 181 os=$config_os
 182
 183 ###
 184 ### I put this here to prevent those annoying emails from people who cannot
 185 ### read and try to compile glibc on unsupported platforms.  --drepper
 186 ###
 187 ### By using the undocumented --enable-hacker-mode option for configure
 188 ### one can skip this test to make the configuration not fail for unsupported
 189 ### platforms.
 190 ###
 191 if test -z "$enable_hacker_mode"; then
 192   case "$machine-$host_os" in
 193   *-linux* | *-gnu* | arm*-none*)
 194     ;;
 195   *)
 196     echo "*** The GNU C library is currently not available for this platform."
 197     echo "*** So far nobody cared to port it and if there is no volunteer it"
 198     echo "*** might never happen.  So, if you have interest to see glibc on"
 199     echo "*** this platform visit"
 200     echo "***   http://www.gnu.org/software/libc/porting.html"
 201     echo "*** and join the group of porters"
 202     exit 1
 203     ;;
 204   esac
 205 fi
 206
 207 dnl We need to use [ and ] for other purposes for a while now.
 208 changequote(,)dnl
 209 # Expand the configuration machine name into a subdirectory by architecture
 210 # type and particular chip.
 211 case "$machine" in
 212 a29k | am29000) base_machine=a29k machine=a29k ;;
 213 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 214 arm*)           base_machine=arm machine=arm/$machine ;;
 215 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 216 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 217 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 218 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 219 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 220 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 221 m88???)         base_machine=m88k machine=m88k/$machine ;;
 222 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 223 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 224 mips*)          base_machine=mips
 225                 case "`uname -m`" in
 226                 IP22) machine=mips/mips3 ;;
 227                 *)    machine=mips/$machine ;;
 228                 esac ;;
 229 sparc | sparcv[67])
 230                 base_machine=sparc machine=sparc/sparc32 ;;
 231 sparcv8 | supersparc | hypersparc)
 232                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 233 sparcv8plus | sparcv8plusa | sparcv9)
 234                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 235 sparc64 | ultrasparc)
 236                 base_machine=sparc machine=sparc/sparc64 ;;
 237 esac
 238 changequote([,])dnl
 239 AC_SUBST(base_machine)
 240
 241 if test "$base_machine" = "i386"; then
 242   AC_DEFINE(USE_REGPARMS)
 243 fi
 244
 245 # Compute the list of sysdep directories for this configuration.
 246 # This can take a while to compute.
 247 sysdep_dir=$srcdir/sysdeps
 248 AC_MSG_CHECKING(sysdep dirs)
 249 dnl We need to use [ and ] for other purposes for a while now.
 250 changequote(,)dnl
 251 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 252 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 253
 254 case "$os" in
 255 gnu*)
 256   base_os=mach/hurd ;;
 257 netbsd* | 386bsd* | freebsd* | bsdi*)
 258   base_os=unix/bsd/bsd4.4 ;;
 259 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 260   base_os=unix/bsd ;;
 261 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 262   base_os=unix/sysv ;;
 263 irix6*)
 264   base_os=unix/sysv/irix6/$os ;;
 265 solaris[2-9]*)
 266   base_os=unix/sysv/sysv4 ;;
 267 hpux*)
 268   base_os=unix/sysv/hpux/$os ;;
 269 none)
 270   base_os=standalone ;;
 271 *)
 272   base_os='' ;;
 273 esac
 274
 275 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 276 tail=$os
 277 ostry=$os
 278 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 279   ostry="$ostry /$o"
 280   tail=$o
 281 done
 282 o=`echo $tail | sed 's/[0-9]*$//'`
 283 if test $o != $tail; then
 284   ostry="$ostry /$o"
 285 fi
 286 # For linux-gnu, try linux-gnu, then linux.
 287 o=`echo $tail | sed 's/-.*$//'`
 288 if test $o != $tail; then
 289   ostry="$ostry /$o"
 290 fi
 291
 292 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 293 base=
 294 tail=$base_os
 295 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 296   set $b
 297   base="$base /$1"
 298   tail="$2"
 299 done
 300
 301 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 302 mach=
 303 tail=$machine
 304 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 305   set $m
 306   # Prepend the machine's FPU directory unless --without-fp.
 307   if test "$with_fp" = yes; then
 308     mach="$mach /$1/fpu"
 309   fi
 310   mach="$mach /$1"
 311   tail="$2"
 312 done
 313
 314 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 315 changequote([,])dnl
 316
 317 # Find what sysdep directories exist.
 318 sysnames=
 319 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 320 for d in $add_ons_pfx ''; do
 321   for b in $base ''; do
 322     for m0 in $mach ''; do
 323       for v in /$vendor ''; do
 324         test "$v" = / && continue
 325         for o in /$ostry ''; do
 326           test "$o" = / && continue
 327           for m in $mach ''; do
 328             if test "$m0$b$v$o$m"; then
 329               try="${d}sysdeps$m0$b$v$o$m"
 330               test -n "$enable_debug_configure" &&
 331               echo "$0 [DEBUG]: try $try" >&2
 332               if test -d $srcdir/$try; then
 333                 sysnames="$sysnames $try"
 334                 { test -n "$o" || test -n "$b"; } && os_used=t
 335                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 336               fi
 337             fi
 338           done
 339         done
 340       done
 341     done
 342   done
 343 done
 344 IFS="$ac_save_ifs"
 345
 346 if test -z "$os_used" && test "$os" != none; then
 347   AC_MSG_ERROR(Operating system $os is not supported.)
 348 fi
 349 if test -z "$machine_used" && test "$machine" != none; then
 350   AC_MSG_ERROR(The $machine is not supported.)
 351 fi
 352
 353 # We have now validated the configuration.
 354
 355
 356 # If using ELF, look for an `elf' subdirectory of each machine directory.
 357 # We prepend these rather than inserting them whereever the machine appears
 358 # because things specified by the machine's ELF ABI should override
 359 # OS-specific things, and should always be the same for any OS on the
 360 # machine (otherwise what's the point of an ABI?).
 361 if test "$elf" = yes; then
 362   elf_dirs=
 363   for d in $add_ons_pfx ''; do
 364     for m in $mach; do
 365       if test -d $srcdir/${d}sysdeps$m/elf; then
 366         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 367       fi
 368     done
 369   done
 370   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 371 fi
 372
 373
 374 # Expand the list of system names into a full list of directories
 375 # from each element's parent name and Implies file (if present).
 376 set $sysnames
 377 names=
 378 while test $# -gt 0; do
 379   name=$1
 380   shift
 381
 382   case " $names " in *" $name "*)
 383     # Already in the list.
 384     continue
 385   esac
 386
 387   # Report each name as we discover it, so there is no long pause in output.
 388   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 389
 390   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 391
 392   case $name in
 393     /*) xsrcdir= ;;
 394     *)  xsrcdir=$srcdir/ ;;
 395   esac
 396   test -n "$enable_debug_configure" &&
 397   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 398
 399   if test -f $xsrcdir$name/Implies; then
 400     # Collect more names from the `Implies' file (removing comments).
 401     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 402     implied=
 403     for x in $implied_candidate; do
 404       if test -d $xsrcdir$name_base/$x; then
 405         implied="$implied $name_base/$x";
 406       else
 407         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 408       fi
 409     done
 410   else
 411     implied=
 412   fi
 413
 414   # Add NAME to the list of names.
 415   names="$names $name"
 416
 417   # Find the parent of NAME, using the empty string if it has none.
 418 changequote(,)dnl
 419   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 420 changequote([,])dnl
 421
 422   # Add the names implied by NAME, and NAME's parent (if it has one), to
 423   # the list of names to be processed (the argument list).  We prepend the
 424   # implied names to the list and append the parent.  We want implied
 425   # directories to come before further directories inferred from the
 426   # configuration components; this ensures that for sysv4, unix/common
 427   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 428   # after sysv4).
 429   sysnames="`echo $implied $* $parent`"
 430   test -n "$sysnames" && set $sysnames
 431 done
 432
 433 # Add the default directories.
 434 default_sysnames=sysdeps/generic
 435 if test "$elf" = yes; then
 436   default_sysnames="sysdeps/generic/elf $default_sysnames"
 437 fi
 438 sysnames="$names $default_sysnames"
 439 AC_SUBST(sysnames)
 440 # The other names were emitted during the scan.
 441 AC_MSG_RESULT($default_sysnames)
 442
 443
 444 ### Locate tools.
 445
 446 AC_PROG_INSTALL
 447 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 448   # The makefiles need to use a different form to find it in $srcdir.
 449   INSTALL='\$(..)./scripts/install-sh -c'
 450 fi
 451 AC_PROG_LN_S
 452
 453 # These programs are version sensitive.
 454 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 455 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 456   [version \([egcygnustp-]*[0-9.]*\)],
 457   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9].*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 458   critic_missing=t)
 459 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 460   [version \([0-9][0-9.]*\), by],
 461   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 462
 463 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 464   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 465   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 466 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 467   [GNU texinfo.* \([0-9][0-9.]*\)],
 468   [3.1[1-9] | 3.[2-9][0-9] | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 469
 470 if test -n "$critic_missing"; then
 471 AC_MSG_ERROR([
 472 *** Some critical program is missing or too old.
 473 *** Check the INSTALL file for required versions.])
 474 fi
 475
 476 test -n "$aux_missing" && AC_MSG_WARN([
 477 *** An auxiliary program is missing or too old;
 478 *** some features will be disabled.
 479 *** Check the INSTALL file for required versions.])
 480
 481 # glibcbug.in wants to know the compiler version.
 482 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 483 AC_SUBST(CCVERSION)
 484
 485 AC_PROG_CC_LOCAL
 486 AC_CANONICAL_BUILD
 487 if test $host != $build; then
 488   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 489 fi
 490 AC_SUBST(cross_compiling)
 491 AC_PROG_CPP
 492 LIBC_PROG_BINUTILS
 493 AC_CHECK_TOOL(MIG, mig)
 494
 495 # if using special system headers, find out the compiler's sekrit
 496 # header directory and add that to the list.  NOTE: Only does the right
 497 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 498 if test -n "$sysheaders"; then
 499   ccheaders=`$CC -print-file-name=include`
 500   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 501 fi
 502 AC_SUBST(SYSINCLUDES)
 503
 504 # check if ranlib is necessary
 505 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 506 cat > conftest.c <<EOF
 507 int a;
 508 char b;
 509 void c(void) {}
 510 EOF
 511 $CC $CFLAGS -c conftest.c
 512 $AR cr conftest.a conftest.c
 513 cp conftest.a conftest2.a
 514 $RANLIB conftest.a
 515 if cmp -s conftest.a conftest2.a; then
 516   libc_cv_ranlib_necessary=no
 517 else
 518   libc_cv_ranlib_necessary=yes
 519 fi
 520 rm -rf conftest*])
 521 if test "$libc_cv_ranlib_necessary" = no; then
 522  RANLIB=:
 523 fi
 524
 525 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 526 # since this would lead to problems installing/building glibc.
 527 # LD_LIBRARY_PATH contains the current directory if one of the following
 528 # is true:
 529 # - one of the terminals (":" and ";") is the first or last sign
 530 # - two terminals occur directly after each other
 531 # - the path contains an element with a dot in it
 532 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 533 changequote(,)dnl
 534 case ${LD_LIBRARY_PATH} in
 535   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 536     ld_library_path_setting="contains current directory"
 537     ;;
 538   *)
 539     ld_library_path_setting="ok"
 540     ;;
 541 esac
 542 changequote([,])dnl
 543 AC_MSG_RESULT($ld_library_path_setting)
 544 if test "$ld_library_path_setting" != "ok"; then
 545 AC_MSG_ERROR([
 546 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 547 *** building glibc. Please change the environment variable
 548 *** and run configure again.])
 549 fi
 550
 551 AC_PATH_PROG(BASH, bash, no)
 552 if test "$BASH" != no &&
 553    $BASH -c 'test "$BASH_VERSINFO" \
 554              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 555   libc_cv_have_bash2=yes
 556 else
 557   libc_cv_have_bash2=no
 558 fi
 559 AC_SUBST(libc_cv_have_bash2)
 560
 561 dnl We need a ksh compatible shell for tzselect.
 562 if test "$BASH" = no; then
 563   AC_PATH_PROG(KSH, ksh, no)
 564   if test "$KSH" = no; then
 565     libc_cv_have_ksh=no
 566   else
 567     libc_cv_have_ksh=yes
 568   fi
 569 else
 570   KSH="$BASH"
 571   AC_SUBST(KSH)
 572   libc_cv_have_ksh=yes
 573 fi
 574 AC_SUBST(libc_cv_have_ksh)
 575
 576 AC_PROG_AWK
 577 AC_PATH_PROG(PERL, perl, no)
 578 AC_SUBST(PERL)
 579 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 580              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 581 AC_SUBST(INSTALL_INFO)
 582 if test "$INSTALL_INFO" != "no"; then
 583 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 584  [mkdir conftest.d
 585   # There is a hard ^_ on the next line.  I am open to better ideas.
 586   (echo '\x1f'
 587   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 588   echo '* Menu:') >conftest.d/dir
 589   (echo 'INFO-DIR-SECTION i-d-s works'
 590   echo 'START-INFO-DIR-ENTRY'
 591   echo '* Prog: (prog).   Program.'
 592   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 593   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 594   then
 595     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 596     then libc_cv_old_debian_install_info=no
 597     else libc_cv_old_debian_install_info=yes
 598     fi
 599   else libc_cv_old_debian_install_info=no testfailed=t
 600   fi
 601   rm -fr conftest.d])
 602 if test -n "$testfailed"
 603 then AC_MSG_WARN([install-info errored out, check config.log])
 604 fi
 605 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 606 fi
 607 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 608
 609 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 610 echo '#include <stddef.h>
 611 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 612 if eval "$ac_cpp conftest.c 2>/dev/null" \
 613 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 614   libc_cv_signed_size_t=no
 615 else
 616   libc_cv_signed_size_t=yes
 617 fi
 618 rm -f conftest*])
 619 if test $libc_cv_signed_size_t = yes; then
 620   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 621   cat >> confdefs.h <<\EOF
 622 #undef __SIZE_TYPE__
 623 #define __SIZE_TYPE__ unsigned
 624 EOF
 625 fi
 626
 627 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 628 AC_TRY_COMPILE(dnl
 629 [#define __need_size_t
 630 #define __need_wchar_t
 631 #include <stddef.h>
 632 #define __need_NULL
 633 #include <stddef.h>], [size_t size; wchar_t wchar;
 634 #ifdef offsetof
 635 #error stddef.h ignored __need_*
 636 #endif
 637 if (&size == NULL || &wchar == NULL) abort ();],
 638                libc_cv_friendly_stddef=yes,
 639                libc_cv_friendly_stddef=no)])
 640 if test $libc_cv_friendly_stddef = yes; then
 641   config_vars="$config_vars
 642 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 643 fi
 644
 645 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 646                libc_cv_need_minus_P, [dnl
 647 cat > conftest.S <<EOF
 648 #include "confdefs.h"
 649 /* Nothing whatsoever.  */
 650 EOF
 651 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 652   libc_cv_need_minus_P=no
 653 else
 654   libc_cv_need_minus_P=yes
 655 fi
 656 rm -f conftest*])
 657 if test $libc_cv_need_minus_P = yes; then
 658   config_vars="$config_vars
 659 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 660 fi
 661
 662 AC_CACHE_CHECK(for assembler global-symbol directive,
 663                libc_cv_asm_global_directive, [dnl
 664 libc_cv_asm_global_directive=UNKNOWN
 665 for ac_globl in .globl .global .EXPORT; do
 666   cat > conftest.s <<EOF
 667         .text
 668         ${ac_globl} foo
 669 foo:
 670 EOF
 671   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 672     libc_cv_asm_global_directive=${ac_globl}
 673   fi
 674   rm -f conftest*
 675   test $libc_cv_asm_global_directive != UNKNOWN && break
 676 done])
 677 if test $libc_cv_asm_global_directive = UNKNOWN; then
 678   AC_MSG_ERROR(cannot determine asm global directive)
 679 else
 680   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 681 fi
 682
 683 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 684 cat > conftest.s <<EOF
 685 .text
 686 foo:
 687 .set glibc_conftest_frobozz,foo
 688 $libc_cv_asm_global_directive glibc_conftest_frobozz
 689 EOF
 690 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 691 # (but it doesn't work), so we must do a linking check to be sure.
 692 cat > conftest1.c <<\EOF
 693 extern int glibc_conftest_frobozz;
 694 main () { printf ("%d\n", glibc_conftest_frobozz); }
 695 EOF
 696 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 697             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 698   libc_cv_asm_set_directive=yes
 699 else
 700   libc_cv_asm_set_directive=no
 701 fi
 702 rm -f conftest*])
 703 if test $libc_cv_asm_set_directive = yes; then
 704   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 705 fi
 706
 707 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 708 [cat > conftest.s <<EOF
 709 .text
 710 _sym:
 711 .symver _sym,sym@VERS
 712 EOF
 713 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 714   libc_cv_asm_symver_directive=yes
 715 else
 716   libc_cv_asm_symver_directive=no
 717 fi
 718 rm -f conftest*])
 719 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 720 if test $libc_cv_asm_symver_directive = yes; then
 721   cat > conftest.s <<EOF
 722 .text
 723 _sym:
 724 .symver _sym,sym@VERS
 725 EOF
 726   cat > conftest.map <<EOF
 727 VERS_1 {
 728         global: sym;
 729 };
 730
 731 VERS_2 {
 732         global: sym;
 733 } VERS_1;
 734 EOF
 735   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 736     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 737                                         -nostartfiles -nostdlib
 738                                         -Wl,--version-script,conftest.map
 739                        1>&AC_FD_CC]);
 740     then
 741       libc_cv_ld_version_script_option=yes
 742     else
 743       libc_cv_ld_version_script_option=no
 744     fi
 745   else
 746     libc_cv_ld_version_script_option=no
 747   fi
 748 else
 749   libc_cv_ld_version_script_option=no
 750 fi
 751 rm -f conftest*])
 752 if test $libc_cv_asm_symver_directive = yes &&
 753    test $libc_cv_ld_version_script_option = yes &&
 754    test $enable_versioning = yes; then
 755   VERSIONING=yes
 756   AC_DEFINE(DO_VERSIONING)
 757 else
 758   VERSIONING=no
 759 fi
 760 AC_SUBST(VERSIONING)
 761
 762 if test $VERSIONING = no; then
 763   echo "\
 764 *** WARNING: You should not compile GNU libc without versioning. Not using
 765 *** versioning will introduce incompatibilities so that old binaries
 766 *** will not run anymore.
 767 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 768 fi
 769 if test $elf = yes; then
 770   AC_CACHE_CHECK(for .previous assembler directive,
 771                  libc_cv_asm_previous_directive, [dnl
 772   cat > conftest.s <<EOF
 773 .section foo_section
 774 .previous
 775 EOF
 776   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 777     libc_cv_asm_previous_directive=yes
 778   else
 779     libc_cv_asm_previous_directive=no
 780   fi
 781   rm -f conftest*])
 782   if test $libc_cv_asm_previous_directive = yes; then
 783     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 784   else
 785     AC_CACHE_CHECK(for .popsection assembler directive,
 786                    libc_cv_asm_popsection_directive, [dnl
 787     cat > conftest.s <<EOF
 788 .pushsection foo_section
 789 .popsection
 790 EOF
 791     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 792       libc_cv_asm_popsection_directive=yes
 793     else
 794       libc_cv_asm_popsection_directive=no
 795     fi
 796     rm -f conftest*])
 797     if test $libc_cv_asm_popsection_directive = yes; then
 798       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 799     fi
 800   fi
 801 fi
 802
 803 if test $elf != yes; then
 804   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 805                  [AC_TRY_COMPILE(, [asm (".section .init");
 806                                     asm (".section .fini");
 807                                     asm (".text");],
 808                                  libc_cv_have_initfini=yes,
 809                                  libc_cv_have_initfini=no)])
 810   AC_SUBST(libc_cv_have_initfini)dnl
 811   if test $libc_cv_have_initfini = yes; then
 812     AC_DEFINE(HAVE_INITFINI)
 813   fi
 814 fi
 815
 816 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 817 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 818 [cat > conftest.$ac_ext <<EOF
 819 dnl This sometimes fails to find confdefs.h, for some reason.
 820 dnl [#]line __oline__ "[$]0"
 821 [#]line __oline__ "configure"
 822 #include "confdefs.h"
 823 void underscore_test(void) {
 824 return; }
 825 EOF
 826 if AC_TRY_EVAL(ac_compile); then
 827   if grep _underscore_test conftest* >/dev/null; then
 828     ifelse([$1], , :, [rm -f conftest*
 829     $1])
 830   else
 831     ifelse([$2], , , [rm -f conftest*
 832     $2])
 833   fi
 834 else
 835   echo "configure: failed program was:" >&AC_FD_CC
 836   cat conftest.$ac_ext >&AC_FD_CC
 837   ifelse([$2], , , [rm -f conftest*
 838   $2])
 839 fi
 840 rm -f conftest*])
 841
 842 if test $elf = yes; then
 843   libc_cv_asm_underscores=no
 844 else
 845   if test $ac_cv_prog_cc_works = yes; then
 846     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 847                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 848                                 libc_cv_asm_underscores=yes,
 849                                 libc_cv_asm_underscores=no)])
 850   else
 851     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 852                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 853                                             libc_cv_asm_underscores=no)])
 854   fi
 855 fi
 856 if test $libc_cv_asm_underscores = no; then
 857   AC_DEFINE(NO_UNDERSCORES)
 858 fi
 859
 860 if test $elf = yes; then
 861   libc_cv_weak_symbols=yes
 862 fi
 863
 864 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 865                  [dnl
 866 cat > conftest.s <<EOF
 867 .text
 868 ${libc_cv_asm_global_directive} foo
 869 foo:
 870 .weak foo
 871 .weak bar; bar = foo
 872 EOF
 873 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 874   libc_cv_asm_weak_directive=yes
 875 else
 876   libc_cv_asm_weak_directive=no
 877 fi
 878 rm -f conftest*])
 879
 880 if test $libc_cv_asm_weak_directive = no; then
 881   AC_CACHE_CHECK(for assembler .weakext directive,
 882                  libc_cv_asm_weakext_directive,
 883                  [dnl
 884 cat > conftest.s <<EOF
 885 .text
 886 ${libc_cv_asm_global_directive} foo
 887 foo:
 888 .weakext bar foo
 889 .weakext baz
 890 ${libc_cv_asm_global_directive} baz
 891 baz:
 892 EOF
 893   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 894     libc_cv_asm_weakext_directive=yes
 895   else
 896     libc_cv_asm_weakext_directive=no
 897   fi
 898   rm -f conftest*])
 899
 900 fi # no .weak
 901
 902 if test $libc_cv_asm_weak_directive = yes; then
 903   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 904 elif test $libc_cv_asm_weakext_directive = yes; then
 905   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 906 fi
 907
 908 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 909 cat > conftest.c <<\EOF
 910 _start () {}
 911 int __eh_pc;
 912 __throw () {}
 913 EOF
 914 dnl No \ in command here because it ends up inside ''.
 915 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 916                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 917                             -o conftest conftest.c 1>&AC_FD_CC]); then
 918   libc_cv_ld_no_whole_archive=yes
 919 else
 920   libc_cv_ld_no_whole_archive=no
 921 fi
 922 rm -f conftest*])
 923 if test $libc_cv_ld_no_whole_archive = yes; then
 924   no_whole_archive=-Wl,--no-whole-archive
 925 fi
 926 AC_SUBST(no_whole_archive)dnl
 927
 928 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 929 cat > conftest.c <<\EOF
 930 _start () {}
 931 int __eh_pc;
 932 __throw () {}
 933 EOF
 934 dnl No \ in command here because it ends up inside ''.
 935 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 936                             -nostdlib -nostartfiles -fexceptions
 937                             -o conftest conftest.c 1>&AC_FD_CC]); then
 938   libc_cv_gcc_exceptions=yes
 939 else
 940   libc_cv_gcc_exceptions=no
 941 fi
 942 rm -f conftest*])
 943 if test $libc_cv_gcc_exceptions = yes; then
 944   exceptions=-fexceptions
 945 fi
 946 AC_SUBST(exceptions)dnl
 947
 948 if test "$base_machine" = alpha ; then
 949 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 950 cat > conftest.c <<\EOF
 951 foo () { }
 952 EOF
 953 dnl
 954 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 955 then
 956   libc_cv_gcc_alpha_ng_prefix=yes
 957 else
 958   libc_cv_gcc_alpha_ng_prefix=no
 959 fi
 960 rm -f conftest* ])
 961 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 962   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 963 else
 964   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 965 fi
 966 fi
 967
 968 if test "$host_cpu" = powerpc ; then
 969 # Check for a bug present in at least versions 2.8.x of GCC
 970 # and versions 1.0.x of EGCS.
 971 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 972 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 973                libc_cv_c_asmcr0_bug='no',
 974                libc_cv_c_asmcr0_bug='yes')])
 975 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 976   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 977 fi
 978 fi
 979
 980 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 981 [cat > conftest.c <<EOF
 982 #line __oline__ "configure"
 983 static char __EH_FRAME_BEGIN__[];
 984 _start ()
 985 {
 986 #ifdef CHECK__register_frame
 987   __register_frame (__EH_FRAME_BEGIN__);
 988   __deregister_frame (__EH_FRAME_BEGIN__);
 989 #endif
 990 #ifdef CHECK__register_frame_info
 991   __register_frame_info (__EH_FRAME_BEGIN__);
 992   __deregister_frame_info (__EH_FRAME_BEGIN__);
 993 #endif
 994 }
 995 int __eh_pc;
 996 __throw () {}
 997 /* FIXME: this is fragile.  */
 998 malloc () {}
 999 strcmp () {}
1000 strlen () {}
1001 memcpy () {}
1002 memset () {}
1003 free () {}
1004 abort () {}
1005 __bzero () {}
1006 EOF
1007 dnl No \ in command here because it ends up inside ''.
1008 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1009                             -nostdlib -nostartfiles
1010                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1011   libc_cv_gcc_dwarf2_unwind_info=static
1012 else
1013   libc_cv_gcc_dwarf2_unwind_info=no
1014 fi
1015 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1016   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1017                               -nostdlib -nostartfiles
1018                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1019     libc_cv_gcc_dwarf2_unwind_info=yes
1020   else
1021     libc_cv_gcc_dwarf2_unwind_info=no
1022   fi
1023 fi
1024 rm -f conftest*])
1025 case $libc_cv_gcc_dwarf2_unwind_info in
1026 yes)
1027   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1028   ;;
1029 static)
1030   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1031   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1032   ;;
1033 esac
1034
1035 dnl Check whether compiler understands __builtin_expect.
1036 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1037 [cat > conftest.c <<EOF
1038 #line __oline__ "configure"
1039 int foo (int a)
1040 {
1041   a = __builtin_expect (a, 10);
1042   return a == 10 ? 0 : 1;
1043 }
1044 EOF
1045 dnl No \ in command here because it ends up inside ''.
1046 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1047                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1048   libc_cv_gcc_builtin_expect=yes
1049 else
1050   libc_cv_gcc_builtin_expect=no
1051 fi
1052 rm -f conftest*])
1053 if test "$libc_cv_gcc_builtin_expect" = yes; then
1054   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1055 fi
1056
1057 dnl Check whether the compiler supports subtraction of local labels.
1058 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1059 [cat > conftest.c <<EOF
1060 changequote(,)dnl
1061 #line __oline__ "configure"
1062 int foo (int a)
1063 {
1064   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1065   void *p = &&l1 + ar[a];
1066   goto *p;
1067  l1:
1068   return 1;
1069  l2:
1070   return 2;
1071 }
1072 changequote([,])dnl
1073 EOF
1074 dnl No \ in command here because it ends up inside ''.
1075 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1076                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1077   libc_cv_gcc_subtract_local_labels=yes
1078 else
1079   libc_cv_gcc_subtract_local_labels=no
1080 fi
1081 rm -f conftest*])
1082 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1083   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1084 fi
1085
1086
1087 ### End of automated tests.
1088 ### Now run sysdeps configure fragments.
1089
1090 # sysdeps configure fragments may set these with files to be linked below.
1091 libc_link_dests=
1092 libc_link_sources=
1093
1094 # They also can set these variables.
1095 ldd_rewrite_script=no
1096
1097 # Iterate over all the sysdep directories we will use, running their
1098 # configure fragments, and looking for a uname implementation.
1099 uname=
1100 for dir in $sysnames; do
1101   case $dir in
1102     /*) dest=$dir ;;
1103     *)  dest=$srcdir/$dir ;;
1104   esac
1105   if test -r $dest/configure; then
1106     AC_MSG_RESULT(running configure fragment for $dest)
1107     . $dest/configure
1108   fi
1109 [
1110   if test -z "$uname"; then
1111     if test -r $dest/uname.c ||
1112        test -r $dest/uname.S ||
1113        { test -r $dest/syscalls.list &&
1114          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1115       uname=$dir
1116     fi
1117   fi
1118 ]dnl
1119 done
1120
1121 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1122
1123 # If we will use the generic uname implementation, we must figure out what
1124 # it will say by examining the system, and write the results in config-name.h.
1125 if test "$uname" = "sysdeps/generic"; then
1126
1127 changequote(,)dnl
1128   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1129 changequote([,])dnl
1130   if test $uname_sysname != $config_os; then
1131     config_release=`echo $config_os | sed s/$uname_sysname//`
1132   fi
1133 dnl
1134 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1135     if test -r /vmunix; then
1136       kernel_id=`strings /vmunix | grep UNIX`
1137     elif test -r /dynix; then
1138       kernel_id=`strings /dynix | grep DYNIX`
1139     else
1140       kernel_id=
1141     fi
1142 ])dnl
1143
1144   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1145 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1146 changequote(,)dnl
1147   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1148 changequote([,])dnl
1149   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1150          != x$config_release; then
1151     # The configuration release is a substring of the kernel release.
1152     libc_cv_uname_release=$kernel_release
1153   elif test x$config_release != x; then
1154     libc_cv_uname_release=$config_release
1155   elif test x$kernel_release != x; then
1156     libc_cv_uname_release=$kernel_release
1157   else
1158     libc_cv_uname_release=unknown
1159   fi])
1160   uname_release="$libc_cv_uname_release"
1161
1162   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1163 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1164 changequote(,)dnl
1165   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1166 changequote([,])dnl
1167   if test -n "$kernel_version"; then
1168     libc_cv_uname_version="$kernel_version"
1169   else
1170     libc_cv_uname_version=unknown
1171   fi])
1172   uname_version="$libc_cv_uname_version"
1173
1174 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1175   config_uname=config-name.h:config-name.in
1176 else
1177   # For non-generic uname, we don't need to create config-name.h at all.
1178   config_uname=
1179 fi
1180
1181 AC_MSG_CHECKING(stdio selection)
1182 AC_SUBST(stdio)
1183 case $stdio in
1184 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1185 default) stdio=stdio ;;
1186 esac
1187 AC_MSG_RESULT($stdio)
1188
1189 # Test for old glibc 2.0.x headers so that they can be removed properly
1190 # Search only in includedir.
1191 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1192 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1193 then
1194   old_glibc_headers=yes
1195 else
1196   old_glibc_headers=no
1197 fi
1198 AC_MSG_RESULT($old_glibc_headers)
1199 if test ${old_glibc_headers} = yes; then
1200   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1201   AC_MSG_WARN(*** be removed.)
1202 fi
1203 AC_SUBST(old_glibc_headers)
1204
1205 AC_SUBST(libc_cv_slibdir)
1206 AC_SUBST(libc_cv_sysconfdir)
1207 AC_SUBST(libc_cv_rootsbindir)
1208
1209 AC_SUBST(has_ldconfig)
1210 AC_SUBST(ldd_rewrite_script)
1211
1212 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1213 if test $gnu_ld = yes; then
1214   AC_DEFINE(HAVE_GNU_LD)
1215 fi
1216 if test $gnu_as = yes; then
1217   AC_DEFINE(HAVE_GNU_AS)
1218 fi
1219 if test $elf = yes; then
1220   AC_DEFINE(HAVE_ELF)
1221 fi
1222
1223 AC_SUBST(static)
1224 AC_SUBST(shared)
1225 if test $shared = default; then
1226   if test $gnu_ld = yes; then
1227     shared=$elf
1228   else
1229     # For now we do not assume shared libs are available.  In future more
1230     # tests might become available.
1231     shared=no
1232   fi
1233 fi
1234
1235 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1236 [pic_default=yes
1237 cat > conftest.c <<EOF
1238 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1239 # error PIC is default.
1240 #endif
1241 EOF
1242 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1243   pic_default=no
1244 fi
1245 rm -f conftest.*])
1246 AC_SUBST(pic_default)
1247
1248 AC_SUBST(profile)
1249 AC_SUBST(omitfp)
1250 AC_SUBST(bounded)
1251 AC_SUBST(static_nss)
1252 AC_SUBST(nopic_initfini)
1253
1254 AC_SUBST(DEFINES)
1255
1256 case "$add_ons" in
1257   *door*) linux_doors=yes ;;
1258   *) linux_doors=no ;;
1259 esac
1260 AC_SUBST(linux_doors)
1261
1262 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1263   config_makefile=
1264 else
1265   config_makefile=Makefile
1266 fi
1267
1268 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1269 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1270 AC_SUBST(VERSION)
1271 AC_SUBST(RELEASE)
1272
1273 echo '*** Do NOT install this release on any production system!'
1274 echo '*** It is known to be broken and will be so for quite some time.'
1275 echo '*** Use the latest released version instead.'
1276
1277 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1278 case $CONFIG_FILES in *config.make*)
1279 echo "$config_vars" >> config.make;;
1280 esac
1281 test -d bits || mkdir bits], [config_vars='$config_vars'])