sysdeps/powerpc/powerpc32/__longjmp-common.S

   1 /* longjmp for PowerPC.
   2    Copyright (C) 1995-1997, 1999-2001, 2003, 2004, 2005, 2006, 2009
   3         Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #define _ASM
  23 #ifdef __NO_VMX__
  24 # include <novmxsetjmp.h>
  25 #else
  26 # include <jmpbuf-offsets.h>
  27 #endif
  28 #include <bp-sym.h>
  29 #include <bp-asm.h>
  30
  31 ENTRY (BP_SYM (__longjmp))
  32         CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
  33
  34 #if defined PTR_DEMANGLE || defined CHECK_SP
  35         lwz r24,(JB_GPR1*4)(r3)
  36 # ifdef CHECK_SP
  37 #  ifdef PTR_DEMANGLE
  38         PTR_DEMANGLE3 (r24, r24, r25)
  39 #  endif
  40         CHECK_SP (r24)
  41         mr r1,r24
  42 # endif
  43 #else
  44         lwz r1,(JB_GPR1*4)(r3)
  45 #endif
  46         lwz r0,(JB_LR*4)(r3)
  47         lwz r14,((JB_GPRS+0)*4)(r3)
  48         lwz r15,((JB_GPRS+1)*4)(r3)
  49         lwz r16,((JB_GPRS+2)*4)(r3)
  50         lwz r17,((JB_GPRS+3)*4)(r3)
  51         lwz r18,((JB_GPRS+4)*4)(r3)
  52         lwz r19,((JB_GPRS+5)*4)(r3)
  53         lwz r20,((JB_GPRS+6)*4)(r3)
  54 #ifdef PTR_DEMANGLE
  55 # ifndef CHECK_SP
  56         PTR_DEMANGLE3 (r1, r24, r25)
  57 # endif
  58         PTR_DEMANGLE2 (r0, r25)
  59 #endif
  60         mtlr r0
  61         lwz r21,((JB_GPRS+7)*4)(r3)
  62         lwz r22,((JB_GPRS+8)*4)(r3)
  63         lwz r0,(JB_CR*4)(r3)
  64         lwz r23,((JB_GPRS+9)*4)(r3)
  65         lwz r24,((JB_GPRS+10)*4)(r3)
  66         lwz r25,((JB_GPRS+11)*4)(r3)
  67         mtcrf 0xFF,r0
  68         lwz r26,((JB_GPRS+12)*4)(r3)
  69         lwz r27,((JB_GPRS+13)*4)(r3)
  70         lwz r28,((JB_GPRS+14)*4)(r3)
  71         lwz r29,((JB_GPRS+15)*4)(r3)
  72         lwz r30,((JB_GPRS+16)*4)(r3)
  73         lwz r31,((JB_GPRS+17)*4)(r3)
  74         mr r3,r4
  75         blr
  76 END (BP_SYM (__longjmp))