configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 AC_ARG_ENABLE(static, dnl
  74 [  --enable-static         build static library [default=yes]],
  75               static=$enableval, static=yes)
  76 AC_ARG_ENABLE(shared, dnl
  77 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  78               shared=$enableval, shared=default)
  79 AC_ARG_ENABLE(profile, dnl
  80 [  --enable-profile        build profiled library [default=yes]],
  81               profile=$enableval, profile=yes)
  82 AC_ARG_ENABLE(omitfp, dnl
  83 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  84               omitfp=$enableval, omitfp=no)
  85 AC_ARG_ENABLE(bounded, dnl
  86 [  --enable-bounded        build with runtime bounds checking [default=no]],
  87               bounded=$enableval, bounded=no)
  88 AC_ARG_ENABLE(versioning, dnl
  89 [  --disable-versioning    do not include versioning information in the
  90                           library objects [default=yes if supported]],
  91              enable_versioning=$enableval, enable_versioning=yes)
  92
  93 dnl Generic infrastructure for drop-in additions to libc.
  94 AC_ARG_ENABLE(add-ons, dnl
  95 [  --enable-add-ons[=DIR1,DIR2]...
  96                           configure and build add-ons in DIR1,DIR2,...
  97                           search for add-ons if no parameter given],
  98   [case "$enableval" in
  99     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 100          test "$add_ons" = "*" && add_ons= ;;
 101     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 102    esac],
 103   [add_ons=])
 104
 105 AC_CONFIG_SUBDIRS($add_ons)
 106 add_ons_pfx=
 107 if test x"$add_ons" != x; then
 108   for f in $add_ons; do
 109     # Test whether such a subdir really exists.
 110     if test -d $srcdir/$f; then
 111       add_ons_pfx="$add_ons_pfx $f/"
 112     else
 113       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 114     fi
 115   done
 116 fi
 117
 118 dnl On some platforms we cannot use dynamic loading.  We must provide
 119 dnl static NSS modules.
 120 AC_ARG_ENABLE(static-nss, dnl
 121 [  --enable-static-nss     build static NSS modules [default=no]],
 122               static_nss=$enableval, static_nss=no)
 123 if test x"$static_nss" = xyes; then
 124   AC_DEFINE(DO_STATIC_NSS)
 125 fi
 126
 127 AC_ARG_ENABLE(force-install,
 128 [  --disable-force-install don't force installation of files from this package,
 129                           even if they are older than the installed files],
 130               force_install=$enableval, force_install=yes)
 131 AC_SUBST(force_install)
 132
 133 AC_CANONICAL_HOST
 134
 135 # The way shlib-versions is used to generate soversions.mk uses a
 136 # fairly simplistic model for name recognition that can't distinguish
 137 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 138 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 139 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 140 case "$host_os" in
 141 linux*)
 142   ;;
 143 gnu*)
 144   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 145   ;;
 146 esac
 147
 148 # We keep the original values in `$config_*' and never modify them, so we
 149 # can write them unchanged into config.make.  Everything else uses
 150 # $machine, $vendor, and $os, and changes them whenever convenient.
 151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 152
 153 # Some configurations imply other options.
 154 case "$host_os" in
 155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 156   # These systems always use GNU tools.
 157   gnu_ld=yes gnu_as=yes ;;
 158 esac
 159 case "$host_os" in
 160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 162   ;;
 163 gnu* | linux* | sysv4* | solaris2* | irix6*)
 164   # These systems (almost) always use the ELF format.
 165   elf=yes
 166   ;;
 167 esac
 168
 169 machine=$config_machine
 170 vendor=$config_vendor
 171 os=$config_os
 172
 173 ###
 174 ### I put this here to prevent those annoying emails from people who cannot
 175 ### read and try to compile glibc on unsupported platforms.  --drepper
 176 ###
 177 ### By using the undocumented --enable-hacker-mode option for configure
 178 ### one can skip this test to make the configuration not fail for unsupported
 179 ### platforms.
 180 ###
 181 if test -z "$enable_hacker_mode"; then
 182   case "$machine-$host_os" in
 183   *-linux* | *-gnu* | arm*-none*)
 184     ;;
 185   *)
 186     echo "*** The GNU C library is currently not available for this platform."
 187     echo "*** So far nobody cared to port it and if there is no volunteer it"
 188     echo "*** might never happen.  So, if you have interest to see glibc on"
 189     echo "*** this platform visit"
 190     echo "***   http://www.gnu.org/software/libc/porting.html"
 191     echo "*** and join the group of porters"
 192     exit 1
 193     ;;
 194   esac
 195 fi
 196
 197 dnl We need to use [ and ] for other purposes for a while now.
 198 changequote(,)dnl
 199 # Expand the configuration machine name into a subdirectory by architecture
 200 # type and particular chip.
 201 case "$machine" in
 202 a29k | am29000) base_machine=a29k machine=a29k ;;
 203 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 204 arm*)           base_machine=arm machine=arm/$machine ;;
 205 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 206 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 207 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 208 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 209 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 210 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 211 m88???)         base_machine=m88k machine=m88k/$machine ;;
 212 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 213 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 214 mips*)          base_machine=mips
 215                 case "`uname -m`" in
 216                 IP22) machine=mips/mips3 ;;
 217                 *)    machine=mips/$machine ,,
 218                 esac ;;
 219 sparc | sparcv[67])
 220                 base_machine=sparc machine=sparc/sparc32 ;;
 221 sparcv8 | supersparc | hypersparc)
 222                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 223 sparc64 | ultrasparc)
 224                 base_machine=sparc machine=sparc/sparc64 ;;
 225 esac
 226 changequote([,])dnl
 227 AC_SUBST(base_machine)
 228
 229 if test "$base_machine" = "i386"; then
 230   AC_DEFINE(USE_REGPARMS)
 231 fi
 232
 233 # Compute the list of sysdep directories for this configuration.
 234 # This can take a while to compute.
 235 sysdep_dir=$srcdir/sysdeps
 236 AC_MSG_CHECKING(sysdep dirs)
 237 dnl We need to use [ and ] for other purposes for a while now.
 238 changequote(,)dnl
 239 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 240 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 241
 242 case "$os" in
 243 gnu*)
 244   base_os=mach/hurd ;;
 245 netbsd* | 386bsd* | freebsd* | bsdi*)
 246   base_os=unix/bsd/bsd4.4 ;;
 247 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 248   base_os=unix/bsd ;;
 249 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 250   base_os=unix/sysv ;;
 251 irix6*)
 252   base_os=unix/sysv/irix6/$os ;;
 253 solaris[2-9]*)
 254   base_os=unix/sysv/sysv4 ;;
 255 none)
 256   base_os=standalone ;;
 257 *)
 258   base_os='' ;;
 259 esac
 260
 261 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 262 tail=$os
 263 ostry=$os
 264 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 265   ostry="$ostry /$o"
 266   tail=$o
 267 done
 268 o=`echo $tail | sed 's/[0-9]*$//'`
 269 if test $o != $tail; then
 270   ostry="$ostry /$o"
 271 fi
 272 # For linux-gnu, try linux-gnu, then linux.
 273 o=`echo $tail | sed 's/-.*$//'`
 274 if test $o != $tail; then
 275   ostry="$ostry /$o"
 276 fi
 277
 278 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 279 base=
 280 tail=$base_os
 281 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 282   set $b
 283   base="$base /$1"
 284   tail="$2"
 285 done
 286
 287 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 288 mach=
 289 tail=$machine
 290 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 291   set $m
 292   # Prepend the machine's FPU directory unless --without-fp.
 293   if test "$with_fp" = yes; then
 294     mach="$mach /$1/fpu"
 295   fi
 296   mach="$mach /$1"
 297   tail="$2"
 298 done
 299
 300 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 301 changequote([,])dnl
 302
 303 # Find what sysdep directories exist.
 304 sysnames=
 305 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 306 for d in $add_ons_pfx ''; do
 307   for b in $base ''; do
 308     for m0 in $mach ''; do
 309       for v in /$vendor ''; do
 310         test "$v" = / && continue
 311         for o in /$ostry ''; do
 312           test "$o" = / && continue
 313           for m in $mach ''; do
 314             if test "$m0$b$v$o$m"; then
 315               try="${d}sysdeps$m0$b$v$o$m"
 316               test -n "$enable_debug_configure" &&
 317               echo "$0 [DEBUG]: try $try" >&2
 318               if test -d $srcdir/$try; then
 319                 sysnames="$sysnames $try"
 320                 { test -n "$o" || test -n "$b"; } && os_used=t
 321                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 322               fi
 323             fi
 324           done
 325         done
 326       done
 327     done
 328   done
 329 done
 330 IFS="$ac_save_ifs"
 331
 332 if test -z "$os_used" && test "$os" != none; then
 333   AC_MSG_ERROR(Operating system $os is not supported.)
 334 fi
 335 if test -z "$machine_used" && test "$machine" != none; then
 336   AC_MSG_ERROR(The $machine is not supported.)
 337 fi
 338
 339 # We have now validated the configuration.
 340
 341
 342 # If using ELF, look for an `elf' subdirectory of each machine directory.
 343 # We prepend these rather than inserting them whereever the machine appears
 344 # because things specified by the machine's ELF ABI should override
 345 # OS-specific things, and should always be the same for any OS on the
 346 # machine (otherwise what's the point of an ABI?).
 347 if test "$elf" = yes; then
 348   elf_dirs=
 349   for d in $add_ons_pfx ''; do
 350     for m in $mach; do
 351       if test -d $srcdir/${d}sysdeps$m/elf; then
 352         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 353       fi
 354     done
 355   done
 356   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 357 fi
 358
 359
 360 # Expand the list of system names into a full list of directories
 361 # from each element's parent name and Implies file (if present).
 362 set $sysnames
 363 names=
 364 while test $# -gt 0; do
 365   name=$1
 366   shift
 367
 368   case " $names " in *" $name "*)
 369     # Already in the list.
 370     continue
 371   esac
 372
 373   # Report each name as we discover it, so there is no long pause in output.
 374   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 375
 376   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 377
 378   case $name in
 379     /*) xsrcdir= ;;
 380     *)  xsrcdir=$srcdir/ ;;
 381   esac
 382   test -n "$enable_debug_configure" &&
 383   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 384
 385   if test -f $xsrcdir$name/Implies; then
 386     # Collect more names from the `Implies' file (removing comments).
 387     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 388     implied=
 389     for x in $implied_candidate; do
 390       if test -d $xsrcdir$name_base/$x; then
 391         implied="$implied $name_base/$x";
 392       else
 393         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 394       fi
 395     done
 396   else
 397     implied=
 398   fi
 399
 400   # Add NAME to the list of names.
 401   names="$names $name"
 402
 403   # Find the parent of NAME, using the empty string if it has none.
 404 changequote(,)dnl
 405   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 406 changequote([,])dnl
 407
 408   # Add the names implied by NAME, and NAME's parent (if it has one), to
 409   # the list of names to be processed (the argument list).  We prepend the
 410   # implied names to the list and append the parent.  We want implied
 411   # directories to come before further directories inferred from the
 412   # configuration components; this ensures that for sysv4, unix/common
 413   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 414   # after sysv4).
 415   sysnames="`echo $implied $* $parent`"
 416   test -n "$sysnames" && set $sysnames
 417 done
 418
 419 # Add the default directories.
 420 default_sysnames=sysdeps/generic
 421 if test "$elf" = yes; then
 422   default_sysnames="sysdeps/generic/elf $default_sysnames"
 423 fi
 424 sysnames="$names $default_sysnames"
 425 AC_SUBST(sysnames)
 426 # The other names were emitted during the scan.
 427 AC_MSG_RESULT($default_sysnames)
 428
 429
 430 ### Locate tools.
 431
 432 AC_PROG_INSTALL
 433 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 434   # The makefiles need to use a different form to find it in $srcdir.
 435   INSTALL='\$(..)./install-sh -c'
 436 fi
 437 AC_PROG_LN_S
 438
 439 # These programs are version sensitive.
 440 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 441 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 442   [version \([egcygnustp-]*[0-9.]*\)],
 443   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|cygnus-2.9[1-9].*],
 444   critic_missing=t)
 445 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 446   [version \([0-9][0-9.]*\), by],
 447   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 448
 449 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 450   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 451   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 452 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 453   [GNU texinfo \([0-9][0-9.]*\)],
 454   [3.1[1-9] | 3.[2-9][0-9]], MAKEINFO=: aux_missing=t)
 455
 456 if test -n "$critic_missing"; then
 457 AC_MSG_ERROR([
 458 *** Some critical program is missing or too old.
 459 *** Check the INSTALL file for required versions.])
 460 fi
 461
 462 test -n "$aux_missing" && AC_MSG_WARN([
 463 *** An auxiliary program is missing or too old;
 464 *** some features will be disabled.
 465 *** Check the INSTALL file for required versions.])
 466
 467 AC_PROG_CC_LOCAL
 468 AC_CANONICAL_BUILD
 469 if test $host != $build; then
 470   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 471 fi
 472 AC_SUBST(cross_compiling)
 473 AC_PROG_CPP
 474 LIBC_PROG_BINUTILS
 475 AC_CHECK_TOOL(AR, ar)
 476 AC_CHECK_TOOL(RANLIB, ranlib, :)
 477 AC_CHECK_TOOL(MIG, mig)
 478
 479 # if using special system headers, find out the compiler's sekrit
 480 # header directory and add that to the list.  NOTE: Only does the right
 481 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 482 if test -n "$sysheaders"; then
 483   ccheaders=`$CC -print-file-name=include`
 484   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 485 fi
 486 AC_SUBST(SYSINCLUDES)
 487
 488 # check if ranlib is necessary
 489 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 490 cat > conftest.c <<EOF
 491 int a;
 492 char b;
 493 void c(void) {}
 494 EOF
 495 $CC $CFLAGS -c conftest.c
 496 $AR cr conftest.a conftest.c
 497 cp conftest.a conftest2.a
 498 $RANLIB conftest.a
 499 if cmp -s conftest.a conftest2.a; then
 500   libc_cv_ranlib_necessary=no
 501 else
 502   libc_cv_ranlib_necessary=yes
 503 fi
 504 rm -rf conftest*])
 505 if test "$libc_cv_ranlib_necessary" = no; then
 506  RANLIB=:
 507 fi
 508
 509 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 510 # since this would lead to problems installing/building glibc.
 511 # LD_LIBRARY_PATH contains the current directory if one of the following
 512 # is true:
 513 # - one of the terminals (":" and ";") is the first or last sign
 514 # - two terminals occur directly after each other
 515 # - the path contains an element with a dot in it
 516 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 517 changequote(,)dnl
 518 case ${LD_LIBRARY_PATH} in
 519   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 520     ld_library_path_setting="contains current directory"
 521     ;;
 522   *)
 523     ld_library_path_setting="ok"
 524     ;;
 525 esac
 526 changequote([,])dnl
 527 AC_MSG_RESULT($ld_library_path_setting)
 528 if test "$ld_library_path_setting" != "ok"; then
 529 AC_MSG_ERROR([
 530 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 531 *** building glibc. Please change the environment variable
 532 *** and run configure again.])
 533 fi
 534
 535 AC_PATH_PROG(BASH, bash, no)
 536 if test "$BASH" != no &&
 537    $BASH -c 'test "$BASH_VERSINFO" \
 538              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 539   libc_cv_have_bash2=yes
 540 else
 541   libc_cv_have_bash2=no
 542 fi
 543 AC_SUBST(libc_cv_have_bash2)
 544
 545 dnl We need a ksh compatible shell for tzselect.
 546 if test "$BASH" = no; then
 547   AC_PATH_PROG(KSH, ksh, no)
 548   if test "$KSH" = no; then
 549     libc_cv_have_ksh=no
 550   else
 551     libc_cv_have_ksh=yes
 552   fi
 553 else
 554   KSH="$BASH"
 555   AC_SUBST(KSH)
 556   libc_cv_have_ksh=yes
 557 fi
 558 AC_SUBST(libc_cv_have_ksh)
 559
 560 AC_PROG_AWK
 561 AC_PATH_PROG(PERL, perl, no)
 562 AC_SUBST(PERL)
 563 AC_PATH_PROG(INSTALL_INFO, install-info, no, dnl
 564 /usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 565 AC_SUBST(INSTALL_INFO)
 566 if test "$INSTALL_INFO" != "no"; then
 567 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 568  [mkdir conftest.d
 569   # There is a hard ^_ on the next line.  I am open to better ideas.
 570   (echo '\x1f'
 571   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 572   echo '* Menu:') >conftest.d/dir
 573   (echo 'INFO-DIR-SECTION i-d-s works'
 574   echo 'START-INFO-DIR-ENTRY'
 575   echo '* Prog: (prog).   Program.'
 576   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 577   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 578   then
 579     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 580     then libc_cv_old_debian_install_info=no
 581     else libc_cv_old_debian_install_info=yes
 582     fi
 583   else libc_cv_old_debian_install_info=no testfailed=t
 584   fi
 585   rm -fr conftest.d])
 586 if test -n "$testfailed"
 587 then AC_MSG_WARN([install-info errored out, check config.log])
 588 fi
 589 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 590 fi
 591 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 592
 593 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 594 echo '#include <stddef.h>
 595 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 596 if eval "$ac_cpp conftest.c 2>/dev/null" \
 597 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 598   libc_cv_signed_size_t=no
 599 else
 600   libc_cv_signed_size_t=yes
 601 fi
 602 rm -f conftest*])
 603 if test $libc_cv_signed_size_t = yes; then
 604   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 605   cat >> confdefs.h <<\EOF
 606 #undef __SIZE_TYPE__
 607 #define __SIZE_TYPE__ unsigned
 608 EOF
 609 fi
 610
 611 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 612 AC_TRY_COMPILE(dnl
 613 [#define __need_size_t
 614 #define __need_wchar_t
 615 #include <stddef.h>
 616 #define __need_NULL
 617 #include <stddef.h>], [size_t size; wchar_t wchar;
 618 #ifdef offsetof
 619 #error stddef.h ignored __need_*
 620 #endif
 621 if (&size == NULL || &wchar == NULL) abort ();],
 622                libc_cv_friendly_stddef=yes,
 623                libc_cv_friendly_stddef=no)])
 624 if test $libc_cv_friendly_stddef = yes; then
 625   config_vars="$config_vars
 626 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 627 fi
 628
 629 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 630                libc_cv_need_minus_P, [dnl
 631 cat > conftest.S <<EOF
 632 #include "confdefs.h"
 633 /* Nothing whatsoever.  */
 634 EOF
 635 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 636   libc_cv_need_minus_P=no
 637 else
 638   libc_cv_need_minus_P=yes
 639 fi
 640 rm -f conftest*])
 641 if test $libc_cv_need_minus_P = yes; then
 642   config_vars="$config_vars
 643 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 644 fi
 645
 646 AC_CACHE_CHECK(for assembler global-symbol directive,
 647                libc_cv_asm_global_directive, [dnl
 648 libc_cv_asm_global_directive=UNKNOWN
 649 for ac_globl in .globl .global; do
 650   cat > conftest.s <<EOF
 651 .text
 652 ${ac_globl} foo
 653 foo:
 654 EOF
 655   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 656     libc_cv_asm_global_directive=${ac_globl}
 657   fi
 658   rm -f conftest*
 659   test $libc_cv_asm_global_directive != UNKNOWN && break
 660 done])
 661 if test $libc_cv_asm_global_directive = UNKNOWN; then
 662   AC_MSG_ERROR(cannot determine asm global directive)
 663 else
 664   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 665 fi
 666
 667 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 668 cat > conftest.s <<EOF
 669 .text
 670 foo:
 671 .set glibc_conftest_frobozz,foo
 672 $libc_cv_asm_global_directive glibc_conftest_frobozz
 673 EOF
 674 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 675 # (but it doesn't work), so we must do a linking check to be sure.
 676 cat > conftest1.c <<\EOF
 677 extern int glibc_conftest_frobozz;
 678 main () { printf ("%d\n", glibc_conftest_frobozz); }
 679 EOF
 680 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 681             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 682   libc_cv_asm_set_directive=yes
 683 else
 684   libc_cv_asm_set_directive=no
 685 fi
 686 rm -f conftest*])
 687 if test $libc_cv_asm_set_directive = yes; then
 688   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 689 fi
 690
 691 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 692 [cat > conftest.s <<EOF
 693 .text
 694 _sym:
 695 .symver _sym,sym@VERS
 696 EOF
 697 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 698   libc_cv_asm_symver_directive=yes
 699 else
 700   libc_cv_asm_symver_directive=no
 701 fi
 702 rm -f conftest*])
 703 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 704 if test $libc_cv_asm_symver_directive = yes; then
 705   cat > conftest.s <<EOF
 706 .text
 707 _sym:
 708 .symver _sym,sym@VERS
 709 EOF
 710   cat > conftest.map <<EOF
 711 VERS_1 {
 712         global: sym;
 713 };
 714
 715 VERS_2 {
 716         global: sym;
 717 } VERS_1;
 718 EOF
 719   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 720     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 721                                         -nostartfiles -nostdlib
 722                                         -Wl,--version-script,conftest.map
 723                        1>&AC_FD_CC]);
 724     then
 725       libc_cv_ld_version_script_option=yes
 726     else
 727       libc_cv_ld_version_script_option=no
 728     fi
 729   else
 730     libc_cv_ld_version_script_option=no
 731   fi
 732 else
 733   libc_cv_ld_version_script_option=no
 734 fi
 735 rm -f conftest*])
 736 if test $libc_cv_asm_symver_directive = yes &&
 737    test $libc_cv_ld_version_script_option = yes &&
 738    test $enable_versioning = yes; then
 739   VERSIONING=yes
 740   AC_DEFINE(DO_VERSIONING)
 741 else
 742   VERSIONING=no
 743 fi
 744 AC_SUBST(VERSIONING)
 745
 746 if test $VERSIONING = no; then
 747   echo "\
 748 *** WARNING: You should not compile GNU libc without versioning. Not using
 749 *** versioning will introduce incompatibilities so that old binaries
 750 *** will not run anymore.
 751 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 752 fi
 753 if test $elf = yes; then
 754   AC_CACHE_CHECK(for .previous assembler directive,
 755                  libc_cv_asm_previous_directive, [dnl
 756   cat > conftest.s <<EOF
 757 .section foo_section
 758 .previous
 759 EOF
 760   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 761     libc_cv_asm_previous_directive=yes
 762   else
 763     libc_cv_asm_previous_directive=no
 764   fi
 765   rm -f conftest*])
 766   if test $libc_cv_asm_previous_directive = yes; then
 767     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 768   else
 769     AC_CACHE_CHECK(for .popsection assembler directive,
 770                    libc_cv_asm_popsection_directive, [dnl
 771     cat > conftest.s <<EOF
 772 .pushsection foo_section
 773 .popsection
 774 EOF
 775     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 776       libc_cv_asm_popsection_directive=yes
 777     else
 778       libc_cv_asm_popsection_directive=no
 779     fi
 780     rm -f conftest*])
 781     if test $libc_cv_asm_popsection_directive = yes; then
 782       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 783     fi
 784   fi
 785 fi
 786
 787 if test $elf != yes; then
 788   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 789                  [AC_TRY_COMPILE(, [asm (".section .init");
 790                                     asm (".section .fini");
 791                                     asm (".text");],
 792                                  libc_cv_have_initfini=yes,
 793                                  libc_cv_have_initfini=no)])
 794   AC_SUBST(libc_cv_have_initfini)dnl
 795   if test $libc_cv_have_initfini = yes; then
 796     AC_DEFINE(HAVE_INITFINI)
 797   fi
 798 fi
 799
 800 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 801 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 802 [cat > conftest.$ac_ext <<EOF
 803 dnl This sometimes fails to find confdefs.h, for some reason.
 804 dnl [#]line __oline__ "[$]0"
 805 [#]line __oline__ "configure"
 806 #include "confdefs.h"
 807 void underscore_test(void) {
 808 return; }
 809 EOF
 810 if AC_TRY_EVAL(ac_compile); then
 811   if grep _underscore_test conftest* >/dev/null; then
 812     ifelse([$1], , :, [rm -f conftest*
 813     $1])
 814   else
 815     ifelse([$2], , , [rm -f conftest*
 816     $2])
 817   fi
 818 else
 819   echo "configure: failed program was:" >&AC_FD_CC
 820   cat conftest.$ac_ext >&AC_FD_CC
 821   ifelse([$2], , , [rm -f conftest*
 822   $2])
 823 fi
 824 rm -f conftest*])
 825
 826 if test $elf = yes; then
 827   libc_cv_asm_underscores=no
 828 else
 829   if test $ac_cv_prog_cc_works = yes; then
 830     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 831                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 832                                 libc_cv_asm_underscores=yes,
 833                                 libc_cv_asm_underscores=no)])
 834   else
 835     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 836                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 837                                             libc_cv_asm_underscores=no)])
 838   fi
 839 fi
 840 if test $libc_cv_asm_underscores = no; then
 841   AC_DEFINE(NO_UNDERSCORES)
 842 fi
 843
 844 if test $elf = yes; then
 845   libc_cv_weak_symbols=yes
 846 fi
 847
 848 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 849                  [dnl
 850 cat > conftest.s <<EOF
 851 .text
 852 ${libc_cv_asm_global_directive} foo
 853 foo:
 854 .weak foo
 855 .weak bar; bar = foo
 856 EOF
 857 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 858   libc_cv_asm_weak_directive=yes
 859 else
 860   libc_cv_asm_weak_directive=no
 861 fi
 862 rm -f conftest*])
 863
 864 if test $libc_cv_asm_weak_directive = no; then
 865   AC_CACHE_CHECK(for assembler .weakext directive,
 866                  libc_cv_asm_weakext_directive,
 867                  [dnl
 868 cat > conftest.s <<EOF
 869 .text
 870 ${libc_cv_asm_global_directive} foo
 871 foo:
 872 .weakext bar foo
 873 .weakext baz
 874 ${libc_cv_asm_global_directive} baz
 875 baz:
 876 EOF
 877   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 878     libc_cv_asm_weakext_directive=yes
 879   else
 880     libc_cv_asm_weakext_directive=no
 881   fi
 882   rm -f conftest*])
 883
 884 fi # no .weak
 885
 886 if test $libc_cv_asm_weak_directive = yes; then
 887   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 888 elif test $libc_cv_asm_weakext_directive = yes; then
 889   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 890 fi
 891
 892 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 893 cat > conftest.c <<\EOF
 894 _start () {}
 895 int __eh_pc;
 896 __throw () {}
 897 EOF
 898 dnl No \ in command here because it ends up inside ''.
 899 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 900                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 901                             -o conftest conftest.c 1>&AC_FD_CC]); then
 902   libc_cv_ld_no_whole_archive=yes
 903 else
 904   libc_cv_ld_no_whole_archive=no
 905 fi
 906 rm -f conftest*])
 907 if test $libc_cv_ld_no_whole_archive = yes; then
 908   no_whole_archive=-Wl,--no-whole-archive
 909 fi
 910 AC_SUBST(no_whole_archive)dnl
 911
 912 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 913 cat > conftest.c <<\EOF
 914 _start () {}
 915 int __eh_pc;
 916 __throw () {}
 917 EOF
 918 dnl No \ in command here because it ends up inside ''.
 919 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 920                             -nostdlib -nostartfiles -fexceptions
 921                             -o conftest conftest.c 1>&AC_FD_CC]); then
 922   libc_cv_gcc_exceptions=yes
 923 else
 924   libc_cv_gcc_exceptions=no
 925 fi
 926 rm -f conftest*])
 927 if test $libc_cv_gcc_exceptions = yes; then
 928   exceptions=-fexceptions
 929 fi
 930 AC_SUBST(exceptions)dnl
 931
 932 if test "$base_machine" = alpha ; then
 933 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 934 cat > conftest.c <<\EOF
 935 foo () { }
 936 EOF
 937 dnl
 938 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 939 then
 940   libc_cv_gcc_alpha_ng_prefix=yes
 941 else
 942   libc_cv_gcc_alpha_ng_prefix=no
 943 fi
 944 rm -f conftest* ])
 945 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 946   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 947 else
 948   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 949 fi
 950 fi
 951
 952 if test "$host_cpu" = powerpc ; then
 953 # Check for a bug present in at least versions 2.8.x of GCC
 954 # and versions 1.0.x of EGCS.
 955 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 956 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 957                libc_cv_c_asmcr0_bug='no',
 958                libc_cv_c_asmcr0_bug='yes')])
 959 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 960   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 961 fi
 962 fi
 963
 964 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 965 [cat > conftest.c <<EOF
 966 #line __oline__ "configure"
 967 static char __EH_FRAME_BEGIN__[];
 968 _start ()
 969 {
 970 #ifdef CHECK__register_frame
 971   __register_frame (__EH_FRAME_BEGIN__);
 972   __deregister_frame (__EH_FRAME_BEGIN__);
 973 #endif
 974 #ifdef CHECK__register_frame_info
 975   __register_frame_info (__EH_FRAME_BEGIN__);
 976   __deregister_frame_info (__EH_FRAME_BEGIN__);
 977 #endif
 978 }
 979 int __eh_pc;
 980 __throw () {}
 981 /* FIXME: this is fragile.  */
 982 malloc () {}
 983 strcmp () {}
 984 strlen () {}
 985 memcpy () {}
 986 memset () {}
 987 free () {}
 988 abort () {}
 989 __bzero () {}
 990 EOF
 991 dnl No \ in command here because it ends up inside ''.
 992 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 993                             -nostdlib -nostartfiles
 994                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 995   libc_cv_gcc_dwarf2_unwind_info=static
 996 else
 997   libc_cv_gcc_dwarf2_unwind_info=no
 998 fi
 999 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1000   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1001                               -nostdlib -nostartfiles
1002                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1003     libc_cv_gcc_dwarf2_unwind_info=yes
1004   else
1005     libc_cv_gcc_dwarf2_unwind_info=no
1006   fi
1007 fi
1008 rm -f conftest*])
1009 case $libc_cv_gcc_dwarf2_unwind_info in
1010 yes)
1011   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1012   ;;
1013 static)
1014   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1015   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1016   ;;
1017 esac
1018
1019 dnl Check whether compiler understands __builtin_expect.
1020 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1021 [cat > conftest.c <<EOF
1022 #line __oline__ "configure"
1023 int foo (int a)
1024 {
1025   a = __builtin_expect (a, 10);
1026   return a == 10 ? 0 : 1;
1027 }
1028 EOF
1029 dnl No \ in command here because it ends up inside ''.
1030 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1031                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1032   libc_cv_gcc_builtin_expect=yes
1033 else
1034   libc_cv_gcc_builtin_expect=no
1035 fi
1036 rm -f conftest*])
1037 if test "$libc_cv_gcc_builtin_expect" = yes; then
1038   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1039 fi
1040
1041 ### End of automated tests.
1042 ### Now run sysdeps configure fragments.
1043
1044 # sysdeps configure fragments may set these with files to be linked below.
1045 libc_link_dests=
1046 libc_link_sources=
1047
1048 # They also can set these variables.
1049 ldd_rewrite_script=no
1050
1051 # Iterate over all the sysdep directories we will use, running their
1052 # configure fragments, and looking for a uname implementation.
1053 uname=
1054 for dir in $sysnames; do
1055   case $dir in
1056     /*) dest=$dir ;;
1057     *)  dest=$srcdir/$dir ;;
1058   esac
1059   if test -r $dest/configure; then
1060     AC_MSG_RESULT(running configure fragment for $dest)
1061     . $dest/configure
1062   fi
1063 [
1064   if test -z "$uname"; then
1065     if test -r $dest/uname.c ||
1066        test -r $dest/uname.S ||
1067        { test -r $dest/syscalls.list &&
1068          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1069       uname=$dir
1070     fi
1071   fi
1072 ]dnl
1073 done
1074
1075 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1076
1077 # If we will use the generic uname implementation, we must figure out what
1078 # it will say by examining the system, and write the results in config-name.h.
1079 if test "$uname" = "sysdeps/generic"; then
1080
1081 changequote(,)dnl
1082   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1083 changequote([,])dnl
1084   if test $uname_sysname != $config_os; then
1085     config_release=`echo $config_os | sed s/$uname_sysname//`
1086   fi
1087 dnl
1088 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1089     if test -r /vmunix; then
1090       kernel_id=`strings /vmunix | grep UNIX`
1091     elif test -r /dynix; then
1092       kernel_id=`strings /dynix | grep DYNIX`
1093     else
1094       kernel_id=
1095     fi
1096 ])dnl
1097
1098   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1099 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1100 changequote(,)dnl
1101   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1102 changequote([,])dnl
1103   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1104          != x$config_release; then
1105     # The configuration release is a substring of the kernel release.
1106     libc_cv_uname_release=$kernel_release
1107   elif test x$config_release != x; then
1108     libc_cv_uname_release=$config_release
1109   elif test x$kernel_release != x; then
1110     libc_cv_uname_release=$kernel_release
1111   else
1112     libc_cv_uname_release=unknown
1113   fi])
1114   uname_release="$libc_cv_uname_release"
1115
1116   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1117 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1118 changequote(,)dnl
1119   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1120 changequote([,])dnl
1121   if test -n "$kernel_version"; then
1122     libc_cv_uname_version="$kernel_version"
1123   else
1124     libc_cv_uname_version=unknown
1125   fi])
1126   uname_version="$libc_cv_uname_version"
1127
1128 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1129   config_uname=config-name.h:config-name.in
1130 else
1131   # For non-generic uname, we don't need to create config-name.h at all.
1132   config_uname=
1133 fi
1134
1135 AC_MSG_CHECKING(stdio selection)
1136 AC_SUBST(stdio)
1137 case $stdio in
1138 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1139 default) stdio=stdio ;;
1140 esac
1141 AC_MSG_RESULT($stdio)
1142
1143 # Test for old glibc 2.0.x headers so that they can be removed properly
1144 # Search only in includedir.
1145 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1146 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1147 then
1148   old_glibc_headers=yes
1149 else
1150   old_glibc_headers=no
1151 fi
1152 AC_MSG_RESULT($old_glibc_headers)
1153 if test ${old_glibc_headers} = yes; then
1154   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1155   AC_MSG_WARN(*** be removed.)
1156 fi
1157 AC_SUBST(old_glibc_headers)
1158
1159 AC_SUBST(libc_cv_slibdir)
1160 AC_SUBST(libc_cv_sysconfdir)
1161 AC_SUBST(libc_cv_rootsbindir)
1162
1163 AC_SUBST(has_ldconfig)
1164 AC_SUBST(ldd_rewrite_script)
1165
1166 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1167 if test $gnu_ld = yes; then
1168   AC_DEFINE(HAVE_GNU_LD)
1169 fi
1170 if test $gnu_as = yes; then
1171   AC_DEFINE(HAVE_GNU_AS)
1172 fi
1173 if test $elf = yes; then
1174   AC_DEFINE(HAVE_ELF)
1175 fi
1176
1177 AC_SUBST(static)
1178 AC_SUBST(shared)
1179 if test $shared = default; then
1180   if test $gnu_ld = yes; then
1181     shared=$elf
1182   else
1183     # For now we do not assume shared libs are available.  In future more
1184     # tests might become available.
1185     shared=no
1186   fi
1187 fi
1188
1189 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1190 [pic_default=yes
1191 cat > conftest.c <<EOF
1192 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1193 # error PIC is default.
1194 #endif
1195 EOF
1196 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1197   pic_default=no
1198 fi
1199 rm -f conftest.*])
1200 AC_SUBST(pic_default)
1201
1202 AC_SUBST(profile)
1203 AC_SUBST(omitfp)
1204 AC_SUBST(bounded)
1205 AC_SUBST(static_nss)
1206 AC_SUBST(nopic_initfini)
1207
1208 AC_SUBST(DEFINES)
1209
1210 case "$add_ons" in
1211   *door*) linux_doors=yes ;;
1212   *) linux_doors=no ;;
1213 esac
1214 AC_SUBST(linux_doors)
1215
1216 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1217   config_makefile=
1218 else
1219   config_makefile=Makefile
1220 fi
1221
1222 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1223 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1224 AC_SUBST(VERSION)
1225 AC_SUBST(RELEASE)
1226
1227 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1228 case $CONFIG_FILES in *config.make*)
1229 echo "$config_vars" >> config.make;;
1230 esac
1231 test -d bits || mkdir bits], [config_vars='$config_vars'])