sysdeps/sparc/sparc32/addmul_1.S

   1 ! SPARC __mpn_addmul_1 -- Multiply a limb vector with a limb and add
   2 ! the result to a second limb vector.
   3 !
   4 ! Copyright (C) 1992, 1993, 1994, 1997 Free Software Foundation, Inc.
   5 !
   6 ! This file is part of the GNU MP Library.
   7 !
   8 ! The GNU MP Library is free software; you can redistribute it and/or modify
   9 ! it under the terms of the GNU Lesser General Public License as published by
  10 ! the Free Software Foundation; either version 2.1 of the License, or (at your
  11 ! option) any later version.
  12 !
  13 ! The GNU MP Library is distributed in the hope that it will be useful, but
  14 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 ! License for more details.
  17 !
  18 ! You should have received a copy of the GNU Lesser General Public License
  19 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  21 ! MA 02111-1307, USA.
  22
  23
  24 ! INPUT PARAMETERS
  25 ! RES_PTR       o0
  26 ! S1_PTR        o1
  27 ! SIZE          o2
  28 ! S2_LIMB       o3
  29
  30 #include <sysdep.h>
  31
  32 ENTRY(__mpn_addmul_1)
  33         ! Make S1_PTR and RES_PTR point at the end of their blocks
  34         ! and put (- 4 x SIZE) in index/loop counter.
  35         sll     %o2,2,%o2
  36         add     %o0,%o2,%o4     ! RES_PTR in o4 since o0 is retval
  37         add     %o1,%o2,%o1
  38         sub     %g0,%o2,%o2
  39
  40         cmp     %o3,0xfff
  41         bgu     LOC(large)
  42         nop
  43
  44         ld      [%o1+%o2],%o5
  45         mov     0,%o0
  46         b       LOC(0)
  47          add    %o4,-4,%o4
  48 LOC(loop0):
  49         addcc   %o5,%g1,%g1
  50         ld      [%o1+%o2],%o5
  51         addx    %o0,%g0,%o0
  52         st      %g1,[%o4+%o2]
  53 LOC(0): wr      %g0,%o3,%y
  54         sra     %o5,31,%g2
  55         and     %o3,%g2,%g2
  56         andcc   %g1,0,%g1
  57         mulscc  %g1,%o5,%g1
  58         mulscc  %g1,%o5,%g1
  59         mulscc  %g1,%o5,%g1
  60         mulscc  %g1,%o5,%g1
  61         mulscc  %g1,%o5,%g1
  62         mulscc  %g1,%o5,%g1
  63         mulscc  %g1,%o5,%g1
  64         mulscc  %g1,%o5,%g1
  65         mulscc  %g1,%o5,%g1
  66         mulscc  %g1,%o5,%g1
  67         mulscc  %g1,%o5,%g1
  68         mulscc  %g1,%o5,%g1
  69         mulscc  %g1,0,%g1
  70         sra     %g1,20,%g4
  71         sll     %g1,12,%g1
  72         rd      %y,%g3
  73         srl     %g3,20,%g3
  74         or      %g1,%g3,%g1
  75
  76         addcc   %g1,%o0,%g1
  77         addx    %g2,%g4,%o0     ! add sign-compensation and cy to hi limb
  78         addcc   %o2,4,%o2       ! loop counter
  79         bne     LOC(loop0)
  80          ld     [%o4+%o2],%o5
  81
  82         addcc   %o5,%g1,%g1
  83         addx    %o0,%g0,%o0
  84         retl
  85         st      %g1,[%o4+%o2]
  86
  87
  88 LOC(large):
  89         ld      [%o1+%o2],%o5
  90         mov     0,%o0
  91         sra     %o3,31,%g4      ! g4 = mask of ones iff S2_LIMB < 0
  92         b       LOC(1)
  93          add    %o4,-4,%o4
  94 LOC(loop):
  95         addcc   %o5,%g3,%g3
  96         ld      [%o1+%o2],%o5
  97         addx    %o0,%g0,%o0
  98         st      %g3,[%o4+%o2]
  99 LOC(1): wr      %g0,%o5,%y
 100         and     %o5,%g4,%g2
 101         andcc   %g0,%g0,%g1
 102         mulscc  %g1,%o3,%g1
 103         mulscc  %g1,%o3,%g1
 104         mulscc  %g1,%o3,%g1
 105         mulscc  %g1,%o3,%g1
 106         mulscc  %g1,%o3,%g1
 107         mulscc  %g1,%o3,%g1
 108         mulscc  %g1,%o3,%g1
 109         mulscc  %g1,%o3,%g1
 110         mulscc  %g1,%o3,%g1
 111         mulscc  %g1,%o3,%g1
 112         mulscc  %g1,%o3,%g1
 113         mulscc  %g1,%o3,%g1
 114         mulscc  %g1,%o3,%g1
 115         mulscc  %g1,%o3,%g1
 116         mulscc  %g1,%o3,%g1
 117         mulscc  %g1,%o3,%g1
 118         mulscc  %g1,%o3,%g1
 119         mulscc  %g1,%o3,%g1
 120         mulscc  %g1,%o3,%g1
 121         mulscc  %g1,%o3,%g1
 122         mulscc  %g1,%o3,%g1
 123         mulscc  %g1,%o3,%g1
 124         mulscc  %g1,%o3,%g1
 125         mulscc  %g1,%o3,%g1
 126         mulscc  %g1,%o3,%g1
 127         mulscc  %g1,%o3,%g1
 128         mulscc  %g1,%o3,%g1
 129         mulscc  %g1,%o3,%g1
 130         mulscc  %g1,%o3,%g1
 131         mulscc  %g1,%o3,%g1
 132         mulscc  %g1,%o3,%g1
 133         mulscc  %g1,%o3,%g1
 134         mulscc  %g1,%g0,%g1
 135         rd      %y,%g3
 136         addcc   %g3,%o0,%g3
 137         addx    %g2,%g1,%o0
 138         addcc   %o2,4,%o2
 139         bne     LOC(loop)
 140          ld     [%o4+%o2],%o5
 141
 142         addcc   %o5,%g3,%g3
 143         addx    %o0,%g0,%o0
 144         retl
 145         st      %g3,[%o4+%o2]
 146
 147 END(__mpn_addmul_1)