configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([binutils],
 131             AC_HELP_STRING([--with-binutils=PATH],
 132                            [specify location of binutils (as and ld)]),
 133             [path_binutils=$withval],
 134             [path_binutils=''])
 135 AC_ARG_WITH([selinux],
 136             AC_HELP_STRING([--with-selinux],
 137                            [if building with SELinux support]),
 138             [with_selinux=$withval],
 139             [with_selinux=auto])
 140
 141 AC_ARG_WITH([headers],
 142             AC_HELP_STRING([--with-headers=PATH],
 143                            [location of system headers to use
 144                             (for example /usr/src/linux/include)
 145                             @<:@default=compiler default@:>@]),
 146             [sysheaders=$withval],
 147             [sysheaders=''])
 148 AC_SUBST(sysheaders)
 149
 150 AC_SUBST(use_default_link)
 151 AC_ARG_WITH([default-link],
 152             AC_HELP_STRING([--with-default-link],
 153                            [do not use explicit linker scripts]),
 154             [use_default_link=$withval],
 155             [use_default_link=default])
 156
 157 AC_ARG_ENABLE([sanity-checks],
 158               AC_HELP_STRING([--disable-sanity-checks],
 159                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 160               [enable_sanity=$enableval],
 161               [enable_sanity=yes])
 162
 163 AC_ARG_ENABLE([shared],
 164               AC_HELP_STRING([--enable-shared],
 165                              [build shared library @<:@default=yes if GNU ld@:>@]),
 166               [shared=$enableval],
 167               [shared=yes])
 168 AC_ARG_ENABLE([profile],
 169               AC_HELP_STRING([--enable-profile],
 170                              [build profiled library @<:@default=no@:>@]),
 171               [profile=$enableval],
 172               [profile=no])
 173 AC_ARG_ENABLE([static-pie],
 174               AC_HELP_STRING([--enable-static-pie],
 175                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 176               [static_pie=$enableval],
 177               [static_pie=no])
 178 AC_ARG_ENABLE([timezone-tools],
 179               AC_HELP_STRING([--disable-timezone-tools],
 180                              [do not install timezone tools @<:@default=install@:>@]),
 181               [enable_timezone_tools=$enableval],
 182               [enable_timezone_tools=yes])
 183 AC_SUBST(enable_timezone_tools)
 184
 185 AC_ARG_ENABLE([hardcoded-path-in-tests],
 186               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 187                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 188               [hardcoded_path_in_tests=$enableval],
 189               [hardcoded_path_in_tests=no])
 190 AC_SUBST(hardcoded_path_in_tests)
 191
 192 AC_ARG_ENABLE([stackguard-randomization],
 193               AC_HELP_STRING([--enable-stackguard-randomization],
 194                              [initialize __stack_chk_guard canary with a random number at program start]),
 195               [enable_stackguard_randomize=$enableval],
 196               [enable_stackguard_randomize=no])
 197 if test "$enable_stackguard_randomize" = yes; then
 198   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 199 fi
 200
 201 AC_ARG_ENABLE([hidden-plt],
 202               AC_HELP_STRING([--disable-hidden-plt],
 203                              [do not hide internal function calls to avoid PLT]),
 204               [hidden=$enableval],
 205               [hidden=yes])
 206 if test "x$hidden" = xno; then
 207   AC_DEFINE(NO_HIDDEN)
 208 fi
 209
 210 AC_ARG_ENABLE([bind-now],
 211               AC_HELP_STRING([--enable-bind-now],
 212                              [disable lazy relocations in DSOs]),
 213               [bindnow=$enableval],
 214               [bindnow=no])
 215 AC_SUBST(bindnow)
 216 if test "x$bindnow" = xyes; then
 217   AC_DEFINE(BIND_NOW)
 218 fi
 219
 220 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 221 dnl -fstack-protector-strong.
 222 AC_ARG_ENABLE([stack-protector],
 223               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 224                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 225               [enable_stack_protector=$enableval],
 226               [enable_stack_protector=no])
 227 case "$enable_stack_protector" in
 228 all|yes|no|strong) ;;
 229 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 230 esac
 231
 232 dnl On some platforms we cannot use dynamic loading.  We must provide
 233 dnl static NSS modules.
 234 AC_ARG_ENABLE([static-nss],
 235               AC_HELP_STRING([--enable-static-nss],
 236                              [build static NSS modules @<:@default=no@:>@]),
 237               [static_nss=$enableval],
 238               [static_nss=no])
 239 dnl Enable static NSS also if we build no shared objects.
 240 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 241   static_nss=yes
 242   AC_DEFINE(DO_STATIC_NSS)
 243 fi
 244
 245 AC_ARG_ENABLE([force-install],
 246               AC_HELP_STRING([--disable-force-install],
 247                              [don't force installation of files from this package, even if they are older than the installed files]),
 248               [force_install=$enableval],
 249               [force_install=yes])
 250 AC_SUBST(force_install)
 251
 252 AC_ARG_ENABLE([maintainer-mode],
 253               AC_HELP_STRING([--enable-maintainer-mode],
 254                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 255               [maintainer=$enableval],
 256               [maintainer=no])
 257
 258 dnl On some platforms we allow dropping compatibility with all kernel
 259 dnl versions.
 260 AC_ARG_ENABLE([kernel],
 261               AC_HELP_STRING([--enable-kernel=VERSION],
 262                              [compile for compatibility with kernel not older than VERSION]),
 263               [minimum_kernel=$enableval],
 264               [])
 265 dnl Prevent unreasonable values.
 266 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 267   # Better nothing than this.
 268   minimum_kernel=""
 269 else
 270   if test "$minimum_kernel" = current; then
 271     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 272   fi
 273 fi
 274
 275 dnl For the development we sometimes want gcc to issue even more warnings.
 276 dnl This is not the default since many of the extra warnings are not
 277 dnl appropriate.
 278 AC_ARG_ENABLE([all-warnings],
 279               AC_HELP_STRING([--enable-all-warnings],
 280                              [enable all useful warnings gcc can issue]),
 281               [all_warnings=$enableval],
 282               [])
 283 AC_SUBST(all_warnings)
 284
 285 AC_ARG_ENABLE([werror],
 286               AC_HELP_STRING([--disable-werror],
 287                              [do not build with -Werror]),
 288               [enable_werror=$enableval],
 289               [enable_werror=yes])
 290 AC_SUBST(enable_werror)
 291
 292 AC_ARG_ENABLE([multi-arch],
 293               AC_HELP_STRING([--enable-multi-arch],
 294                              [enable single DSO with optimizations for multiple architectures]),
 295               [multi_arch=$enableval],
 296               [multi_arch=default])
 297
 298 AC_ARG_ENABLE([experimental-malloc],
 299               AC_HELP_STRING([--disable-experimental-malloc],
 300                              [disable experimental malloc features]),
 301               [experimental_malloc=$enableval],
 302               [experimental_malloc=yes])
 303 AC_SUBST(experimental_malloc)
 304
 305 AC_ARG_ENABLE([nss-crypt],
 306               AC_HELP_STRING([--enable-nss-crypt],
 307                              [enable libcrypt to use nss]),
 308               [nss_crypt=$enableval],
 309               [nss_crypt=no])
 310 if test x$nss_crypt = xyes; then
 311   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 312   if test $? -ne 0; then
 313     AC_MSG_ERROR([cannot find include directory with nss-config])
 314   fi
 315   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 316   if test $? -ne 0; then
 317     AC_MSG_ERROR([cannot find include directory with nspr-config])
 318   fi
 319   old_CFLAGS="$CFLAGS"
 320   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 321   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 322 #include <hasht.h>
 323 #include <nsslowhash.h>
 324 void f (void) { NSSLOW_Init (); }])],
 325              libc_cv_nss_crypt=yes,
 326              AC_MSG_ERROR([
 327 cannot find NSS headers with lowlevel hash function interfaces]))
 328   old_LIBS="$LIBS"
 329   old_LDFLAGS="$LDFLAGS"
 330   LIBS="$LIBS -lfreebl3"
 331   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 332 #include <hasht.h>
 333 #include <nsslowhash.h>],
 334                                   [NSSLOW_Init();])],
 335                  libc_cv_nss_crypt=yes,
 336                  AC_MSG_ERROR([
 337 cannot link program using lowlevel NSS hash functions]))
 338   # Check to see if there is a static NSS cryptographic library.
 339   # If there isn't then we can't link anything with libcrypt.a,
 340   # and that might mean disabling some static tests.
 341   LDFLAGS="$LDFLAGS -static"
 342   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 343 #include <hasht.h>
 344 #include <nsslowhash.h>],
 345                                   [NSSLOW_Init();])],
 346                  libc_cv_static_nss_crypt=yes,
 347                  libc_cv_static_nss_crypt=no)
 348   LDFLAGS="$old_LDFLAGS"
 349   CFLAGS="$old_CFLAGS"
 350   LIBS="$old_LIBS"
 351 else
 352   libc_cv_nss_crypt=no
 353   libc_cv_static_nss_crypt=no
 354 fi
 355 AC_SUBST(libc_cv_nss_crypt)
 356 AC_SUBST(libc_cv_static_nss_crypt)
 357
 358
 359 AC_ARG_ENABLE([obsolete-rpc],
 360               AC_HELP_STRING([--enable-obsolete-rpc],
 361                              [build and install the obsolete RPC code for link-time usage]),
 362               [link_obsolete_rpc=$enableval],
 363               [link_obsolete_rpc=no])
 364 AC_SUBST(link_obsolete_rpc)
 365
 366 if test "$link_obsolete_rpc" = yes; then
 367   AC_DEFINE(LINK_OBSOLETE_RPC)
 368 fi
 369
 370 AC_ARG_ENABLE([obsolete-nsl],
 371               AC_HELP_STRING([--enable-obsolete-nsl],
 372                              [build and install the obsolete libnsl library and depending NSS modules]),
 373               [build_obsolete_nsl=$enableval],
 374               [build_obsolete_nsl=no])
 375 AC_SUBST(build_obsolete_nsl)
 376
 377 if test "$build_obsolete_nsl" = yes; then
 378   AC_DEFINE(LINK_OBSOLETE_NSL)
 379 fi
 380
 381 AC_ARG_ENABLE([systemtap],
 382               [AS_HELP_STRING([--enable-systemtap],
 383                [enable systemtap static probe points @<:@default=no@:>@])],
 384               [systemtap=$enableval],
 385               [systemtap=no])
 386 if test "x$systemtap" != xno; then
 387   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 388   old_CFLAGS="$CFLAGS"
 389   CFLAGS="-std=gnu11 $CFLAGS"
 390   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 391 void foo (int i, void *p)
 392 {
 393   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 394        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 395 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 396   CFLAGS="$old_CFLAGS"])
 397   if test $libc_cv_sdt = yes; then
 398     AC_DEFINE([USE_STAP_PROBE])
 399   elif test "x$systemtap" != xauto; then
 400     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 401   fi
 402 fi
 403
 404 AC_ARG_ENABLE([build-nscd],
 405               [AS_HELP_STRING([--disable-build-nscd],
 406                [disable building and installing the nscd daemon])],
 407               [build_nscd=$enableval],
 408               [build_nscd=default])
 409 AC_SUBST(build_nscd)
 410
 411 # Note the use of $use_nscd is near the bottom of the file.
 412 AC_ARG_ENABLE([nscd],
 413               [AS_HELP_STRING([--disable-nscd],
 414                [library functions will not contact the nscd daemon])],
 415               [use_nscd=$enableval],
 416               [use_nscd=yes])
 417
 418 AC_ARG_ENABLE([pt_chown],
 419               [AS_HELP_STRING([--enable-pt_chown],
 420                [Enable building and installing pt_chown])],
 421               [build_pt_chown=$enableval],
 422               [build_pt_chown=no])
 423 AC_SUBST(build_pt_chown)
 424 if test "$build_pt_chown" = yes; then
 425   AC_DEFINE(HAVE_PT_CHOWN)
 426 fi
 427
 428 AC_ARG_ENABLE([tunables],
 429               [AS_HELP_STRING([--enable-tunables],
 430                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 431               [have_tunables=$enableval],
 432               [have_tunables=yes])
 433 AC_SUBST(have_tunables)
 434 if test "$have_tunables" = yes; then
 435   AC_DEFINE(HAVE_TUNABLES)
 436 fi
 437
 438 # The abi-tags file uses a fairly simplistic model for name recognition that
 439 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 440 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 441 # This doesn't get used much beyond that, so it's fairly safe.
 442 case "$host_os" in
 443 linux*)
 444   ;;
 445 gnu*)
 446   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 447   ;;
 448 esac
 449
 450 AC_ARG_ENABLE([mathvec],
 451               [AS_HELP_STRING([--enable-mathvec],
 452               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 453               [build_mathvec=$enableval],
 454               [build_mathvec=notset])
 455
 456 # We keep the original values in `$config_*' and never modify them, so we
 457 # can write them unchanged into config.make.  Everything else uses
 458 # $machine, $vendor, and $os, and changes them whenever convenient.
 459 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 460
 461 # Don't allow vendor == "unknown"
 462 test "$config_vendor" = unknown && config_vendor=
 463 config_os="`echo $config_os | sed 's/^unknown-//'`"
 464
 465 # Some configurations imply other options.
 466 elf=yes
 467
 468 # The configure fragment of a port can modify these to supplement
 469 # or override the table in the case statement below.  No fragment should
 470 # ever change the config_* variables, however.
 471 machine=$config_machine
 472 vendor=$config_vendor
 473 os=$config_os
 474 base_os=''
 475
 476 submachine=
 477 AC_ARG_WITH([cpu],
 478             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 479             [dnl
 480   case "$withval" in
 481   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 482   no) ;;
 483   *) submachine="$withval" ;;
 484   esac
 485 ])
 486
 487 # An preconfigure script can set this when it wants to disable the sanity
 488 # check below.
 489 libc_config_ok=no
 490
 491 # A preconfigure script for a system that may or may not use fpu
 492 # sysdeps directories sets this to a preprocessor conditional for
 493 # whether to use such directories.
 494 with_fp_cond=1
 495
 496 dnl Let sysdeps/*/preconfigure act here.
 497 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 498
 499
 500 ###
 501 ### By using the undocumented --enable-hacker-mode option for configure
 502 ### one can skip this test to make the configuration not fail for unsupported
 503 ### platforms.
 504 ###
 505 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 506   case "$machine-$host_os" in
 507   *-linux* | *-gnu*)
 508     ;;
 509   *)
 510     AC_MSG_ERROR([
 511 *** The GNU C library is currently unavailable for this platform.
 512 *** If you are interested in seeing glibc on this platform visit
 513 *** the "How to submit a new port" in the wiki:
 514 ***   https://sourceware.org/glibc/wiki/#Development
 515 *** and join the community!])
 516     ;;
 517   esac
 518 fi
 519
 520 # Set base_machine if not set by a preconfigure fragment.
 521 test -n "$base_machine" || base_machine=$machine
 522 AC_SUBST(base_machine)
 523
 524 # Determine whether to use fpu or nofpu sysdeps directories.
 525 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 526                libc_cv_with_fp, [dnl
 527 cat > conftest.c <<EOF
 528 #if $with_fp_cond
 529 int dummy;
 530 #else
 531 # error "no hardware floating point"
 532 #endif
 533 EOF
 534 libc_cv_with_fp=no
 535 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 536    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 537   libc_cv_with_fp=yes
 538 fi
 539 rm -f conftest*])
 540 AC_SUBST(libc_cv_with_fp)
 541
 542 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 543 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 544                    [libc_cv_ssp=yes],
 545                    [libc_cv_ssp=no])
 546 ])
 547
 548 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 549 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 550                    [libc_cv_ssp_strong=yes],
 551                    [libc_cv_ssp_strong=no])
 552 ])
 553
 554 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 555 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 556                    [libc_cv_ssp_all=yes],
 557                    [libc_cv_ssp_all=no])
 558 ])
 559
 560 stack_protector=
 561 no_stack_protector=
 562 if test "$libc_cv_ssp" = yes; then
 563   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 564   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 565 fi
 566
 567 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 568   stack_protector="-fstack-protector"
 569   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 570 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 571   stack_protector="-fstack-protector-all"
 572   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 573 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 574   stack_protector="-fstack-protector-strong"
 575   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 576 else
 577   stack_protector="-fno-stack-protector"
 578   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 579 fi
 580 AC_SUBST(libc_cv_ssp)
 581 AC_SUBST(stack_protector)
 582 AC_SUBST(no_stack_protector)
 583
 584 if test -n "$stack_protector"; then
 585   dnl Don't run configure tests with stack-protection on, to avoid problems with
 586   dnl bootstrapping.
 587   no_ssp=-fno-stack-protector
 588 else
 589   no_ssp=
 590
 591   if test "$enable_stack_protector" != no; then
 592     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 593   fi
 594 fi
 595
 596 # For the multi-arch option we need support in the assembler & linker.
 597 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 598                libc_cv_ld_gnu_indirect_function, [dnl
 599 cat > conftest.S <<EOF
 600 .type foo,%gnu_indirect_function
 601 foo:
 602 .globl _start
 603 _start:
 604 .globl __start
 605 __start:
 606 .data
 607 #ifdef _LP64
 608 .quad foo
 609 #else
 610 .long foo
 611 #endif
 612 EOF
 613 libc_cv_ld_gnu_indirect_function=no
 614 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 615             -nostartfiles -nostdlib $no_ssp \
 616             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 617   # Do a link to see if the backend supports IFUNC relocs.
 618   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 619   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 620     libc_cv_ld_gnu_indirect_function=yes
 621   }
 622 fi
 623 rm -f conftest*])
 624
 625 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 626 AC_CACHE_CHECK([for gcc attribute ifunc support],
 627                libc_cv_gcc_indirect_function, [dnl
 628 cat > conftest.c <<EOF
 629 extern int func (int);
 630 int used_func (int a)
 631 {
 632   return a;
 633 }
 634 static void *resolver ()
 635 {
 636   return &used_func;
 637 }
 638 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 639 EOF
 640 libc_cv_gcc_indirect_function=no
 641 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 642    2>&AS_MESSAGE_LOG_FD ; then
 643   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 644     libc_cv_gcc_indirect_function=yes
 645   fi
 646 fi
 647 rm -f conftest*])
 648
 649 # Check if gcc warns about alias for function with incompatible types.
 650 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 651                libc_cv_gcc_incompatible_alias, [dnl
 652 cat > conftest.c <<EOF
 653 int __redirect_foo (const void *s, int c);
 654
 655 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 656 __typeof (__redirect_foo) *foo_impl (void)
 657 {
 658   return 0;
 659 }
 660
 661 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 662 EOF
 663 libc_cv_gcc_incompatible_alias=yes
 664 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 665   libc_cv_gcc_incompatible_alias=no
 666 fi
 667 rm -f conftest*])
 668
 669 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 670   if test x"$multi_arch" = xyes; then
 671     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 672   else
 673     multi_arch=no
 674   fi
 675 fi
 676 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 677   # GCC 8+ emits a warning for alias with incompatible types and it might
 678   # fail to build ifunc resolvers aliases to either weak or internal
 679   # symbols.  Disables multiarch build in this case.
 680   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 681     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 682     if test x"$multi_arch" = xyes; then
 683       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 684     fi
 685     AC_MSG_WARN([Multi-arch is disabled.])
 686     multi_arch=no
 687   elif test x"$multi_arch" = xyes; then
 688     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 689 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 690   fi
 691 fi
 692 multi_arch_d=
 693 if test x"$multi_arch" != xno; then
 694   multi_arch_d=/multiarch
 695 fi
 696
 697 # Compute the list of sysdep directories for this configuration.
 698 # This can take a while to compute.
 699 sysdep_dir=$srcdir/sysdeps
 700 AC_MSG_CHECKING(sysdep dirs)
 701 dnl We need to use [ and ] for other purposes for a while now.
 702 changequote(,)dnl
 703 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 704 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 705
 706 test "x$base_os" != x || case "$os" in
 707 gnu*)
 708   base_os=mach/hurd ;;
 709 linux*)
 710   base_os=unix/sysv ;;
 711 esac
 712
 713 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 714 tail=$os
 715 ostry=$os
 716 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 717   ostry="$ostry /$o"
 718   tail=$o
 719 done
 720 o=`echo $tail | sed 's/[0-9]*$//'`
 721 if test $o != $tail; then
 722   ostry="$ostry /$o"
 723 fi
 724 # For linux-gnu, try linux-gnu, then linux.
 725 o=`echo $tail | sed 's/-.*$//'`
 726 if test $o != $tail; then
 727   ostry="$ostry /$o"
 728 fi
 729
 730 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 731 base=
 732 tail=$base_os
 733 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 734   set $b
 735   base="$base /$1"
 736   tail="$2"
 737 done
 738
 739 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 740 mach=
 741 tail=$machine${submachine:+/$submachine}
 742 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 743   set $m
 744   # Prepend the machine's FPU directory unless --without-fp.
 745   if test "$libc_cv_with_fp" = yes; then
 746     maybe_fpu=/fpu
 747   else
 748     maybe_fpu=/nofpu
 749   fi
 750   # For each machine term, try it with and then without /multiarch.
 751   for try_fpu in $maybe_fpu ''; do
 752     for try_multi in $multi_arch_d ''; do
 753       mach="$mach /$1$try_fpu$try_multi"
 754     done
 755   done
 756   tail="$2"
 757 done
 758
 759 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 760 changequote([,])dnl
 761
 762 # Find what sysdep directories exist.
 763 sysnames=
 764 for b in $base ''; do
 765   for m0 in $mach ''; do
 766     for v in /$vendor ''; do
 767       test "$v" = / && continue
 768       for o in /$ostry ''; do
 769         test "$o" = / && continue
 770         for m in $mach ''; do
 771           try_suffix="$m0$b$v$o$m"
 772           if test -n "$try_suffix"; then
 773             try_srcdir="${srcdir}/"
 774             try="sysdeps$try_suffix"
 775             test -n "$enable_debug_configure" &&
 776             echo "$0 [DEBUG]: try $try" >&2
 777             if test -d "$try_srcdir$try"; then
 778               sysnames="$sysnames $try"
 779               { test -n "$o" || test -n "$b"; } && os_used=t
 780               { test -n "$m" || test -n "$m0"; } && machine_used=t
 781               case x${m0:-$m} in
 782               x*/$submachine) submachine_used=t ;;
 783               esac
 784             fi
 785           fi
 786         done
 787       done
 788     done
 789   done
 790 done
 791
 792 # If the assembler supports gnu_indirect_function symbol type and the
 793 # architecture supports multi-arch, we enable multi-arch by default.
 794 case $sysnames in
 795 *"$multi_arch_d"*)
 796   ;;
 797 *)
 798   test x"$multi_arch" = xdefault && multi_arch=no
 799   ;;
 800 esac
 801 if test x"$multi_arch" != xno; then
 802   AC_DEFINE(USE_MULTIARCH)
 803 fi
 804 AC_SUBST(multi_arch)
 805
 806 if test -z "$os_used" && test "$os" != none; then
 807   AC_MSG_ERROR(Operating system $os is not supported.)
 808 fi
 809 if test -z "$machine_used" && test "$machine" != none; then
 810   AC_MSG_ERROR(The $machine is not supported.)
 811 fi
 812 if test -z "$submachine_used" && test -n "$submachine"; then
 813   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 814 fi
 815 AC_SUBST(submachine)
 816
 817 # We have now validated the configuration.
 818
 819 # Expand the list of system names into a full list of directories
 820 # from each element's parent name and Implies file (if present).
 821 set $sysnames
 822 names=
 823 while test $# -gt 0; do
 824   name=$1
 825   shift
 826
 827   case " $names " in *" $name "*)
 828     # Already in the list.
 829     continue
 830   esac
 831
 832   # Report each name as we discover it, so there is no long pause in output.
 833   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 834
 835   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 836
 837   case $name in
 838     /*) xsrcdir= ;;
 839     *)  xsrcdir=$srcdir/ ;;
 840   esac
 841   test -n "$enable_debug_configure" &&
 842   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 843
 844   for implies_file in Implies Implies-before Implies-after; do
 845     implies_type=`echo $implies_file | sed s/-/_/`
 846     eval ${implies_type}=
 847     if test -f $xsrcdir$name/$implies_file; then
 848       # Collect more names from the `Implies' file (removing comments).
 849       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 850       for x in $implied_candidate; do
 851         found=no
 852         if test -d $xsrcdir$name_base/$x; then
 853           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 854           found=yes
 855         fi
 856         try="sysdeps/$x"
 857         try_srcdir=$srcdir/
 858         test -n "$enable_debug_configure" &&
 859          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 860         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 861         then
 862           eval "${implies_type}=\"\$${implies_type} \$try\""
 863           found=yes
 864         fi
 865         if test $found = no; then
 866           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 867         fi
 868       done
 869     fi
 870   done
 871
 872   # Add NAME to the list of names.
 873   names="$names $name"
 874
 875   # Find the parent of NAME, using the empty string if it has none.
 876 changequote(,)dnl
 877   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 878 changequote([,])dnl
 879
 880   test -n "$enable_debug_configure" &&
 881     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 882 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 883
 884   # Add the names implied by NAME, and NAME's parent (if it has one), to
 885   # the list of names to be processed (the argument list).  We prepend the
 886   # implied names to the list and append the parent.  We want implied
 887   # directories to come before further directories inferred from the
 888   # configuration components; this ensures that for sysv4, unix/common
 889   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 890   # after sysv4).
 891   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 892   test -n "$sysnames" && set $sysnames
 893 done
 894
 895 # Add the default directories.
 896 default_sysnames="sysdeps/generic"
 897 sysnames="$names $default_sysnames"
 898 AC_SUBST(sysnames)
 899 # The other names were emitted during the scan.
 900 AC_MSG_RESULT($default_sysnames)
 901
 902
 903 ### Locate tools.
 904
 905 AC_PROG_INSTALL
 906 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 907   # The makefiles need to use a different form to find it in $srcdir.
 908   INSTALL='\$(..)./scripts/install-sh -c'
 909 fi
 910 AC_PROG_LN_S
 911
 912 LIBC_PROG_BINUTILS
 913
 914 # Accept binutils 2.25 or newer.
 915 AC_CHECK_PROG_VER(AS, $AS, --version,
 916                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 917                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 918                   AS=: critic_missing="$critic_missing as")
 919
 920 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 921   # Accept gold 1.14 or higher
 922   AC_CHECK_PROG_VER(LD, $LD, --version,
 923                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 924                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 925                     LD=: critic_missing="$critic_missing GNU gold")
 926 else
 927   AC_CHECK_PROG_VER(LD, $LD, --version,
 928                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 929                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 930                     LD=: critic_missing="$critic_missing GNU ld")
 931 fi
 932
 933 # These programs are version sensitive.
 934 AC_CHECK_TOOL_PREFIX
 935 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 936   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 937   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 938
 939 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 940   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 941   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 942   MSGFMT=: aux_missing="$aux_missing msgfmt")
 943 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 944   [GNU texinfo.* \([0-9][0-9.]*\)],
 945   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 946   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 947 AC_CHECK_PROG_VER(SED, sed, --version,
 948   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 949   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 950   SED=: aux_missing="$aux_missing sed")
 951 AC_CHECK_PROG_VER(AWK, gawk, --version,
 952   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 953   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 954 AC_CHECK_PROG_VER(BISON, bison, --version,
 955   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
 956   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
 957
 958 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 959 AC_TRY_COMPILE([], [
 960 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 961 #error insufficient compiler
 962 #endif],
 963                [libc_cv_compiler_ok=yes],
 964                [libc_cv_compiler_ok=no])])
 965 AS_IF([test $libc_cv_compiler_ok != yes],
 966       [critic_missing="$critic_missing compiler"])
 967
 968 AC_CHECK_TOOL(NM, nm, false)
 969
 970 if test "x$maintainer" = "xyes"; then
 971   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 972   case "x$AUTOCONF" in
 973   xno|x|x:) AUTOCONF=no ;;
 974   *)
 975     AC_CACHE_CHECK(dnl
 976   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 977     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 978       libc_cv_autoconf_works=yes
 979     else
 980       libc_cv_autoconf_works=no
 981     fi])
 982     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 983     ;;
 984   esac
 985   if test "x$AUTOCONF" = xno; then
 986     aux_missing="$aux_missing autoconf"
 987   fi
 988 else
 989   AUTOCONF=no
 990 fi
 991
 992 # Check for python3 if available, or else python.
 993 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
 994 case "x$PYTHON_PROG" in
 995 xno|x|x:) PYTHON_PROG=no ;;
 996 *) ;;
 997 esac
 998
 999 if test "x$PYTHON_PROG" = xno; then
1000   aux_missing="$aux_missing python"
1001 else
1002   PYTHON="$PYTHON_PROG -B"
1003   AC_SUBST(PYTHON)
1004 fi
1005
1006 test -n "$critic_missing" && AC_MSG_ERROR([
1007 *** These critical programs are missing or too old:$critic_missing
1008 *** Check the INSTALL file for required versions.])
1009
1010 test -n "$aux_missing" && AC_MSG_WARN([
1011 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1012 *** some features or tests will be disabled.
1013 *** Check the INSTALL file for required versions.])
1014
1015 # if using special system headers, find out the compiler's sekrit
1016 # header directory and add that to the list.  NOTE: Only does the right
1017 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1018 if test -n "$sysheaders"; then
1019   SYSINCLUDES=-nostdinc
1020   for d in include include-fixed; do
1021     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1022     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1023   done
1024   SYSINCLUDES="$SYSINCLUDES \
1025 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1026   if test -n "$CXX"; then
1027     CXX_SYSINCLUDES=
1028     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1029     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1030       test "x$cxxheaders" != x &&
1031       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1032     done
1033   fi
1034 fi
1035 AC_SUBST(SYSINCLUDES)
1036 AC_SUBST(CXX_SYSINCLUDES)
1037
1038 # Obtain some C++ header file paths.  This is used to make a local
1039 # copy of those headers in Makerules.
1040 if test -n "$CXX"; then
1041   find_cxx_header () {
1042     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1043          | sed -n "\,$1:,{s/:\$//;p}"
1044   }
1045   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1046   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1047   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1048 fi
1049 AC_SUBST(CXX_CSTDLIB_HEADER)
1050 AC_SUBST(CXX_CMATH_HEADER)
1051 AC_SUBST(CXX_BITS_STD_ABS_H)
1052
1053 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1054 # since this would lead to problems installing/building glibc.
1055 # LD_LIBRARY_PATH contains the current directory if one of the following
1056 # is true:
1057 # - one of the terminals (":" and ";") is the first or last sign
1058 # - two terminals occur directly after each other
1059 # - the path contains an element with a dot in it
1060 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1061 changequote(,)dnl
1062 case ${LD_LIBRARY_PATH} in
1063   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1064     ld_library_path_setting="contains current directory"
1065     ;;
1066   *)
1067     ld_library_path_setting="ok"
1068     ;;
1069 esac
1070 changequote([,])dnl
1071 AC_MSG_RESULT($ld_library_path_setting)
1072 if test "$ld_library_path_setting" != "ok"; then
1073 AC_MSG_ERROR([
1074 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1075 *** building glibc. Please change the environment variable
1076 *** and run configure again.])
1077 fi
1078
1079 AC_PATH_PROG(BASH_SHELL, bash, no)
1080
1081 AC_PATH_PROG(PERL, perl, no)
1082 if test "$PERL" != no &&
1083    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1084   PERL=no
1085 fi
1086 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1087              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1088
1089 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1090 cat > conftest.s <<EOF
1091 .text
1092 foo:
1093 .set glibc_conftest_frobozz,foo
1094 .globl glibc_conftest_frobozz
1095 EOF
1096 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1097 # (but it doesn't work), so we must do a linking check to be sure.
1098 cat > conftest1.c <<\EOF
1099 extern int glibc_conftest_frobozz;
1100 void _start() { glibc_conftest_frobozz = 1; }
1101 EOF
1102 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1103             -nostartfiles -nostdlib $no_ssp \
1104             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1105   libc_cv_asm_set_directive=yes
1106 else
1107   libc_cv_asm_set_directive=no
1108 fi
1109 rm -f conftest*])
1110 if test $libc_cv_asm_set_directive = yes; then
1111   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1112 fi
1113
1114 AC_CACHE_CHECK(linker support for protected data symbol,
1115                libc_cv_protected_data,
1116                [cat > conftest.c <<EOF
1117                 int bar __attribute__ ((visibility ("protected"))) = 1;
1118 EOF
1119                 libc_cv_protected_data=no
1120                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1121                   cat > conftest.c <<EOF
1122                   extern int bar;
1123                   int main (void) { return bar; }
1124 EOF
1125                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1126                     libc_cv_protected_data=yes
1127                   fi
1128                 fi
1129                 rm -f conftest.*
1130                ])
1131 AC_SUBST(libc_cv_protected_data)
1132
1133 AC_CACHE_CHECK(linker support for INSERT in linker script,
1134                libc_cv_insert,
1135                [cat > conftest.c <<EOF
1136                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1137                 int test (void) { return bar; }
1138 EOF
1139                 cat > conftest.t <<EOF
1140                 SECTIONS
1141                 {
1142                   .bar : { *(.bar) }
1143                 }
1144                 INSERT AFTER .rela.dyn;
1145 EOF
1146                 libc_cv_insert=no
1147                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1148                   libc_cv_insert=yes
1149                 fi
1150                 rm -f conftest.*
1151                ])
1152 AC_SUBST(libc_cv_insert)
1153
1154 AC_CACHE_CHECK(for broken __attribute__((alias())),
1155                libc_cv_broken_alias_attribute,
1156                [cat > conftest.c <<EOF
1157                extern int foo (int x) __asm ("xyzzy");
1158                int bar (int x) { return x; }
1159                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1160                extern int dfoo;
1161                extern __typeof (dfoo) dfoo __asm ("abccb");
1162                int dfoo = 1;
1163 EOF
1164                libc_cv_broken_alias_attribute=yes
1165                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1166                  if grep 'xyzzy' conftest.s >/dev/null &&
1167                     grep 'abccb' conftest.s >/dev/null; then
1168                    libc_cv_broken_alias_attribute=no
1169                  fi
1170                fi
1171                rm -f conftest.c conftest.s
1172                ])
1173 if test $libc_cv_broken_alias_attribute = yes; then
1174   AC_MSG_ERROR(working alias attribute support required)
1175 fi
1176
1177 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1178                libc_cv_have_sdata_section,
1179                [echo "int i;" > conftest.c
1180                 libc_cv_have_sdata_section=no
1181                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1182                    | grep '\.sdata' >/dev/null; then
1183                   libc_cv_have_sdata_section=yes
1184                 fi
1185                 rm -f conftest.c conftest.so
1186                ])
1187 if test $libc_cv_have_sdata_section = yes; then
1188   AC_DEFINE(HAVE_SDATA_SECTION)
1189 fi
1190
1191 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1192                libc_cv_ctors_header, [dnl
1193   libc_cv_ctors_header=yes
1194   LIBC_TRY_LINK_STATIC([
1195 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1196 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1197 ],
1198               [dnl
1199       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1200         { gsub(/\@<:@ */, "@<:@") }
1201         $2 == ".ctors" || $2 == ".dtors" {
1202           size = strtonum("0x" $6)
1203           align = strtonum("0x" $NF)
1204           seen@<:@$2@:>@ = 1
1205           stub@<:@$2@:>@ = size == align * 2
1206         }
1207         END {
1208           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1209           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1210           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1211         }
1212       '], [libc_cv_ctors_header=no])
1213     ], [dnl
1214       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1215     ])
1216 ])
1217 if test $libc_cv_ctors_header = no; then
1218   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1219 fi
1220
1221 AC_CACHE_CHECK(for libunwind-support in compiler,
1222                libc_cv_cc_with_libunwind, [
1223   cat > conftest.c <<EOF
1224 int main (void) { return 0; }
1225 EOF
1226   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1227      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1228     libc_cv_cc_with_libunwind=yes
1229   else
1230     libc_cv_cc_with_libunwind=no
1231   fi
1232   rm -f conftest*])
1233 AC_SUBST(libc_cv_cc_with_libunwind)
1234 if test $libc_cv_cc_with_libunwind = yes; then
1235   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1236 fi
1237
1238 ASFLAGS_config=
1239 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1240                libc_cv_as_noexecstack, [dnl
1241 cat > conftest.c <<EOF
1242 void foo (void) { }
1243 EOF
1244 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1245                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1246    && grep .note.GNU-stack conftest.s >/dev/null \
1247    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1248                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1249 then
1250   libc_cv_as_noexecstack=yes
1251 else
1252   libc_cv_as_noexecstack=no
1253 fi
1254 rm -f conftest*])
1255 if test $libc_cv_as_noexecstack = yes; then
1256   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1257 fi
1258 AC_SUBST(ASFLAGS_config)
1259
1260 AC_CACHE_CHECK(for -z combreloc,
1261                libc_cv_z_combreloc, [dnl
1262 cat > conftest.c <<EOF
1263 extern int bar (int);
1264 extern int mumble;
1265 int foo (void) { return bar (mumble); }
1266 EOF
1267 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1268                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1269                         -nostdlib -nostartfiles
1270                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1271 then
1272 dnl The following test is a bit weak.  We must use a tool which can test
1273 dnl cross-platform since the gcc used can be a cross compiler.  Without
1274 dnl introducing new options this is not easily doable.  Instead use a tool
1275 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1276 dnl look for a section named .rel.dyn or .rela.dyn.
1277   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1278     libc_cv_z_combreloc=yes
1279   else
1280     libc_cv_z_combreloc=no
1281   fi
1282 else
1283   libc_cv_z_combreloc=no
1284 fi
1285 rm -f conftest*])
1286 if test "$libc_cv_z_combreloc" = yes; then
1287   AC_DEFINE(HAVE_Z_COMBRELOC)
1288 fi
1289 AC_SUBST(libc_cv_z_combreloc)
1290
1291 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1292                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1293 AC_SUBST(libc_cv_z_execstack)
1294
1295 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1296                     [-Wl,--no-dynamic-linker],
1297                     [libc_cv_no_dynamic_linker=yes],
1298                     [libc_cv_no_dynamic_linker=no])
1299 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1300
1301 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1302 LIBC_TRY_CC_OPTION([-static-pie],
1303                    [libc_cv_static_pie=yes],
1304                    [libc_cv_static_pie=no])
1305 ])
1306 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1307
1308 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1309 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1310 ])
1311
1312 AC_SUBST(libc_cv_fpie)
1313
1314 AC_CACHE_CHECK(for --hash-style option,
1315                libc_cv_hashstyle, [dnl
1316 cat > conftest.c <<EOF
1317 int _start (void) { return 42; }
1318 EOF
1319 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1320                             -fPIC -shared -o conftest.so conftest.c
1321                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1322 then
1323   libc_cv_hashstyle=yes
1324 else
1325   libc_cv_hashstyle=no
1326 fi
1327 rm -f conftest*])
1328 AC_SUBST(libc_cv_hashstyle)
1329
1330 # The linker's default -shared behavior is good enough if it
1331 # does these things that our custom linker scripts ensure that
1332 # all allocated NOTE sections come first.
1333 if test "$use_default_link" = default; then
1334   AC_CACHE_CHECK([for sufficient default -shared layout],
1335                   libc_cv_use_default_link, [dnl
1336   libc_cv_use_default_link=no
1337   cat > conftest.s <<\EOF
1338           .section .note.a,"a",%note
1339           .balign 4
1340           .long 4,4,9
1341           .string "GNU"
1342           .string "foo"
1343           .section .note.b,"a",%note
1344           .balign 4
1345           .long 4,4,9
1346           .string "GNU"
1347           .string "bar"
1348 EOF
1349   if AC_TRY_COMMAND([dnl
1350   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1351        ac_try=`$READELF -S conftest.so | sed -n \
1352          ['${x;p;}
1353           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1354           t a
1355           b
1356           : a
1357           H']`
1358   then
1359     libc_seen_a=no libc_seen_b=no
1360     set -- $ac_try
1361     while test $# -ge 2 -a "$1" = NOTE; do
1362       case "$2" in
1363       .note.a) libc_seen_a=yes ;;
1364       .note.b) libc_seen_b=yes ;;
1365       esac
1366       shift 2
1367     done
1368     case "$libc_seen_a$libc_seen_b" in
1369     yesyes)
1370       libc_cv_use_default_link=yes
1371       ;;
1372     *)
1373       echo >&AS_MESSAGE_LOG_FD "\
1374 $libc_seen_a$libc_seen_b from:
1375 $ac_try"
1376       ;;
1377     esac
1378   fi
1379   rm -f conftest*])
1380   use_default_link=$libc_cv_use_default_link
1381 fi
1382
1383 AC_CACHE_CHECK(for GLOB_DAT reloc,
1384                libc_cv_has_glob_dat, [dnl
1385 cat > conftest.c <<EOF
1386 extern int mumble;
1387 int foo (void) { return mumble; }
1388 EOF
1389 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1390                         -fPIC -shared -o conftest.so conftest.c
1391                         -nostdlib -nostartfiles $no_ssp
1392                         1>&AS_MESSAGE_LOG_FD])
1393 then
1394 dnl look for GLOB_DAT relocation.
1395   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1396     libc_cv_has_glob_dat=yes
1397   else
1398     libc_cv_has_glob_dat=no
1399   fi
1400 else
1401   libc_cv_has_glob_dat=no
1402 fi
1403 rm -f conftest*])
1404 AC_SUBST(libc_cv_has_glob_dat)
1405
1406 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1407 if libc_cv_output_format=`
1408 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1409 then
1410   :
1411 else
1412   libc_cv_output_format=
1413 fi
1414 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1415 AC_SUBST(libc_cv_output_format)
1416
1417 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1418 cat > conftest.c <<EOF
1419 int foo;
1420 EOF
1421 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1422                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1423 then
1424   libc_cv_fno_toplevel_reorder=yes
1425 else
1426   libc_cv_fno_toplevel_reorder=no
1427 fi
1428 rm -f conftest*])
1429 if test $libc_cv_fno_toplevel_reorder = yes; then
1430   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1431 else
1432   fno_unit_at_a_time=-fno-unit-at-a-time
1433 fi
1434 AC_SUBST(fno_unit_at_a_time)
1435
1436 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1437 [dnl
1438 cat > conftest.c <<EOF
1439 __thread int i;
1440 void foo (void)
1441 {
1442   i = 10;
1443 }
1444 EOF
1445 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1446                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1447 then
1448   libc_cv_mtls_dialect_gnu2=yes
1449 else
1450   libc_cv_mtls_dialect_gnu2=no
1451 fi
1452 rm -f conftest*])
1453 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1454 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1455
1456 AC_CACHE_CHECK(whether cc puts quotes around section names,
1457                libc_cv_have_section_quotes,
1458                [cat > conftest.c <<EOF
1459                 static const int foo
1460                 __attribute__ ((section ("bar"))) = 1;
1461 EOF
1462                 if ${CC-cc} -S conftest.c -o conftest.s; then
1463                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1464                     libc_cv_have_section_quotes=yes
1465                   else
1466                     libc_cv_have_section_quotes=no
1467                   fi
1468                 else
1469                   libc_cv_have_section_quotes=unknown
1470                 fi
1471                 rm -f conftest.{c,s}
1472                 ])
1473 if test $libc_cv_have_section_quotes = yes; then
1474   AC_DEFINE(HAVE_SECTION_QUOTES)
1475 fi
1476
1477 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1478 cat > conftest.c <<\EOF
1479 void zero (void *x)
1480 {
1481   __builtin_memset (x, 0, 1000);
1482 }
1483 EOF
1484 dnl
1485 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1486 then
1487   libc_cv_gcc_builtin_memset=no
1488 else
1489   libc_cv_gcc_builtin_memset=yes
1490 fi
1491 rm -f conftest* ])
1492 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1493   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1494 fi
1495
1496 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1497 cat > conftest.c <<\EOF
1498 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1499 char *foo (const char *a, const char *b)
1500 {
1501   return __builtin_strstr (a, b);
1502 }
1503 EOF
1504 dnl
1505 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1506 then
1507   libc_cv_gcc_builtin_redirection=yes
1508 else
1509   libc_cv_gcc_builtin_redirection=no
1510 fi
1511 rm -f conftest* ])
1512 if test "$libc_cv_gcc_builtin_redirection" = no; then
1513   AC_MSG_ERROR([support for the symbol redirection needed])
1514 fi
1515
1516 dnl Determine how to disable generation of FMA instructions.
1517 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1518                libc_cv_cc_nofma, [dnl
1519 libc_cv_cc_nofma=
1520 for opt in -ffp-contract=off -mno-fused-madd; do
1521   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1522 done])
1523 AC_SUBST(libc_cv_cc_nofma)
1524
1525 if test -n "$submachine"; then
1526   AC_CACHE_CHECK([for compiler option for CPU variant],
1527                  libc_cv_cc_submachine, [dnl
1528   libc_cv_cc_submachine=no
1529   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1530     LIBC_TRY_CC_OPTION([$opt], [
1531       libc_cv_cc_submachine="$opt"
1532       break], [])
1533   done])
1534   if test "x$libc_cv_cc_submachine" = xno; then
1535     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1536   fi
1537 fi
1538 AC_SUBST(libc_cv_cc_submachine)
1539
1540 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1541 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1542 cat > conftest.c <<EOF
1543 void
1544 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1545 foo (void) {}
1546 EOF
1547 libc_cv_cc_loop_to_function=no
1548 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1549 then
1550   libc_cv_cc_loop_to_function=yes
1551 fi
1552 rm -f conftest*])
1553 if test $libc_cv_cc_loop_to_function = yes; then
1554   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1555 fi
1556 AC_SUBST(libc_cv_cc_loop_to_function)
1557
1558 dnl Check whether we have the gd library available.
1559 AC_MSG_CHECKING(for libgd)
1560 if test "$with_gd" != "no"; then
1561   old_CFLAGS="$CFLAGS"
1562   CFLAGS="$CFLAGS $libgd_include"
1563   old_LDFLAGS="$LDFLAGS"
1564   LDFLAGS="$LDFLAGS $libgd_ldflags"
1565   old_LIBS="$LIBS"
1566   LIBS="$LIBS -lgd -lpng -lz -lm"
1567   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1568   CFLAGS="$old_CFLAGS"
1569   LDFLAGS="$old_LDFLAGS"
1570   LIBS="$old_LIBS"
1571 else
1572   LIBGD=no
1573 fi
1574 AC_MSG_RESULT($LIBGD)
1575 AC_SUBST(LIBGD)
1576
1577 # SELinux detection
1578 if test x$with_selinux = xno ; then
1579   have_selinux=no;
1580 else
1581   # See if we have the SELinux library
1582   AC_CHECK_LIB(selinux, is_selinux_enabled,
1583                have_selinux=yes, have_selinux=no)
1584   if test x$with_selinux = xyes ; then
1585     if test x$have_selinux = xno ; then
1586       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1587     fi
1588   fi
1589 fi
1590 # Check if we're building with SELinux support.
1591 if test "x$have_selinux" = xyes; then
1592   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1593
1594   # See if we have the libaudit library
1595   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1596                have_libaudit=yes, have_libaudit=no)
1597   if test "x$have_libaudit" = xyes; then
1598     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1599   fi
1600   AC_SUBST(have_libaudit)
1601
1602   # See if we have the libcap library
1603   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1604   if test "x$have_libcap" = xyes; then
1605     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1606   fi
1607   AC_SUBST(have_libcap)
1608 fi
1609 AC_SUBST(have_selinux)
1610
1611 CPPUNDEFS=
1612 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1613 dnl Since we are building the implementations of the fortified functions here,
1614 dnl having the macro defined interacts very badly.
1615 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1616 [AC_TRY_COMPILE([], [
1617 #ifdef _FORTIFY_SOURCE
1618 # error bogon
1619 #endif],
1620                 [libc_cv_predef_fortify_source=no],
1621                 [libc_cv_predef_fortify_source=yes])])
1622 if test $libc_cv_predef_fortify_source = yes; then
1623   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1624 fi
1625 AC_SUBST(CPPUNDEFS)
1626
1627 # Some linkers on some architectures support __ehdr_start but with
1628 # bugs.  Make sure usage of it does not create relocations in the
1629 # output (as the linker should resolve them all for us).
1630 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1631                libc_cv_ehdr_start, [
1632 old_CFLAGS="$CFLAGS"
1633 old_LDFLAGS="$LDFLAGS"
1634 old_LIBS="$LIBS"
1635 CFLAGS="$CFLAGS -fPIC"
1636 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1637 LIBS=
1638 AC_LINK_IFELSE([AC_LANG_SOURCE([
1639 typedef struct {
1640   char foo;
1641   long val;
1642 } Ehdr;
1643 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1644 long ehdr (void) { return __ehdr_start.val; }
1645 ])],
1646                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1647                   libc_cv_ehdr_start=broken
1648                 else
1649                   libc_cv_ehdr_start=yes
1650                 fi], [libc_cv_ehdr_start=no])
1651 CFLAGS="$old_CFLAGS"
1652 LDFLAGS="$old_LDFLAGS"
1653 LIBS="$old_LIBS"
1654 ])
1655 if test "$libc_cv_ehdr_start" = yes; then
1656   AC_DEFINE([HAVE_EHDR_START])
1657 elif test "$libc_cv_ehdr_start" = broken; then
1658   AC_MSG_WARN([linker is broken -- you should upgrade])
1659 fi
1660
1661 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1662                libc_cv_builtin_trap, [dnl
1663 libc_cv_builtin_trap=no
1664 AC_TRY_COMPILE([], [__builtin_trap ()], [
1665 libc_undefs=`$NM -u conftest.o |
1666   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1667     2>&AS_MESSAGE_LOG_FD` || {
1668   AC_MSG_ERROR([confusing output from $NM -u])
1669 }
1670 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1671 if test -z "$libc_undefs"; then
1672   libc_cv_builtin_trap=yes
1673 fi])])
1674 if test $libc_cv_builtin_trap = yes; then
1675   AC_DEFINE([HAVE_BUILTIN_TRAP])
1676 fi
1677
1678 dnl C++ feature tests.
1679 AC_LANG_PUSH([C++])
1680
1681 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1682                libc_cv_cxx_thread_local, [
1683 old_CXXFLAGS="$CXXFLAGS"
1684 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1685 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1686 #include <thread>
1687
1688 // Compiler support.
1689 struct S
1690 {
1691   S ();
1692   ~S ();
1693 };
1694 thread_local S s;
1695 S * get () { return &s; }
1696
1697 // libstdc++ support.
1698 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1699 #error __cxa_thread_atexit_impl not supported
1700 #endif
1701 ])],
1702                [libc_cv_cxx_thread_local=yes],
1703                [libc_cv_cxx_thread_local=no])
1704 CXXFLAGS="$old_CXXFLAGS"
1705 ])
1706 AC_SUBST(libc_cv_cxx_thread_local)
1707
1708 AC_LANG_POP([C++])
1709 dnl End of C++ feature tests.
1710
1711 ### End of automated tests.
1712 ### Now run sysdeps configure fragments.
1713
1714 # They also can set these variables.
1715 use_ldconfig=no
1716 ldd_rewrite_script=no
1717 libc_cv_sysconfdir=$sysconfdir
1718 libc_cv_localstatedir=$localstatedir
1719 libc_cv_gcc_unwind_find_fde=no
1720 libc_cv_idn=no
1721
1722 # Iterate over all the sysdep directories we will use, running their
1723 # configure fragments.
1724 for dir in $sysnames; do
1725   case $dir in
1726     /*) dest=$dir ;;
1727     *)  dest=$srcdir/$dir ;;
1728   esac
1729   if test -r $dest/configure; then
1730     AC_MSG_RESULT(running configure fragment for $dir)
1731     . $dest/configure
1732   fi
1733 done
1734
1735 if test x"$build_mathvec" = xnotset; then
1736   build_mathvec=no
1737 fi
1738 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1739
1740 AC_SUBST(libc_extra_cflags)
1741 AC_SUBST(libc_extra_cppflags)
1742
1743 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1744   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1745 fi
1746 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1747
1748 # A sysdeps configure fragment can reset this if IFUNC is not actually
1749 # usable even though the assembler knows how to generate the symbol type.
1750 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1751   AC_DEFINE(HAVE_IFUNC)
1752 fi
1753
1754 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1755   AC_DEFINE(HAVE_GCC_IFUNC)
1756 fi
1757
1758 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1759 # configure fragment can override the value to prevent this AC_DEFINE.
1760 AC_SUBST(use_nscd)
1761 if test "x$use_nscd" != xno; then
1762   AC_DEFINE([USE_NSCD])
1763 fi
1764 if test "x$build_nscd" = xdefault; then
1765   build_nscd=$use_nscd
1766 fi
1767
1768 AC_SUBST(libc_cv_slibdir)
1769 AC_SUBST(libc_cv_rtlddir)
1770 AC_SUBST(libc_cv_complocaledir)
1771 AC_SUBST(libc_cv_sysconfdir)
1772 AC_SUBST(libc_cv_localstatedir)
1773 AC_SUBST(libc_cv_rootsbindir)
1774
1775 if test x$use_ldconfig = xyes; then
1776   AC_DEFINE(USE_LDCONFIG)
1777 fi
1778 AC_SUBST(use_ldconfig)
1779 AC_SUBST(ldd_rewrite_script)
1780
1781 AC_SUBST(static)
1782 AC_SUBST(shared)
1783
1784 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1785 [libc_cv_pic_default=yes
1786 cat > conftest.c <<EOF
1787 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1788 # error PIC is default.
1789 #endif
1790 EOF
1791 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1792   libc_cv_pic_default=no
1793 fi
1794 rm -f conftest.*])
1795 AC_SUBST(libc_cv_pic_default)
1796
1797 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1798 [libc_cv_cc_pie_default=yes
1799 cat > conftest.c <<EOF
1800 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1801 # error PIE is default.
1802 #endif
1803 EOF
1804 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1805   libc_cv_cc_pie_default=no
1806 fi
1807 rm -f conftest.*])
1808 libc_cv_pie_default=$libc_cv_cc_pie_default
1809 AC_SUBST(libc_cv_cc_pie_default)
1810 AC_SUBST(libc_cv_pie_default)
1811
1812 # Set the `multidir' variable by grabbing the variable from the compiler.
1813 # We do it once and save the result in a generated makefile.
1814 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1815 AC_SUBST(libc_cv_multidir)
1816
1817 if test "$static_pie" = yes; then
1818   # The linker must support --no-dynamic-linker.
1819   if test "$libc_cv_no_dynamic_linker" != yes; then
1820     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1821   fi
1822   # Default to PIE.
1823   libc_cv_pie_default=yes
1824   AC_DEFINE(ENABLE_STATIC_PIE)
1825 fi
1826 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1827
1828 AC_SUBST(profile)
1829 AC_SUBST(static_nss)
1830
1831 AC_SUBST(DEFINES)
1832
1833 dnl See sysdeps/mach/configure.ac for this variable.
1834 AC_SUBST(mach_interface_list)
1835
1836 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1837 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1838 AC_SUBST(VERSION)
1839 AC_SUBST(RELEASE)
1840
1841 AC_CONFIG_FILES([config.make Makefile])
1842 AC_CONFIG_COMMANDS([default],[[
1843 case $CONFIG_FILES in *config.make*)
1844 echo "$config_vars" >> config.make;;
1845 esac
1846 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1847 AC_OUTPUT