configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  23 AC_ARG_WITH(gd, dnl
  24   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  25             [dnl
  26 case "$with_gd" in
  27 yes|''|no) ;;
  28 *) libgd_include="-I$withval/include"
  29    libgd_ldflags="-L$withval/lib" ;;
  30 esac
  31 ])
  32 AC_ARG_WITH(gd-include, dnl
  33   --with-gd-include=DIR   find libgd include files in DIR,
  34             [dnl
  35 case "$with_gd_include" in
  36 ''|no) ;;
  37 *) libgd_include="-I$withval" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH(gd-lib, dnl
  41   --with-gd-lib=DIR       find libgd library files in DIR,
  42             [dnl
  43 case "$with_gd_lib" in
  44 ''|no) ;;
  45 *) libgd_ldflags="-L$withval" ;;
  46 esac
  47 ])
  48
  49 if test -n "$libgd_include"; then
  50   config_vars="$config_vars
  51 CFLAGS-memusagestat.c = $libgd_include"
  52 fi
  53 if test -n "$libgd_ldflags"; then
  54   config_vars="$config_vars
  55 libgd-LDFLAGS = $libgd_ldflags"
  56 fi
  57
  58 dnl Arguments to specify presence of other packages/features.
  59 AC_ARG_WITH(fp, dnl
  60 [  --with-fp              if using floating-point hardware [default=yes]],
  61             with_fp=$withval, with_fp=yes)
  62 AC_ARG_WITH(binutils, dnl
  63   --with-binutils=PATH    specify location of binutils (as and ld),
  64             path_binutils=$withval, path_binutils='')
  65 AC_ARG_WITH(elf, dnl
  66   --with-elf              if using the ELF object format,
  67             elf=$withval, elf=no)
  68 AC_ARG_WITH(cvs, dnl
  69 [  --without-cvs          if CVS should not be used],
  70             with_cvs=$withval, with_cvs=yes)
  71 AC_SUBST(with_cvs)
  72
  73 AC_ARG_WITH(headers, dnl
  74 [  --with-headers=PATH     location of system headers to use
  75                           [e.g. /usr/src/linux/include]
  76                           [default=compiler default]],
  77             sysheaders=$withval, sysheaders='')
  78
  79 AC_ARG_ENABLE(libio, dnl
  80 [  --enable-libio          build in GNU libio instead of GNU stdio],
  81               [if test $enableval = yes; then
  82                  stdio=libio
  83                else
  84                  stdio=stdio
  85                fi],
  86               stdio=default)
  87
  88 AC_ARG_ENABLE(sanity-checks, dnl
  89 [  --disable-sanity-checks really do not use threads (should not be used
  90                           except in special situations) [default=yes]],
  91               enable_sanity=$enableval, enable_sanity=yes)
  92
  93 dnl Arguments to enable or disable building the static, shared, profiled,
  94 dnl and -fomit-frame-pointer libraries.
  95 dnl I've disabled this for now since we cannot build glibc without static
  96 dnl libraries built in the moment.
  97 dnl AC_ARG_ENABLE(static, dnl
  98 dnl [  --enable-static         build static library [default=yes]],
  99 dnl           static=$enableval, static=yes)
 100 static=yes
 101 AC_ARG_ENABLE(shared, dnl
 102 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 103               shared=$enableval, shared=default)
 104 AC_ARG_ENABLE(profile, dnl
 105 [  --enable-profile        build profiled library [default=yes]],
 106               profile=$enableval, profile=yes)
 107 AC_ARG_ENABLE(omitfp, dnl
 108 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 109               omitfp=$enableval, omitfp=no)
 110 AC_ARG_ENABLE(bounded, dnl
 111 [  --enable-bounded        build with runtime bounds checking [default=no]],
 112               bounded=$enableval, bounded=no)
 113 AC_ARG_ENABLE(versioning, dnl
 114 [  --disable-versioning    do not include versioning information in the
 115                           library objects [default=yes if supported]],
 116              enable_versioning=$enableval, enable_versioning=yes)
 117
 118 dnl Generic infrastructure for drop-in additions to libc.
 119 AC_ARG_ENABLE(add-ons, dnl
 120 [  --enable-add-ons[=DIR1,DIR2]...
 121                           configure and build add-ons in DIR1,DIR2,...
 122                           search for add-ons if no parameter given],
 123   [case "$enableval" in
 124     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 125          test "$add_ons" = "*" && add_ons= ;;
 126     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 127    esac],
 128   [add_ons=])
 129
 130 AC_CONFIG_SUBDIRS($add_ons)
 131 add_ons_pfx=
 132 if test x"$add_ons" != x; then
 133   for f in $add_ons; do
 134     # Test whether such a subdir really exists.
 135     if test -d $srcdir/$f; then
 136       add_ons_pfx="$add_ons_pfx $f/"
 137     else
 138       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 139     fi
 140   done
 141 fi
 142
 143 dnl On some platforms we cannot use dynamic loading.  We must provide
 144 dnl static NSS modules.
 145 AC_ARG_ENABLE(static-nss, dnl
 146 [  --enable-static-nss     build static NSS modules [default=no]],
 147               static_nss=$enableval, static_nss=no)
 148 if test x"$static_nss" = xyes; then
 149   AC_DEFINE(DO_STATIC_NSS)
 150 fi
 151
 152 AC_ARG_ENABLE(force-install,
 153 [  --disable-force-install don't force installation of files from this package,
 154                           even if they are older than the installed files],
 155               force_install=$enableval, force_install=yes)
 156 AC_SUBST(force_install)
 157
 158 dnl On some platforms we allow dropping compatibility with all kernel
 159 dnl versions.
 160 AC_ARG_ENABLE(kernel,
 161 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 162                            than VERSION],
 163               minimum_kernel=$enableval)
 164 dnl Prevent unreasonable values.
 165 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 166   # Better nothing than this.
 167   minimum_kernel=""
 168 else
 169   if test "$minimum_kernel" = current; then
 170     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 171   fi
 172 fi
 173
 174 AC_CANONICAL_HOST
 175
 176 # The way shlib-versions is used to generate soversions.mk uses a
 177 # fairly simplistic model for name recognition that can't distinguish
 178 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 179 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 180 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 181 case "$host_os" in
 182 linux*)
 183   ;;
 184 gnu*)
 185   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 186   ;;
 187 esac
 188
 189 # We keep the original values in `$config_*' and never modify them, so we
 190 # can write them unchanged into config.make.  Everything else uses
 191 # $machine, $vendor, and $os, and changes them whenever convenient.
 192 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 193
 194 # Don't allow vendor == "unknown"
 195 test "$config_vendor" = unknown && config_vendor=
 196 config_os="`echo $config_os | sed 's/^unknown-//'`"
 197
 198 # Some configurations imply other options.
 199 case "$host_os" in
 200 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 201   # These systems always use GNU tools.
 202   gnu_ld=yes gnu_as=yes ;;
 203 esac
 204 case "$host_os" in
 205 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 206 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 207   ;;
 208 gnu* | linux* | sysv4* | solaris2* | irix6*)
 209   # These systems (almost) always use the ELF format.
 210   elf=yes
 211   ;;
 212 esac
 213
 214 machine=$config_machine
 215 vendor=$config_vendor
 216 os=$config_os
 217
 218 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 219 # Unify this here.
 220 if test "$machine" = rs6000; then
 221   machine="powerpc"
 222 fi
 223
 224 ###
 225 ### I put this here to prevent those annoying emails from people who cannot
 226 ### read and try to compile glibc on unsupported platforms.  --drepper
 227 ###
 228 ### By using the undocumented --enable-hacker-mode option for configure
 229 ### one can skip this test to make the configuration not fail for unsupported
 230 ### platforms.
 231 ###
 232 if test -z "$enable_hacker_mode"; then
 233   case "$machine-$host_os" in
 234   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 235     ;;
 236   *)
 237     echo "*** The GNU C library is currently not available for this platform."
 238     echo "*** So far nobody cared to port it and if there is no volunteer it"
 239     echo "*** might never happen.  So, if you have interest to see glibc on"
 240     echo "*** this platform visit"
 241     echo "***   http://www.gnu.org/software/libc/porting.html"
 242     echo "*** and join the group of porters"
 243     exit 1
 244     ;;
 245   esac
 246 fi
 247
 248 dnl We need to use [ and ] for other purposes for a while now.
 249 changequote(,)dnl
 250 # Expand the configuration machine name into a subdirectory by architecture
 251 # type and particular chip.
 252 case "$machine" in
 253 a29k | am29000) base_machine=a29k machine=a29k ;;
 254 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 255 arm*)           base_machine=arm machine=arm/$machine ;;
 256 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 257 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 258 hppa*64*)       base_machine=hppa machine=hppa/hppa64 ;;
 259 hppa*)          base_machine=hppa machine=hppa/hppa1.1 ;;
 260 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 261 ia64)           base_machine=ia64 machine=ia64 ;;
 262 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 263 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 264 m88???)         base_machine=m88k machine=m88k/$machine ;;
 265 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 266 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 267 mips*)          base_machine=mips
 268                 case "`uname -m`" in
 269                 IP22) machine=mips/mips3 ;;
 270                 *)    machine=mips/$machine ;;
 271                 esac ;;
 272 sh3*)           base_machine=sh machine=sh/sh3 ;;
 273 sh4*)           base_machine=sh machine=sh/sh4 ;;
 274 sparc | sparcv[67])
 275                 base_machine=sparc machine=sparc/sparc32 ;;
 276 sparcv8 | supersparc | hypersparc)
 277                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 278 sparcv8plus | sparcv8plusa | sparcv9)
 279                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 280 sparc64 | ultrasparc)
 281                 base_machine=sparc machine=sparc/sparc64 ;;
 282 esac
 283 changequote([,])dnl
 284 AC_SUBST(base_machine)
 285
 286 if test "$base_machine" = "i386"; then
 287   AC_DEFINE(USE_REGPARMS)
 288 fi
 289
 290 # Compute the list of sysdep directories for this configuration.
 291 # This can take a while to compute.
 292 sysdep_dir=$srcdir/sysdeps
 293 AC_MSG_CHECKING(sysdep dirs)
 294 dnl We need to use [ and ] for other purposes for a while now.
 295 changequote(,)dnl
 296 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 297 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 298
 299 case "$os" in
 300 gnu*)
 301   base_os=mach/hurd ;;
 302 netbsd* | 386bsd* | freebsd* | bsdi*)
 303   base_os=unix/bsd/bsd4.4 ;;
 304 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 305   base_os=unix/bsd ;;
 306 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 307   base_os=unix/sysv ;;
 308 irix6*)
 309   base_os=unix/sysv/irix6/$os ;;
 310 solaris[2-9]*)
 311   base_os=unix/sysv/sysv4 ;;
 312 hpux*)
 313   base_os=unix/sysv/hpux/$os ;;
 314 aix4.3*)
 315   base_os=unix/sysv/aix/aix4.3 ;;
 316 none)
 317   base_os=standalone ;;
 318 *)
 319   base_os='' ;;
 320 esac
 321
 322 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 323 tail=$os
 324 ostry=$os
 325 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 326   ostry="$ostry /$o"
 327   tail=$o
 328 done
 329 o=`echo $tail | sed 's/[0-9]*$//'`
 330 if test $o != $tail; then
 331   ostry="$ostry /$o"
 332 fi
 333 # For linux-gnu, try linux-gnu, then linux.
 334 o=`echo $tail | sed 's/-.*$//'`
 335 if test $o != $tail; then
 336   ostry="$ostry /$o"
 337 fi
 338
 339 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 340 base=
 341 tail=$base_os
 342 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 343   set $b
 344   base="$base /$1"
 345   tail="$2"
 346 done
 347
 348 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 349 mach=
 350 tail=$machine
 351 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 352   set $m
 353   # Prepend the machine's FPU directory unless --without-fp.
 354   if test "$with_fp" = yes; then
 355     mach="$mach /$1/fpu"
 356   fi
 357   mach="$mach /$1"
 358   tail="$2"
 359 done
 360
 361 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 362 changequote([,])dnl
 363
 364 # Find what sysdep directories exist.
 365 sysnames=
 366 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 367 for d in $add_ons_pfx ''; do
 368   for b in $base ''; do
 369     for m0 in $mach ''; do
 370       for v in /$vendor ''; do
 371         test "$v" = / && continue
 372         for o in /$ostry ''; do
 373           test "$o" = / && continue
 374           for m in $mach ''; do
 375             if test "$m0$b$v$o$m"; then
 376               try="${d}sysdeps$m0$b$v$o$m"
 377               test -n "$enable_debug_configure" &&
 378               echo "$0 [DEBUG]: try $try" >&2
 379               if test -d $srcdir/$try; then
 380                 sysnames="$sysnames $try"
 381                 { test -n "$o" || test -n "$b"; } && os_used=t
 382                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 383               fi
 384             fi
 385           done
 386         done
 387       done
 388     done
 389   done
 390 done
 391 IFS="$ac_save_ifs"
 392
 393 if test -z "$os_used" && test "$os" != none; then
 394   AC_MSG_ERROR(Operating system $os is not supported.)
 395 fi
 396 if test -z "$machine_used" && test "$machine" != none; then
 397   AC_MSG_ERROR(The $machine is not supported.)
 398 fi
 399
 400 # We have now validated the configuration.
 401
 402
 403 # If using ELF, look for an `elf' subdirectory of each machine directory.
 404 # We prepend these rather than inserting them whereever the machine appears
 405 # because things specified by the machine's ELF ABI should override
 406 # OS-specific things, and should always be the same for any OS on the
 407 # machine (otherwise what's the point of an ABI?).
 408 if test "$elf" = yes; then
 409   elf_dirs=
 410   for d in $add_ons_pfx ''; do
 411     for m in $mach; do
 412       if test -d $srcdir/${d}sysdeps$m/elf; then
 413         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 414       fi
 415     done
 416   done
 417   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 418 fi
 419
 420
 421 # Expand the list of system names into a full list of directories
 422 # from each element's parent name and Implies file (if present).
 423 set $sysnames
 424 names=
 425 while test $# -gt 0; do
 426   name=$1
 427   shift
 428
 429   case " $names " in *" $name "*)
 430     # Already in the list.
 431     continue
 432   esac
 433
 434   # Report each name as we discover it, so there is no long pause in output.
 435   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 436
 437   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 438
 439   case $name in
 440     /*) xsrcdir= ;;
 441     *)  xsrcdir=$srcdir/ ;;
 442   esac
 443   test -n "$enable_debug_configure" &&
 444   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 445
 446   if test -f $xsrcdir$name/Implies; then
 447     # Collect more names from the `Implies' file (removing comments).
 448     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 449     implied=
 450     for x in $implied_candidate; do
 451       if test -d $xsrcdir$name_base/$x; then
 452         implied="$implied $name_base/$x";
 453       else
 454         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 455       fi
 456     done
 457   else
 458     implied=
 459   fi
 460
 461   # Add NAME to the list of names.
 462   names="$names $name"
 463
 464   # Find the parent of NAME, using the empty string if it has none.
 465 changequote(,)dnl
 466   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 467 changequote([,])dnl
 468
 469   # Add the names implied by NAME, and NAME's parent (if it has one), to
 470   # the list of names to be processed (the argument list).  We prepend the
 471   # implied names to the list and append the parent.  We want implied
 472   # directories to come before further directories inferred from the
 473   # configuration components; this ensures that for sysv4, unix/common
 474   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 475   # after sysv4).
 476   sysnames="`echo $implied $* $parent`"
 477   test -n "$sysnames" && set $sysnames
 478 done
 479
 480 # Add the default directories.
 481 default_sysnames=sysdeps/generic
 482 if test "$elf" = yes; then
 483   default_sysnames="sysdeps/generic/elf $default_sysnames"
 484 fi
 485 sysnames="$names $default_sysnames"
 486 AC_SUBST(sysnames)
 487 # The other names were emitted during the scan.
 488 AC_MSG_RESULT($default_sysnames)
 489
 490
 491 ### Locate tools.
 492
 493 AC_PROG_INSTALL
 494 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 495   # The makefiles need to use a different form to find it in $srcdir.
 496   INSTALL='\$(..)./scripts/install-sh -c'
 497 fi
 498 AC_PROG_LN_S
 499
 500 # We need the physical current working directory.  We cannot use the
 501 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 502 # find a pwd binary.  Note that assigning to the PWD environment
 503 # variable might have some interesting side effects, so we don't do
 504 # that.
 505 AC_PATH_PROG(PWD_P, pwd, no)
 506 if test "$PWD_P" = no; then
 507   AC_MSG_ERROR(*** A pwd binary could not be found.)
 508 fi
 509
 510 # These programs are version sensitive.
 511 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 512 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 513   [version \([egcygnustpi-]*[0-9.]*\)],
 514   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]|sgicc-*],
 515   critic_missing=t)
 516 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 517   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 518   [3.79* | 3.[89]*], critic_missing=t)
 519
 520 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 521   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 522   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 523 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 524   [GNU texinfo.* \([0-9][0-9.]*\)],
 525   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 526 AC_CHECK_PROG_VER(SED, gsed sed, --version,
 527   [GNU sed version \([0-9]*\.[0-9.]*\)],
 528   [3.0[2-9]*|3.[1-9]*|[4-9]*], SED=: aux_missing=t)
 529
 530 if test -n "$critic_missing"; then
 531 AC_MSG_ERROR([
 532 *** Some critical program is missing or too old.
 533 *** Check the INSTALL file for required versions.])
 534 fi
 535
 536 test -n "$aux_missing" && AC_MSG_WARN([
 537 *** An auxiliary program is missing or too old;
 538 *** some features will be disabled.
 539 *** Check the INSTALL file for required versions.])
 540
 541 # glibcbug.in wants to know the compiler version.
 542 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 543 AC_SUBST(CCVERSION)
 544
 545 AC_PROG_CC_LOCAL
 546 AC_CANONICAL_BUILD
 547 if test $host != $build; then
 548   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 549 fi
 550 AC_SUBST(cross_compiling)
 551 AC_PROG_CPP
 552 LIBC_PROG_BINUTILS
 553 AC_CHECK_TOOL(MIG, mig)
 554
 555 # if using special system headers, find out the compiler's sekrit
 556 # header directory and add that to the list.  NOTE: Only does the right
 557 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 558 if test -n "$sysheaders"; then
 559   ccheaders=`$CC -print-file-name=include`
 560   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 561 fi
 562 AC_SUBST(SYSINCLUDES)
 563
 564 # check if ranlib is necessary
 565 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 566 cat > conftest.c <<EOF
 567 int a;
 568 char b;
 569 void c(void) {}
 570 EOF
 571 $CC $CFLAGS -c conftest.c
 572 $AR cr conftest.a conftest.c
 573 cp conftest.a conftest2.a
 574 $RANLIB conftest.a
 575 if cmp -s conftest.a conftest2.a; then
 576   libc_cv_ranlib_necessary=no
 577 else
 578   libc_cv_ranlib_necessary=yes
 579 fi
 580 rm -rf conftest*])
 581 if test "$libc_cv_ranlib_necessary" = no; then
 582  RANLIB=:
 583 fi
 584
 585 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 586 # since this would lead to problems installing/building glibc.
 587 # LD_LIBRARY_PATH contains the current directory if one of the following
 588 # is true:
 589 # - one of the terminals (":" and ";") is the first or last sign
 590 # - two terminals occur directly after each other
 591 # - the path contains an element with a dot in it
 592 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 593 changequote(,)dnl
 594 case ${LD_LIBRARY_PATH} in
 595   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 596     ld_library_path_setting="contains current directory"
 597     ;;
 598   *)
 599     ld_library_path_setting="ok"
 600     ;;
 601 esac
 602 changequote([,])dnl
 603 AC_MSG_RESULT($ld_library_path_setting)
 604 if test "$ld_library_path_setting" != "ok"; then
 605 AC_MSG_ERROR([
 606 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 607 *** building glibc. Please change the environment variable
 608 *** and run configure again.])
 609 fi
 610
 611 AC_PATH_PROG(BASH, bash, no)
 612 if test "$BASH" != no &&
 613    $BASH -c 'test "$BASH_VERSINFO" \
 614              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 615   libc_cv_have_bash2=yes
 616 else
 617   libc_cv_have_bash2=no
 618 fi
 619 AC_SUBST(libc_cv_have_bash2)
 620
 621 dnl We need a ksh compatible shell for tzselect.
 622 if test "$BASH" = no; then
 623   AC_PATH_PROG(KSH, ksh, no)
 624   if test "$KSH" = no; then
 625     libc_cv_have_ksh=no
 626   else
 627     libc_cv_have_ksh=yes
 628   fi
 629 else
 630   KSH="$BASH"
 631   AC_SUBST(KSH)
 632   libc_cv_have_ksh=yes
 633 fi
 634 AC_SUBST(libc_cv_have_ksh)
 635
 636 AC_PROG_AWK
 637 AC_PATH_PROG(PERL, perl, no)
 638 if test "$PERL" != no &&
 639    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
 640   PERL=no
 641 fi
 642 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 643              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 644 if test "$INSTALL_INFO" != "no"; then
 645 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 646  [mkdir conftest.d
 647   # There is a hard ^_ on the next line.  I am open to better ideas.
 648   (echo '\x1f'
 649   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 650   echo '* Menu:') >conftest.d/dir
 651   (echo 'INFO-DIR-SECTION i-d-s works'
 652   echo 'START-INFO-DIR-ENTRY'
 653   echo '* Prog: (prog).   Program.'
 654   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 655   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 656   then
 657     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 658     then libc_cv_old_debian_install_info=no
 659     else libc_cv_old_debian_install_info=yes
 660     fi
 661   else libc_cv_old_debian_install_info=no testfailed=t
 662   fi
 663   rm -fr conftest.d])
 664 if test -n "$testfailed"
 665 then AC_MSG_WARN([install-info errored out, check config.log])
 666 fi
 667 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 668 fi
 669 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 670
 671 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 672 echo '#include <stddef.h>
 673 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 674 if eval "$ac_cpp conftest.c 2>/dev/null" \
 675 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 676   libc_cv_signed_size_t=no
 677 else
 678   libc_cv_signed_size_t=yes
 679 fi
 680 rm -f conftest*])
 681 if test $libc_cv_signed_size_t = yes; then
 682   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 683   cat >> confdefs.h <<\EOF
 684 #undef __SIZE_TYPE__
 685 #define __SIZE_TYPE__ unsigned
 686 EOF
 687 fi
 688
 689 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 690 AC_TRY_COMPILE(dnl
 691 [#define __need_size_t
 692 #define __need_wchar_t
 693 #include <stddef.h>
 694 #define __need_NULL
 695 #include <stddef.h>], [size_t size; wchar_t wchar;
 696 #ifdef offsetof
 697 #error stddef.h ignored __need_*
 698 #endif
 699 if (&size == NULL || &wchar == NULL) abort ();],
 700                libc_cv_friendly_stddef=yes,
 701                libc_cv_friendly_stddef=no)])
 702 if test $libc_cv_friendly_stddef = yes; then
 703   config_vars="$config_vars
 704 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 705 fi
 706
 707 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 708                libc_cv_need_minus_P, [dnl
 709 cat > conftest.S <<EOF
 710 #include "confdefs.h"
 711 /* Nothing whatsoever.  */
 712 EOF
 713 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 714   libc_cv_need_minus_P=no
 715 else
 716   libc_cv_need_minus_P=yes
 717 fi
 718 rm -f conftest*])
 719 if test $libc_cv_need_minus_P = yes; then
 720   config_vars="$config_vars
 721 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 722 fi
 723
 724 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 725 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 726 cat > conftest.s <<EOF
 727 .text
 728 EOF
 729 libc_cv_dot_text=
 730 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 731   libc_cv_dot_text=.text
 732 fi
 733 rm -f conftest*])
 734 if test -z "$libc_cv_dot_text"; then
 735   AC_MSG_RESULT(no)
 736 else
 737   AC_MSG_RESULT(yes)
 738 fi
 739
 740 AC_CACHE_CHECK(for assembler global-symbol directive,
 741                libc_cv_asm_global_directive, [dnl
 742 libc_cv_asm_global_directive=UNKNOWN
 743 for ac_globl in .globl .global .EXPORT; do
 744   cat > conftest.s <<EOF
 745         ${libc_cv_dot_text}
 746         ${ac_globl} foo
 747 foo:
 748 EOF
 749   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 750     libc_cv_asm_global_directive=${ac_globl}
 751   fi
 752   rm -f conftest*
 753   test $libc_cv_asm_global_directive != UNKNOWN && break
 754 done])
 755 if test $libc_cv_asm_global_directive = UNKNOWN; then
 756   AC_MSG_ERROR(cannot determine asm global directive)
 757 else
 758   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 759 fi
 760
 761 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 762 cat > conftest.s <<EOF
 763 ${libc_cv_dot_text}
 764 foo:
 765 .set glibc_conftest_frobozz,foo
 766 $libc_cv_asm_global_directive glibc_conftest_frobozz
 767 EOF
 768 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 769 # (but it doesn't work), so we must do a linking check to be sure.
 770 cat > conftest1.c <<\EOF
 771 extern int glibc_conftest_frobozz;
 772 main () { printf ("%d\n", glibc_conftest_frobozz); }
 773 EOF
 774 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 775             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 776   libc_cv_asm_set_directive=yes
 777 else
 778   libc_cv_asm_set_directive=no
 779 fi
 780 rm -f conftest*])
 781 if test $libc_cv_asm_set_directive = yes; then
 782   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 783 fi
 784
 785 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 786 [cat > conftest.s <<EOF
 787 ${libc_cv_dot_text}
 788 _sym:
 789 .symver _sym,sym@VERS
 790 EOF
 791 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 792   libc_cv_asm_symver_directive=yes
 793 else
 794   libc_cv_asm_symver_directive=no
 795 fi
 796 rm -f conftest*])
 797 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 798 if test $libc_cv_asm_symver_directive = yes; then
 799   cat > conftest.s <<EOF
 800 ${libc_cv_dot_text}
 801 _sym:
 802 .symver _sym,sym@VERS
 803 EOF
 804   cat > conftest.map <<EOF
 805 VERS_1 {
 806         global: sym;
 807 };
 808
 809 VERS_2 {
 810         global: sym;
 811 } VERS_1;
 812 EOF
 813   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 814     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 815                                         -nostartfiles -nostdlib
 816                                         -Wl,--version-script,conftest.map
 817                        1>&AC_FD_CC]);
 818     then
 819       libc_cv_ld_version_script_option=yes
 820     else
 821       libc_cv_ld_version_script_option=no
 822     fi
 823   else
 824     libc_cv_ld_version_script_option=no
 825   fi
 826 else
 827   libc_cv_ld_version_script_option=no
 828 fi
 829 rm -f conftest*])
 830 if test $shared != no &&
 831    test $libc_cv_asm_symver_directive = yes &&
 832    test $libc_cv_ld_version_script_option = yes &&
 833    test $enable_versioning = yes; then
 834   VERSIONING=yes
 835   AC_DEFINE(DO_VERSIONING)
 836 else
 837   VERSIONING=no
 838 fi
 839 AC_SUBST(VERSIONING)
 840
 841 if test $shared != no && test $VERSIONING = no; then
 842   echo "\
 843 *** WARNING: You should not compile GNU libc without versioning. Not using
 844 *** versioning will introduce incompatibilities so that old binaries
 845 *** will not run anymore.
 846 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 847 fi
 848 if test $elf = yes; then
 849   AC_CACHE_CHECK(for .previous assembler directive,
 850                  libc_cv_asm_previous_directive, [dnl
 851   cat > conftest.s <<EOF
 852 .section foo_section
 853 .previous
 854 EOF
 855   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 856     libc_cv_asm_previous_directive=yes
 857   else
 858     libc_cv_asm_previous_directive=no
 859   fi
 860   rm -f conftest*])
 861   if test $libc_cv_asm_previous_directive = yes; then
 862     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 863   else
 864     AC_CACHE_CHECK(for .popsection assembler directive,
 865                    libc_cv_asm_popsection_directive, [dnl
 866     cat > conftest.s <<EOF
 867 .pushsection foo_section
 868 .popsection
 869 EOF
 870     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 871       libc_cv_asm_popsection_directive=yes
 872     else
 873       libc_cv_asm_popsection_directive=no
 874     fi
 875     rm -f conftest*])
 876     if test $libc_cv_asm_popsection_directive = yes; then
 877       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 878     fi
 879   fi
 880   AC_CACHE_CHECK(for .protected and .hidden assembler directive,
 881                  libc_cv_asm_protected_directive, [dnl
 882   cat > conftest.s <<EOF
 883 .protected foo
 884 foo:
 885 .hidden bar
 886 bar:
 887 EOF
 888   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 889     libc_cv_asm_protected_directive=yes
 890   else
 891     libc_cv_asm_protected_directive=no
 892   fi
 893   rm -f conftest*])
 894   AC_SUBST(libc_cv_asm_protected_directive)
 895
 896   AC_CACHE_CHECK(for -z nodelete option,
 897                  libc_cv_z_nodelete, [dnl
 898   cat > conftest.c <<EOF
 899 int _start (void) { return 42; }
 900 EOF
 901   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodelete 1>&AC_FD_CC])
 902   then
 903     libc_cv_z_nodelete=yes
 904   else
 905     libc_cv_z_nodelete=no
 906   fi
 907   rm -f conftest*])
 908   AC_SUBST(libc_cv_z_nodelete)
 909
 910   AC_CACHE_CHECK(for -z nodlopen option,
 911                  libc_cv_z_nodlopen, [dnl
 912   cat > conftest.c <<EOF
 913 int _start (void) { return 42; }
 914 EOF
 915   if AC_TRY_COMMAND([${CC-cc} -shared -o conftest.so conftest.c -Wl,--enable-new-dtags,-z,nodlopen 1>&AC_FD_CC])
 916   then
 917     libc_cv_z_nodlopen=yes
 918   else
 919     libc_cv_z_nodlopen=no
 920   fi
 921   rm -f conftest*])
 922   AC_SUBST(libc_cv_z_nodlopen)
 923 fi
 924
 925 if test $elf != yes; then
 926   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 927                  [AC_TRY_COMPILE(, [asm (".section .init");
 928                                     asm (".section .fini");
 929                                     asm ("${libc_cv_dot_text}");],
 930                                  libc_cv_have_initfini=yes,
 931                                  libc_cv_have_initfini=no)])
 932   AC_SUBST(libc_cv_have_initfini)dnl
 933   if test $libc_cv_have_initfini = yes; then
 934     AC_DEFINE(HAVE_INITFINI)
 935   fi
 936 fi
 937
 938 if test $elf = yes -a $gnu_ld = yes; then
 939   AC_CACHE_CHECK(whether cc puts quotes around section names,
 940                  libc_cv_have_section_quotes,
 941                  [cat > conftest.c <<EOF
 942                   static const int foo
 943                   __attribute__ ((section ("bar"))) = 1;
 944 EOF
 945                   if ${CC-cc} -S conftest.c -o conftest.s; then
 946                     if grep '\.section.*"bar"' conftest.s >/dev/null; then
 947                       libc_cv_have_section_quotes=yes
 948                     else
 949                       libc_cv_have_section_quotes=no
 950                     fi
 951                   else
 952                     libc_cv_have_section_quotes=unknown
 953                   fi
 954                   rm -f conftest.[cs]
 955                  ])
 956   if test $libc_cv_have_section_quotes = yes; then
 957     AC_DEFINE(HAVE_SECTION_QUOTES)
 958   fi
 959 fi
 960
 961 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 962 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 963 [cat > conftest.$ac_ext <<EOF
 964 dnl This sometimes fails to find confdefs.h, for some reason.
 965 dnl [#]line __oline__ "[$]0"
 966 [#]line __oline__ "configure"
 967 #include "confdefs.h"
 968 void underscore_test(void) {
 969 return; }
 970 EOF
 971 if AC_TRY_EVAL(ac_compile); then
 972   if grep _underscore_test conftest* >/dev/null; then
 973     ifelse([$1], , :, [rm -f conftest*
 974     $1])
 975   else
 976     ifelse([$2], , , [rm -f conftest*
 977     $2])
 978   fi
 979 else
 980   echo "configure: failed program was:" >&AC_FD_CC
 981   cat conftest.$ac_ext >&AC_FD_CC
 982   ifelse([$2], , , [rm -f conftest*
 983   $2])
 984 fi
 985 rm -f conftest*])
 986
 987 if test $elf = yes; then
 988   libc_cv_asm_underscores=no
 989 else
 990   if test $ac_cv_prog_cc_works = yes; then
 991     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 992                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 993                                 libc_cv_asm_underscores=yes,
 994                                 libc_cv_asm_underscores=no)])
 995   else
 996     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 997                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 998                                             libc_cv_asm_underscores=no)])
 999   fi
1000 fi
1001 if test $libc_cv_asm_underscores = no; then
1002   AC_DEFINE(NO_UNDERSCORES)
1003 fi
1004
1005 if test $elf = yes; then
1006   libc_cv_weak_symbols=yes
1007 fi
1008
1009 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1010                [dnl
1011 cat > conftest.s <<EOF
1012 ${libc_cv_dot_text}
1013 ${libc_cv_asm_global_directive} foo
1014 foo:
1015 .weak foo
1016 .weak bar; bar = foo
1017 EOF
1018 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1019   libc_cv_asm_weak_directive=yes
1020 else
1021   libc_cv_asm_weak_directive=no
1022 fi
1023 rm -f conftest*])
1024
1025 if test $libc_cv_asm_weak_directive = no; then
1026   AC_CACHE_CHECK(for assembler .weakext directive,
1027                  libc_cv_asm_weakext_directive,
1028                  [dnl
1029 cat > conftest.s <<EOF
1030 ${libc_cv_dot_text}
1031 ${libc_cv_asm_global_directive} foo
1032 foo:
1033 .weakext bar foo
1034 .weakext baz
1035 ${libc_cv_asm_global_directive} baz
1036 baz:
1037 EOF
1038   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
1039     libc_cv_asm_weakext_directive=yes
1040   else
1041     libc_cv_asm_weakext_directive=no
1042   fi
1043   rm -f conftest*])
1044
1045 fi # no .weak
1046
1047 if test $libc_cv_asm_weak_directive = yes; then
1048   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1049 elif test $libc_cv_asm_weakext_directive = yes; then
1050   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1051 fi
1052
1053 dnl The standard hppa assembler uses `;' to start comments and `!'
1054 dnl as a line separator.
1055 case "${host_cpu}-${host_os}" in
1056   hppa*linux*)
1057   AC_CACHE_CHECK(for assembler line separator,
1058                  libc_cv_asm_line_sep, [dnl
1059   cat > conftest.s <<EOF
1060  nop ; is_old_puffin
1061 EOF
1062   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
1063     libc_cv_asm_line_sep='!'
1064   else
1065     if test -z "$enable_hacker_mode"; then
1066       echo "*** You need a newer assembler to compile glibc"
1067       rm -f conftest*
1068       exit 1
1069     fi
1070     libc_cv_asm_line_sep=';'
1071   fi
1072   rm -f conftest*])
1073   AC_DEFINE_UNQUOTED(ASM_LINE_SEP, $libc_cv_asm_line_sep)
1074   ;;
1075 esac
1076
1077 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1078 cat > conftest.c <<\EOF
1079 _start () {}
1080 int __eh_pc;
1081 __throw () {}
1082 EOF
1083 dnl No \ in command here because it ends up inside ''.
1084 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1085                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1086                             -o conftest conftest.c 1>&AC_FD_CC]); then
1087   libc_cv_ld_no_whole_archive=yes
1088 else
1089   libc_cv_ld_no_whole_archive=no
1090 fi
1091 rm -f conftest*])
1092 if test $libc_cv_ld_no_whole_archive = yes; then
1093   no_whole_archive=-Wl,--no-whole-archive
1094 fi
1095 AC_SUBST(no_whole_archive)dnl
1096
1097 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1098 cat > conftest.c <<\EOF
1099 _start () {}
1100 int __eh_pc;
1101 __throw () {}
1102 EOF
1103 dnl No \ in command here because it ends up inside ''.
1104 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
1105                             -nostdlib -nostartfiles -fexceptions
1106                             -o conftest conftest.c 1>&AC_FD_CC]); then
1107   libc_cv_gcc_exceptions=yes
1108 else
1109   libc_cv_gcc_exceptions=no
1110 fi
1111 rm -f conftest*])
1112 if test $libc_cv_gcc_exceptions = yes; then
1113   exceptions=-fexceptions
1114 fi
1115 AC_SUBST(exceptions)dnl
1116
1117 if test "$base_machine" = alpha ; then
1118 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1119 cat > conftest.c <<\EOF
1120 foo () { }
1121 EOF
1122 dnl
1123 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1124 then
1125   libc_cv_gcc_alpha_ng_prefix=yes
1126 else
1127   libc_cv_gcc_alpha_ng_prefix=no
1128 fi
1129 rm -f conftest* ])
1130 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1131   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1132 else
1133   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1134 fi
1135 fi
1136
1137 if test "$host_cpu" = powerpc ; then
1138 # Check for a bug present in at least versions 2.8.x of GCC
1139 # and versions 1.0.x of EGCS.
1140 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1141 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1142                libc_cv_c_asmcr0_bug='no',
1143                libc_cv_c_asmcr0_bug='yes')])
1144 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1145   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1146 fi
1147 fi
1148
1149 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1150 [cat > conftest.c <<EOF
1151 #line __oline__ "configure"
1152 static char __EH_FRAME_BEGIN__[];
1153 _start ()
1154 {
1155 #ifdef CHECK__register_frame
1156   __register_frame (__EH_FRAME_BEGIN__);
1157   __deregister_frame (__EH_FRAME_BEGIN__);
1158 #endif
1159 #ifdef CHECK__register_frame_info
1160   __register_frame_info (__EH_FRAME_BEGIN__);
1161   __deregister_frame_info (__EH_FRAME_BEGIN__);
1162 #endif
1163 }
1164 int __eh_pc;
1165 __throw () {}
1166 /* FIXME: this is fragile.  */
1167 malloc () {}
1168 strcmp () {}
1169 strlen () {}
1170 memcpy () {}
1171 memset () {}
1172 free () {}
1173 abort () {}
1174 __bzero () {}
1175 EOF
1176 dnl No \ in command here because it ends up inside ''.
1177 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1178                             -nostdlib -nostartfiles
1179                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1180   libc_cv_gcc_dwarf2_unwind_info=static
1181 else
1182   libc_cv_gcc_dwarf2_unwind_info=no
1183 fi
1184 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1185   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1186                               -nostdlib -nostartfiles
1187                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1188     libc_cv_gcc_dwarf2_unwind_info=yes
1189   else
1190     libc_cv_gcc_dwarf2_unwind_info=no
1191   fi
1192 fi
1193 rm -f conftest*])
1194 case $libc_cv_gcc_dwarf2_unwind_info in
1195 yes)
1196   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1197   ;;
1198 static)
1199   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1200   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1201   ;;
1202 esac
1203
1204 dnl Check whether compiler understands __builtin_expect.
1205 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1206 [cat > conftest.c <<EOF
1207 #line __oline__ "configure"
1208 int foo (int a)
1209 {
1210   a = __builtin_expect (a, 10);
1211   return a == 10 ? 0 : 1;
1212 }
1213 EOF
1214 dnl No \ in command here because it ends up inside ''.
1215 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1216                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1217   libc_cv_gcc_builtin_expect=yes
1218 else
1219   libc_cv_gcc_builtin_expect=no
1220 fi
1221 rm -f conftest*])
1222 if test "$libc_cv_gcc_builtin_expect" = yes; then
1223   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1224 fi
1225
1226 dnl Check whether the compiler supports subtraction of local labels.
1227 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1228 [cat > conftest.c <<EOF
1229 changequote(,)dnl
1230 #line __oline__ "configure"
1231 int foo (int a)
1232 {
1233   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1234   void *p = &&l1 + ar[a];
1235   goto *p;
1236  l1:
1237   return 1;
1238  l2:
1239   return 2;
1240 }
1241 changequote([,])dnl
1242 EOF
1243 dnl No \ in command here because it ends up inside ''.
1244 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1245                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1246   libc_cv_gcc_subtract_local_labels=yes
1247 else
1248   libc_cv_gcc_subtract_local_labels=no
1249 fi
1250 rm -f conftest*])
1251 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1252   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1253 fi
1254
1255 dnl Check whether we have the gd library available.
1256 AC_MSG_CHECKING(for libgd)
1257 old_CFLAGS="$CFLAGS"
1258 CFLAGS="$CFLAGS $libgd_include"
1259 old_LDFLAGS="$LDFLAGS"
1260 LDFLAGS="$LDFLAGS $libgd_ldflags"
1261 old_LIBS="$LIBS"
1262 LIBS="$LIBS -lgd -lpng -lz -lm"
1263 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1264 CFLAGS="$old_CFLAGS"
1265 LDFLAGS="$old_LDFLAGS"
1266 LIBS="$old_LIBS"
1267 AC_MSG_RESULT($LIBGD)
1268 AC_SUBST(LIBGD)
1269
1270 dnl check for the size of 'long double'.
1271 AC_CHECK_SIZEOF(long double, 0)
1272 sizeof_long_double=$ac_cv_sizeof_long_double
1273 AC_SUBST(sizeof_long_double)
1274
1275 ### End of automated tests.
1276 ### Now run sysdeps configure fragments.
1277
1278 # sysdeps configure fragments may set these with files to be linked below.
1279 libc_link_dests=
1280 libc_link_sources=
1281
1282 # They also can set these variables.
1283 use_ldconfig=no
1284 ldd_rewrite_script=no
1285
1286 # Iterate over all the sysdep directories we will use, running their
1287 # configure fragments, and looking for a uname implementation.
1288 uname=
1289 for dir in $sysnames; do
1290   case $dir in
1291     /*) dest=$dir ;;
1292     *)  dest=$srcdir/$dir ;;
1293   esac
1294   if test -r $dest/configure; then
1295     AC_MSG_RESULT(running configure fragment for $dest)
1296     . $dest/configure
1297   fi
1298 [
1299   if test -z "$uname"; then
1300     if test -r $dest/uname.c ||
1301        test -r $dest/uname.S ||
1302        { test -r $dest/syscalls.list &&
1303          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1304       uname=$dir
1305     fi
1306   fi
1307 ]dnl
1308 done
1309
1310 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1311
1312 # If we will use the generic uname implementation, we must figure out what
1313 # it will say by examining the system, and write the results in config-name.h.
1314 if test "$uname" = "sysdeps/generic"; then
1315
1316 changequote(,)dnl
1317   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1318 changequote([,])dnl
1319   if test $uname_sysname != $config_os; then
1320     config_release=`echo $config_os | sed s/$uname_sysname//`
1321   fi
1322 dnl
1323 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1324     if test -r /vmunix; then
1325       kernel_id=`strings /vmunix | grep UNIX`
1326     elif test -r /dynix; then
1327       kernel_id=`strings /dynix | grep DYNIX`
1328     else
1329       kernel_id=
1330     fi
1331 ])dnl
1332
1333   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1334 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1335 changequote(,)dnl
1336   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1337 changequote([,])dnl
1338   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1339          != x$config_release; then
1340     # The configuration release is a substring of the kernel release.
1341     libc_cv_uname_release=$kernel_release
1342   elif test x$config_release != x; then
1343     libc_cv_uname_release=$config_release
1344   elif test x$kernel_release != x; then
1345     libc_cv_uname_release=$kernel_release
1346   else
1347     libc_cv_uname_release=unknown
1348   fi])
1349   uname_release="$libc_cv_uname_release"
1350
1351   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1352 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1353 changequote(,)dnl
1354   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1355 changequote([,])dnl
1356   if test -n "$kernel_version"; then
1357     libc_cv_uname_version="$kernel_version"
1358   else
1359     libc_cv_uname_version=unknown
1360   fi])
1361   uname_version="$libc_cv_uname_version"
1362
1363 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1364   config_uname=config-name.h:config-name.in
1365 else
1366   # For non-generic uname, we don't need to create config-name.h at all.
1367   config_uname=
1368 fi
1369
1370 AC_MSG_CHECKING(stdio selection)
1371 AC_SUBST(stdio)
1372 case $stdio in
1373 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1374 default) stdio=stdio ;;
1375 esac
1376 AC_MSG_RESULT($stdio)
1377
1378 # Test for old glibc 2.0.x headers so that they can be removed properly
1379 # Search only in includedir.
1380 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1381 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1382 then
1383   old_glibc_headers=yes
1384 else
1385   old_glibc_headers=no
1386 fi
1387 AC_MSG_RESULT($old_glibc_headers)
1388 if test ${old_glibc_headers} = yes; then
1389   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1390   AC_MSG_WARN(*** be removed.)
1391 fi
1392 AC_SUBST(old_glibc_headers)
1393
1394 AC_SUBST(libc_cv_slibdir)
1395 AC_SUBST(libc_cv_localedir)
1396 AC_SUBST(libc_cv_sysconfdir)
1397 AC_SUBST(libc_cv_rootsbindir)
1398
1399 AC_SUBST(use_ldconfig)
1400 AC_SUBST(ldd_rewrite_script)
1401
1402 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1403 if test $gnu_ld = yes; then
1404   AC_DEFINE(HAVE_GNU_LD)
1405 fi
1406 if test $gnu_as = yes; then
1407   AC_DEFINE(HAVE_GNU_AS)
1408 fi
1409 if test $elf = yes; then
1410   AC_DEFINE(HAVE_ELF)
1411 fi
1412
1413 AC_SUBST(static)
1414 AC_SUBST(shared)
1415 if test $shared = default; then
1416   if test $gnu_ld = yes; then
1417     shared=$elf
1418   else
1419     # For now we do not assume shared libs are available.  In future more
1420     # tests might become available.
1421     shared=no
1422   fi
1423 fi
1424
1425 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1426 [pic_default=yes
1427 cat > conftest.c <<EOF
1428 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1429 # error PIC is default.
1430 #endif
1431 EOF
1432 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1433   pic_default=no
1434 fi
1435 rm -f conftest.*])
1436 AC_SUBST(pic_default)
1437
1438 AC_SUBST(profile)
1439 AC_SUBST(omitfp)
1440 AC_SUBST(bounded)
1441 AC_SUBST(static_nss)
1442 AC_SUBST(nopic_initfini)
1443
1444 AC_SUBST(DEFINES)
1445
1446 case "$add_ons" in
1447   *door*) linux_doors=yes ;;
1448   *) linux_doors=no ;;
1449 esac
1450 AC_SUBST(linux_doors)
1451
1452 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1453   config_makefile=
1454 else
1455   config_makefile=Makefile
1456 fi
1457
1458 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1459 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1460 AC_SUBST(VERSION)
1461 AC_SUBST(RELEASE)
1462
1463 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1464 case $CONFIG_FILES in *config.make*)
1465 echo "$config_vars" >> config.make;;
1466 esac
1467 test -d bits || mkdir bits], [config_vars='$config_vars'])