sysdeps/x86_64/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/x86_64.
   3
   4 dnl Check if asm supports AVX512.
   5 AC_CACHE_CHECK(for AVX512 support in assembler, libc_cv_asm_avx512, [dnl
   6 cat > conftest.s <<\EOF
   7         vmovdqu64 %zmm0, (%rsp)
   8         vandpd (%rax), %zmm6, %zmm1
   9 EOF
  10 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
  11   libc_cv_asm_avx512=yes
  12 else
  13   libc_cv_asm_avx512=no
  14 fi
  15 rm -f conftest*])
  16 if test $libc_cv_asm_avx512 = yes; then
  17   AC_DEFINE(HAVE_AVX512_ASM_SUPPORT)
  18 fi
  19
  20 dnl Check if -mavx512f works.
  21 AC_CACHE_CHECK(for AVX512 support, libc_cv_cc_avx512, [dnl
  22 LIBC_TRY_CC_OPTION([-mavx512f], [libc_cv_cc_avx512=$libc_cv_asm_avx512], [libc_cv_cc_avx512=no])
  23 ])
  24 if test $libc_cv_cc_avx512 = yes; then
  25   AC_DEFINE(HAVE_AVX512_SUPPORT)
  26 fi
  27 LIBC_CONFIG_VAR([config-cflags-avx512], [$libc_cv_cc_avx512])
  28
  29 dnl Check whether asm supports Intel MPX
  30 AC_CACHE_CHECK(for Intel MPX support, libc_cv_asm_mpx, [dnl
  31 cat > conftest.s <<\EOF
  32         bndmov %bnd0,(%rsp)
  33 EOF
  34 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
  35   libc_cv_asm_mpx=yes
  36 else
  37   libc_cv_asm_mpx=no
  38 fi
  39 rm -f conftest*])
  40 if test $libc_cv_asm_mpx = yes; then
  41   AC_DEFINE(HAVE_MPX_SUPPORT)
  42 fi
  43
  44 if test x"$build_mathvec" = xnotset; then
  45   build_mathvec=yes
  46 fi
  47
  48 dnl It is always possible to access static and hidden symbols in an
  49 dnl position independent way.
  50 AC_DEFINE(PI_STATIC_AND_HIDDEN)
  51 # work around problem with autoconf and empty lines at the end of files