sysdeps/sh/_mcount.S

   1 /* Machine-specific calling sequence for `mcount' profiling function.  SuperH
   2    Copyright (C) 2001, 2005 Free Software Foundation, Inc.
   3    Contributed by NIIBE Yutaka <gniibe@m17n.org>
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23         ASM_GLOBAL_DIRECTIVE C_SYMBOL_NAME(_mcount)
  24         ASM_TYPE_DIRECTIVE (C_SYMBOL_NAME(_mcount),function)
  25         cfi_startproc
  26         .align  5
  27 C_LABEL(_mcount)
  28         /* Save registers.  */
  29         mov.l   r4,@-r15
  30         cfi_adjust_cfa_offset (4)
  31         cfi_rel_offset (r4, 0)
  32         mov.l   r5,@-r15
  33         cfi_adjust_cfa_offset (4)
  34         cfi_rel_offset (r5, 0)
  35         mov.l   r6,@-r15
  36         cfi_adjust_cfa_offset (4)
  37         cfi_rel_offset (r6, 0)
  38         mov.l   r7,@-r15
  39         cfi_adjust_cfa_offset (4)
  40         cfi_rel_offset (r7, 0)
  41         sts.l   pr,@-r15
  42         cfi_adjust_cfa_offset (4)
  43         cfi_rel_offset (pr, 0)
  44
  45         mov.l   @(20,r15),r4
  46         sts     pr,r5
  47
  48 #ifdef SHARED
  49         mov.l   0f,r1
  50         mova    0f,r0
  51         add     r1,r0
  52         mov.l   1f,r1
  53         mov.l   @(r0,r1),r1
  54 #else
  55         mov.l   1f,r1
  56 #endif
  57         jsr     @r1
  58          nop
  59
  60         /* Pop the saved registers.  */
  61         lds.l   @r15+,pr
  62         mov.l   @r15+,r7
  63         mov.l   @r15+,r6
  64         mov.l   @r15+,r5
  65         rts
  66          mov.l  @r15+,r4
  67
  68         .align 2
  69 #ifdef SHARED
  70 0:      .long   _GLOBAL_OFFSET_TABLE_
  71 1:      .long   C_SYMBOL_NAME(__mcount_internal)@GOT
  72 #else
  73 1:      .long   C_SYMBOL_NAME(__mcount_internal)
  74 #endif
  75         cfi_endproc
  76 ASM_SIZE_DIRECTIVE(C_SYMBOL_NAME(_mcount))
  77
  78 #undef mcount
  79 weak_alias (_mcount, mcount)