sysdeps/s390/s390-64/setjmp-common.S

   1 /* setjmp for 64 bit S/390, ELF version.
   2    Copyright (C) 2001-2014 Free Software Foundation, Inc.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24
  25         /* We include the BSD entry points here as well but we make
  26            them weak.  */
  27 ENTRY (setjmp)
  28         .weak C_SYMBOL_NAME (setjmp)
  29         lghi   %r3,1                /* Second argument of one.  */
  30         j      0f                   /* Branch relativ to __sigsetjmp.  */
  31 END (setjmp)
  32
  33         /* Binary compatibility entry point.  */
  34 ENTRY(_setjmp)
  35         .weak  C_SYMBOL_NAME (_setjmp)
  36         slgr   %r3,%r3              /* Second argument of zero.  */
  37         j      0f                   /* Branch relativ to __sigsetjmp.  */
  38 END (_setjmp)
  39 libc_hidden_def (_setjmp)
  40
  41 ENTRY(__setjmp)
  42         slgr   %r3,%r3              /* Second argument of zero.  */
  43         j      0f                   /* Branch relativ to __sigsetjmp.  */
  44 END (__setjmp)
  45
  46 ENTRY(__sigsetjmp)
  47 0:
  48 #ifdef PTR_MANGLE
  49         stmg   %r6,%r13,0(%r2)      /* Store registers in jmp_buf.  */
  50         lgr    %r4,%r14
  51         lgr    %r5,%r15
  52         PTR_MANGLE (%r4, %r1)
  53         PTR_MANGLE2 (%r5, %r1)
  54         stmg   %r4,%r5,64(%r2)
  55 #else
  56         stmg   %r6,%r15,0(%r2)      /* Store registers in jmp_buf.  */
  57 #endif
  58 #ifndef __V1_JMPBUF
  59         lghi   %r4,0
  60         stg    %r4,144(%r2)         /* Set __flags to 0.  */
  61 #endif
  62         std    %f8,80(%r2)
  63         std    %f9,88(%r2)
  64         std    %f10,96(%r2)
  65         std    %f11,104(%r2)
  66         std    %f12,112(%r2)
  67         std    %f13,120(%r2)
  68         std    %f14,128(%r2)
  69         std    %f15,136(%r2)
  70 #if defined NOT_IN_libc && defined IS_IN_rtld
  71         /* In ld.so we never save the signal mask.  */
  72         lghi   %r2,0
  73         br     %r14
  74 #elif defined PIC
  75         jg     __sigjmp_save@PLT    /* Branch to PLT of __sigsetjmp.  */
  76 #else
  77         jg     __sigjmp_save
  78 #endif
  79 END (__sigsetjmp)