sysdeps/arm/setjmp.S

   1 /* setjmp for ARM.
   2    Copyright (C) 1997-2016 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <stap-probe.h>
  21 #include <bits/setjmp.h>
  22 #include <rtld-global-offsets.h>
  23 #include <arm-features.h>
  24
  25 ENTRY (__sigsetjmp)
  26 #ifdef PTR_MANGLE
  27         PTR_MANGLE_LOAD (a3, ip)
  28 #endif
  29         mov     ip, r0
  30
  31         /* setjmp probe expects sigsetjmp first argument (4@r0), second
  32            argument (-4@r1), and target address (4@r14), respectively.  */
  33         LIBC_PROBE (setjmp, 3, 4@r0, -4@r1, 4@r14)
  34
  35         /* Save sp and lr */
  36 #ifdef PTR_MANGLE
  37         mov     a4, sp
  38         PTR_MANGLE2 (a4, a4, a3)
  39         sfi_breg ip, \
  40         str     a4, [\B], #4
  41         PTR_MANGLE2 (a4, lr, a3)
  42         sfi_breg ip, \
  43         str     a4, [\B], #4
  44 #else
  45         sfi_breg ip, \
  46         str     sp, [\B], #4
  47         sfi_breg ip, \
  48         str     lr, [\B], #4
  49 #endif
  50         /* Save registers */
  51         sfi_breg ip, \
  52         stmia   \B!, JMP_BUF_REGLIST
  53
  54 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  55 # define NEED_HWCAP 1
  56 #endif
  57
  58 #ifdef NEED_HWCAP
  59         /* Check if we have a VFP unit.  */
  60 # if IS_IN (rtld)
  61         LDST_PCREL (ldr, a3, a4, \
  62                     C_SYMBOL_NAME(_rtld_local_ro) \
  63                     + RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
  64 # else
  65 #  ifdef SHARED
  66         LDR_GLOBAL (a3, a4, C_SYMBOL_NAME(_rtld_global_ro), \
  67                     RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
  68 #  else
  69         LDR_GLOBAL (a3, a4, C_SYMBOL_NAME(_dl_hwcap), 0)
  70 #  endif
  71 # endif
  72 #endif
  73
  74 #ifdef __SOFTFP__
  75         tst     a3, #HWCAP_ARM_VFP
  76         beq     .Lno_vfp
  77 #endif
  78
  79         /* Store the VFP registers.
  80            Don't use VFP instructions directly because this code
  81            is used in non-VFP multilibs.  */
  82         /* Following instruction is vstmia ip!, {d8-d15}.  */
  83         sfi_breg ip, \
  84         stc     p11, cr8, [\B], #64
  85 .Lno_vfp:
  86
  87 #ifndef ARM_ASSUME_NO_IWMMXT
  88         tst     a3, #HWCAP_ARM_IWMMXT
  89         beq     .Lno_iwmmxt
  90
  91         /* Save the call-preserved iWMMXt registers.  */
  92         /* Following instructions are wstrd wr10, [ip], #8 (etc.)  */
  93         sfi_breg r12, \
  94         stcl    p1, cr10, [\B], #8
  95         sfi_breg r12, \
  96         stcl    p1, cr11, [\B], #8
  97         sfi_breg r12, \
  98         stcl    p1, cr12, [\B], #8
  99         sfi_breg r12, \
 100         stcl    p1, cr13, [\B], #8
 101         sfi_breg r12, \
 102         stcl    p1, cr14, [\B], #8
 103         sfi_breg r12, \
 104         stcl    p1, cr15, [\B], #8
 105 .Lno_iwmmxt:
 106 #endif
 107
 108         /* Make a tail call to __sigjmp_save; it takes the same args.  */
 109         B       PLTJMP(C_SYMBOL_NAME(__sigjmp_save))
 110
 111 END (__sigsetjmp)
 112
 113 hidden_def (__sigsetjmp)