sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-1997,2000-2002,2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  21    We cannot do it in C because it must be a tail-call, so frame-unwinding
  22    in setjmp doesn't clobber the state restored by longjmp.  */
  23
  24 #include <sysdep.h>
  25 #include <jmpbuf-offsets.h>
  26 #include "bp-sym.h"
  27 #include "bp-asm.h"
  28
  29 #define PARMS   LINKAGE         /* no space for saved regs */
  30 #define JMPBUF  PARMS
  31 #define SIGMSK  JMPBUF+PTR_SIZE
  32
  33 ENTRY (BP_SYM (_setjmp))
  34         ENTER
  35
  36         xorl %eax, %eax
  37         movl JMPBUF(%esp), %edx
  38         CHECK_BOUNDS_BOTH_WIDE (%edx, JMPBUF(%esp), $(JB_SIZE+4))
  39
  40         /* Save registers.  */
  41         movl %ebx, (JB_BX*4)(%edx)
  42         movl %esi, (JB_SI*4)(%edx)
  43         movl %edi, (JB_DI*4)(%edx)
  44         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  45 #ifdef PTR_MANGLE
  46         PTR_MANGLE (%ecx)
  47 #endif
  48         movl %ecx, (JB_SP*4)(%edx)
  49         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  50 #ifdef PTR_MANGLE
  51         PTR_MANGLE (%ecx)
  52 #endif
  53         movl %ecx, (JB_PC*4)(%edx)
  54         LEAVE
  55         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  56
  57         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  58         ret
  59 END (BP_SYM (_setjmp))
  60 libc_hidden_def (_setjmp)