sysdeps/libm-i387/s_asinhl.S

   1 /* ix87 specific implementation of arcsinh.
   2    Copyright (C) 1996 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1996.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(huge,@object)
  31 huge:   .tfloat 1e+4930
  32         ASM_SIZE_DIRECTIVE(huge)
  33         .align ALIGNARG(4)
  34         /* Please note that we use double value for 1.0.  This number
  35            has an exact representation and so we don't get accuracy
  36            problems.  The advantage is that the code is simpler.  */
  37         ASM_TYPE_DIRECTIVE(one,@object)
  38 one:    .double 1.0
  39         ASM_SIZE_DIRECTIVE(one)
  40         /* It is not important that this constant is precise.  It is only
  41            a value which is known to be on the safe side for using the
  42            fyl2xp1 instruction.  */
  43         ASM_TYPE_DIRECTIVE(limit,@object)
  44 limit:  .double 0.29
  45         ASM_SIZE_DIRECTIVE(limit)
  46
  47 #ifdef PIC
  48 #define MO(op) op##@GOTOFF(%edx)
  49 #else
  50 #define MO(op) op
  51 #endif
  52
  53         .text
  54 ENTRY(__asinhl)
  55         movl    12(%esp), %ecx
  56         movl    $0x7fff, %eax
  57         andl    %ecx, %eax
  58         andl    $0x8000, %ecx
  59         xorl    %ecx, 12(%esp)
  60         fldt    4(%esp)                 // |x|
  61         cmpl    $0x3fde, %eax
  62         jb      2f                      // |x| < 2^-34
  63         fldln2                          // log(2) : |x|
  64         cmpl    $0x4020, %eax
  65         fxch                            // |x| : log(2)
  66         ja      3f                      // |x| > 2^34
  67 #ifdef  PIC
  68         call    1f
  69 1:      popl    %edx
  70         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
  71 #endif
  72         cmpl    $0x4000, %eax
  73         ja      5f                      // |x| > 2
  74
  75         // 2^-34 <= |x| <= 2 => y = sign(x)*log1p(|x|+|x|^2/(1+sqrt(1+|x|^2)))
  76         fld     %st                     // |x| : |x| : log(2)
  77         fmul    %st(1)                  // |x|^2 : |x| : log(2)
  78         fld     %st                     // |x|^2 : |x|^2 : |x| : log(2)
  79         faddl   MO(one)                 // 1+|x|^2 : |x|^2 : |x| : log(2)
  80         fsqrt                           // sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  81         faddl   MO(one)                 // 1+sqrt(1+|x|^2) : |x|^2 : |x| : log(2)
  82         fdivrp                          // |x|^2/(1+sqrt(1+|x|^2)) : |x| : log(2)
  83         faddp                           // |x|+|x|^2/(1+sqrt(1+|x|^2)) : log(2)
  84         fcoml   MO(limit)
  85         fnstsw
  86         sahf
  87         ja      6f
  88         fyl2xp1
  89         jecxz   4f
  90         fchs
  91 4:      ret
  92
  93 6:      faddl   MO(one)
  94         fyl2x
  95         jecxz   4f
  96         fchs
  97 4:      ret
  98
  99         // |x| < 2^-34 => y = x (inexact iff |x| != 0.0)
 100         .align ALIGNARG(4)
 101 2:
 102 #ifdef  PIC
 103         call    1f
 104 1:      popl    %edx
 105         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b], %edx
 106 #endif
 107         jecxz   4f
 108         fchs                            // x
 109 4:      fld     %st                     // x : x
 110         fldt    MO(huge)                // huge : x : x
 111         faddp                           // huge+x : x
 112         fstp    %st(0)                  // x
 113         ret
 114
 115         // |x| > 2^34 => y = sign(x) * (log(|x|) + log(2))
 116         .align ALIGNARG(4)
 117 3:      fyl2x                           // log(|x|)
 118         fldln2                          // log(2) : log(|x|)
 119         faddp                           // log(|x|)+log(2)
 120         jecxz   4f
 121         fchs
 122 4:      ret
 123
 124         // |x| > 2 => y = sign(x) * log(2*|x| + 1/(|x|+sqrt(x*x+1)))
 125         .align ALIGNARG(4)
 126 5:      fld     %st                     // |x| : |x| : log(2)
 127         fadd    %st, %st(1)             // |x| : 2*|x| : log(2)
 128         fld     %st                     // |x| : |x| : 2*|x| : log(2)
 129         fmul    %st(1)                  // |x|^2 : |x| : 2*|x| : log(2)
 130         faddl   MO(one)                 // 1+|x|^2 : |x| : 2*|x| : log(2)
 131         fsqrt                           // sqrt(1+|x|^2) : |x| : 2*|x| : log(2)
 132         faddp                           // |x|+sqrt(1+|x|^2) : 2*|x| : log(2)
 133         fdivrl  MO(one)                 // 1/(|x|+sqrt(1+|x|^2)) : 2*|x| : log(2)
 134         faddp                           // 2*|x|+1/(|x|+sqrt(1+|x|^2)) : log(2)
 135         fyl2x                           // log(2*|x|+1/(|x|+sqrt(1+|x|^2)))
 136         jecxz   4f
 137         fchs
 138 4:      ret
 139 END(__asinhl)
 140 weak_alias (__asinhl, asinhl)