sysdeps/ia64/memchr.S

   1 /* Optimized version of the standard memchr() function.
   2    This file is part of the GNU C Library.
   3    Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   4    Contributed by Dan Pop <Dan.Pop@cern.ch>.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* Return: the address of the first occurence of chr in str or NULL
  22
  23    Inputs:
  24         in0:    str
  25         in1:    chr
  26         in2:    byte count
  27
  28    This implementation assumes little endian mode.  For big endian mode,
  29    the instruction czx1.r should be replaced by czx1.l.
  30
  31    The algorithm is fairly straightforward: search byte by byte until we
  32    we get to a word aligned address, then search word by word as much as
  33    possible; the remaining few bytes are searched one at a time.
  34
  35    The word by word search is performed by xor-ing the word with a word
  36    containing chr in every byte.  If there is a hit, the result will
  37    contain a zero byte in the corresponding position.  The presence and
  38    position of that zero byte is detected with a czx instruction.
  39
  40    All the loops in this function could have had the internal branch removed
  41    if br.ctop and br.cloop could be predicated :-(.  */
  42
  43 #include <sysdep.h>
  44 #undef ret
  45
  46 #define saved_pr        r15
  47 #define saved_lc        r16
  48 #define chr             r17
  49 #define len             r18
  50 #define pos0            r20
  51 #define val             r21
  52 #define tmp             r24
  53 #define chrx8           r25
  54 #define loopcnt         r30
  55
  56 #define str             in0
  57
  58 ENTRY(__memchr)
  59         .prologue
  60         alloc r2 = ar.pfs, 3, 0, 29, 32
  61 #include "softpipe.h"
  62         .rotr   value[MEMLAT+1], addr[MEMLAT+3], aux[2], poschr[2]
  63         .rotp   p[MEMLAT+3]
  64         .save ar.lc, saved_lc
  65         mov     saved_lc = ar.lc        // save the loop counter
  66         .save pr, saved_pr
  67         mov     saved_pr = pr           // save the predicates
  68         .body
  69         mov     ret0 = str
  70         and     tmp = 7, str            // tmp = str % 8
  71         cmp.ne  p7, p0 = r0, r0         // clear p7
  72         extr.u  chr = in1, 0, 8         // chr = (unsigned char) in1
  73         mov     len = in2
  74         cmp.gtu p6, p0 = 16, in2        // use a simple loop for short
  75 (p6)    br.cond.spnt .srchfew ;;        // searches
  76         sub     loopcnt = 8, tmp        // loopcnt = 8 - tmp
  77         cmp.eq  p6, p0 = tmp, r0
  78 (p6)    br.cond.sptk    .str_aligned;;
  79         sub     len = len, loopcnt
  80         adds    loopcnt = -1, loopcnt;;
  81         mov     ar.lc = loopcnt
  82 .l1:
  83         ld1     val = [ret0], 1
  84         ;;
  85         cmp.eq  p6, p0 = val, chr
  86 (p6)    br.cond.spnt    .foundit
  87         br.cloop.sptk   .l1 ;;
  88 .str_aligned:
  89         cmp.ne  p6, p0 = r0, r0         // clear p6
  90         shr.u   loopcnt = len, 3        // loopcnt = len / 8
  91         and     len = 7, len ;;         // remaining len = len & 7
  92         adds    loopcnt = -1, loopcnt
  93         mov     ar.ec = MEMLAT + 3
  94         mux1    chrx8 = chr, @brcst ;;  // get a word full of chr
  95         mov     ar.lc = loopcnt
  96         mov     pr.rot = 1 << 16 ;;
  97 .l2:
  98 (p[0])          mov     addr[0] = ret0
  99 (p[0])          ld8     value[0] = [ret0], 8
 100 (p[MEMLAT])     xor     aux[0] = value[MEMLAT], chrx8
 101 (p[MEMLAT+1])   czx1.r  poschr[0] = aux[1]
 102 (p[MEMLAT+2])   cmp.ne  p7, p0 = 8, poschr[1]
 103 (p7)            br.cond.dpnt .foundit
 104                 br.ctop.dptk .l2
 105 .srchfew:
 106         adds    loopcnt = -1, len
 107         cmp.eq  p6, p0 = len, r0
 108 (p6)    br.cond.spnt .notfound ;;
 109         mov     ar.lc = loopcnt
 110 .l3:
 111         ld1     val = [ret0], 1
 112         ;;
 113         cmp.eq  p6, p0 = val, chr
 114 (p6)    br.cond.dpnt    .foundit
 115         br.cloop.sptk   .l3 ;;
 116 .notfound:
 117         cmp.ne  p6, p0 = r0, r0 // clear p6 (p7 was already 0 when we got here)
 118         mov     ret0 = r0 ;;    // return NULL
 119 .foundit:
 120         .pred.rel "mutex" p6, p7
 121 (p6)    adds    ret0 = -1, ret0                    // if we got here from l1 or l3
 122 (p7)    add     ret0 = addr[MEMLAT+2], poschr[1]   // if we got here from l2
 123         mov     pr = saved_pr, -1
 124         mov     ar.lc = saved_lc
 125         br.ret.sptk.many b0
 126
 127 END(__memchr)
 128
 129 weak_alias (__memchr, memchr)
 130 #if !__BOUNDED_POINTERS__
 131 weak_alias (__memchr, __ubp_memchr)
 132 #endif
 133 libc_hidden_builtin_def (memchr)