sysdeps/powerpc/memset.S

   1 /* Optimized memset implementation for PowerPC.
   2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* __ptr_t [r3] memset (__ptr_t s [r3], int c [r4], size_t n [r5]));
  25    Returns 's'.
  26
  27    The memset is done in three sizes: byte (8 bits), word (32 bits),
  28    cache line (256 bits). There is a special case for setting cache lines
  29    to 0, to take advantage of the dcbz instruction.  */
  30
  31 EALIGN (BP_SYM (memset), 5, 1)
  32
  33 #define rTMP    r0
  34 #define rRTN    r3      /* initial value of 1st argument */
  35 #if __BOUNDED_POINTERS__
  36 # define rMEMP0 r4      /* original value of 1st arg */
  37 # define rCHR   r5      /* char to set in each byte */
  38 # define rLEN   r6      /* length of region to set */
  39 # define rMEMP  r10     /* address at which we are storing */
  40 #else
  41 # define rMEMP0 r3      /* original value of 1st arg */
  42 # define rCHR   r4      /* char to set in each byte */
  43 # define rLEN   r5      /* length of region to set */
  44 # define rMEMP  r6      /* address at which we are storing */
  45 #endif
  46 #define rALIGN  r7      /* number of bytes we are setting now (when aligning) */
  47 #define rMEMP2  r8
  48
  49 #define rPOS32  r7      /* constant +32 for clearing with dcbz */
  50 #define rNEG64  r8      /* constant -64 for clearing with dcbz */
  51 #define rNEG32  r9      /* constant -32 for clearing with dcbz */
  52
  53 #if __BOUNDED_POINTERS__
  54         cmplwi  cr1, rRTN, 0
  55         CHECK_BOUNDS_BOTH_WIDE (rMEMP0, rTMP, rTMP2, rLEN)
  56         beq     cr1, L(b0)
  57         STORE_RETURN_VALUE (rMEMP0)
  58         STORE_RETURN_BOUNDS (rTMP, rTMP2)
  59 L(b0):
  60 #endif
  61
  62 /* take care of case for size <= 4  */
  63         cmplwi  cr1, rLEN, 4
  64         andi.   rALIGN, rMEMP0, 3
  65         mr      rMEMP, rMEMP0
  66         ble-    cr1, L(small)
  67 /* align to word boundary  */
  68         cmplwi  cr5, rLEN, 31
  69         rlwimi  rCHR, rCHR, 8, 16, 23
  70         beq+    L(aligned)      /* 8th instruction from .align */
  71         mtcrf   0x01, rMEMP0
  72         subfic  rALIGN, rALIGN, 4
  73         add     rMEMP, rMEMP, rALIGN
  74         sub     rLEN, rLEN, rALIGN
  75         bf+     31, L(g0)
  76         stb     rCHR, 0(rMEMP0)
  77         bt      30, L(aligned)
  78 L(g0):  sth     rCHR, -2(rMEMP) /* 16th instruction from .align */
  79 /* take care of case for size < 31 */
  80 L(aligned):
  81         mtcrf   0x01, rLEN
  82         rlwimi  rCHR, rCHR, 16, 0, 15
  83         ble     cr5, L(medium)
  84 /* align to cache line boundary...  */
  85         andi.   rALIGN, rMEMP, 0x1C
  86         subfic  rALIGN, rALIGN, 0x20
  87         beq     L(caligned)
  88         mtcrf   0x01, rALIGN
  89         add     rMEMP, rMEMP, rALIGN
  90         sub     rLEN, rLEN, rALIGN
  91         cmplwi  cr1, rALIGN, 0x10
  92         mr      rMEMP2, rMEMP
  93         bf      28, L(a1)
  94         stw     rCHR, -4(rMEMP2)
  95         stwu    rCHR, -8(rMEMP2)
  96 L(a1):  blt     cr1, L(a2)
  97         stw     rCHR, -4(rMEMP2) /* 32nd instruction from .align */
  98         stw     rCHR, -8(rMEMP2)
  99         stw     rCHR, -12(rMEMP2)
 100         stwu    rCHR, -16(rMEMP2)
 101 L(a2):  bf      29, L(caligned)
 102         stw     rCHR, -4(rMEMP2)
 103 /* now aligned to a cache line.  */
 104 L(caligned):
 105         cmplwi  cr1, rCHR, 0
 106         clrrwi. rALIGN, rLEN, 5
 107         mtcrf   0x01, rLEN      /* 40th instruction from .align */
 108         beq     cr1, L(zloopstart) /* special case for clearing memory using dcbz */
 109         srwi    rTMP, rALIGN, 5
 110         mtctr   rTMP
 111         beq     L(medium)       /* we may not actually get to do a full line */
 112         clrlwi. rLEN, rLEN, 27
 113         add     rMEMP, rMEMP, rALIGN
 114         li      rNEG64, -0x40
 115         bdz     L(cloopdone)    /* 48th instruction from .align */
 116
 117 L(c3):  dcbz    rNEG64, rMEMP
 118         stw     rCHR, -4(rMEMP)
 119         stw     rCHR, -8(rMEMP)
 120         stw     rCHR, -12(rMEMP)
 121         stw     rCHR, -16(rMEMP)
 122         nop                     /* let 601 fetch last 4 instructions of loop */
 123         stw     rCHR, -20(rMEMP)
 124         stw     rCHR, -24(rMEMP) /* 56th instruction from .align */
 125         nop                     /* let 601 fetch first 8 instructions of loop */
 126         stw     rCHR, -28(rMEMP)
 127         stwu    rCHR, -32(rMEMP)
 128         bdnz    L(c3)
 129 L(cloopdone):
 130         stw     rCHR, -4(rMEMP)
 131         stw     rCHR, -8(rMEMP)
 132         stw     rCHR, -12(rMEMP)
 133         stw     rCHR, -16(rMEMP) /* 64th instruction from .align */
 134         stw     rCHR, -20(rMEMP)
 135         cmplwi  cr1, rLEN, 16
 136         stw     rCHR, -24(rMEMP)
 137         stw     rCHR, -28(rMEMP)
 138         stwu    rCHR, -32(rMEMP)
 139         beqlr
 140         add     rMEMP, rMEMP, rALIGN
 141         b       L(medium_tail2) /* 72nd instruction from .align */
 142
 143         .align 5
 144         nop
 145 /* Clear lines of memory in 128-byte chunks.  */
 146 L(zloopstart):
 147         clrlwi  rLEN, rLEN, 27
 148         mtcrf   0x02, rALIGN
 149         srwi.   rTMP, rALIGN, 7
 150         mtctr   rTMP
 151         li      rPOS32, 0x20
 152         li      rNEG64, -0x40
 153         cmplwi  cr1, rLEN, 16   /* 8 */
 154         bf      26, L(z0)
 155         dcbz    0, rMEMP
 156         addi    rMEMP, rMEMP, 0x20
 157 L(z0):  li      rNEG32, -0x20
 158         bf      25, L(z1)
 159         dcbz    0, rMEMP
 160         dcbz    rPOS32, rMEMP
 161         addi    rMEMP, rMEMP, 0x40 /* 16 */
 162 L(z1):  cmplwi  cr5, rLEN, 0
 163         beq     L(medium)
 164 L(zloop):
 165         dcbz    0, rMEMP
 166         dcbz    rPOS32, rMEMP
 167         addi    rMEMP, rMEMP, 0x80
 168         dcbz    rNEG64, rMEMP
 169         dcbz    rNEG32, rMEMP
 170         bdnz    L(zloop)
 171         beqlr   cr5
 172         b       L(medium_tail2)
 173
 174         .align 5
 175 L(small):
 176 /* Memset of 4 bytes or less.  */
 177         cmplwi  cr5, rLEN, 1
 178         cmplwi  cr1, rLEN, 3
 179         bltlr   cr5
 180         stb     rCHR, 0(rMEMP)
 181         beqlr   cr5
 182         nop
 183         stb     rCHR, 1(rMEMP)
 184         bltlr   cr1
 185         stb     rCHR, 2(rMEMP)
 186         beqlr   cr1
 187         nop
 188         stb     rCHR, 3(rMEMP)
 189         blr
 190
 191 /* Memset of 0-31 bytes.  */
 192         .align 5
 193 L(medium):
 194         cmplwi  cr1, rLEN, 16
 195 L(medium_tail2):
 196         add     rMEMP, rMEMP, rLEN
 197 L(medium_tail):
 198         bt-     31, L(medium_31t)
 199         bt-     30, L(medium_30t)
 200 L(medium_30f):
 201         bt-     29, L(medium_29t)
 202 L(medium_29f):
 203         bge-    cr1, L(medium_27t)
 204         bflr-   28
 205         stw     rCHR, -4(rMEMP) /* 8th instruction from .align */
 206         stw     rCHR, -8(rMEMP)
 207         blr
 208
 209 L(medium_31t):
 210         stbu    rCHR, -1(rMEMP)
 211         bf-     30, L(medium_30f)
 212 L(medium_30t):
 213         sthu    rCHR, -2(rMEMP)
 214         bf-     29, L(medium_29f)
 215 L(medium_29t):
 216         stwu    rCHR, -4(rMEMP)
 217         blt-    cr1, L(medium_27f) /* 16th instruction from .align */
 218 L(medium_27t):
 219         stw     rCHR, -4(rMEMP)
 220         stw     rCHR, -8(rMEMP)
 221         stw     rCHR, -12(rMEMP)
 222         stwu    rCHR, -16(rMEMP)
 223 L(medium_27f):
 224         bflr-   28
 225 L(medium_28t):
 226         stw     rCHR, -4(rMEMP)
 227         stw     rCHR, -8(rMEMP)
 228         blr
 229 END (BP_SYM (memset))