configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 239 dnl -fstack-protector-strong.
 240 AC_ARG_ENABLE([stack-protector],
 241               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 242                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 243               [enable_stack_protector=$enableval],
 244               [enable_stack_protector=no])
 245 case "$enable_stack_protector" in
 246 all|yes|no|strong) ;;
 247 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 248 esac
 249
 250 dnl On some platforms we cannot use dynamic loading.  We must provide
 251 dnl static NSS modules.
 252 AC_ARG_ENABLE([static-nss],
 253               AC_HELP_STRING([--enable-static-nss],
 254                              [build static NSS modules @<:@default=no@:>@]),
 255               [static_nss=$enableval],
 256               [static_nss=no])
 257 dnl Enable static NSS also if we build no shared objects.
 258 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 259   static_nss=yes
 260   AC_DEFINE(DO_STATIC_NSS)
 261 fi
 262
 263 AC_ARG_ENABLE([force-install],
 264               AC_HELP_STRING([--disable-force-install],
 265                              [don't force installation of files from this package, even if they are older than the installed files]),
 266               [force_install=$enableval],
 267               [force_install=yes])
 268 AC_SUBST(force_install)
 269
 270 AC_ARG_ENABLE([maintainer-mode],
 271               AC_HELP_STRING([--enable-maintainer-mode],
 272                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 273               [maintainer=$enableval],
 274               [maintainer=no])
 275
 276 dnl On some platforms we allow dropping compatibility with all kernel
 277 dnl versions.
 278 AC_ARG_ENABLE([kernel],
 279               AC_HELP_STRING([--enable-kernel=VERSION],
 280                              [compile for compatibility with kernel not older than VERSION]),
 281               [minimum_kernel=$enableval],
 282               [])
 283 dnl Prevent unreasonable values.
 284 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 285   # Better nothing than this.
 286   minimum_kernel=""
 287 else
 288   if test "$minimum_kernel" = current; then
 289     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 290   fi
 291 fi
 292
 293 dnl For the development we sometimes want gcc to issue even more warnings.
 294 dnl This is not the default since many of the extra warnings are not
 295 dnl appropriate.
 296 AC_ARG_ENABLE([all-warnings],
 297               AC_HELP_STRING([--enable-all-warnings],
 298                              [enable all useful warnings gcc can issue]),
 299               [all_warnings=$enableval],
 300               [])
 301 AC_SUBST(all_warnings)
 302
 303 AC_ARG_ENABLE([werror],
 304               AC_HELP_STRING([--disable-werror],
 305                              [do not build with -Werror]),
 306               [enable_werror=$enableval],
 307               [enable_werror=yes])
 308 AC_SUBST(enable_werror)
 309
 310 AC_ARG_ENABLE([multi-arch],
 311               AC_HELP_STRING([--enable-multi-arch],
 312                              [enable single DSO with optimizations for multiple architectures]),
 313               [multi_arch=$enableval],
 314               [multi_arch=default])
 315
 316 AC_ARG_ENABLE([nss-crypt],
 317               AC_HELP_STRING([--enable-nss-crypt],
 318                              [enable libcrypt to use nss]),
 319               [nss_crypt=$enableval],
 320               [nss_crypt=no])
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   old_CFLAGS="$CFLAGS"
 327   CFLAGS="$CFLAGS $nss_includes"
 328   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 329 #include <hasht.h>
 330 #include <nsslowhash.h>
 331 void f (void) { NSSLOW_Init (); }])],
 332              libc_cv_nss_crypt=yes,
 333              AC_MSG_ERROR([
 334 cannot find NSS headers with lowlevel hash function interfaces]))
 335   old_LIBS="$LIBS"
 336   old_LDFLAGS="$LDFLAGS"
 337   LIBS="$LIBS -lfreebl3"
 338   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 339 #include <hasht.h>
 340 #include <nsslowhash.h>],
 341                                   [NSSLOW_Init();])],
 342                  libc_cv_nss_crypt=yes,
 343                  AC_MSG_ERROR([
 344 cannot link program using lowlevel NSS hash functions]))
 345   # Check to see if there is a static NSS cryptographic library.
 346   # If there isn't then we can't link anything with libcrypt.a,
 347   # and that might mean disabling some static tests.
 348   LDFLAGS="$LDFLAGS -static"
 349   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 350 #include <hasht.h>
 351 #include <nsslowhash.h>],
 352                                   [NSSLOW_Init();])],
 353                  libc_cv_static_nss_crypt=yes,
 354                  libc_cv_static_nss_crypt=no)
 355   LDFLAGS="$old_LDFLAGS"
 356   CFLAGS="$old_CFLAGS"
 357   LIBS="$old_LIBS"
 358 else
 359   libc_cv_nss_crypt=no
 360   libc_cv_static_nss_crypt=no
 361 fi
 362 AC_SUBST(libc_cv_nss_crypt)
 363 AC_SUBST(libc_cv_static_nss_crypt)
 364
 365
 366 AC_ARG_ENABLE([obsolete-rpc],
 367               AC_HELP_STRING([--enable-obsolete-rpc],
 368                              [build and install the obsolete RPC code for link-time usage]),
 369               [link_obsolete_rpc=$enableval],
 370               [link_obsolete_rpc=no])
 371 AC_SUBST(link_obsolete_rpc)
 372
 373 if test "$link_obsolete_rpc" = yes; then
 374   AC_DEFINE(LINK_OBSOLETE_RPC)
 375 fi
 376
 377 AC_ARG_ENABLE([obsolete-nsl],
 378               AC_HELP_STRING([--enable-obsolete-nsl],
 379                              [build and install the obsolete libnsl library and depending NSS modules]),
 380               [build_obsolete_nsl=$enableval],
 381               [build_obsolete_nsl=no])
 382 AC_SUBST(build_obsolete_nsl)
 383
 384 if test "$build_obsolete_nsl" = yes; then
 385   AC_DEFINE(LINK_OBSOLETE_NSL)
 386 fi
 387
 388 AC_ARG_ENABLE([systemtap],
 389               [AS_HELP_STRING([--enable-systemtap],
 390                [enable systemtap static probe points @<:@default=no@:>@])],
 391               [systemtap=$enableval],
 392               [systemtap=no])
 393 if test "x$systemtap" != xno; then
 394   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 395   old_CFLAGS="$CFLAGS"
 396   CFLAGS="-std=gnu11 $CFLAGS"
 397   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 398 void foo (int i, void *p)
 399 {
 400   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 401        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 402 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 403   CFLAGS="$old_CFLAGS"])
 404   if test $libc_cv_sdt = yes; then
 405     AC_DEFINE([USE_STAP_PROBE])
 406   elif test "x$systemtap" != xauto; then
 407     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 408   fi
 409 fi
 410
 411 AC_ARG_ENABLE([build-nscd],
 412               [AS_HELP_STRING([--disable-build-nscd],
 413                [disable building and installing the nscd daemon])],
 414               [build_nscd=$enableval],
 415               [build_nscd=default])
 416 AC_SUBST(build_nscd)
 417
 418 # Note the use of $use_nscd is near the bottom of the file.
 419 AC_ARG_ENABLE([nscd],
 420               [AS_HELP_STRING([--disable-nscd],
 421                [library functions will not contact the nscd daemon])],
 422               [use_nscd=$enableval],
 423               [use_nscd=yes])
 424
 425 AC_ARG_ENABLE([pt_chown],
 426               [AS_HELP_STRING([--enable-pt_chown],
 427                [Enable building and installing pt_chown])],
 428               [build_pt_chown=$enableval],
 429               [build_pt_chown=no])
 430 AC_SUBST(build_pt_chown)
 431 if test "$build_pt_chown" = yes; then
 432   AC_DEFINE(HAVE_PT_CHOWN)
 433 fi
 434
 435 AC_ARG_ENABLE([tunables],
 436               [AS_HELP_STRING([--enable-tunables],
 437                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 438               [have_tunables=$enableval],
 439               [have_tunables=no])
 440 AC_SUBST(have_tunables)
 441 if test "$have_tunables" = yes; then
 442   AC_DEFINE(HAVE_TUNABLES)
 443 fi
 444
 445 # The abi-tags file uses a fairly simplistic model for name recognition that
 446 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 447 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 448 # This doesn't get used much beyond that, so it's fairly safe.
 449 case "$host_os" in
 450 linux*)
 451   ;;
 452 gnu*)
 453   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 454   ;;
 455 esac
 456
 457 AC_ARG_ENABLE([mathvec],
 458               [AS_HELP_STRING([--enable-mathvec],
 459               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 460               [build_mathvec=$enableval],
 461               [build_mathvec=notset])
 462
 463 # We keep the original values in `$config_*' and never modify them, so we
 464 # can write them unchanged into config.make.  Everything else uses
 465 # $machine, $vendor, and $os, and changes them whenever convenient.
 466 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 467
 468 # Don't allow vendor == "unknown"
 469 test "$config_vendor" = unknown && config_vendor=
 470 config_os="`echo $config_os | sed 's/^unknown-//'`"
 471
 472 # Some configurations imply other options.
 473 elf=yes
 474
 475 # The configure fragment of an add-on port can modify these to supplement
 476 # or override the table in the case statement below.  No fragment should
 477 # ever change the config_* variables, however.
 478 machine=$config_machine
 479 vendor=$config_vendor
 480 os=$config_os
 481 base_os=''
 482
 483 submachine=
 484 AC_ARG_WITH([cpu],
 485             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 486             [dnl
 487   case "$withval" in
 488   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 489   no) ;;
 490   *) submachine="$withval" ;;
 491   esac
 492 ])
 493
 494 # An preconfigure script can set this when it wants to disable the sanity
 495 # check below.
 496 libc_config_ok=no
 497
 498 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 499 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 500
 501 dnl Having this here, though empty, makes sure that if add-ons' fragments
 502 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 503 dnl our AC_OUTPUT will actually use it.
 504 AC_CONFIG_SUBDIRS()
 505
 506 case "$enable_add_ons" in
 507 ''|no) add_ons= ;;
 508 yes|'*')
 509  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 510           sed 's@/[[^/]]*$@@' | sort | uniq`
 511          add_ons_automatic=yes
 512          ;;
 513 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 514        add_ons_automatic=no ;;
 515 esac
 516
 517 configured_add_ons=
 518 add_ons_sfx=
 519 add_ons_pfx=
 520 if test x"$add_ons" != x; then
 521   for f in $add_ons; do
 522     # Some sanity checks
 523     case "$f" in
 524     crypt)
 525       AC_MSG_ERROR([
 526 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 527 *** part of glibc and using the old add-on will not work with this
 528 *** release.  Start again with fresh sources and without the old
 529 *** \`crypt' add-on.])
 530     ;;
 531     localedata)
 532       AC_MSG_ERROR([
 533 *** It seems that you're using an old \`localedata' add-on.  localedata
 534 *** is now part of glibc and using the old add-on will not work with
 535 *** this release.  Start again with fresh sources and without the old
 536 *** \`localedata' add-on.])
 537     ;;
 538     esac
 539   done
 540
 541   # Now source each add-on's configure fragment.
 542   # The fragments can use $srcdir/$libc_add_on to find themselves,
 543   # and test $add_ons_automatic to see if they were explicitly requested.
 544   # A fragment can clear (or even change) $libc_add_on to affect
 545   # whether it goes into the list to be actually used in the build.
 546   use_add_ons=
 547   for libc_add_on in $add_ons; do
 548     # Test whether such a directory really exists.
 549     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 550     case "$libc_add_on" in
 551     /*)
 552       libc_add_on_srcdir=$libc_add_on
 553       ;;
 554     *)
 555       test -d "$srcdir/$libc_add_on" || {
 556         if test -d "$libc_add_on"; then
 557           libc_add_on="`pwd`/$libc_add_on"
 558         else
 559           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 560         fi
 561       }
 562       libc_add_on_srcdir=$srcdir/$libc_add_on
 563       ;;
 564     esac
 565
 566     libc_add_on_frag=$libc_add_on_srcdir/configure
 567     libc_add_on_canonical=
 568     libc_add_on_config_subdirs=
 569     if test -r "$libc_add_on_frag"; then
 570       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 571       libc_add_on_canonical=unknown
 572       libc_add_on_subdirs=
 573       . "$libc_add_on_frag"
 574       test -z "$libc_add_on" || {
 575         configured_add_ons="$configured_add_ons $libc_add_on"
 576         if test "x$libc_add_on_canonical" = xunknown; then
 577           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 578         fi
 579         for d in $libc_add_on_subdirs; do
 580           case "$libc_add_on" in
 581           /*) subdir_srcdir="$libc_add_on" ;;
 582           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 583           esac
 584           case "$d" in
 585           .)
 586             d="${libc_add_on_canonical:-$libc_add_on}"
 587             ;;
 588           /*)
 589             subdir_srcdir="$d"
 590             ;;
 591           *)
 592             subdir_srcdir="$subdir_srcdir/$d"
 593             ;;
 594           esac
 595           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 596           add_on_subdirs="$add_on_subdirs $d"
 597           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 598 $d-srcdir = $subdir_srcdir"
 599         done
 600         for d in $libc_add_on_config_subdirs; do
 601           case "$d" in
 602           /*) AC_MSG_ERROR(dnl
 603 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 604           esac
 605           if test ! -d "$libc_add_on_srcdir/$d"; then
 606             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 607           fi
 608           case "$libc_add_on" in
 609           /*) AC_MSG_ERROR(dnl
 610 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 611           esac
 612           subdirs="$subdirs $libc_add_on/$d"
 613         done
 614       }
 615     fi
 616     if test -n "$libc_add_on"; then
 617       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 618       use_add_ons="$use_add_ons $libc_add_on"
 619       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 620       test -z "$libc_add_on_canonical" ||
 621       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 622     fi
 623   done
 624   # Use echo to strip excess whitespace.
 625   add_ons="`echo $use_add_ons`"
 626 fi
 627 AC_SUBST(add_ons)
 628 AC_SUBST(add_on_subdirs)
 629
 630
 631 ###
 632 ### By using the undocumented --enable-hacker-mode option for configure
 633 ### one can skip this test to make the configuration not fail for unsupported
 634 ### platforms.
 635 ###
 636 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 637   case "$machine-$host_os" in
 638   *-linux* | *-gnu*)
 639     ;;
 640   *)
 641     AC_MSG_ERROR([
 642 *** The GNU C library is currently unavailable for this platform.
 643 *** If you are interested in seeing glibc on this platform visit
 644 *** the "How to submit a new port" in the wiki:
 645 ***   https://sourceware.org/glibc/wiki/#Development
 646 *** and join the community!])
 647     ;;
 648   esac
 649 fi
 650
 651 # Set base_machine if not set by a preconfigure fragment.
 652 test -n "$base_machine" || base_machine=$machine
 653 AC_SUBST(base_machine)
 654
 655 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 656 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 657                    [libc_cv_ssp=yes],
 658                    [libc_cv_ssp=no])
 659 ])
 660
 661 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 662 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 663                    [libc_cv_ssp_strong=yes],
 664                    [libc_cv_ssp_strong=no])
 665 ])
 666
 667 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 668 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 669                    [libc_cv_ssp_all=yes],
 670                    [libc_cv_ssp_all=no])
 671 ])
 672
 673 stack_protector=
 674 no_stack_protector=
 675 if test "$libc_cv_ssp" = yes; then
 676   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 677   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 678 fi
 679
 680 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 681   stack_protector="-fstack-protector"
 682   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 683 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 684   stack_protector="-fstack-protector-all"
 685   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 686 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 687   stack_protector="-fstack-protector-strong"
 688   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 689 else
 690   stack_protector="-fno-stack-protector"
 691   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 692 fi
 693 AC_SUBST(libc_cv_ssp)
 694 AC_SUBST(stack_protector)
 695 AC_SUBST(no_stack_protector)
 696
 697 if test -n "$stack_protector"; then
 698   dnl Don't run configure tests with stack-protection on, to avoid problems with
 699   dnl bootstrapping.
 700   no_ssp=-fno-stack-protector
 701 else
 702   no_ssp=
 703
 704   if test "$enable_stack_protector" != no; then
 705     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 706   fi
 707 fi
 708
 709 # For the multi-arch option we need support in the assembler & linker.
 710 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 711                libc_cv_ld_gnu_indirect_function, [dnl
 712 cat > conftest.S <<EOF
 713 .type foo,%gnu_indirect_function
 714 foo:
 715 .globl _start
 716 _start:
 717 .globl __start
 718 __start:
 719 .data
 720 #ifdef _LP64
 721 .quad foo
 722 #else
 723 .long foo
 724 #endif
 725 EOF
 726 libc_cv_ld_gnu_indirect_function=no
 727 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 728             -nostartfiles -nostdlib $no_ssp \
 729             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 730   # Do a link to see if the backend supports IFUNC relocs.
 731   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 732   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 733     libc_cv_ld_gnu_indirect_function=yes
 734   }
 735 fi
 736 rm -f conftest*])
 737
 738 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 739 AC_CACHE_CHECK([for gcc attribute ifunc support],
 740                libc_cv_gcc_indirect_function, [dnl
 741 cat > conftest.c <<EOF
 742 extern int func (int);
 743 int used_func (int a)
 744 {
 745   return a;
 746 }
 747 static void *resolver ()
 748 {
 749   return &used_func;
 750 }
 751 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 752 EOF
 753 libc_cv_gcc_indirect_function=no
 754 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 755    2>&AS_MESSAGE_LOG_FD ; then
 756   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 757     libc_cv_gcc_indirect_function=yes
 758   fi
 759 fi
 760 rm -f conftest*])
 761
 762 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 763   if test x"$multi_arch" = xyes; then
 764     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 765   else
 766     multi_arch=no
 767   fi
 768 fi
 769 if test x"$libc_cv_gcc_indirect_function" != xyes &&
 770    test x"$multi_arch" = xyes; then
 771   AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 772 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 773 fi
 774 multi_arch_d=
 775 if test x"$multi_arch" != xno; then
 776   multi_arch_d=/multiarch
 777 fi
 778
 779 # Compute the list of sysdep directories for this configuration.
 780 # This can take a while to compute.
 781 sysdep_dir=$srcdir/sysdeps
 782 AC_MSG_CHECKING(sysdep dirs)
 783 dnl We need to use [ and ] for other purposes for a while now.
 784 changequote(,)dnl
 785 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 786 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 787
 788 test "x$base_os" != x || case "$os" in
 789 gnu*)
 790   base_os=mach/hurd ;;
 791 linux*)
 792   base_os=unix/sysv ;;
 793 esac
 794
 795 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 796 tail=$os
 797 ostry=$os
 798 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 799   ostry="$ostry /$o"
 800   tail=$o
 801 done
 802 o=`echo $tail | sed 's/[0-9]*$//'`
 803 if test $o != $tail; then
 804   ostry="$ostry /$o"
 805 fi
 806 # For linux-gnu, try linux-gnu, then linux.
 807 o=`echo $tail | sed 's/-.*$//'`
 808 if test $o != $tail; then
 809   ostry="$ostry /$o"
 810 fi
 811
 812 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 813 base=
 814 tail=$base_os
 815 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 816   set $b
 817   base="$base /$1"
 818   tail="$2"
 819 done
 820
 821 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 822 mach=
 823 tail=$machine${submachine:+/$submachine}
 824 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 825   set $m
 826   # Prepend the machine's FPU directory unless --without-fp.
 827   if test "$with_fp" = yes; then
 828     maybe_fpu=/fpu
 829   else
 830     maybe_fpu=/nofpu
 831   fi
 832   # For each machine term, try it with and then without /multiarch.
 833   for try_fpu in $maybe_fpu ''; do
 834     for try_multi in $multi_arch_d ''; do
 835       mach="$mach /$1$try_fpu$try_multi"
 836     done
 837   done
 838   tail="$2"
 839 done
 840
 841 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 842 changequote([,])dnl
 843
 844 # Find what sysdep directories exist.
 845 sysnames_add_ons=
 846 sysnames=
 847 for b in $base ''; do
 848   for m0 in $mach ''; do
 849     for v in /$vendor ''; do
 850       test "$v" = / && continue
 851       for o in /$ostry ''; do
 852         test "$o" = / && continue
 853         for m in $mach ''; do
 854           for d in $add_ons_pfx ''; do
 855             for a in $add_ons_sfx ''; do
 856               try_suffix="$m0$b$v$o$m"
 857               if test -n "$try_suffix"; then
 858                 try_srcdir="${srcdir}/"
 859                 case "$d" in
 860                 /*) try_srcdir= ;;
 861                 esac
 862                 try="${d}sysdeps$try_suffix$a"
 863                 test -n "$enable_debug_configure" &&
 864                 echo "$0 [DEBUG]: try $try" >&2
 865                 if test -d "$try_srcdir$try"; then
 866                   sysnames="$sysnames $try"
 867                   { test -n "$o" || test -n "$b"; } && os_used=t
 868                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 869                   case x${m0:-$m} in
 870                   x*/$submachine) submachine_used=t ;;
 871                   esac
 872                   if test -n "$d"; then
 873                     case "$sysnames_add_ons" in
 874                     *" $d "*) ;;
 875                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 876                     esac
 877                   fi
 878                 fi
 879               fi
 880             done
 881           done
 882         done
 883       done
 884     done
 885   done
 886 done
 887
 888 # If the assembler supports gnu_indirect_function symbol type and the
 889 # architecture supports multi-arch, we enable multi-arch by default.
 890 case $sysnames_add_ons$sysnames in
 891 *"$multi_arch_d"*)
 892   ;;
 893 *)
 894   test x"$multi_arch" = xdefault && multi_arch=no
 895   ;;
 896 esac
 897 if test x"$multi_arch" != xno; then
 898   AC_DEFINE(USE_MULTIARCH)
 899 fi
 900 AC_SUBST(multi_arch)
 901
 902 if test -z "$os_used" && test "$os" != none; then
 903   AC_MSG_ERROR(Operating system $os is not supported.)
 904 fi
 905 if test -z "$machine_used" && test "$machine" != none; then
 906   AC_MSG_ERROR(The $machine is not supported.)
 907 fi
 908 if test -z "$submachine_used" && test -n "$submachine"; then
 909   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 910 fi
 911 AC_SUBST(submachine)
 912
 913 # We have now validated the configuration.
 914
 915 # Expand the list of system names into a full list of directories
 916 # from each element's parent name and Implies file (if present).
 917 set $sysnames
 918 names=
 919 while test $# -gt 0; do
 920   name=$1
 921   shift
 922
 923   case " $names " in *" $name "*)
 924     # Already in the list.
 925     continue
 926   esac
 927
 928   # Report each name as we discover it, so there is no long pause in output.
 929   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 930
 931   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 932
 933   case $name in
 934     /*) xsrcdir= ;;
 935     *)  xsrcdir=$srcdir/ ;;
 936   esac
 937   test -n "$enable_debug_configure" &&
 938   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 939
 940   for implies_file in Implies Implies-before Implies-after; do
 941     implies_type=`echo $implies_file | sed s/-/_/`
 942     eval ${implies_type}=
 943     if test -f $xsrcdir$name/$implies_file; then
 944       # Collect more names from the `Implies' file (removing comments).
 945       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 946       for x in $implied_candidate; do
 947         found=no
 948         if test -d $xsrcdir$name_base/$x; then
 949           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 950           found=yes
 951         fi
 952         for d in $add_ons_pfx ''; do
 953           try="${d}sysdeps/$x"
 954           case $d in
 955            /*) try_srcdir= ;;
 956            *) try_srcdir=$srcdir/ ;;
 957           esac
 958           test -n "$enable_debug_configure" &&
 959            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 960           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 961           then
 962             eval "${implies_type}=\"\$${implies_type} \$try\""
 963             found=yes
 964             case "$sysnames_add_ons" in
 965             *" $d "*) ;;
 966             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 967             esac
 968           fi
 969         done
 970         if test $found = no; then
 971           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 972         fi
 973       done
 974     fi
 975   done
 976
 977   # Add NAME to the list of names.
 978   names="$names $name"
 979
 980   # Find the parent of NAME, using the empty string if it has none.
 981 changequote(,)dnl
 982   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 983 changequote([,])dnl
 984
 985   test -n "$enable_debug_configure" &&
 986     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 987 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 988
 989   # Add the names implied by NAME, and NAME's parent (if it has one), to
 990   # the list of names to be processed (the argument list).  We prepend the
 991   # implied names to the list and append the parent.  We want implied
 992   # directories to come before further directories inferred from the
 993   # configuration components; this ensures that for sysv4, unix/common
 994   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 995   # after sysv4).
 996   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 997   test -n "$sysnames" && set $sysnames
 998 done
 999
1000 # Add the default directories.
1001 default_sysnames="sysdeps/generic"
1002 sysnames="$names $default_sysnames"
1003 AC_SUBST(sysnames)
1004 # The other names were emitted during the scan.
1005 AC_MSG_RESULT($default_sysnames)
1006
1007 # Collect the list of add-ons that supply partial sysdeps trees.
1008 sysdeps_add_ons=
1009 for add_on in $add_ons; do
1010   case "$add_on" in
1011   /*) xsrcdir= ;;
1012   *) xsrcdir="$srcdir/" ;;
1013   esac
1014
1015   test -d "$xsrcdir$add_on/sysdeps" || {
1016     case "$configured_add_ons " in
1017     *" $add_on "*) ;;
1018     *|'')
1019       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
1020       ;;
1021     esac
1022     continue
1023   }
1024
1025   sysdeps_add_ons="$sysdeps_add_ons $add_on"
1026   case "$sysnames_add_ons" in
1027   *" $add_on/ "*) ;;
1028   *|'')
1029     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
1030     continue ;;
1031   esac
1032
1033   found=no
1034   for d in $sysnames; do
1035     case "$d" in
1036     $add_on/sysdeps/*) ;;
1037     *) continue ;;
1038     esac
1039     (cd "$xsrcdir$d" && for f in *[[!~]]; do
1040        case "$f" in
1041        sys|bits)
1042          for ff in $f/*.h; do
1043            test -d "$ff" || { test -e "$ff" && exit 88; }
1044          done
1045          ;;
1046        *)
1047          test -d "$f" || { test -e "$f" && exit 88; }
1048          ;;
1049        esac
1050      done)
1051     if test $? -eq 88; then
1052       found=yes
1053       break
1054     fi
1055   done
1056   if test $found = no; then
1057     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
1058   fi
1059 done
1060 AC_SUBST(sysdeps_add_ons)
1061
1062
1063 ### Locate tools.
1064
1065 AC_PROG_INSTALL
1066 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
1067   # The makefiles need to use a different form to find it in $srcdir.
1068   INSTALL='\$(..)./scripts/install-sh -c'
1069 fi
1070 AC_PROG_LN_S
1071
1072 LIBC_PROG_BINUTILS
1073
1074 # Accept binutils 2.22 or newer.
1075 AC_CHECK_PROG_VER(AS, $AS, --version,
1076                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
1077                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1078                   AS=: critic_missing="$critic_missing as")
1079 AC_CHECK_PROG_VER(LD, $LD, --version,
1080                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1081                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1082                   LD=: critic_missing="$critic_missing ld")
1083
1084 # These programs are version sensitive.
1085 AC_CHECK_TOOL_PREFIX
1086 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1087   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1088   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1089
1090 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1091   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1092   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1093   MSGFMT=: aux_missing="$aux_missing msgfmt")
1094 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1095   [GNU texinfo.* \([0-9][0-9.]*\)],
1096   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1097   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1098 AC_CHECK_PROG_VER(SED, sed, --version,
1099   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1100   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1101   SED=: aux_missing="$aux_missing sed")
1102 AC_CHECK_PROG_VER(AWK, gawk, --version,
1103   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1104   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1105
1106 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1107 AC_TRY_COMPILE([], [
1108 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
1109 #error insufficient compiler
1110 #endif],
1111                [libc_cv_compiler_ok=yes],
1112                [libc_cv_compiler_ok=no])])
1113 AS_IF([test $libc_cv_compiler_ok != yes],
1114       [critic_missing="$critic_missing compiler"])
1115
1116 AC_CHECK_TOOL(NM, nm, false)
1117
1118 if test "x$maintainer" = "xyes"; then
1119   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1120   case "x$AUTOCONF" in
1121   xno|x|x:) AUTOCONF=no ;;
1122   *)
1123     AC_CACHE_CHECK(dnl
1124   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1125     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1126       libc_cv_autoconf_works=yes
1127     else
1128       libc_cv_autoconf_works=no
1129     fi])
1130     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1131     ;;
1132   esac
1133   if test "x$AUTOCONF" = xno; then
1134     aux_missing="$aux_missing autoconf"
1135   fi
1136 else
1137   AUTOCONF=no
1138 fi
1139
1140 # Check for python3 if available, or else python.
1141 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1142 case "x$PYTHON_PROG" in
1143 xno|x|x:) PYTHON_PROG=no ;;
1144 *) ;;
1145 esac
1146
1147 if test "x$PYTHON_PROG" = xno; then
1148   aux_missing="$aux_missing python"
1149 else
1150   PYTHON="$PYTHON_PROG -B"
1151   AC_SUBST(PYTHON)
1152 fi
1153
1154 test -n "$critic_missing" && AC_MSG_ERROR([
1155 *** These critical programs are missing or too old:$critic_missing
1156 *** Check the INSTALL file for required versions.])
1157
1158 test -n "$aux_missing" && AC_MSG_WARN([
1159 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1160 *** some features or tests will be disabled.
1161 *** Check the INSTALL file for required versions.])
1162
1163 # if using special system headers, find out the compiler's sekrit
1164 # header directory and add that to the list.  NOTE: Only does the right
1165 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1166 if test -n "$sysheaders"; then
1167   SYSINCLUDES=-nostdinc
1168   for d in include include-fixed; do
1169     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1170     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1171   done
1172   SYSINCLUDES="$SYSINCLUDES \
1173 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1174   if test -n "$CXX"; then
1175     CXX_SYSINCLUDES=
1176     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1177     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1178       test "x$cxxheaders" != x &&
1179       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1180     done
1181   fi
1182 fi
1183 AC_SUBST(SYSINCLUDES)
1184 AC_SUBST(CXX_SYSINCLUDES)
1185
1186 # Obtain some C++ header file paths.  This is used to make a local
1187 # copy of those headers in Makerules.
1188 if test -n "$CXX"; then
1189   find_cxx_header () {
1190     echo "#include <$1>" | $CXX -M -MP -x c++ - | sed -n "/$1:/{s/:\$//;p}"
1191   }
1192   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1193   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1194 fi
1195 AC_SUBST(CXX_CSTDLIB_HEADER)
1196 AC_SUBST(CXX_CMATH_HEADER)
1197
1198 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1199 # since this would lead to problems installing/building glibc.
1200 # LD_LIBRARY_PATH contains the current directory if one of the following
1201 # is true:
1202 # - one of the terminals (":" and ";") is the first or last sign
1203 # - two terminals occur directly after each other
1204 # - the path contains an element with a dot in it
1205 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1206 changequote(,)dnl
1207 case ${LD_LIBRARY_PATH} in
1208   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1209     ld_library_path_setting="contains current directory"
1210     ;;
1211   *)
1212     ld_library_path_setting="ok"
1213     ;;
1214 esac
1215 changequote([,])dnl
1216 AC_MSG_RESULT($ld_library_path_setting)
1217 if test "$ld_library_path_setting" != "ok"; then
1218 AC_MSG_ERROR([
1219 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1220 *** building glibc. Please change the environment variable
1221 *** and run configure again.])
1222 fi
1223
1224 AC_PATH_PROG(BASH_SHELL, bash, no)
1225
1226 AC_PATH_PROG(PERL, perl, no)
1227 if test "$PERL" != no &&
1228    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1229   PERL=no
1230 fi
1231 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1232              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1233 AC_CHECK_PROG_VER(BISON, bison, --version,
1234                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1235                   [2.7*|[3-9].*|[1-9][0-9]*],
1236                   BISON=no)
1237
1238 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1239 cat > conftest.s <<EOF
1240 .text
1241 foo:
1242 .set glibc_conftest_frobozz,foo
1243 .globl glibc_conftest_frobozz
1244 EOF
1245 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1246 # (but it doesn't work), so we must do a linking check to be sure.
1247 cat > conftest1.c <<\EOF
1248 extern int glibc_conftest_frobozz;
1249 void _start() { glibc_conftest_frobozz = 1; }
1250 EOF
1251 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1252             -nostartfiles -nostdlib $no_ssp \
1253             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1254   libc_cv_asm_set_directive=yes
1255 else
1256   libc_cv_asm_set_directive=no
1257 fi
1258 rm -f conftest*])
1259 if test $libc_cv_asm_set_directive = yes; then
1260   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1261 fi
1262
1263 AC_CACHE_CHECK(linker support for protected data symbol,
1264                libc_cv_protected_data,
1265                [cat > conftest.c <<EOF
1266                 int bar __attribute__ ((visibility ("protected"))) = 1;
1267 EOF
1268                 libc_cv_protected_data=no
1269                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1270                   cat > conftest.c <<EOF
1271                   extern int bar;
1272                   int main (void) { return bar; }
1273 EOF
1274                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1275                     libc_cv_protected_data=yes
1276                   fi
1277                 fi
1278                 rm -f conftest.*
1279                ])
1280 AC_SUBST(libc_cv_protected_data)
1281
1282 AC_CACHE_CHECK(for broken __attribute__((alias())),
1283                libc_cv_broken_alias_attribute,
1284                [cat > conftest.c <<EOF
1285                extern int foo (int x) __asm ("xyzzy");
1286                int bar (int x) { return x; }
1287                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1288                extern int dfoo;
1289                extern __typeof (dfoo) dfoo __asm ("abccb");
1290                int dfoo = 1;
1291 EOF
1292                libc_cv_broken_alias_attribute=yes
1293                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1294                  if grep 'xyzzy' conftest.s >/dev/null &&
1295                     grep 'abccb' conftest.s >/dev/null; then
1296                    libc_cv_broken_alias_attribute=no
1297                  fi
1298                fi
1299                rm -f conftest.c conftest.s
1300                ])
1301 if test $libc_cv_broken_alias_attribute = yes; then
1302   AC_MSG_ERROR(working alias attribute support required)
1303 fi
1304
1305 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1306                libc_cv_have_sdata_section,
1307                [echo "int i;" > conftest.c
1308                 libc_cv_have_sdata_section=no
1309                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1310                    | grep '\.sdata' >/dev/null; then
1311                   libc_cv_have_sdata_section=yes
1312                 fi
1313                 rm -f conftest.c conftest.so
1314                ])
1315 if test $libc_cv_have_sdata_section = yes; then
1316   AC_DEFINE(HAVE_SDATA_SECTION)
1317 fi
1318
1319 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1320                libc_cv_ctors_header, [dnl
1321   libc_cv_ctors_header=yes
1322   LIBC_TRY_LINK_STATIC([
1323 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1324 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1325 ],
1326               [dnl
1327       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1328         { gsub(/\@<:@ */, "@<:@") }
1329         $2 == ".ctors" || $2 == ".dtors" {
1330           size = strtonum("0x" $6)
1331           align = strtonum("0x" $NF)
1332           seen@<:@$2@:>@ = 1
1333           stub@<:@$2@:>@ = size == align * 2
1334         }
1335         END {
1336           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1337           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1338           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1339         }
1340       '], [libc_cv_ctors_header=no])
1341     ], [dnl
1342       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1343     ])
1344 ])
1345 if test $libc_cv_ctors_header = no; then
1346   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1347 fi
1348
1349 AC_CACHE_CHECK(for libunwind-support in compiler,
1350                libc_cv_cc_with_libunwind, [
1351   cat > conftest.c <<EOF
1352 int main (void) { return 0; }
1353 EOF
1354   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1355      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1356     libc_cv_cc_with_libunwind=yes
1357   else
1358     libc_cv_cc_with_libunwind=no
1359   fi
1360   rm -f conftest*])
1361 AC_SUBST(libc_cv_cc_with_libunwind)
1362 if test $libc_cv_cc_with_libunwind = yes; then
1363   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1364 fi
1365
1366 ASFLAGS_config=
1367 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1368                libc_cv_as_noexecstack, [dnl
1369 cat > conftest.c <<EOF
1370 void foo (void) { }
1371 EOF
1372 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1373                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1374    && grep .note.GNU-stack conftest.s >/dev/null \
1375    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1376                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1377 then
1378   libc_cv_as_noexecstack=yes
1379 else
1380   libc_cv_as_noexecstack=no
1381 fi
1382 rm -f conftest*])
1383 if test $libc_cv_as_noexecstack = yes; then
1384   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1385 fi
1386 AC_SUBST(ASFLAGS_config)
1387
1388 AC_CACHE_CHECK(for -z combreloc,
1389                libc_cv_z_combreloc, [dnl
1390 cat > conftest.c <<EOF
1391 extern int bar (int);
1392 extern int mumble;
1393 int foo (void) { return bar (mumble); }
1394 EOF
1395 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1396                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1397                         -nostdlib -nostartfiles
1398                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1399 then
1400 dnl The following test is a bit weak.  We must use a tool which can test
1401 dnl cross-platform since the gcc used can be a cross compiler.  Without
1402 dnl introducing new options this is not easily doable.  Instead use a tool
1403 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1404 dnl look for a section named .rel.dyn or .rela.dyn.
1405   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1406     libc_cv_z_combreloc=yes
1407   else
1408     libc_cv_z_combreloc=no
1409   fi
1410 else
1411   libc_cv_z_combreloc=no
1412 fi
1413 rm -f conftest*])
1414 if test "$libc_cv_z_combreloc" = yes; then
1415   AC_DEFINE(HAVE_Z_COMBRELOC)
1416 fi
1417 AC_SUBST(libc_cv_z_combreloc)
1418
1419 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1420                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1421 AC_SUBST(libc_cv_z_execstack)
1422
1423 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1424 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1425 ])
1426
1427 AC_SUBST(libc_cv_fpie)
1428
1429 AC_CACHE_CHECK(for --hash-style option,
1430                libc_cv_hashstyle, [dnl
1431 cat > conftest.c <<EOF
1432 int _start (void) { return 42; }
1433 EOF
1434 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1435                             -fPIC -shared -o conftest.so conftest.c
1436                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1437 then
1438   libc_cv_hashstyle=yes
1439 else
1440   libc_cv_hashstyle=no
1441 fi
1442 rm -f conftest*])
1443 AC_SUBST(libc_cv_hashstyle)
1444
1445 # The linker's default -shared behavior is good enough if it
1446 # does these things that our custom linker scripts ensure that
1447 # all allocated NOTE sections come first.
1448 if test "$use_default_link" = default; then
1449   AC_CACHE_CHECK([for sufficient default -shared layout],
1450                   libc_cv_use_default_link, [dnl
1451   libc_cv_use_default_link=no
1452   cat > conftest.s <<\EOF
1453           .section .note.a,"a",%note
1454           .balign 4
1455           .long 4,4,9
1456           .string "GNU"
1457           .string "foo"
1458           .section .note.b,"a",%note
1459           .balign 4
1460           .long 4,4,9
1461           .string "GNU"
1462           .string "bar"
1463 EOF
1464   if AC_TRY_COMMAND([dnl
1465   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1466        ac_try=`$READELF -S conftest.so | sed -n \
1467          ['${x;p;}
1468           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1469           t a
1470           b
1471           : a
1472           H']`
1473   then
1474     libc_seen_a=no libc_seen_b=no
1475     set -- $ac_try
1476     while test $# -ge 2 -a "$1" = NOTE; do
1477       case "$2" in
1478       .note.a) libc_seen_a=yes ;;
1479       .note.b) libc_seen_b=yes ;;
1480       esac
1481       shift 2
1482     done
1483     case "$libc_seen_a$libc_seen_b" in
1484     yesyes)
1485       libc_cv_use_default_link=yes
1486       ;;
1487     *)
1488       echo >&AS_MESSAGE_LOG_FD "\
1489 $libc_seen_a$libc_seen_b from:
1490 $ac_try"
1491       ;;
1492     esac
1493   fi
1494   rm -f conftest*])
1495   use_default_link=$libc_cv_use_default_link
1496 fi
1497
1498 AC_CACHE_CHECK(for GLOB_DAT reloc,
1499                libc_cv_has_glob_dat, [dnl
1500 cat > conftest.c <<EOF
1501 extern int mumble;
1502 int foo (void) { return mumble; }
1503 EOF
1504 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1505                         -fPIC -shared -o conftest.so conftest.c
1506                         -nostdlib -nostartfiles $no_ssp
1507                         1>&AS_MESSAGE_LOG_FD])
1508 then
1509 dnl look for GLOB_DAT relocation.
1510   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1511     libc_cv_has_glob_dat=yes
1512   else
1513     libc_cv_has_glob_dat=no
1514   fi
1515 else
1516   libc_cv_has_glob_dat=no
1517 fi
1518 rm -f conftest*])
1519 AC_SUBST(libc_cv_has_glob_dat)
1520
1521 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1522 if libc_cv_output_format=`
1523 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1524 then
1525   :
1526 else
1527   libc_cv_output_format=
1528 fi
1529 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1530 AC_SUBST(libc_cv_output_format)
1531
1532 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1533 cat > conftest.c <<EOF
1534 int foo;
1535 EOF
1536 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1537                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1538 then
1539   libc_cv_fno_toplevel_reorder=yes
1540 else
1541   libc_cv_fno_toplevel_reorder=no
1542 fi
1543 rm -f conftest*])
1544 if test $libc_cv_fno_toplevel_reorder = yes; then
1545   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1546 else
1547   fno_unit_at_a_time=-fno-unit-at-a-time
1548 fi
1549 AC_SUBST(fno_unit_at_a_time)
1550
1551 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1552 [dnl
1553 cat > conftest.c <<EOF
1554 __thread int i;
1555 void foo (void)
1556 {
1557   i = 10;
1558 }
1559 EOF
1560 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1561                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1562 then
1563   libc_cv_mtls_dialect_gnu2=yes
1564 else
1565   libc_cv_mtls_dialect_gnu2=no
1566 fi
1567 rm -f conftest*])
1568 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1569 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1570
1571 AC_CACHE_CHECK(whether cc puts quotes around section names,
1572                libc_cv_have_section_quotes,
1573                [cat > conftest.c <<EOF
1574                 static const int foo
1575                 __attribute__ ((section ("bar"))) = 1;
1576 EOF
1577                 if ${CC-cc} -S conftest.c -o conftest.s; then
1578                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1579                     libc_cv_have_section_quotes=yes
1580                   else
1581                     libc_cv_have_section_quotes=no
1582                   fi
1583                 else
1584                   libc_cv_have_section_quotes=unknown
1585                 fi
1586                 rm -f conftest.{c,s}
1587                 ])
1588 if test $libc_cv_have_section_quotes = yes; then
1589   AC_DEFINE(HAVE_SECTION_QUOTES)
1590 fi
1591
1592 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1593 cat > conftest.c <<\EOF
1594 void zero (void *x)
1595 {
1596   __builtin_memset (x, 0, 1000);
1597 }
1598 EOF
1599 dnl
1600 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1601 then
1602   libc_cv_gcc_builtin_memset=no
1603 else
1604   libc_cv_gcc_builtin_memset=yes
1605 fi
1606 rm -f conftest* ])
1607 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1608   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1609 fi
1610
1611 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1612 cat > conftest.c <<\EOF
1613 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1614 char *foo (const char *a, const char *b)
1615 {
1616   return __builtin_strstr (a, b);
1617 }
1618 EOF
1619 dnl
1620 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1621 then
1622   libc_cv_gcc_builtin_redirection=yes
1623 else
1624   libc_cv_gcc_builtin_redirection=no
1625 fi
1626 rm -f conftest* ])
1627 if test "$libc_cv_gcc_builtin_redirection" = no; then
1628   AC_MSG_ERROR([support for the symbol redirection needed])
1629 fi
1630
1631 dnl Determine how to disable generation of FMA instructions.
1632 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1633                libc_cv_cc_nofma, [dnl
1634 libc_cv_cc_nofma=
1635 for opt in -ffp-contract=off -mno-fused-madd; do
1636   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1637 done])
1638 AC_SUBST(libc_cv_cc_nofma)
1639
1640 if test -n "$submachine"; then
1641   AC_CACHE_CHECK([for compiler option for CPU variant],
1642                  libc_cv_cc_submachine, [dnl
1643   libc_cv_cc_submachine=no
1644   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1645     LIBC_TRY_CC_OPTION([$opt], [
1646       libc_cv_cc_submachine="$opt"
1647       break], [])
1648   done])
1649   if test "x$libc_cv_cc_submachine" = xno; then
1650     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1651   fi
1652 fi
1653 AC_SUBST(libc_cv_cc_submachine)
1654
1655 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1656 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1657 cat > conftest.c <<EOF
1658 void
1659 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1660 foo (void) {}
1661 EOF
1662 libc_cv_cc_loop_to_function=no
1663 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1664 then
1665   libc_cv_cc_loop_to_function=yes
1666 fi
1667 rm -f conftest*])
1668 if test $libc_cv_cc_loop_to_function = yes; then
1669   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1670 fi
1671 AC_SUBST(libc_cv_cc_loop_to_function)
1672
1673 dnl Check whether we have the gd library available.
1674 AC_MSG_CHECKING(for libgd)
1675 if test "$with_gd" != "no"; then
1676   old_CFLAGS="$CFLAGS"
1677   CFLAGS="$CFLAGS $libgd_include"
1678   old_LDFLAGS="$LDFLAGS"
1679   LDFLAGS="$LDFLAGS $libgd_ldflags"
1680   old_LIBS="$LIBS"
1681   LIBS="$LIBS -lgd -lpng -lz -lm"
1682   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1683   CFLAGS="$old_CFLAGS"
1684   LDFLAGS="$old_LDFLAGS"
1685   LIBS="$old_LIBS"
1686 else
1687   LIBGD=no
1688 fi
1689 AC_MSG_RESULT($LIBGD)
1690 AC_SUBST(LIBGD)
1691
1692 # SELinux detection
1693 if test x$with_selinux = xno ; then
1694   have_selinux=no;
1695 else
1696   # See if we have the SELinux library
1697   AC_CHECK_LIB(selinux, is_selinux_enabled,
1698                have_selinux=yes, have_selinux=no)
1699   if test x$with_selinux = xyes ; then
1700     if test x$have_selinux = xno ; then
1701       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1702     fi
1703   fi
1704 fi
1705 # Check if we're building with SELinux support.
1706 if test "x$have_selinux" = xyes; then
1707   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1708
1709   # See if we have the libaudit library
1710   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1711                have_libaudit=yes, have_libaudit=no)
1712   if test "x$have_libaudit" = xyes; then
1713     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1714   fi
1715   AC_SUBST(have_libaudit)
1716
1717   # See if we have the libcap library
1718   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1719   if test "x$have_libcap" = xyes; then
1720     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1721   fi
1722   AC_SUBST(have_libcap)
1723 fi
1724 AC_SUBST(have_selinux)
1725
1726 CPPUNDEFS=
1727 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1728 dnl Since we are building the implementations of the fortified functions here,
1729 dnl having the macro defined interacts very badly.
1730 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1731 [AC_TRY_COMPILE([], [
1732 #ifdef _FORTIFY_SOURCE
1733 # error bogon
1734 #endif],
1735                 [libc_cv_predef_fortify_source=no],
1736                 [libc_cv_predef_fortify_source=yes])])
1737 if test $libc_cv_predef_fortify_source = yes; then
1738   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1739 fi
1740 AC_SUBST(CPPUNDEFS)
1741
1742 # Some linkers on some architectures support __ehdr_start but with
1743 # bugs.  Make sure usage of it does not create relocations in the
1744 # output (as the linker should resolve them all for us).
1745 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1746                libc_cv_ehdr_start, [
1747 old_CFLAGS="$CFLAGS"
1748 old_LDFLAGS="$LDFLAGS"
1749 old_LIBS="$LIBS"
1750 CFLAGS="$CFLAGS -fPIC"
1751 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1752 LIBS=
1753 AC_LINK_IFELSE([AC_LANG_SOURCE([
1754 typedef struct {
1755   char foo;
1756   long val;
1757 } Ehdr;
1758 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1759 long ehdr (void) { return __ehdr_start.val; }
1760 ])],
1761                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1762                   libc_cv_ehdr_start=broken
1763                 else
1764                   libc_cv_ehdr_start=yes
1765                 fi], [libc_cv_ehdr_start=no])
1766 CFLAGS="$old_CFLAGS"
1767 LDFLAGS="$old_LDFLAGS"
1768 LIBS="$old_LIBS"
1769 ])
1770 if test "$libc_cv_ehdr_start" = yes; then
1771   AC_DEFINE([HAVE_EHDR_START])
1772 elif test "$libc_cv_ehdr_start" = broken; then
1773   AC_MSG_WARN([linker is broken -- you should upgrade])
1774 fi
1775
1776 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1777                libc_cv_builtin_trap, [dnl
1778 libc_cv_builtin_trap=no
1779 AC_TRY_COMPILE([], [__builtin_trap ()], [
1780 libc_undefs=`$NM -u conftest.o |
1781   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1782     2>&AS_MESSAGE_LOG_FD` || {
1783   AC_MSG_ERROR([confusing output from $NM -u])
1784 }
1785 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1786 if test -z "$libc_undefs"; then
1787   libc_cv_builtin_trap=yes
1788 fi])])
1789 if test $libc_cv_builtin_trap = yes; then
1790   AC_DEFINE([HAVE_BUILTIN_TRAP])
1791 fi
1792
1793 dnl C++ feature tests.
1794 AC_LANG_PUSH([C++])
1795
1796 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1797                libc_cv_cxx_thread_local, [
1798 old_CXXFLAGS="$CXXFLAGS"
1799 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1800 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1801 #include <thread>
1802
1803 // Compiler support.
1804 struct S
1805 {
1806   S ();
1807   ~S ();
1808 };
1809 thread_local S s;
1810 S * get () { return &s; }
1811
1812 // libstdc++ support.
1813 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1814 #error __cxa_thread_atexit_impl not supported
1815 #endif
1816 ])],
1817                [libc_cv_cxx_thread_local=yes],
1818                [libc_cv_cxx_thread_local=no])
1819 CXXFLAGS="$old_CXXFLAGS"
1820 ])
1821 AC_SUBST(libc_cv_cxx_thread_local)
1822
1823 AC_LANG_POP([C++])
1824 dnl End of C++ feature tests.
1825
1826 ### End of automated tests.
1827 ### Now run sysdeps configure fragments.
1828
1829 # They also can set these variables.
1830 use_ldconfig=no
1831 ldd_rewrite_script=no
1832 libc_cv_sysconfdir=$sysconfdir
1833 libc_cv_localstatedir=$localstatedir
1834 libc_cv_gcc_unwind_find_fde=no
1835 libc_cv_idn=no
1836
1837 # Iterate over all the sysdep directories we will use, running their
1838 # configure fragments.
1839 for dir in $sysnames; do
1840   case $dir in
1841     /*) dest=$dir ;;
1842     *)  dest=$srcdir/$dir ;;
1843   esac
1844   if test -r $dest/configure; then
1845     AC_MSG_RESULT(running configure fragment for $dir)
1846     . $dest/configure
1847   fi
1848 done
1849
1850 if test x"$build_mathvec" = xnotset; then
1851   build_mathvec=no
1852 fi
1853 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1854
1855 AC_SUBST(libc_extra_cflags)
1856 AC_SUBST(libc_extra_cppflags)
1857
1858 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1859   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1860 fi
1861 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1862
1863 # A sysdeps configure fragment can reset this if IFUNC is not actually
1864 # usable even though the assembler knows how to generate the symbol type.
1865 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1866   AC_DEFINE(HAVE_IFUNC)
1867 fi
1868
1869 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1870   AC_DEFINE(HAVE_GCC_IFUNC)
1871 fi
1872
1873 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1874 # configure fragment can override the value to prevent this AC_DEFINE.
1875 AC_SUBST(use_nscd)
1876 if test "x$use_nscd" != xno; then
1877   AC_DEFINE([USE_NSCD])
1878 fi
1879 if test "x$build_nscd" = xdefault; then
1880   build_nscd=$use_nscd
1881 fi
1882
1883 AC_SUBST(libc_cv_slibdir)
1884 AC_SUBST(libc_cv_rtlddir)
1885 AC_SUBST(libc_cv_complocaledir)
1886 AC_SUBST(libc_cv_sysconfdir)
1887 AC_SUBST(libc_cv_localstatedir)
1888 AC_SUBST(libc_cv_rootsbindir)
1889
1890 if test x$use_ldconfig = xyes; then
1891   AC_DEFINE(USE_LDCONFIG)
1892 fi
1893 AC_SUBST(use_ldconfig)
1894 AC_SUBST(ldd_rewrite_script)
1895
1896 AC_SUBST(static)
1897 AC_SUBST(shared)
1898
1899 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1900 [libc_cv_pic_default=yes
1901 cat > conftest.c <<EOF
1902 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1903 # error PIC is default.
1904 #endif
1905 EOF
1906 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1907   libc_cv_pic_default=no
1908 fi
1909 rm -f conftest.*])
1910 AC_SUBST(libc_cv_pic_default)
1911
1912 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1913 [libc_cv_pie_default=yes
1914 cat > conftest.c <<EOF
1915 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1916 # error PIE is default.
1917 #endif
1918 EOF
1919 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1920   libc_cv_pie_default=no
1921 fi
1922 rm -f conftest.*])
1923 AC_SUBST(libc_cv_pie_default)
1924
1925 AC_SUBST(profile)
1926 AC_SUBST(static_nss)
1927
1928 AC_SUBST(DEFINES)
1929
1930 dnl See sysdeps/mach/configure.ac for this variable.
1931 AC_SUBST(mach_interface_list)
1932
1933 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1934 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1935 AC_SUBST(VERSION)
1936 AC_SUBST(RELEASE)
1937
1938 AC_CONFIG_FILES([config.make Makefile])
1939 AC_CONFIG_COMMANDS([default],[[
1940 case $CONFIG_FILES in *config.make*)
1941 echo "$config_vars" >> config.make;;
1942 esac
1943 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1944 AC_OUTPUT