sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <asm-syntax.h>
  22 #include "bp-sym.h"
  23 #include "bp-asm.h"
  24 #include <stap-probe.h>
  25
  26 #define PARMS   LINKAGE         /* no space for saved regs */
  27 #define JMPBUF  PARMS
  28 #define SIGMSK  JMPBUF+PTR_SIZE
  29
  30 ENTRY (BP_SYM (__sigsetjmp))
  31         ENTER
  32
  33         movl JMPBUF(%esp), %eax
  34         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
  35
  36         /* Save registers.  */
  37         movl %ebx, (JB_BX*4)(%eax)
  38         movl %esi, (JB_SI*4)(%eax)
  39         movl %edi, (JB_DI*4)(%eax)
  40         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  41 #ifdef PTR_MANGLE
  42         PTR_MANGLE (%ecx)
  43 #endif
  44         movl %ecx, (JB_SP*4)(%eax)
  45         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  46         LIBC_PROBE (setjmp, 3, 4@%eax, -4@SIGMSK(%esp), 4@%ecx)
  47 #ifdef PTR_MANGLE
  48         PTR_MANGLE (%ecx)
  49 #endif
  50         movl %ecx, (JB_PC*4)(%eax)
  51         LEAVE /* pop frame pointer to prepare for tail-call.  */
  52         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  53
  54 #if defined NOT_IN_libc && defined IS_IN_rtld
  55         /* In ld.so we never save the signal mask.  */
  56         xorl %eax, %eax
  57         ret
  58 #else
  59         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  60         jmp __sigjmp_save
  61 #endif
  62 END (BP_SYM (__sigsetjmp))